lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxShard;
  11 use PublicInbox::Eml;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids references);
  15 use PublicInbox::ContentHash qw(content_hash content_digest);
  16 use PublicInbox::InboxWritable;
  17 use PublicInbox::OverIdx;
  18 use PublicInbox::Msgmap;
  19 use PublicInbox::Spawn qw(spawn popen_rd);
  20 use PublicInbox::SearchIdx qw(log2stack crlf_adjust is_ancestor check_size);
  21 use IO::Handle; # ->autoflush
  22 use File::Temp ();
  23
  24 my $OID = qr/[a-f0-9]{40,}/;
  25 # an estimate of the post-packed size to the raw uncompressed size
  26 my $PACKING_FACTOR = 0.4;
  27
  28 # SATA storage lags behind what CPUs are capable of, so relying on
  29 # nproc(1) can be misleading and having extra Xapian shards is a
  30 # waste of FDs and space.  It can also lead to excessive IO latency
  31 # and slow things down.  Users on NVME or other fast storage can
  32 # use the NPROC env or switches in our script/public-inbox-* programs
  33 # to increase Xapian shards
  34 our $NPROC_MAX_DEFAULT = 4;
  35
  36 sub detect_nproc () {
  37         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  38         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  39                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  40         }
  41         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  42                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  43         }
  44
  45         # should we bother with `sysctl hw.ncpu`?  Those only give
  46         # us total processor count, not online processor count.
  47         undef
  48 }
  49
  50 sub nproc_shards ($) {
  51         my ($creat_opt) = @_;
  52         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  53         $n //= $ENV{NPROC};
  54         if (!$n) {
  55                 # assume 2 cores if not detectable or zero
  56                 state $NPROC_DETECTED = detect_nproc() || 2;
  57                 $n = $NPROC_DETECTED;
  58                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  59         }
  60
  61         # subtract for the main process and git-fast-import
  62         $n -= 1;
  63         $n < 1 ? 1 : $n;
  64 }
  65
  66 sub count_shards ($) {
  67         my ($self) = @_;
  68         $self->{ibx} ? do {
  69                 # always load existing shards in case core count changes:
  70                 # Also, shard count may change while -watch is running
  71                 my $srch = $self->{ibx}->search or return 0;
  72                 delete $self->{ibx}->{search};
  73                 $srch->{nshard} // 0
  74         } : $self->{nshard}; # self->{nshard} is for ExtSearchIdx
  75 }
  76
  77 sub new {
  78         # $creat may be any true value, or 0/undef.  A hashref is true,
  79         # and $creat->{nproc} may be set to an integer
  80         my ($class, $v2ibx, $creat) = @_;
  81         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  82         my $dir = $v2ibx->assert_usable_dir;
  83         unless (-d $dir) {
  84                 if ($creat) {
  85                         require File::Path;
  86                         File::Path::mkpath($dir);
  87                 } else {
  88                         die "$dir does not exist\n";
  89                 }
  90         }
  91         $v2ibx->umask_prepare;
  92
  93         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  94         my $self = {
  95                 ibx => $v2ibx,
  96                 im => undef, #  PublicInbox::Import
  97                 parallel => 1,
  98                 transact_bytes => 0,
  99                 total_bytes => 0,
 100                 current_info => '',
 101                 xpfx => $xpfx,
 102                 oidx => PublicInbox::OverIdx->new("$xpfx/over.sqlite3"),
 103                 lock_path => "$dir/inbox.lock",
 104                 # limit each git repo (epoch) to 1GB or so
 105                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 106                 last_commit => [], # git epoch -> commit
 107         };
 108         $self->{oidx}->{-no_fsync} = 1 if $v2ibx->{-no_fsync};
 109         $self->{shards} = count_shards($self) || nproc_shards($creat);
 110         bless $self, $class;
 111 }
 112
 113 # public (for now?)
 114 sub init_inbox {
 115         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 116         if (defined $shards) {
 117                 $self->{parallel} = 0 if $shards == 0;
 118                 $self->{shards} = $shards if $shards > 0;
 119         }
 120         $self->idx_init;
 121         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 122         my $epoch_max = -1;
 123         $self->{ibx}->git_dir_latest(\$epoch_max);
 124         if (defined $skip_epoch && $epoch_max == -1) {
 125                 $epoch_max = $skip_epoch;
 126         }
 127         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 128         $self->done;
 129 }
 130
 131 # returns undef on duplicate or spam
 132 # mimics Import::add and wraps it for v2
 133 sub add {
 134         my ($self, $eml, $check_cb) = @_;
 135         $self->{ibx}->with_umask(\&_add, $self, $eml, $check_cb);
 136 }
 137
 138 sub idx_shard ($$) {
 139         my ($self, $num) = @_;
 140         $self->{idx_shards}->[$num % scalar(@{$self->{idx_shards}})];
 141 }
 142
 143 # indexes a message, returns true if checkpointing is needed
 144 sub do_idx ($$$$) {
 145         my ($self, $msgref, $mime, $smsg) = @_;
 146         $smsg->{bytes} = $smsg->{raw_bytes} + crlf_adjust($$msgref);
 147         $self->{oidx}->add_overview($mime, $smsg);
 148         my $idx = idx_shard($self, $smsg->{num});
 149         $idx->index_raw($msgref, $mime, $smsg);
 150         my $n = $self->{transact_bytes} += $smsg->{raw_bytes};
 151         $n >= $self->{batch_bytes};
 152 }
 153
 154 sub _add {
 155         my ($self, $mime, $check_cb) = @_;
 156
 157         # spam check:
 158         if ($check_cb) {
 159                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 160         }
 161
 162         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 163         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 164         # Xapian 1.3.2+ (released 2015-03-15).
 165         # For the most part, we can spawn git-fast-import without
 166         # leaking FDs to it...
 167         $self->idx_init;
 168
 169         my ($num, $mid0) = v2_num_for($self, $mime);
 170         defined $num or return; # duplicate
 171         defined $mid0 or die "BUG: \$mid0 undefined\n";
 172         my $im = $self->importer;
 173         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 174         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 175         $cmt = $im->get_mark($cmt);
 176         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 177
 178         my $msgref = delete $smsg->{-raw_email};
 179         if (do_idx($self, $msgref, $mime, $smsg)) {
 180                 $self->checkpoint;
 181         }
 182
 183         $cmt;
 184 }
 185
 186 sub v2_num_for {
 187         my ($self, $mime) = @_;
 188         my $mids = mids($mime);
 189         if (@$mids) {
 190                 my $mid = $mids->[0];
 191                 my $num = $self->{mm}->mid_insert($mid);
 192                 if (defined $num) { # common case
 193                         return ($num, $mid);
 194                 }
 195
 196                 # crap, Message-ID is already known, hope somebody just resent:
 197                 foreach my $m (@$mids) {
 198                         # read-only lookup now safe to do after above barrier
 199                         # easy, don't store duplicates
 200                         # note: do not add more diagnostic info here since
 201                         # it gets noisy on public-inbox-watch restarts
 202                         return () if content_exists($self, $mime, $m);
 203                 }
 204
 205                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 206                 # or NNTP article number), use that article number if it's
 207                 # not in Over.
 208                 my $altid = $self->{ibx}->{altid};
 209                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 210                         my $num = $self->{mm}->num_for($mid);
 211
 212                         if (defined $num && !$self->{oidx}->get_art($num)) {
 213                                 return ($num, $mid);
 214                         }
 215                 }
 216
 217                 # very unlikely:
 218                 warn "<$mid> reused for mismatched content\n";
 219
 220                 # try the rest of the mids
 221                 for(my $i = $#$mids; $i >= 1; $i--) {
 222                         my $m = $mids->[$i];
 223                         $num = $self->{mm}->mid_insert($m);
 224                         if (defined $num) {
 225                                 warn "alternative <$m> for <$mid> found\n";
 226                                 return ($num, $m);
 227                         }
 228                 }
 229         }
 230         # none of the existing Message-IDs are good, generate a new one:
 231         v2_num_for_harder($self, $mime);
 232 }
 233
 234 sub v2_num_for_harder {
 235         my ($self, $eml) = @_;
 236
 237         my $dig = content_digest($eml);
 238         my $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 239         my $num = $self->{mm}->mid_insert($mid0);
 240         unless (defined $num) {
 241                 # it's hard to spoof the last Received: header
 242                 my @recvd = $eml->header_raw('Received');
 243                 $dig->add("Received: $_") foreach (@recvd);
 244                 $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 245                 $num = $self->{mm}->mid_insert($mid0);
 246
 247                 # fall back to a random Message-ID and give up determinism:
 248                 until (defined($num)) {
 249                         $dig->add(rand);
 250                         $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 251                         warn "using random Message-ID <$mid0> as fallback\n";
 252                         $num = $self->{mm}->mid_insert($mid0);
 253                 }
 254         }
 255         PublicInbox::Import::append_mid($eml, $mid0);
 256         ($num, $mid0);
 257 }
 258
 259 sub _idx_init { # with_umask callback
 260         my ($self, $opt) = @_;
 261         $self->lock_acquire unless $opt && $opt->{-skip_lock};
 262         $self->{oidx}->create;
 263
 264         # xcpdb can change shard count while -watch is idle
 265         my $nshards = count_shards($self);
 266         $self->{shards} = $nshards if $nshards && $nshards != $self->{shards};
 267         $self->{batch_bytes} = $opt->{batch_size} //
 268                                 $PublicInbox::SearchIdx::BATCH_BYTES;
 269         $self->{batch_bytes} *= $self->{shards} if $self->{parallel};
 270
 271         # need to create all shards before initializing msgmap FD
 272         # idx_shards must be visible to all forked processes
 273         my $max = $self->{shards} - 1;
 274         my $idx = $self->{idx_shards} = [];
 275         push @$idx, PublicInbox::SearchIdxShard->new($self, $_) for (0..$max);
 276         my $ibx = $self->{ibx} or return; # ExtIdxSearch
 277
 278         # Now that all subprocesses are up, we can open the FDs
 279         # for SQLite:
 280         my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 281                                 "$ibx->{inboxdir}/msgmap.sqlite3",
 282                                 $ibx->{-no_fsync} ? 2 : 1);
 283         $mm->{dbh}->begin_work;
 284 }
 285
 286 sub parallel_init ($$) {
 287         my ($self, $indexlevel) = @_;
 288         if (($indexlevel // 'full') eq 'basic') {
 289                 $self->{parallel} = 0;
 290         } else {
 291                 pipe(my ($r, $w)) or die "pipe failed: $!";
 292                 # pipe for barrier notifications doesn't need to be big,
 293                 # 1031: F_SETPIPE_SZ
 294                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 295                 $self->{bnote} = [ $r, $w ];
 296                 $w->autoflush(1);
 297         }
 298 }
 299
 300 # idempotent
 301 sub idx_init {
 302         my ($self, $opt) = @_;
 303         return if $self->{idx_shards};
 304         my $ibx = $self->{ibx};
 305
 306         # do not leak read-only FDs to child processes, we only have these
 307         # FDs for duplicate detection so they should not be
 308         # frequently activated.
 309         delete @$ibx{qw(mm search)};
 310         $ibx->git->cleanup;
 311
 312         parallel_init($self, $ibx->{indexlevel});
 313         $ibx->umask_prepare;
 314         $ibx->with_umask(\&_idx_init, $self, $opt);
 315 }
 316
 317 # returns an array mapping [ epoch => latest_commit ]
 318 # latest_commit may be undef if nothing was done to that epoch
 319 # $replace_map = { $object_id => $strref, ... }
 320 sub _replace_oids ($$$) {
 321         my ($self, $mime, $replace_map) = @_;
 322         $self->done;
 323         my $ibx = $self->{ibx};
 324         my $pfx = "$ibx->{inboxdir}/git";
 325         my $rewrites = []; # epoch => commit
 326         my $max = $self->{epoch_max};
 327
 328         unless (defined($max)) {
 329                 defined(my $latest = $ibx->git_dir_latest(\$max)) or return;
 330                 $self->{epoch_max} = $max;
 331         }
 332
 333         foreach my $i (0..$max) {
 334                 my $git_dir = "$pfx/$i.git";
 335                 -d $git_dir or next;
 336                 my $git = PublicInbox::Git->new($git_dir);
 337                 my $im = $self->import_init($git, 0, 1);
 338                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 339                 $im->done;
 340         }
 341         $rewrites;
 342 }
 343
 344 sub content_hashes ($) {
 345         my ($mime) = @_;
 346         my @chashes = ( content_hash($mime) );
 347
 348         # We still support Email::MIME, here, and
 349         # Email::MIME->as_string doesn't always round-trip, so we may
 350         # use a second content_hash
 351         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 352         push @chashes, $rt if $chashes[0] ne $rt;
 353         \@chashes;
 354 }
 355
 356 sub content_matches ($$) {
 357         my ($chashes, $existing) = @_;
 358         my $chash = content_hash($existing);
 359         foreach (@$chashes) {
 360                 return 1 if $_ eq $chash
 361         }
 362         0
 363 }
 364
 365 # used for removing or replacing (purging)
 366 sub rewrite_internal ($$;$$$) {
 367         my ($self, $old_eml, $cmt_msg, $new_eml, $sref) = @_;
 368         $self->idx_init;
 369         my ($im, $need_reindex, $replace_map);
 370         if ($sref) {
 371                 $replace_map = {}; # oid => sref
 372                 $need_reindex = [] if $new_eml;
 373         } else {
 374                 $im = $self->importer;
 375         }
 376         my $oidx = $self->{oidx};
 377         my $chashes = content_hashes($old_eml);
 378         my $removed = [];
 379         my $mids = mids($old_eml);
 380
 381         # We avoid introducing new blobs into git since the raw content
 382         # can be slightly different, so we do not need the user-supplied
 383         # message now that we have the mids and content_hash
 384         $old_eml = undef;
 385         my $mark;
 386
 387         foreach my $mid (@$mids) {
 388                 my %gone; # num => [ smsg, $mime, raw ]
 389                 my ($id, $prev);
 390                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 391                         my $msg = get_blob($self, $smsg);
 392                         if (!defined($msg)) {
 393                                 warn "broken smsg for $mid\n";
 394                                 next; # continue
 395                         }
 396                         my $orig = $$msg;
 397                         my $cur = PublicInbox::Eml->new($msg);
 398                         if (content_matches($chashes, $cur)) {
 399                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 400                         }
 401                 }
 402                 my $n = scalar keys %gone;
 403                 next unless $n;
 404                 if ($n > 1) {
 405                         warn "BUG: multiple articles linked to <$mid>\n",
 406                                 join(',', sort keys %gone), "\n";
 407                 }
 408                 foreach my $num (keys %gone) {
 409                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 410                         # $removed should only be set once assuming
 411                         # no bugs in our deduplication code:
 412                         $removed = [ undef, $mime, $smsg ];
 413                         my $oid = $smsg->{blob};
 414                         if ($replace_map) {
 415                                 $replace_map->{$oid} = $sref;
 416                         } else {
 417                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 418                                 $removed->[0] = $mark;
 419                         }
 420                         $orig = undef;
 421                         if ($need_reindex) { # ->replace
 422                                 push @$need_reindex, $smsg;
 423                         } else { # ->purge or ->remove
 424                                 $self->{mm}->num_delete($num);
 425                         }
 426                         unindex_oid_aux($self, $oid, $mid);
 427                 }
 428         }
 429
 430         if (defined $mark) {
 431                 my $cmt = $im->get_mark($mark);
 432                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 433         }
 434         if ($replace_map && scalar keys %$replace_map) {
 435                 my $rewrites = _replace_oids($self, $new_eml, $replace_map);
 436                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 437         }
 438         defined($mark) ? $removed : undef;
 439 }
 440
 441 # public (see PublicInbox::Import->remove), but note the 3rd element
 442 # (retval[2]) is not part of the stable API shared with Import->remove
 443 sub remove {
 444         my ($self, $eml, $cmt_msg) = @_;
 445         my $r = $self->{ibx}->with_umask(\&rewrite_internal,
 446                                                 $self, $eml, $cmt_msg);
 447         defined($r) && defined($r->[0]) ? @$r: undef;
 448 }
 449
 450 sub _replace ($$;$$) {
 451         my ($self, $old_eml, $new_eml, $sref) = @_;
 452         my $arg = [ $self, $old_eml, undef, $new_eml, $sref ];
 453         my $rewritten = $self->{ibx}->with_umask(\&rewrite_internal,
 454                         $self, $old_eml, undef, $new_eml, $sref) or return;
 455
 456         my $rewrites = $rewritten->{rewrites};
 457         # ->done is called if there are rewrites since we gc+prune from git
 458         $self->idx_init if @$rewrites;
 459
 460         for my $i (0..$#$rewrites) {
 461                 defined(my $cmt = $rewrites->[$i]) or next;
 462                 $self->{last_commit}->[$i] = $cmt;
 463         }
 464         $rewritten;
 465 }
 466
 467 # public
 468 sub purge {
 469         my ($self, $mime) = @_;
 470         my $rewritten = _replace($self, $mime, undef, \'') or return;
 471         $rewritten->{rewrites}
 472 }
 473
 474 # returns the git object_id of $fh, does not write the object to FS
 475 sub git_hash_raw ($$) {
 476         my ($self, $raw) = @_;
 477         # grab the expected OID we have to reindex:
 478         pipe(my($in, $w)) or die "pipe: $!";
 479         my $git_dir = $self->git->{git_dir};
 480         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 481         my $r = popen_rd($cmd, undef, { 0 => $in });
 482         print $w $$raw or die "print \$w: $!";
 483         close $w or die "close \$w: $!";
 484         local $/ = "\n";
 485         chomp(my $oid = <$r>);
 486         close $r or die "git hash-object failed: $?";
 487         $oid =~ /\A$OID\z/ or die "OID not expected: $oid";
 488         $oid;
 489 }
 490
 491 sub _check_mids_match ($$$) {
 492         my ($old_list, $new_list, $hdrs) = @_;
 493         my %old_mids = map { $_ => 1 } @$old_list;
 494         my %new_mids = map { $_ => 1 } @$new_list;
 495         my @old = keys %old_mids;
 496         my @new = keys %new_mids;
 497         my $err = "$hdrs may not be changed when replacing\n";
 498         die $err if scalar(@old) != scalar(@new);
 499         delete @new_mids{@old};
 500         delete @old_mids{@new};
 501         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 502 }
 503
 504 # Changing Message-IDs or References with ->replace isn't supported.
 505 # The rules for dealing with messages with multiple or conflicting
 506 # Message-IDs are pretty complex and rethreading hasn't been fully
 507 # implemented, yet.
 508 sub check_mids_match ($$) {
 509         my ($old, $new) = @_;
 510         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 511         _check_mids_match(references($old), references($new),
 512                         'References/In-Reply-To');
 513 }
 514
 515 # public
 516 sub replace ($$$) {
 517         my ($self, $old_mime, $new_mime) = @_;
 518
 519         check_mids_match($old_mime, $new_mime);
 520
 521         # mutt will always add Content-Length:, Status:, Lines: when editing
 522         PublicInbox::Import::drop_unwanted_headers($new_mime);
 523
 524         my $raw = $new_mime->as_string;
 525         my $expect_oid = git_hash_raw($self, \$raw);
 526         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 527         my $need_reindex = $rewritten->{need_reindex};
 528
 529         # just in case we have bugs in deduplication code:
 530         my $n = scalar(@$need_reindex);
 531         if ($n > 1) {
 532                 my $list = join(', ', map {
 533                                         "$_->{num}: <$_->{mid}>"
 534                                 } @$need_reindex);
 535                 warn <<"";
 536 W: rewritten $n messages matching content of original message (expected: 1).
 537 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 538 W: $list
 539
 540         }
 541
 542         # make sure we really got the OID:
 543         my ($blob, $type, $bytes) = $self->git->check($expect_oid);
 544         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 545
 546         # don't leak FDs to Xapian:
 547         $self->git->cleanup;
 548
 549         # reindex modified messages:
 550         for my $smsg (@$need_reindex) {
 551                 my $new_smsg = bless {
 552                         blob => $blob,
 553                         raw_bytes => $bytes,
 554                         num => $smsg->{num},
 555                         mid => $smsg->{mid},
 556                 }, 'PublicInbox::Smsg';
 557                 my $sync = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 558                 $new_smsg->populate($new_mime, $sync);
 559                 do_idx($self, \$raw, $new_mime, $new_smsg);
 560         }
 561         $rewritten->{rewrites};
 562 }
 563
 564 sub last_epoch_commit ($$;$) {
 565         my ($self, $i, $cmt) = @_;
 566         my $v = PublicInbox::Search::SCHEMA_VERSION();
 567         $self->{mm}->last_commit_xap($v, $i, $cmt);
 568 }
 569
 570 sub set_last_commits ($) {
 571         my ($self) = @_;
 572         defined(my $epoch_max = $self->{epoch_max}) or return;
 573         my $last_commit = $self->{last_commit};
 574         foreach my $i (0..$epoch_max) {
 575                 defined(my $cmt = $last_commit->[$i]) or next;
 576                 $last_commit->[$i] = undef;
 577                 last_epoch_commit($self, $i, $cmt);
 578         }
 579 }
 580
 581 sub barrier_init {
 582         my ($self, $n) = @_;
 583         $self->{bnote} or return;
 584         --$n;
 585         my $barrier = { map { $_ => 1 } (0..$n) };
 586 }
 587
 588 sub barrier_wait {
 589         my ($self, $barrier) = @_;
 590         my $bnote = $self->{bnote} or return;
 591         my $r = $bnote->[0];
 592         while (scalar keys %$barrier) {
 593                 defined(my $l = readline($r)) or die "EOF on barrier_wait: $!";
 594                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 595                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 596         }
 597 }
 598
 599 # public
 600 sub checkpoint ($;$) {
 601         my ($self, $wait) = @_;
 602
 603         if (my $im = $self->{im}) {
 604                 if ($wait) {
 605                         $im->barrier;
 606                 } else {
 607                         $im->checkpoint;
 608                 }
 609         }
 610         my $shards = $self->{idx_shards};
 611         if ($shards) {
 612                 my $dbh = $self->{mm}->{dbh};
 613
 614                 # SQLite msgmap data is second in importance
 615                 $dbh->commit;
 616
 617                 # SQLite overview is third
 618                 $self->{oidx}->commit_lazy;
 619
 620                 # Now deal with Xapian
 621                 if ($wait) {
 622                         my $barrier = $self->barrier_init(scalar @$shards);
 623
 624                         # each shard needs to issue a barrier command
 625                         $_->shard_barrier for @$shards;
 626
 627                         # wait for each Xapian shard
 628                         $self->barrier_wait($barrier);
 629                 } else {
 630                         $_->shard_commit for @$shards;
 631                 }
 632
 633                 # last_commit is special, don't commit these until
 634                 # Xapian shards are done:
 635                 $dbh->begin_work;
 636                 set_last_commits($self);
 637                 $dbh->commit;
 638
 639                 $dbh->begin_work;
 640         }
 641         $self->{total_bytes} += $self->{transact_bytes};
 642         $self->{transact_bytes} = 0;
 643 }
 644
 645 # issue a write barrier to ensure all data is visible to other processes
 646 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 647 # public
 648 sub barrier { checkpoint($_[0], 1) };
 649
 650 # true if locked and active
 651 sub active { !!$_[0]->{im} }
 652
 653 # public
 654 sub done {
 655         my ($self) = @_;
 656         my $err = '';
 657         if (my $im = delete $self->{im}) {
 658                 eval { $im->done }; # PublicInbox::Import::done
 659                 $err .= "import done: $@\n" if $@;
 660         }
 661         if (!$err) {
 662                 eval { checkpoint($self) };
 663                 $err .= "checkpoint: $@\n" if $@;
 664         }
 665         if (my $mm = delete $self->{mm}) {
 666                 my $m = $err ? 'rollback' : 'commit';
 667                 eval { $mm->{dbh}->$m };
 668                 $err .= "msgmap $m: $@\n" if $@;
 669         }
 670         my $shards = delete $self->{idx_shards};
 671         if ($shards) {
 672                 for (@$shards) {
 673                         eval { $_->shard_close };
 674                         $err .= "shard close: $@\n" if $@;
 675                 }
 676         }
 677         eval { $self->{oidx}->dbh_close };
 678         $err .= "over close: $@\n" if $@;
 679         delete $self->{bnote};
 680         my $nbytes = $self->{total_bytes};
 681         $self->{total_bytes} = 0;
 682         $self->lock_release(!!$nbytes) if $shards;
 683         $self->git->cleanup;
 684         die $err if $err;
 685 }
 686
 687 sub write_alternates ($$$) {
 688         my ($info_dir, $mode, $out) = @_;
 689         my $fh = File::Temp->new(TEMPLATE => 'alt-XXXXXXXX', DIR => $info_dir);
 690         my $tmp = $fh->filename;
 691         print $fh @$out or die "print $tmp: $!\n";
 692         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 693         close $fh or die "close $tmp $!\n";
 694         my $alt = "$info_dir/alternates";
 695         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 696         $fh->unlink_on_destroy(0);
 697 }
 698
 699 sub fill_alternates ($$) {
 700         my ($self, $epoch) = @_;
 701
 702         my $pfx = "$self->{ibx}->{inboxdir}/git";
 703         my $all = "$self->{ibx}->{inboxdir}/all.git";
 704         PublicInbox::Import::init_bare($all) unless -d $all;
 705         my $info_dir = "$all/objects/info";
 706         my $alt = "$info_dir/alternates";
 707         my (%alt, $new);
 708         my $mode = 0644;
 709         if (-e $alt) {
 710                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 711                 $mode = (stat($fh))[2] & 07777;
 712
 713                 # we assign a sort score to every alternate and favor
 714                 # the newest (highest numbered) one because loose objects
 715                 # require scanning epochs and only the latest epoch is
 716                 # expected to see loose objects
 717                 my $score;
 718                 my $other = 0; # in case admin adds non-epoch repos
 719                 %alt = map {;
 720                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 721                                 $score = $1 + 0;
 722                         } else {
 723                                 $score = --$other;
 724                         }
 725                         $_ => $score;
 726                 } split(/\n+/, do { local $/; <$fh> });
 727         }
 728
 729         foreach my $i (0..$epoch) {
 730                 my $dir = "../../git/$i.git/objects";
 731                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 732                         $alt{$dir} = $i;
 733                         $new = 1;
 734                 }
 735         }
 736         return unless $new;
 737         write_alternates($info_dir, $mode,
 738                 [join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"]);
 739 }
 740
 741 sub git_init {
 742         my ($self, $epoch) = @_;
 743         my $git_dir = "$self->{ibx}->{inboxdir}/git/$epoch.git";
 744         PublicInbox::Import::init_bare($git_dir);
 745         my @cmd = (qw/git config/, "--file=$git_dir/config",
 746                         'include.path', '../../all.git/config');
 747         PublicInbox::Import::run_die(\@cmd);
 748         fill_alternates($self, $epoch);
 749         $git_dir
 750 }
 751
 752 sub importer {
 753         my ($self) = @_;
 754         my $im = $self->{im};
 755         if ($im) {
 756                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 757                         return $im;
 758                 } else {
 759                         $self->{im} = undef;
 760                         $im->done;
 761                         $im = undef;
 762                         $self->checkpoint;
 763                         my $git_dir = $self->git_init(++$self->{epoch_max});
 764                         my $git = PublicInbox::Git->new($git_dir);
 765                         return $self->import_init($git, 0);
 766                 }
 767         }
 768         my $epoch = 0;
 769         my $max;
 770         my $latest = $self->{ibx}->git_dir_latest(\$max);
 771         if (defined $latest) {
 772                 my $git = PublicInbox::Git->new($latest);
 773                 my $packed_bytes = $git->packed_bytes;
 774                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 775
 776                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 777                         $epoch = $max + 1;
 778                 } else {
 779                         $self->{epoch_max} = $max;
 780                         return $self->import_init($git, $packed_bytes);
 781                 }
 782         }
 783         $self->{epoch_max} = $epoch;
 784         $latest = $self->git_init($epoch);
 785         $self->import_init(PublicInbox::Git->new($latest), 0);
 786 }
 787
 788 sub import_init {
 789         my ($self, $git, $packed_bytes, $tmp) = @_;
 790         my $im = PublicInbox::Import->new($git, undef, undef, $self->{ibx});
 791         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 792         $im->{lock_path} = undef;
 793         $im->{path_type} = 'v2';
 794         $self->{im} = $im unless $tmp;
 795         $im;
 796 }
 797
 798 # XXX experimental
 799 sub diff ($$$) {
 800         my ($mid, $cur, $new) = @_;
 801
 802         my $ah = File::Temp->new(TEMPLATE => 'email-cur-XXXXXXXX', TMPDIR => 1);
 803         print $ah $cur->as_string or die "print: $!";
 804         $ah->flush or die "flush: $!";
 805         PublicInbox::Import::drop_unwanted_headers($new);
 806         my $bh = File::Temp->new(TEMPLATE => 'email-new-XXXXXXXX', TMPDIR => 1);
 807         print $bh $new->as_string or die "print: $!";
 808         $bh->flush or die "flush: $!";
 809         my $cmd = [ qw(diff -u), $ah->filename, $bh->filename ];
 810         print STDERR "# MID conflict <$mid>\n";
 811         my $pid = spawn($cmd, undef, { 1 => 2 });
 812         waitpid($pid, 0) == $pid or die "diff did not finish";
 813 }
 814
 815 sub get_blob ($$) {
 816         my ($self, $smsg) = @_;
 817         if (my $im = $self->{im}) {
 818                 my $msg = $im->cat_blob($smsg->{blob});
 819                 return $msg if $msg;
 820         }
 821         # older message, should be in alternates
 822         $self->{ibx}->msg_by_smsg($smsg);
 823 }
 824
 825 sub content_exists ($$$) {
 826         my ($self, $mime, $mid) = @_;
 827         my $oidx = $self->{oidx};
 828         my $chashes = content_hashes($mime);
 829         my ($id, $prev);
 830         while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 831                 my $msg = get_blob($self, $smsg);
 832                 if (!defined($msg)) {
 833                         warn "broken smsg for $mid\n";
 834                         next;
 835                 }
 836                 my $cur = PublicInbox::Eml->new($msg);
 837                 return 1 if content_matches($chashes, $cur);
 838
 839                 # XXX DEBUG_DIFF is experimental and may be removed
 840                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 841         }
 842         undef;
 843 }
 844
 845 sub atfork_child {
 846         my ($self) = @_;
 847         if (my $shards = $self->{idx_shards}) {
 848                 $_->atfork_child foreach @$shards;
 849         }
 850         if (my $im = $self->{im}) {
 851                 $im->atfork_child;
 852         }
 853         die "unexpected mm" if $self->{mm};
 854         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 855         $self->{bnote}->[1];
 856 }
 857
 858 sub reindex_checkpoint ($$) {
 859         my ($self, $sync) = @_;
 860
 861         $self->git->cleanup; # *async_wait
 862         ${$sync->{need_checkpoint}} = 0;
 863         my $mm_tmp = $sync->{mm_tmp};
 864         $mm_tmp->atfork_prepare if $mm_tmp;
 865         $self->done; # release lock
 866
 867         if (my $pr = $sync->{-opt}->{-progress}) {
 868                 $pr->(sprintf($sync->{-regen_fmt}, ${$sync->{nr}}));
 869         }
 870
 871         # allow -watch or -mda to write...
 872         $self->idx_init($sync->{-opt}); # reacquire lock
 873         $mm_tmp->atfork_parent if $mm_tmp;
 874 }
 875
 876 sub index_oid { # cat_async callback
 877         my ($bref, $oid, $type, $size, $arg) = @_;
 878         return if $size == 0; # purged
 879         my ($num, $mid0);
 880         my $eml = PublicInbox::Eml->new($$bref);
 881         my $mids = mids($eml);
 882         my $chash = content_hash($eml);
 883         my $self = $arg->{v2w};
 884
 885         if (scalar(@$mids) == 0) {
 886                 warn "E: $oid has no Message-ID, skipping\n";
 887                 return;
 888         }
 889
 890         # {unindexed} is unlikely
 891         if ((my $unindexed = $arg->{unindexed}) && scalar(@$mids) == 1) {
 892                 $num = delete($unindexed->{$mids->[0]});
 893                 if (defined $num) {
 894                         $mid0 = $mids->[0];
 895                         $self->{mm}->mid_set($num, $mid0);
 896                         delete($arg->{unindexed}) if !keys(%$unindexed);
 897                 }
 898         }
 899         if (!defined($num)) { # reuse if reindexing (or duplicates)
 900                 my $oidx = $self->{oidx};
 901                 for my $mid (@$mids) {
 902                         ($num, $mid0) = $oidx->num_mid0_for_oid($oid, $mid);
 903                         last if defined $num;
 904                 }
 905         }
 906         $mid0 //= do { # is this a number we got before?
 907                 $num = $arg->{mm_tmp}->num_for($mids->[0]);
 908                 defined($num) ? $mids->[0] : undef;
 909         };
 910         if (!defined($num)) {
 911                 for (my $i = $#$mids; $i >= 1; $i--) {
 912                         $num = $arg->{mm_tmp}->num_for($mids->[$i]);
 913                         if (defined($num)) {
 914                                 $mid0 = $mids->[$i];
 915                                 last;
 916                         }
 917                 }
 918         }
 919         if (defined($num)) {
 920                 $arg->{mm_tmp}->num_delete($num);
 921         } else { # never seen
 922                 $num = $self->{mm}->mid_insert($mids->[0]);
 923                 if (defined($num)) {
 924                         $mid0 = $mids->[0];
 925                 } else { # rare, try the rest of them, backwards
 926                         for (my $i = $#$mids; $i >= 1; $i--) {
 927                                 $num = $self->{mm}->mid_insert($mids->[$i]);
 928                                 if (defined($num)) {
 929                                         $mid0 = $mids->[$i];
 930                                         last;
 931                                 }
 932                         }
 933                 }
 934         }
 935         if (!defined($num)) {
 936                 warn "E: $oid <", join('> <', @$mids), "> is a duplicate\n";
 937                 return;
 938         }
 939         ++${$arg->{nr}};
 940         my $smsg = bless {
 941                 raw_bytes => $size,
 942                 num => $num,
 943                 blob => $oid,
 944                 mid => $mid0,
 945         }, 'PublicInbox::Smsg';
 946         $smsg->populate($eml, $arg);
 947         if (do_idx($self, $bref, $eml, $smsg)) {
 948                 ${$arg->{need_checkpoint}} = 1;
 949         }
 950 }
 951
 952 # only update last_commit for $i on reindex iff newer than current
 953 sub update_last_commit {
 954         my ($self, $git, $i, $cmt) = @_;
 955         my $last = last_epoch_commit($self, $i);
 956         if (defined $last && is_ancestor($git, $last, $cmt)) {
 957                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 958                 chomp(my $n = $git->qx(@cmd));
 959                 return if $n ne '' && $n == 0;
 960         }
 961         last_epoch_commit($self, $i, $cmt);
 962 }
 963
 964 sub last_commits ($$) {
 965         my ($self, $epoch_max) = @_;
 966         my $heads = [];
 967         for (my $i = $epoch_max; $i >= 0; $i--) {
 968                 $heads->[$i] = last_epoch_commit($self, $i);
 969         }
 970         $heads;
 971 }
 972
 973 # returns a revision range for git-log(1)
 974 sub log_range ($$$$) {
 975         my ($sync, $git, $i, $tip) = @_;
 976         my $opt = $sync->{-opt};
 977         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
 978         my $cur = $sync->{ranges}->[$i] or do {
 979                 $pr->("$i.git indexing all of $tip\n") if $pr;
 980                 return $tip; # all of it
 981         };
 982
 983         # fast equality check to avoid (v)fork+execve overhead
 984         if ($cur eq $tip) {
 985                 $sync->{ranges}->[$i] = undef;
 986                 return;
 987         }
 988
 989         my $range = "$cur..$tip";
 990         $pr->("$i.git checking contiguity... ") if $pr;
 991         if (is_ancestor($git, $cur, $tip)) { # common case
 992                 $pr->("OK\n") if $pr;
 993                 my $n = $git->qx(qw(rev-list --count), $range);
 994                 chomp($n);
 995                 if ($n == 0) {
 996                         $sync->{ranges}->[$i] = undef;
 997                         $pr->("$i.git has nothing new\n") if $pr;
 998                         return; # nothing to do
 999                 }
1000                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1001         } else {
1002                 $pr->("FAIL\n") if $pr;
1003                 warn <<"";
1004 discontiguous range: $range
1005 Rewritten history? (in $git->{git_dir})
1006
1007                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1008                 if ($base) {
1009                         $range = "$base..$tip";
1010                         warn "found merge-base: $base\n"
1011                 } else {
1012                         $range = $tip;
1013                         warn "discarding history at $cur\n";
1014                 }
1015                 warn <<"";
1016 reindexing $git->{git_dir} starting at
1017 $range
1018
1019                 $sync->{unindex_range}->{$i} = "$base..$cur";
1020         }
1021         $range;
1022 }
1023
1024 sub sync_prepare ($$$) {
1025         my ($self, $sync, $epoch_max) = @_;
1026         my $pr = $sync->{-opt}->{-progress};
1027         my $regen_max = 0;
1028         my $head = $sync->{ibx}->{ref_head} || 'HEAD';
1029
1030         # reindex stops at the current heads and we later rerun index_sync
1031         # without {reindex}
1032         my $reindex_heads = $self->last_commits($epoch_max) if $sync->{reindex};
1033
1034         for (my $i = $epoch_max; $i >= 0; $i--) {
1035                 my $git_dir = $sync->{ibx}->git_dir_n($i);
1036                 -d $git_dir or next; # missing epochs are fine
1037                 my $git = PublicInbox::Git->new($git_dir);
1038                 if ($reindex_heads) {
1039                         $head = $reindex_heads->[$i] or next;
1040                 }
1041                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1042
1043                 next if $?; # new repo
1044                 my $range = log_range($sync, $git, $i, $tip) or next;
1045                 # can't use 'rev-list --count' if we use --diff-filter
1046                 $pr->("$i.git counting $range ... ") if $pr;
1047                 # Don't bump num_highwater on --reindex by using {D}.
1048                 # We intentionally do NOT use {D} in the non-reindex case
1049                 # because we want NNTP article number gaps from unindexed
1050                 # messages to show up in mirrors, too.
1051                 $sync->{D} //= $sync->{reindex} ? {} : undef; # OID_BIN => NR
1052                 my $stk = log2stack($sync, $git, $range, $sync->{ibx});
1053                 my $nr = $stk ? $stk->num_records : 0;
1054                 $pr->("$nr\n") if $pr;
1055                 $sync->{stacks}->[$i] = $stk if $stk;
1056                 $regen_max += $nr;
1057         }
1058
1059         # XXX this should not happen unless somebody bypasses checks in
1060         # our code and blindly injects "d" file history into git repos
1061         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
1062                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
1063                 my $arg = { v2w => $self };
1064                 for my $oid (@leftovers) {
1065                         $oid = unpack('H*', $oid);
1066                         $self->{current_info} = "leftover $oid";
1067                         $self->git->cat_async($oid, \&unindex_oid, $arg);
1068                 }
1069                 $self->git->cat_async_wait;
1070         }
1071         if (!$regen_max) {
1072                 $sync->{-regen_fmt} = "%u/?\n";
1073                 return 0;
1074         }
1075
1076         # reindex should NOT see new commits anymore, if we do,
1077         # it's a problem and we need to notice it via die()
1078         my $pad = length($regen_max) + 1;
1079         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1080         $sync->{nr} = \(my $nr = 0);
1081         return -1 if $sync->{reindex};
1082         $regen_max + $self->{mm}->num_highwater() || 0;
1083 }
1084
1085 sub unindex_oid_aux ($$$) {
1086         my ($self, $oid, $mid) = @_;
1087         my @removed = $self->{oidx}->remove_oid($oid, $mid);
1088         for my $num (@removed) {
1089                 my $idx = idx_shard($self, $num);
1090                 $idx->shard_remove($oid, $num);
1091         }
1092 }
1093
1094 sub unindex_oid ($$;$) { # git->cat_async callback
1095         my ($bref, $oid, $type, $size, $sync) = @_;
1096         my $self = $sync->{v2w};
1097         my $unindexed = $sync->{in_unindex} ? $sync->{unindexed} : undef;
1098         my $mm = $self->{mm};
1099         my $mids = mids(PublicInbox::Eml->new($bref));
1100         undef $$bref;
1101         my $oidx = $self->{oidx};
1102         foreach my $mid (@$mids) {
1103                 my %gone;
1104                 my ($id, $prev);
1105                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
1106                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1107                 }
1108                 my $n = scalar(keys(%gone)) or next;
1109                 if ($n > 1) {
1110                         warn "BUG: multiple articles linked to $oid\n",
1111                                 join(',',sort keys %gone), "\n";
1112                 }
1113                 foreach my $num (keys %gone) {
1114                         if ($unindexed) {
1115                                 my $mid0 = $mm->mid_for($num);
1116                                 $unindexed->{$mid0} = $num;
1117                         }
1118                         $mm->num_delete($num);
1119                 }
1120                 unindex_oid_aux($self, $oid, $mid);
1121         }
1122 }
1123
1124 sub git { $_[0]->{ibx}->git }
1125
1126 # this is rare, it only happens when we get discontiguous history in
1127 # a mirror because the source used -purge or -edit
1128 sub unindex_epoch ($$$$) {
1129         my ($self, $sync, $git, $unindex_range) = @_;
1130         my $unindexed = $sync->{unindexed} //= {}; # $mid0 => $num
1131         my $before = scalar keys %$unindexed;
1132         # order does not matter, here:
1133         my @cmd = qw(log --raw -r
1134                         --no-notes --no-color --no-abbrev --no-renames);
1135         my $fh = $git->popen(@cmd, $unindex_range);
1136         local $sync->{in_unindex} = 1;
1137         while (<$fh>) {
1138                 /\A:\d{6} 100644 $OID ($OID) [AM]\tm$/o or next;
1139                 $self->git->cat_async($1, \&unindex_oid, $sync);
1140         }
1141         close $fh or die "git log failed: \$?=$?";
1142         $self->git->cat_async_wait;
1143
1144         return unless $sync->{-opt}->{prune};
1145         my $after = scalar keys %$unindexed;
1146         return if $before == $after;
1147
1148         # ensure any blob can not longer be accessed via dumb HTTP
1149         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1150                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1151 }
1152
1153 sub sync_ranges ($$$) {
1154         my ($self, $sync, $epoch_max) = @_;
1155         my $reindex = $sync->{reindex};
1156
1157         return last_commits($self, $epoch_max) unless $reindex;
1158         return [] if ref($reindex) ne 'HASH';
1159
1160         my $ranges = $reindex->{from}; # arrayref;
1161         if (ref($ranges) ne 'ARRAY') {
1162                 die 'BUG: $reindex->{from} not an ARRAY';
1163         }
1164         $ranges;
1165 }
1166
1167 sub index_xap_only { # git->cat_async callback
1168         my ($bref, $oid, $type, $size, $smsg) = @_;
1169         my $self = $smsg->{v2w};
1170         my $idx = idx_shard($self, $smsg->{num});
1171         $smsg->{raw_bytes} = $size;
1172         $idx->index_raw($bref, undef, $smsg);
1173         $self->{transact_bytes} += $size;
1174 }
1175
1176 sub index_xap_step ($$$;$) {
1177         my ($self, $sync, $beg, $step) = @_;
1178         my $end = $sync->{art_end};
1179         return if $beg > $end; # nothing to do
1180
1181         $step //= $self->{shards};
1182         my $ibx = $self->{ibx};
1183         if (my $pr = $sync->{-opt}->{-progress}) {
1184                 $pr->("Xapian indexlevel=$ibx->{indexlevel} ".
1185                         "$beg..$end (% $step)\n");
1186         }
1187         for (my $num = $beg; $num <= $end; $num += $step) {
1188                 my $smsg = $ibx->over->get_art($num) or next;
1189                 $smsg->{v2w} = $self;
1190                 $ibx->git->cat_async($smsg->{blob}, \&index_xap_only, $smsg);
1191                 if ($self->{transact_bytes} >= $self->{batch_bytes}) {
1192                         ${$sync->{nr}} = $num;
1193                         reindex_checkpoint($self, $sync);
1194                 }
1195         }
1196 }
1197
1198 sub index_epoch ($$$) {
1199         my ($self, $sync, $i) = @_;
1200
1201         my $git_dir = $sync->{ibx}->git_dir_n($i);
1202         -d $git_dir or return; # missing epochs are fine
1203         my $git = PublicInbox::Git->new($git_dir);
1204         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) { # rare
1205                 unindex_epoch($self, $sync, $git, $unindex_range);
1206         }
1207         defined(my $stk = $sync->{stacks}->[$i]) or return;
1208         $sync->{stacks}->[$i] = undef;
1209         my $all = $self->git;
1210         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
1211                 $self->{current_info} = "$i.git $oid";
1212                 if ($f eq 'm') {
1213                         my $arg = { %$sync, autime => $at, cotime => $ct };
1214                         if ($sync->{max_size}) {
1215                                 $all->check_async($oid, \&check_size, $arg);
1216                         } else {
1217                                 $all->cat_async($oid, \&index_oid, $arg);
1218                         }
1219                 } elsif ($f eq 'd') {
1220                         $all->cat_async($oid, \&unindex_oid, $sync);
1221                 }
1222                 if (${$sync->{need_checkpoint}}) {
1223                         reindex_checkpoint($self, $sync);
1224                 }
1225         }
1226         $all->async_wait_all;
1227         $self->update_last_commit($git, $i, $stk->{latest_cmt});
1228 }
1229
1230 sub xapian_only {
1231         my ($self, $opt, $sync, $art_beg) = @_;
1232         my $seq = $opt->{sequential_shard};
1233         $art_beg //= 0;
1234         local $self->{parallel} = 0 if $seq;
1235         $self->idx_init($opt); # acquire lock
1236         if (my $art_end = $self->{ibx}->mm->max) {
1237                 $sync //= {
1238                         need_checkpoint => \(my $bool = 0),
1239                         -opt => $opt,
1240                         v2w => $self,
1241                         nr => \(my $nr = 0),
1242                         -regen_fmt => "%u/?\n",
1243                 };
1244                 $sync->{art_end} = $art_end;
1245                 if ($seq || !$self->{parallel}) {
1246                         my $shard_end = $self->{shards} - 1;
1247                         for my $i (0..$shard_end) {
1248                                 index_xap_step($self, $sync, $art_beg + $i);
1249                                 if ($i != $shard_end) {
1250                                         reindex_checkpoint($self, $sync);
1251                                 }
1252                         }
1253                 } else { # parallel (maybe)
1254                         index_xap_step($self, $sync, $art_beg, 1);
1255                 }
1256         }
1257         $self->git->cat_async_wait;
1258         $self->done;
1259 }
1260
1261 # public, called by public-inbox-index
1262 sub index_sync {
1263         my ($self, $opt) = @_;
1264         $opt //= {};
1265         return xapian_only($self, $opt) if $opt->{xapian_only};
1266
1267         my $pr = $opt->{-progress};
1268         my $epoch_max;
1269         my $latest = $self->{ibx}->git_dir_latest(\$epoch_max);
1270         return unless defined $latest;
1271
1272         my $seq = $opt->{sequential_shard};
1273         my $art_beg; # the NNTP article number we start xapian_only at
1274         my $idxlevel = $self->{ibx}->{indexlevel};
1275         local $self->{ibx}->{indexlevel} = 'basic' if $seq;
1276
1277         $self->idx_init($opt); # acquire lock
1278         fill_alternates($self, $epoch_max);
1279         $self->{oidx}->rethread_prepare($opt);
1280         my $sync = {
1281                 need_checkpoint => \(my $bool = 0),
1282                 unindex_range => {}, # EPOCH => oid_old..oid_new
1283                 reindex => $opt->{reindex},
1284                 -opt => $opt,
1285                 v2w => $self,
1286                 ibx => $self->{ibx},
1287         };
1288         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1289         if (sync_prepare($self, $sync, $epoch_max)) {
1290                 # tmp_clone seems to fail if inside a transaction, so
1291                 # we rollback here (because we opened {mm} for reading)
1292                 # Note: we do NOT rely on DBI transactions for atomicity;
1293                 # only for batch performance.
1294                 $self->{mm}->{dbh}->rollback;
1295                 $self->{mm}->{dbh}->begin_work;
1296                 $sync->{mm_tmp} =
1297                         $self->{mm}->tmp_clone($self->{ibx}->{inboxdir});
1298
1299                 # xapian_only works incrementally w/o --reindex
1300                 if ($seq && !$opt->{reindex}) {
1301                         $art_beg = $sync->{mm_tmp}->max;
1302                         $art_beg++ if defined($art_beg);
1303                 }
1304         }
1305         if ($sync->{max_size} = $opt->{max_size}) {
1306                 $sync->{index_oid} = \&index_oid;
1307         }
1308         # work forwards through history
1309         index_epoch($self, $sync, $_) for (0..$epoch_max);
1310         $self->{oidx}->rethread_done($opt);
1311         $self->done;
1312
1313         if (my $nr = $sync->{nr}) {
1314                 my $pr = $sync->{-opt}->{-progress};
1315                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $$nr)) if $pr;
1316         }
1317
1318         # deal with Xapian shards sequentially
1319         if ($seq && delete($sync->{mm_tmp})) {
1320                 $self->{ibx}->{indexlevel} = $idxlevel;
1321                 xapian_only($self, $opt, $sync, $art_beg);
1322         }
1323
1324         # --reindex on the command-line
1325         if ($opt->{reindex} && !ref($opt->{reindex}) && $idxlevel ne 'basic') {
1326                 $self->lock_acquire;
1327                 my $s0 = PublicInbox::SearchIdx->new($self->{ibx}, 0, 0);
1328                 if (my $xdb = $s0->idx_acquire) {
1329                         my $n = $xdb->get_metadata('has_threadid');
1330                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
1331                 }
1332                 $s0->idx_release;
1333                 $self->lock_release;
1334         }
1335
1336         # reindex does not pick up new changes, so we rerun w/o it:
1337         if ($opt->{reindex}) {
1338                 my %again = %$opt;
1339                 $sync = undef;
1340                 delete @again{qw(rethread reindex -skip_lock)};
1341                 index_sync($self, \%again);
1342         }
1343 }
1344
1345 1;