lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use warnings;
   9 use base qw(PublicInbox::Lock);
  10 use 5.010_001;
  11 use PublicInbox::SearchIdxShard;
  12 use PublicInbox::Eml;
  13 use PublicInbox::Git;
  14 use PublicInbox::Import;
  15 use PublicInbox::MID qw(mids references);
  16 use PublicInbox::ContentHash qw(content_hash content_digest);
  17 use PublicInbox::Inbox;
  18 use PublicInbox::OverIdx;
  19 use PublicInbox::Msgmap;
  20 use PublicInbox::Spawn qw(spawn popen_rd);
  21 use PublicInbox::SearchIdx;
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 use PublicInbox::MultiMidQueue;
  24 use IO::Handle; # ->autoflush
  25 use File::Temp qw(tempfile);
  26
  27 # an estimate of the post-packed size to the raw uncompressed size
  28 my $PACKING_FACTOR = 0.4;
  29
  30 # SATA storage lags behind what CPUs are capable of, so relying on
  31 # nproc(1) can be misleading and having extra Xapian shards is a
  32 # waste of FDs and space.  It can also lead to excessive IO latency
  33 # and slow things down.  Users on NVME or other fast storage can
  34 # use the NPROC env or switches in our script/public-inbox-* programs
  35 # to increase Xapian shards
  36 our $NPROC_MAX_DEFAULT = 4;
  37
  38 sub detect_nproc () {
  39         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  40                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  41         }
  42
  43         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  44         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  45                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  46         }
  47
  48         # should we bother with `sysctl hw.ncpu`?  Those only give
  49         # us total processor count, not online processor count.
  50         undef
  51 }
  52
  53 sub nproc_shards ($) {
  54         my ($creat_opt) = @_;
  55         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  56         $n //= $ENV{NPROC};
  57         if (!$n) {
  58                 # assume 2 cores if not detectable or zero
  59                 state $NPROC_DETECTED = detect_nproc() || 2;
  60                 $n = $NPROC_DETECTED;
  61                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  62         }
  63
  64         # subtract for the main process and git-fast-import
  65         $n -= 1;
  66         $n < 1 ? 1 : $n;
  67 }
  68
  69 sub count_shards ($) {
  70         my ($self) = @_;
  71         my $n = 0;
  72         my $xpfx = $self->{xpfx};
  73
  74         # always load existing shards in case core count changes:
  75         # Also, shard count may change while -watch is running
  76         # due to "xcpdb --reshard"
  77         if (-d $xpfx) {
  78                 my $XapianDatabase;
  79                 foreach my $shard (<$xpfx/*>) {
  80                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
  81                         $XapianDatabase //= do {
  82                                 require PublicInbox::Search;
  83                                 PublicInbox::Search::load_xapian();
  84                                 $PublicInbox::Search::X{Database};
  85                         };
  86                         eval {
  87                                 $XapianDatabase->new($shard)->close;
  88                                 $n++;
  89                         };
  90                 }
  91         }
  92         $n;
  93 }
  94
  95 sub new {
  96         # $creat may be any true value, or 0/undef.  A hashref is true,
  97         # and $creat->{nproc} may be set to an integer
  98         my ($class, $v2ibx, $creat) = @_;
  99         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
 100         my $dir = $v2ibx->assert_usable_dir;
 101         unless (-d $dir) {
 102                 if ($creat) {
 103                         require File::Path;
 104                         File::Path::mkpath($dir);
 105                 } else {
 106                         die "$dir does not exist\n";
 107                 }
 108         }
 109         $v2ibx->umask_prepare;
 110
 111         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
 112         my $self = {
 113                 -inbox => $v2ibx,
 114                 im => undef, #  PublicInbox::Import
 115                 parallel => 1,
 116                 transact_bytes => 0,
 117                 current_info => '',
 118                 xpfx => $xpfx,
 119                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3", 1),
 120                 lock_path => "$dir/inbox.lock",
 121                 # limit each git repo (epoch) to 1GB or so
 122                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 123                 last_commit => [], # git repo -> commit
 124         };
 125         $self->{shards} = count_shards($self) || nproc_shards($creat);
 126         $self->{index_max_size} = $v2ibx->{index_max_size};
 127         bless $self, $class;
 128 }
 129
 130 # public (for now?)
 131 sub init_inbox {
 132         my ($self, $shards, $skip_epoch) = @_;
 133         if (defined $shards) {
 134                 $self->{parallel} = 0 if $shards == 0;
 135                 $self->{shards} = $shards if $shards > 0;
 136         }
 137         $self->idx_init;
 138         my $epoch_max = -1;
 139         git_dir_latest($self, \$epoch_max);
 140         if (defined $skip_epoch && $epoch_max == -1) {
 141                 $epoch_max = $skip_epoch;
 142         }
 143         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 144         $self->done;
 145 }
 146
 147 # returns undef on duplicate or spam
 148 # mimics Import::add and wraps it for v2
 149 sub add {
 150         my ($self, $mime, $check_cb) = @_;
 151         $self->{-inbox}->with_umask(sub {
 152                 _add($self, $mime, $check_cb)
 153         });
 154 }
 155
 156 # indexes a message, returns true if checkpointing is needed
 157 sub do_idx ($$$$) {
 158         my ($self, $msgref, $mime, $smsg) = @_;
 159         $smsg->{ds} //= msg_datestamp($mime->header_obj, $self->{autime});
 160         $smsg->{ts} //= msg_timestamp($mime->header_obj, $self->{cotime});
 161         $self->{over}->add_overview($mime, $smsg);
 162         my $idx = idx_shard($self, $smsg->{num} % $self->{shards});
 163         $idx->index_raw($msgref, $mime, $smsg);
 164         my $n = $self->{transact_bytes} += $smsg->{bytes};
 165         $n >= ($PublicInbox::SearchIdx::BATCH_BYTES * $self->{shards});
 166 }
 167
 168 sub _add {
 169         my ($self, $mime, $check_cb) = @_;
 170
 171         # spam check:
 172         if ($check_cb) {
 173                 $mime = $check_cb->($mime) or return;
 174         }
 175
 176         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 177         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 178         # Xapian 1.3.2+ (released 2015-03-15).
 179         # For the most part, we can spawn git-fast-import without
 180         # leaking FDs to it...
 181         $self->idx_init;
 182
 183         my ($num, $mid0) = v2_num_for($self, $mime);
 184         defined $num or return; # duplicate
 185         defined $mid0 or die "BUG: $mid0 undefined\n";
 186         my $im = $self->importer;
 187         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 188         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 189         $cmt = $im->get_mark($cmt);
 190         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 191
 192         my $msgref = delete $smsg->{-raw_email};
 193         if (do_idx($self, $msgref, $mime, $smsg)) {
 194                 $self->checkpoint;
 195         }
 196
 197         $cmt;
 198 }
 199
 200 sub v2_num_for {
 201         my ($self, $mime) = @_;
 202         my $mids = mids($mime->header_obj);
 203         if (@$mids) {
 204                 my $mid = $mids->[0];
 205                 my $num = $self->{mm}->mid_insert($mid);
 206                 if (defined $num) { # common case
 207                         return ($num, $mid);
 208                 }
 209
 210                 # crap, Message-ID is already known, hope somebody just resent:
 211                 foreach my $m (@$mids) {
 212                         # read-only lookup now safe to do after above barrier
 213                         # easy, don't store duplicates
 214                         # note: do not add more diagnostic info here since
 215                         # it gets noisy on public-inbox-watch restarts
 216                         return () if content_exists($self, $mime, $m);
 217                 }
 218
 219                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 220                 # or NNTP article number), use that article number if it's
 221                 # not in Over.
 222                 my $altid = $self->{-inbox}->{altid};
 223                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 224                         my $num = $self->{mm}->num_for($mid);
 225
 226                         if (defined $num && !$self->{over}->get_art($num)) {
 227                                 return ($num, $mid);
 228                         }
 229                 }
 230
 231                 # very unlikely:
 232                 warn "<$mid> reused for mismatched content\n";
 233
 234                 # try the rest of the mids
 235                 for(my $i = $#$mids; $i >= 1; $i--) {
 236                         my $m = $mids->[$i];
 237                         $num = $self->{mm}->mid_insert($m);
 238                         if (defined $num) {
 239                                 warn "alternative <$m> for <$mid> found\n";
 240                                 return ($num, $m);
 241                         }
 242                 }
 243         }
 244         # none of the existing Message-IDs are good, generate a new one:
 245         v2_num_for_harder($self, $mime);
 246 }
 247
 248 sub v2_num_for_harder {
 249         my ($self, $mime) = @_;
 250
 251         my $hdr = $mime->header_obj;
 252         my $dig = content_digest($mime);
 253         my $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 254         my $num = $self->{mm}->mid_insert($mid0);
 255         unless (defined $num) {
 256                 # it's hard to spoof the last Received: header
 257                 my @recvd = $hdr->header_raw('Received');
 258                 $dig->add("Received: $_") foreach (@recvd);
 259                 $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 260                 $num = $self->{mm}->mid_insert($mid0);
 261
 262                 # fall back to a random Message-ID and give up determinism:
 263                 until (defined($num)) {
 264                         $dig->add(rand);
 265                         $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 266                         warn "using random Message-ID <$mid0> as fallback\n";
 267                         $num = $self->{mm}->mid_insert($mid0);
 268                 }
 269         }
 270         PublicInbox::Import::append_mid($hdr, $mid0);
 271         ($num, $mid0);
 272 }
 273
 274 sub idx_shard {
 275         my ($self, $shard_i) = @_;
 276         $self->{idx_shards}->[$shard_i];
 277 }
 278
 279 # idempotent
 280 sub idx_init {
 281         my ($self, $opt) = @_;
 282         return if $self->{idx_shards};
 283         my $ibx = $self->{-inbox};
 284
 285         # do not leak read-only FDs to child processes, we only have these
 286         # FDs for duplicate detection so they should not be
 287         # frequently activated.
 288         delete $ibx->{$_} foreach (qw(git mm search));
 289
 290         my $indexlevel = $ibx->{indexlevel};
 291         if ($indexlevel && $indexlevel eq 'basic') {
 292                 $self->{parallel} = 0;
 293         }
 294
 295         if ($self->{parallel}) {
 296                 pipe(my ($r, $w)) or die "pipe failed: $!";
 297                 # pipe for barrier notifications doesn't need to be big,
 298                 # 1031: F_SETPIPE_SZ
 299                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 300                 $self->{bnote} = [ $r, $w ];
 301                 $w->autoflush(1);
 302         }
 303
 304         my $over = $self->{over};
 305         $ibx->umask_prepare;
 306         $ibx->with_umask(sub {
 307                 $self->lock_acquire unless ($opt && $opt->{-skip_lock});
 308                 $over->create;
 309
 310                 # xcpdb can change shard count while -watch is idle
 311                 my $nshards = count_shards($self);
 312                 if ($nshards && $nshards != $self->{shards}) {
 313                         $self->{shards} = $nshards;
 314                 }
 315
 316                 # need to create all shards before initializing msgmap FD
 317                 my $max = $self->{shards} - 1;
 318
 319                 # idx_shards must be visible to all forked processes
 320                 my $idx = $self->{idx_shards} = [];
 321                 for my $i (0..$max) {
 322                         push @$idx, PublicInbox::SearchIdxShard->new($self, $i);
 323                 }
 324
 325                 # Now that all subprocesses are up, we can open the FDs
 326                 # for SQLite:
 327                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 328                         "$self->{-inbox}->{inboxdir}/msgmap.sqlite3", 1);
 329                 $mm->{dbh}->begin_work;
 330         });
 331 }
 332
 333 # returns an array mapping [ epoch => latest_commit ]
 334 # latest_commit may be undef if nothing was done to that epoch
 335 # $replace_map = { $object_id => $strref, ... }
 336 sub _replace_oids ($$$) {
 337         my ($self, $mime, $replace_map) = @_;
 338         $self->done;
 339         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 340         my $rewrites = []; # epoch => commit
 341         my $max = $self->{epoch_max};
 342
 343         unless (defined($max)) {
 344                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 345                 $self->{epoch_max} = $max;
 346         }
 347
 348         foreach my $i (0..$max) {
 349                 my $git_dir = "$pfx/$i.git";
 350                 -d $git_dir or next;
 351                 my $git = PublicInbox::Git->new($git_dir);
 352                 my $im = $self->import_init($git, 0, 1);
 353                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 354                 $im->done;
 355         }
 356         $rewrites;
 357 }
 358
 359 sub content_hashes ($) {
 360         my ($mime) = @_;
 361         my @chashes = ( content_hash($mime) );
 362
 363         # We still support Email::MIME, here, and
 364         # Email::MIME->as_string doesn't always round-trip, so we may
 365         # use a second content_hash
 366         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 367         push @chashes, $rt if $chashes[0] ne $rt;
 368         \@chashes;
 369 }
 370
 371 sub content_matches ($$) {
 372         my ($chashes, $existing) = @_;
 373         my $chash = content_hash($existing);
 374         foreach (@$chashes) {
 375                 return 1 if $_ eq $chash
 376         }
 377         0
 378 }
 379
 380 # used for removing or replacing (purging)
 381 sub rewrite_internal ($$;$$$) {
 382         my ($self, $old_mime, $cmt_msg, $new_mime, $sref) = @_;
 383         $self->idx_init;
 384         my ($im, $need_reindex, $replace_map);
 385         if ($sref) {
 386                 $replace_map = {}; # oid => sref
 387                 $need_reindex = [] if $new_mime;
 388         } else {
 389                 $im = $self->importer;
 390         }
 391         my $over = $self->{over};
 392         my $chashes = content_hashes($old_mime);
 393         my @removed;
 394         my $mids = mids($old_mime->header_obj);
 395
 396         # We avoid introducing new blobs into git since the raw content
 397         # can be slightly different, so we do not need the user-supplied
 398         # message now that we have the mids and content_hash
 399         $old_mime = undef;
 400         my $mark;
 401
 402         foreach my $mid (@$mids) {
 403                 my %gone; # num => [ smsg, $mime, raw ]
 404                 my ($id, $prev);
 405                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 406                         my $msg = get_blob($self, $smsg);
 407                         if (!defined($msg)) {
 408                                 warn "broken smsg for $mid\n";
 409                                 next; # continue
 410                         }
 411                         my $orig = $$msg;
 412                         my $cur = PublicInbox::Eml->new($msg);
 413                         if (content_matches($chashes, $cur)) {
 414                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 415                         }
 416                 }
 417                 my $n = scalar keys %gone;
 418                 next unless $n;
 419                 if ($n > 1) {
 420                         warn "BUG: multiple articles linked to <$mid>\n",
 421                                 join(',', sort keys %gone), "\n";
 422                 }
 423                 foreach my $num (keys %gone) {
 424                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 425                         # @removed should only be set once assuming
 426                         # no bugs in our deduplication code:
 427                         @removed = (undef, $mime, $smsg);
 428                         my $oid = $smsg->{blob};
 429                         if ($replace_map) {
 430                                 $replace_map->{$oid} = $sref;
 431                         } else {
 432                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 433                                 $removed[0] = $mark;
 434                         }
 435                         $orig = undef;
 436                         if ($need_reindex) { # ->replace
 437                                 push @$need_reindex, $smsg;
 438                         } else { # ->purge or ->remove
 439                                 $self->{mm}->num_delete($num);
 440                         }
 441                         unindex_oid_remote($self, $oid, $mid);
 442                 }
 443         }
 444
 445         if (defined $mark) {
 446                 my $cmt = $im->get_mark($mark);
 447                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 448         }
 449         if ($replace_map && scalar keys %$replace_map) {
 450                 my $rewrites = _replace_oids($self, $new_mime, $replace_map);
 451                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 452         }
 453         defined($mark) ? @removed : undef;
 454 }
 455
 456 # public (see PublicInbox::Import->remove), but note the 3rd element
 457 # (retval[2]) is not part of the stable API shared with Import->remove
 458 sub remove {
 459         my ($self, $mime, $cmt_msg) = @_;
 460         my @ret;
 461         $self->{-inbox}->with_umask(sub {
 462                 @ret = rewrite_internal($self, $mime, $cmt_msg);
 463         });
 464         defined($ret[0]) ? @ret : undef;
 465 }
 466
 467 sub _replace ($$;$$) {
 468         my ($self, $old_mime, $new_mime, $sref) = @_;
 469         my $rewritten = $self->{-inbox}->with_umask(sub {
 470                 rewrite_internal($self, $old_mime, undef, $new_mime, $sref);
 471         }) or return;
 472
 473         my $rewrites = $rewritten->{rewrites};
 474         # ->done is called if there are rewrites since we gc+prune from git
 475         $self->idx_init if @$rewrites;
 476
 477         for my $i (0..$#$rewrites) {
 478                 defined(my $cmt = $rewrites->[$i]) or next;
 479                 $self->{last_commit}->[$i] = $cmt;
 480         }
 481         $rewritten;
 482 }
 483
 484 # public
 485 sub purge {
 486         my ($self, $mime) = @_;
 487         my $rewritten = _replace($self, $mime, undef, \'') or return;
 488         $rewritten->{rewrites}
 489 }
 490
 491 # returns the git object_id of $fh, does not write the object to FS
 492 sub git_hash_raw ($$) {
 493         my ($self, $raw) = @_;
 494         # grab the expected OID we have to reindex:
 495         open my $tmp_fh, '+>', undef or die "failed to open tmp: $!";
 496         $tmp_fh->autoflush(1);
 497         print $tmp_fh $$raw or die "print \$tmp_fh: $!";
 498         sysseek($tmp_fh, 0, 0) or die "seek failed: $!";
 499
 500         my $git_dir = $self->{-inbox}->git->{git_dir};
 501         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 502         my $r = popen_rd($cmd, undef, { 0 => $tmp_fh });
 503         local $/ = "\n";
 504         chomp(my $oid = <$r>);
 505         close $r or die "git hash-object failed: $?";
 506         $oid =~ /\A[a-f0-9]{40}\z/ or die "OID not expected: $oid";
 507         $oid;
 508 }
 509
 510 sub _check_mids_match ($$$) {
 511         my ($old_list, $new_list, $hdrs) = @_;
 512         my %old_mids = map { $_ => 1 } @$old_list;
 513         my %new_mids = map { $_ => 1 } @$new_list;
 514         my @old = keys %old_mids;
 515         my @new = keys %new_mids;
 516         my $err = "$hdrs may not be changed when replacing\n";
 517         die $err if scalar(@old) != scalar(@new);
 518         delete @new_mids{@old};
 519         delete @old_mids{@new};
 520         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 521 }
 522
 523 # Changing Message-IDs or References with ->replace isn't supported.
 524 # The rules for dealing with messages with multiple or conflicting
 525 # Message-IDs are pretty complex and rethreading hasn't been fully
 526 # implemented, yet.
 527 sub check_mids_match ($$) {
 528         my ($old_mime, $new_mime) = @_;
 529         my $old = $old_mime->header_obj;
 530         my $new = $new_mime->header_obj;
 531         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 532         _check_mids_match(references($old), references($new),
 533                         'References/In-Reply-To');
 534 }
 535
 536 # public
 537 sub replace ($$$) {
 538         my ($self, $old_mime, $new_mime) = @_;
 539
 540         check_mids_match($old_mime, $new_mime);
 541
 542         # mutt will always add Content-Length:, Status:, Lines: when editing
 543         PublicInbox::Import::drop_unwanted_headers($new_mime);
 544
 545         my $raw = $new_mime->as_string;
 546         my $expect_oid = git_hash_raw($self, \$raw);
 547         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 548         my $need_reindex = $rewritten->{need_reindex};
 549
 550         # just in case we have bugs in deduplication code:
 551         my $n = scalar(@$need_reindex);
 552         if ($n > 1) {
 553                 my $list = join(', ', map {
 554                                         "$_->{num}: <$_->{mid}>"
 555                                 } @$need_reindex);
 556                 warn <<"";
 557 W: rewritten $n messages matching content of original message (expected: 1).
 558 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 559 W: $list
 560
 561         }
 562
 563         # make sure we really got the OID:
 564         my ($blob, $type, $bytes) = $self->{-inbox}->git->check($expect_oid);
 565         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 566
 567         # don't leak FDs to Xapian:
 568         $self->{-inbox}->git->cleanup;
 569
 570         # reindex modified messages:
 571         for my $smsg (@$need_reindex) {
 572                 my $new_smsg = bless {
 573                         blob => $blob,
 574                         bytes => $bytes,
 575                         num => $smsg->{num},
 576                         mid => $smsg->{mid},
 577                 }, 'PublicInbox::Smsg';
 578                 do_idx($self, \$raw, $new_mime, $new_smsg);
 579         }
 580         $rewritten->{rewrites};
 581 }
 582
 583 sub last_epoch_commit ($$;$) {
 584         my ($self, $i, $cmt) = @_;
 585         my $v = PublicInbox::Search::SCHEMA_VERSION();
 586         $self->{mm}->last_commit_xap($v, $i, $cmt);
 587 }
 588
 589 sub set_last_commits ($) {
 590         my ($self) = @_;
 591         defined(my $epoch_max = $self->{epoch_max}) or return;
 592         my $last_commit = $self->{last_commit};
 593         foreach my $i (0..$epoch_max) {
 594                 defined(my $cmt = $last_commit->[$i]) or next;
 595                 $last_commit->[$i] = undef;
 596                 last_epoch_commit($self, $i, $cmt);
 597         }
 598 }
 599
 600 sub barrier_init {
 601         my ($self, $n) = @_;
 602         $self->{bnote} or return;
 603         --$n;
 604         my $barrier = { map { $_ => 1 } (0..$n) };
 605 }
 606
 607 sub barrier_wait {
 608         my ($self, $barrier) = @_;
 609         my $bnote = $self->{bnote} or return;
 610         my $r = $bnote->[0];
 611         while (scalar keys %$barrier) {
 612                 defined(my $l = readline($r)) or die "EOF on barrier_wait: $!";
 613                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 614                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 615         }
 616 }
 617
 618 # public
 619 sub checkpoint ($;$) {
 620         my ($self, $wait) = @_;
 621
 622         if (my $im = $self->{im}) {
 623                 if ($wait) {
 624                         $im->barrier;
 625                 } else {
 626                         $im->checkpoint;
 627                 }
 628         }
 629         my $shards = $self->{idx_shards};
 630         if ($shards) {
 631                 my $dbh = $self->{mm}->{dbh};
 632
 633                 # SQLite msgmap data is second in importance
 634                 $dbh->commit;
 635
 636                 # SQLite overview is third
 637                 $self->{over}->commit_lazy;
 638
 639                 # Now deal with Xapian
 640                 if ($wait) {
 641                         my $barrier = $self->barrier_init(scalar @$shards);
 642
 643                         # each shard needs to issue a barrier command
 644                         $_->remote_barrier for @$shards;
 645
 646                         # wait for each Xapian shard
 647                         $self->barrier_wait($barrier);
 648                 } else {
 649                         $_->remote_commit for @$shards;
 650                 }
 651
 652                 # last_commit is special, don't commit these until
 653                 # remote shards are done:
 654                 $dbh->begin_work;
 655                 set_last_commits($self);
 656                 $dbh->commit;
 657
 658                 $dbh->begin_work;
 659         }
 660         $self->{transact_bytes} = 0;
 661 }
 662
 663 # issue a write barrier to ensure all data is visible to other processes
 664 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 665 # public
 666 sub barrier { checkpoint($_[0], 1) };
 667
 668 # public
 669 sub done {
 670         my ($self) = @_;
 671         my $im = delete $self->{im};
 672         $im->done if $im; # PublicInbox::Import::done
 673         checkpoint($self);
 674         my $mm = delete $self->{mm};
 675         $mm->{dbh}->commit if $mm;
 676         my $shards = delete $self->{idx_shards};
 677         if ($shards) {
 678                 $_->remote_close for @$shards;
 679         }
 680         $self->{over}->disconnect;
 681         delete $self->{bnote};
 682         $self->{transact_bytes} = 0;
 683         $self->lock_release if $shards;
 684         $self->{-inbox}->git->cleanup;
 685 }
 686
 687 sub fill_alternates ($$) {
 688         my ($self, $epoch) = @_;
 689
 690         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 691         my $all = "$self->{-inbox}->{inboxdir}/all.git";
 692
 693         unless (-d $all) {
 694                 PublicInbox::Import::init_bare($all);
 695         }
 696         my $info_dir = "$all/objects/info";
 697         my $alt = "$info_dir/alternates";
 698         my (%alt, $new);
 699         my $mode = 0644;
 700         if (-e $alt) {
 701                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 702                 $mode = (stat($fh))[2] & 07777;
 703
 704                 # we assign a sort score to every alternate and favor
 705                 # the newest (highest numbered) one when we
 706                 my $score;
 707                 my $other = 0; # in case admin adds non-epoch repos
 708                 %alt = map {;
 709                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 710                                 $score = $1 + 0;
 711                         } else {
 712                                 $score = --$other;
 713                         }
 714                         $_ => $score;
 715                 } split(/\n+/, do { local $/; <$fh> });
 716         }
 717
 718         foreach my $i (0..$epoch) {
 719                 my $dir = "../../git/$i.git/objects";
 720                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 721                         $alt{$dir} = $i;
 722                         $new = 1;
 723                 }
 724         }
 725         return unless $new;
 726
 727         my ($fh, $tmp) = tempfile('alt-XXXXXXXX', DIR => $info_dir);
 728         print $fh join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"
 729                 or die "print $tmp: $!\n";
 730         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 731         close $fh or die "close $tmp $!\n";
 732         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 733 }
 734
 735 sub git_init {
 736         my ($self, $epoch) = @_;
 737         my $git_dir = "$self->{-inbox}->{inboxdir}/git/$epoch.git";
 738         PublicInbox::Import::init_bare($git_dir);
 739         my @cmd = (qw/git config/, "--file=$git_dir/config",
 740                         'include.path', '../../all.git/config');
 741         PublicInbox::Import::run_die(\@cmd);
 742         fill_alternates($self, $epoch);
 743         $git_dir
 744 }
 745
 746 sub git_dir_latest {
 747         my ($self, $max) = @_;
 748         $$max = -1;
 749         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 750         return unless -d $pfx;
 751         my $latest;
 752         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 753         while (defined(my $git_dir = readdir($dh))) {
 754                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 755                 if ($1 > $$max) {
 756                         $$max = $1;
 757                         $latest = "$pfx/$git_dir";
 758                 }
 759         }
 760         $latest;
 761 }
 762
 763 sub importer {
 764         my ($self) = @_;
 765         my $im = $self->{im};
 766         if ($im) {
 767                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 768                         return $im;
 769                 } else {
 770                         $self->{im} = undef;
 771                         $im->done;
 772                         $im = undef;
 773                         $self->checkpoint;
 774                         my $git_dir = $self->git_init(++$self->{epoch_max});
 775                         my $git = PublicInbox::Git->new($git_dir);
 776                         return $self->import_init($git, 0);
 777                 }
 778         }
 779         my $epoch = 0;
 780         my $max;
 781         my $latest = git_dir_latest($self, \$max);
 782         if (defined $latest) {
 783                 my $git = PublicInbox::Git->new($latest);
 784                 my $packed_bytes = $git->packed_bytes;
 785                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 786
 787                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 788                         $epoch = $max + 1;
 789                 } else {
 790                         $self->{epoch_max} = $max;
 791                         return $self->import_init($git, $packed_bytes);
 792                 }
 793         }
 794         $self->{epoch_max} = $epoch;
 795         $latest = $self->git_init($epoch);
 796         $self->import_init(PublicInbox::Git->new($latest), 0);
 797 }
 798
 799 sub import_init {
 800         my ($self, $git, $packed_bytes, $tmp) = @_;
 801         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 802         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 803         $im->{lock_path} = undef;
 804         $im->{path_type} = 'v2';
 805         $self->{im} = $im unless $tmp;
 806         $im;
 807 }
 808
 809 # XXX experimental
 810 sub diff ($$$) {
 811         my ($mid, $cur, $new) = @_;
 812
 813         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 814         print $ah $cur->as_string or die "print: $!";
 815         close $ah or die "close: $!";
 816         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 817         PublicInbox::Import::drop_unwanted_headers($new);
 818         print $bh $new->as_string or die "print: $!";
 819         close $bh or die "close: $!";
 820         my $cmd = [ qw(diff -u), $an, $bn ];
 821         print STDERR "# MID conflict <$mid>\n";
 822         my $pid = spawn($cmd, undef, { 1 => 2 });
 823         waitpid($pid, 0) == $pid or die "diff did not finish";
 824         unlink($an, $bn);
 825 }
 826
 827 sub get_blob ($$) {
 828         my ($self, $smsg) = @_;
 829         if (my $im = $self->{im}) {
 830                 my $msg = $im->cat_blob($smsg->{blob});
 831                 return $msg if $msg;
 832         }
 833         # older message, should be in alternates
 834         my $ibx = $self->{-inbox};
 835         $ibx->msg_by_smsg($smsg);
 836 }
 837
 838 sub content_exists ($$$) {
 839         my ($self, $mime, $mid) = @_;
 840         my $over = $self->{over};
 841         my $chashes = content_hashes($mime);
 842         my ($id, $prev);
 843         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 844                 my $msg = get_blob($self, $smsg);
 845                 if (!defined($msg)) {
 846                         warn "broken smsg for $mid\n";
 847                         next;
 848                 }
 849                 my $cur = PublicInbox::Eml->new($msg);
 850                 return 1 if content_matches($chashes, $cur);
 851
 852                 # XXX DEBUG_DIFF is experimental and may be removed
 853                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 854         }
 855         undef;
 856 }
 857
 858 sub atfork_child {
 859         my ($self) = @_;
 860         my $fh = delete $self->{reindex_pipe};
 861         close $fh if $fh;
 862         if (my $shards = $self->{idx_shards}) {
 863                 $_->atfork_child foreach @$shards;
 864         }
 865         if (my $im = $self->{im}) {
 866                 $im->atfork_child;
 867         }
 868         die "unexpected mm" if $self->{mm};
 869         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 870         $self->{bnote}->[1];
 871 }
 872
 873 sub mark_deleted ($$$$) {
 874         my ($self, $sync, $git, $oid) = @_;
 875         return if PublicInbox::SearchIdx::too_big($self, $git, $oid);
 876         my $msgref = $git->cat_file($oid);
 877         my $mime = PublicInbox::Eml->new($$msgref);
 878         my $mids = mids($mime->header_obj);
 879         my $chash = content_hash($mime);
 880         foreach my $mid (@$mids) {
 881                 $sync->{D}->{"$mid\0$chash"} = $oid;
 882         }
 883 }
 884
 885 sub reindex_checkpoint ($$$) {
 886         my ($self, $sync, $git) = @_;
 887
 888         $git->cleanup;
 889         $sync->{mm_tmp}->atfork_prepare;
 890         $self->done; # release lock
 891
 892         if (my $pr = $sync->{-opt}->{-progress}) {
 893                 my ($bn) = (split('/', $git->{git_dir}))[-1];
 894                 $pr->("$bn ".sprintf($sync->{-regen_fmt}, $sync->{nr}));
 895         }
 896
 897         # allow -watch or -mda to write...
 898         $self->idx_init; # reacquire lock
 899         $sync->{mm_tmp}->atfork_parent;
 900 }
 901
 902 # only for a few odd messages with multiple Message-IDs
 903 sub reindex_oid_m ($$$$;$) {
 904         my ($self, $sync, $git, $oid, $regen_num) = @_;
 905         $self->{current_info} = "multi_mid $oid";
 906         my ($num, $mid0, $len);
 907         my $msgref = $git->cat_file($oid, \$len);
 908         my $mime = PublicInbox::Eml->new($$msgref);
 909         my $mids = mids($mime->header_obj);
 910         my $chash = content_hash($mime);
 911         die "BUG: reindex_oid_m called for <=1 mids" if scalar(@$mids) <= 1;
 912
 913         for my $mid (reverse @$mids) {
 914                 delete($sync->{D}->{"$mid\0$chash"}) and
 915                         die "BUG: reindex_oid should handle <$mid> delete";
 916         }
 917         my $over = $self->{over};
 918         for my $mid (reverse @$mids) {
 919                 ($num, $mid0) = $over->num_mid0_for_oid($oid, $mid);
 920                 next unless defined $num;
 921                 if (defined($regen_num) && $regen_num != $num) {
 922                         die "BUG: regen(#$regen_num) != over(#$num)";
 923                 }
 924         }
 925         unless (defined($num)) {
 926                 for my $mid (reverse @$mids) {
 927                         # is this a number we got before?
 928                         my $n = $sync->{mm_tmp}->num_for($mid);
 929                         next unless defined $n;
 930                         next if defined($regen_num) && $regen_num != $n;
 931                         ($num, $mid0) = ($n, $mid);
 932                         last;
 933                 }
 934         }
 935         if (defined($num)) {
 936                 $sync->{mm_tmp}->num_delete($num);
 937         } elsif (defined $regen_num) {
 938                 $num = $regen_num;
 939                 for my $mid (reverse @$mids) {
 940                         $self->{mm}->mid_set($num, $mid) == 1 or next;
 941                         $mid0 = $mid;
 942                         last;
 943                 }
 944                 unless (defined $mid0) {
 945                         warn "E: cannot regen #$num\n";
 946                         return;
 947                 }
 948         } else { # fixup bugs in old mirrors on reindex
 949                 for my $mid (reverse @$mids) {
 950                         $num = $self->{mm}->mid_insert($mid);
 951                         next unless defined $num;
 952                         $mid0 = $mid;
 953                         last;
 954                 }
 955                 if (defined $mid0) {
 956                         if ($sync->{reindex}) {
 957                                 warn "reindex added #$num <$mid0>\n";
 958                         }
 959                 } else {
 960                         warn "E: cannot find article #\n";
 961                         return;
 962                 }
 963         }
 964         $sync->{nr}++;
 965         my $smsg = bless {
 966                 bytes => $len,
 967                 num => $num,
 968                 blob => $oid,
 969                 mid => $mid0,
 970         }, 'PublicInbox::Smsg';
 971         if (do_idx($self, $msgref, $mime, $smsg)) {
 972                 reindex_checkpoint($self, $sync, $git);
 973         }
 974 }
 975
 976 sub check_unindexed ($$$) {
 977         my ($self, $num, $mid0) = @_;
 978         my $unindexed = $self->{unindexed} // {};
 979         my $n = delete($unindexed->{$mid0});
 980         defined $n or return;
 981         if ($n != $num) {
 982                 die "BUG: unindexed $n != $num <$mid0>\n";
 983         } else {
 984                 $self->{mm}->mid_set($num, $mid0);
 985         }
 986 }
 987
 988 sub multi_mid_q_push ($$$) {
 989         my ($self, $sync, $oid) = @_;
 990         my $multi_mid = $sync->{multi_mid} //= PublicInbox::MultiMidQueue->new;
 991         if ($sync->{reindex}) { # no regen on reindex
 992                 $multi_mid->push_oid($oid, $self);
 993         } else {
 994                 my $num = $sync->{regen}--;
 995                 die "BUG: ran out of article numbers" if $num <= 0;
 996                 $multi_mid->set_oid($num, $oid, $self);
 997         }
 998 }
 999
1000 sub reindex_oid ($$$$) {
1001         my ($self, $sync, $git, $oid) = @_;
1002         return if PublicInbox::SearchIdx::too_big($self, $git, $oid);
1003         my ($num, $mid0, $len);
1004         my $msgref = $git->cat_file($oid, \$len);
1005         return if $len == 0; # purged
1006         my $mime = PublicInbox::Eml->new($$msgref);
1007         my $mids = mids($mime->header_obj);
1008         my $chash = content_hash($mime);
1009
1010         if (scalar(@$mids) == 0) {
1011                 warn "E: $oid has no Message-ID, skipping\n";
1012                 return;
1013         } elsif (scalar(@$mids) == 1) {
1014                 my $mid = $mids->[0];
1015
1016                 # was the file previously marked as deleted?, skip if so
1017                 if (delete($sync->{D}->{"$mid\0$chash"})) {
1018                         if (!$sync->{reindex}) {
1019                                 $num = $sync->{regen}--;
1020                                 $self->{mm}->num_highwater($num);
1021                         }
1022                         return;
1023                 }
1024
1025                 # is this a number we got before?
1026                 $num = $sync->{mm_tmp}->num_for($mid);
1027                 if (defined $num) {
1028                         $mid0 = $mid;
1029                         check_unindexed($self, $num, $mid0);
1030                 } else {
1031                         $num = $sync->{regen}--;
1032                         die "BUG: ran out of article numbers" if $num <= 0;
1033                         if ($self->{mm}->mid_set($num, $mid) != 1) {
1034                                 warn "E: unable to assign $num => <$mid>\n";
1035                                 return;
1036                         }
1037                         $mid0 = $mid;
1038                 }
1039         } else { # multiple MIDs are a weird case:
1040                 my $del = 0;
1041                 for (@$mids) {
1042                         $del += delete($sync->{D}->{"$_\0$chash"}) // 0;
1043                 }
1044                 if ($del) {
1045                         unindex_oid_remote($self, $oid, $_) for @$mids;
1046                         # do not delete from {mm_tmp}, since another
1047                         # single-MID message may use it.
1048                 } else { # handle them at the end:
1049                         multi_mid_q_push($self, $sync, $oid);
1050                 }
1051                 return;
1052         }
1053         $sync->{mm_tmp}->mid_delete($mid0) or
1054                 die "failed to delete <$mid0> for article #$num\n";
1055         $sync->{nr}++;
1056         my $smsg = bless {
1057                 bytes => $len,
1058                 num => $num,
1059                 blob => $oid,
1060                 mid => $mid0,
1061         }, 'PublicInbox::Smsg';
1062         if (do_idx($self, $msgref, $mime, $smsg)) {
1063                 reindex_checkpoint($self, $sync, $git);
1064         }
1065 }
1066
1067 # only update last_commit for $i on reindex iff newer than current
1068 sub update_last_commit ($$$$) {
1069         my ($self, $git, $i, $cmt) = @_;
1070         my $last = last_epoch_commit($self, $i);
1071         if (defined $last && is_ancestor($git, $last, $cmt)) {
1072                 my @cmd = (qw(rev-list --count), "$last..$cmt");
1073                 chomp(my $n = $git->qx(@cmd));
1074                 return if $n ne '' && $n == 0;
1075         }
1076         last_epoch_commit($self, $i, $cmt);
1077 }
1078
1079 sub git_dir_n ($$) { "$_[0]->{-inbox}->{inboxdir}/git/$_[1].git" }
1080
1081 sub last_commits ($$) {
1082         my ($self, $epoch_max) = @_;
1083         my $heads = [];
1084         for (my $i = $epoch_max; $i >= 0; $i--) {
1085                 $heads->[$i] = last_epoch_commit($self, $i);
1086         }
1087         $heads;
1088 }
1089
1090 *is_ancestor = *PublicInbox::SearchIdx::is_ancestor;
1091
1092 # returns a revision range for git-log(1)
1093 sub log_range ($$$$$) {
1094         my ($self, $sync, $git, $i, $tip) = @_;
1095         my $opt = $sync->{-opt};
1096         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
1097         my $cur = $sync->{ranges}->[$i] or do {
1098                 $pr->("$i.git indexing all of $tip") if $pr;
1099                 return $tip; # all of it
1100         };
1101
1102         # fast equality check to avoid (v)fork+execve overhead
1103         if ($cur eq $tip) {
1104                 $sync->{ranges}->[$i] = undef;
1105                 return;
1106         }
1107
1108         my $range = "$cur..$tip";
1109         $pr->("$i.git checking contiguity... ") if $pr;
1110         if (is_ancestor($git, $cur, $tip)) { # common case
1111                 $pr->("OK\n") if $pr;
1112                 my $n = $git->qx(qw(rev-list --count), $range);
1113                 chomp($n);
1114                 if ($n == 0) {
1115                         $sync->{ranges}->[$i] = undef;
1116                         $pr->("$i.git has nothing new\n") if $pr;
1117                         return; # nothing to do
1118                 }
1119                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1120         } else {
1121                 $pr->("FAIL\n") if $pr;
1122                 warn <<"";
1123 discontiguous range: $range
1124 Rewritten history? (in $git->{git_dir})
1125
1126                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1127                 if ($base) {
1128                         $range = "$base..$tip";
1129                         warn "found merge-base: $base\n"
1130                 } else {
1131                         $range = $tip;
1132                         warn "discarding history at $cur\n";
1133                 }
1134                 warn <<"";
1135 reindexing $git->{git_dir} starting at
1136 $range
1137
1138                 $sync->{unindex_range}->{$i} = "$base..$cur";
1139         }
1140         $range;
1141 }
1142
1143 sub sync_prepare ($$$) {
1144         my ($self, $sync, $epoch_max) = @_;
1145         my $pr = $sync->{-opt}->{-progress};
1146         my $regen_max = 0;
1147         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
1148
1149         # reindex stops at the current heads and we later rerun index_sync
1150         # without {reindex}
1151         my $reindex_heads = last_commits($self, $epoch_max) if $sync->{reindex};
1152
1153         for (my $i = $epoch_max; $i >= 0; $i--) {
1154                 die 'BUG: already indexing!' if $self->{reindex_pipe};
1155                 my $git_dir = git_dir_n($self, $i);
1156                 -d $git_dir or next; # missing epochs are fine
1157                 my $git = PublicInbox::Git->new($git_dir);
1158                 if ($reindex_heads) {
1159                         $head = $reindex_heads->[$i] or next;
1160                 }
1161                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1162
1163                 next if $?; # new repo
1164                 my $range = log_range($self, $sync, $git, $i, $tip) or next;
1165                 $sync->{ranges}->[$i] = $range;
1166
1167                 # can't use 'rev-list --count' if we use --diff-filter
1168                 $pr->("$i.git counting $range ... ") if $pr;
1169                 my $n = 0;
1170                 my $fh = $git->popen(qw(log --pretty=tformat:%H
1171                                 --no-notes --no-color --no-renames
1172                                 --diff-filter=AM), $range, '--', 'm');
1173                 ++$n while <$fh>;
1174                 close $fh or die "git log failed: \$?=$?";
1175                 $pr->("$n\n") if $pr;
1176                 $regen_max += $n;
1177         }
1178
1179         return 0 if (!$regen_max && !keys(%{$self->{unindex_range}}));
1180
1181         # reindex should NOT see new commits anymore, if we do,
1182         # it's a problem and we need to notice it via die()
1183         my $pad = length($regen_max) + 1;
1184         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1185         $sync->{nr} = 0;
1186         return -1 if $sync->{reindex};
1187         $regen_max + $self->{mm}->num_highwater() || 0;
1188 }
1189
1190 sub unindex_oid_remote ($$$) {
1191         my ($self, $oid, $mid) = @_;
1192         $_->remote_remove($oid, $mid) foreach @{$self->{idx_shards}};
1193         $self->{over}->remove_oid($oid, $mid);
1194 }
1195
1196 sub unindex_oid ($$$;$) {
1197         my ($self, $git, $oid, $unindexed) = @_;
1198         my $mm = $self->{mm};
1199         my $msgref = $git->cat_file($oid);
1200         my $mime = PublicInbox::Eml->new($msgref);
1201         my $mids = mids($mime->header_obj);
1202         $mime = $msgref = undef;
1203         my $over = $self->{over};
1204         foreach my $mid (@$mids) {
1205                 my %gone;
1206                 my ($id, $prev);
1207                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1208                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1209                         1; # continue
1210                 }
1211                 my $n = scalar keys %gone;
1212                 next unless $n;
1213                 if ($n > 1) {
1214                         warn "BUG: multiple articles linked to $oid\n",
1215                                 join(',',sort keys %gone), "\n";
1216                 }
1217                 foreach my $num (keys %gone) {
1218                         if ($unindexed) {
1219                                 my $mid0 = $mm->mid_for($num);
1220                                 $unindexed->{$mid0} = $num;
1221                         }
1222                         $mm->num_delete($num);
1223                 }
1224                 unindex_oid_remote($self, $oid, $mid);
1225         }
1226 }
1227
1228 my $x40 = qr/[a-f0-9]{40}/;
1229 sub unindex ($$$$) {
1230         my ($self, $sync, $git, $unindex_range) = @_;
1231         my $unindexed = $self->{unindexed} ||= {}; # $mid0 => $num
1232         my $before = scalar keys %$unindexed;
1233         # order does not matter, here:
1234         my @cmd = qw(log --raw -r
1235                         --no-notes --no-color --no-abbrev --no-renames);
1236         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
1237         while (<$fh>) {
1238                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
1239                 unindex_oid($self, $git, $1, $unindexed);
1240         }
1241         delete $self->{reindex_pipe};
1242         close $fh or die "git log failed: \$?=$?";
1243
1244         return unless $sync->{-opt}->{prune};
1245         my $after = scalar keys %$unindexed;
1246         return if $before == $after;
1247
1248         # ensure any blob can not longer be accessed via dumb HTTP
1249         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1250                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1251 }
1252
1253 sub sync_ranges ($$$) {
1254         my ($self, $sync, $epoch_max) = @_;
1255         my $reindex = $sync->{reindex};
1256
1257         return last_commits($self, $epoch_max) unless $reindex;
1258         return [] if ref($reindex) ne 'HASH';
1259
1260         my $ranges = $reindex->{from}; # arrayref;
1261         if (ref($ranges) ne 'ARRAY') {
1262                 die 'BUG: $reindex->{from} not an ARRAY';
1263         }
1264         $ranges;
1265 }
1266
1267 sub index_epoch ($$$) {
1268         my ($self, $sync, $i) = @_;
1269
1270         my $git_dir = git_dir_n($self, $i);
1271         die 'BUG: already reindexing!' if $self->{reindex_pipe};
1272         -d $git_dir or return; # missing epochs are fine
1273         fill_alternates($self, $i);
1274         my $git = PublicInbox::Git->new($git_dir);
1275         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) {
1276                 unindex($self, $sync, $git, $unindex_range);
1277         }
1278         defined(my $range = $sync->{ranges}->[$i]) or return;
1279         if (my $pr = $sync->{-opt}->{-progress}) {
1280                 $pr->("$i.git indexing $range\n");
1281         }
1282
1283         my @cmd = qw(log --raw -r --pretty=tformat:%H.%at.%ct
1284                         --no-notes --no-color --no-abbrev --no-renames);
1285         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
1286         my $cmt;
1287         while (<$fh>) {
1288                 chomp;
1289                 $self->{current_info} = "$i.git $_";
1290                 if (/\A($x40)\.([0-9]+)\.([0-9]+)$/o) {
1291                         $cmt //= $1;
1292                         $self->{autime} = $2;
1293                         $self->{cotime} = $3;
1294                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
1295                         reindex_oid($self, $sync, $git, $1);
1296                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
1297                         mark_deleted($self, $sync, $git, $1);
1298                 }
1299         }
1300         close $fh or die "git log failed: \$?=$?";
1301         delete $self->{reindex_pipe};
1302         update_last_commit($self, $git, $i, $cmt) if defined $cmt;
1303 }
1304
1305 # public, called by public-inbox-index
1306 sub index_sync {
1307         my ($self, $opt) = @_;
1308         $opt ||= {};
1309         my $pr = $opt->{-progress};
1310         my $epoch_max;
1311         my $latest = git_dir_latest($self, \$epoch_max);
1312         return unless defined $latest;
1313         $self->idx_init($opt); # acquire lock
1314         my $sync = {
1315                 D => {}, # "$mid\0$chash" => $oid
1316                 unindex_range => {}, # EPOCH => oid_old..oid_new
1317                 reindex => $opt->{reindex},
1318                 -opt => $opt
1319         };
1320         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1321         $sync->{regen} = sync_prepare($self, $sync, $epoch_max);
1322
1323         if ($sync->{regen}) {
1324                 # tmp_clone seems to fail if inside a transaction, so
1325                 # we rollback here (because we opened {mm} for reading)
1326                 # Note: we do NOT rely on DBI transactions for atomicity;
1327                 # only for batch performance.
1328                 $self->{mm}->{dbh}->rollback;
1329                 $self->{mm}->{dbh}->begin_work;
1330                 $sync->{mm_tmp} = $self->{mm}->tmp_clone;
1331         }
1332
1333         # work backwards through history
1334         for (my $i = $epoch_max; $i >= 0; $i--) {
1335                 index_epoch($self, $sync, $i);
1336         }
1337
1338         # unindex is required for leftovers if "deletes" affect messages
1339         # in a previous fetch+index window:
1340         my $git;
1341         if (my @leftovers = values %{delete $sync->{D}}) {
1342                 $git = $self->{-inbox}->git;
1343                 for my $oid (@leftovers) {
1344                         $self->{current_info} = "leftover $oid";
1345                         unindex_oid($self, $git, $oid);
1346                 }
1347         }
1348         if (my $multi_mid = delete $sync->{multi_mid}) {
1349                 $git //= $self->{-inbox}->git;
1350                 my $min = $multi_mid->{min};
1351                 my $max = $multi_mid->{max};
1352                 if ($sync->{reindex}) {
1353                         # we may need to create new Message-IDs if mirrors
1354                         # were initially indexed with old versions
1355                         for (my $i = $max; $i >= $min; $i--) {
1356                                 my $oid;
1357                                 $oid = $multi_mid->get_oid($i, $self) or next;
1358                                 next unless defined $oid;
1359                                 reindex_oid_m($self, $sync, $git, $oid);
1360                         }
1361                 } else { # regen on initial index
1362                         for my $num ($min..$max) {
1363                                 my $oid;
1364                                 $oid = $multi_mid->get_oid($num, $self) or next;
1365                                 reindex_oid_m($self, $sync, $git, $oid, $num);
1366                         }
1367                 }
1368         }
1369         $git->cleanup if $git;
1370         $self->done;
1371
1372         if (my $nr = $sync->{nr}) {
1373                 my $pr = $sync->{-opt}->{-progress};
1374                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $nr)) if $pr;
1375         }
1376
1377         # reindex does not pick up new changes, so we rerun w/o it:
1378         if ($opt->{reindex}) {
1379                 my %again = %$opt;
1380                 $sync = undef;
1381                 delete @again{qw(reindex -skip_lock)};
1382                 index_sync($self, \%again);
1383         }
1384 }
1385
1386 1;