lib/PublicInbox/View.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  11 use PublicInbox::MsgTime qw(msg_datestamp);
  12 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  13                         ts2str fmt_ts);
  14 use PublicInbox::Linkify;
  15 use PublicInbox::MID qw(id_compress mids mids_for_index references
  16                         $MID_EXTRACT);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::Address;
  19 use PublicInbox::WwwStream qw(html_oneshot);
  20 use PublicInbox::Reply;
  21 use PublicInbox::ViewDiff qw(flush_diff);
  22 use PublicInbox::Eml;
  23 use POSIX qw(strftime);
  24 use Time::Local qw(timegm);
  25 use PublicInbox::Smsg qw(subject_normalized);
  26 use PublicInbox::ContentHash qw(content_hash);
  27 use constant COLS => 72;
  28 use constant INDENT => '  ';
  29 use constant TCHILD => '` ';
  30 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  31
  32 sub msg_page_i {
  33         my ($ctx, $eml) = @_;
  34         if ($eml) { # called by WwwStream::async_eml or getline
  35                 my $smsg = $ctx->{smsg};
  36                 my $over = $ctx->{ibx}->over;
  37                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  38                                 : $ctx->gone('over');
  39                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  40                                 "../${\mid_href($smsg->{mid})}/" : '';
  41                 if (_msg_page_prepare($eml, $ctx)) {
  42                         $eml->each_part(\&add_text_body, $ctx, 1);
  43                         print { $ctx->{zfh} } '</pre><hr>';
  44                 }
  45                 html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 ''; # XXX TODO cleanup
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         if (_msg_page_prepare($eml, $ctx)) { # sets {-title_html}
  60                 $eml->each_part(\&add_text_body, $ctx, 1);
  61                 print { $ctx->{zfh} } '</pre><hr>';
  62         }
  63         html_footer($ctx, $eml);
  64         $ctx->html_done;
  65 }
  66
  67 # public functions: (unstable)
  68
  69 sub msg_page {
  70         my ($ctx) = @_;
  71         my $ibx = $ctx->{ibx};
  72         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  73         my $over = $ibx->over or return no_over_html($ctx);
  74         my ($id, $prev);
  75         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  76
  77         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  78                 return; # undef == 404
  79
  80         # allow user to easily browse the range around this message if
  81         # they have ->over
  82         $ctx->{-t_max} = $smsg->{ts};
  83         PublicInbox::WwwStream::aresponse($ctx, \&msg_page_i);
  84 }
  85
  86 # /$INBOX/$MESSAGE_ID/#R
  87 sub msg_reply ($$) {
  88         my ($ctx, $hdr) = @_;
  89         my $se_url =
  90          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  91         my $p_url =
  92          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  93
  94         my $info = '';
  95         my $ibx = $ctx->{ibx};
  96         if (my $url = $ibx->{infourl}) {
  97                 $url = prurl($ctx->{env}, $url);
  98                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  99         }
 100
 101         my ($arg, $link, $reply_to_all) =
 102                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 103         if (ref($arg) eq 'SCALAR') {
 104                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 105         }
 106
 107         # mailto: link only works if address obfuscation is disabled
 108         if ($link) {
 109                 $link = <<EOF;
 110
 111 * If your mail client supports setting the <b>In-Reply-To</b> header
 112   via mailto: links, try the <a
 113 href="$link">mailto: link</a>
 114 EOF
 115         }
 116
 117         push @$arg, '/path/to/YOUR_REPLY';
 118         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 119         <<EOF
 120 <hr><pre
 121 id=R><b>Reply instructions:</b>
 122
 123 You may reply publicly to <a
 124 href=#t>this message</a> via plain-text email
 125 using any one of the following methods:
 126
 127 * Save the following mbox file, import it into your mail client,
 128   and $reply_to_all from there: <a
 129 href=raw>mbox</a>
 130
 131   Avoid top-posting and favor interleaved quoting:
 132   <a
 133 href="$p_url">$p_url</a>
 134 $info
 135 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 136   switches of git-send-email(1):
 137
 138   git send-email$arg
 139
 140   <a
 141 href="$se_url">$se_url</a>
 142 $link</pre>
 143
 144   Be sure your reply has a <b>Subject:</b> header at the top and a blank line
 145   before the message body.
 146 EOF
 147 }
 148
 149 sub in_reply_to {
 150         my ($hdr) = @_;
 151         my $refs = references($hdr);
 152         $refs->[-1];
 153 }
 154
 155 sub fold_addresses ($) {
 156         return $_[0] if length($_[0]) <= COLS;
 157         # try to fold on commas after non-word chars before $lim chars,
 158         # Try to get the "," preceded by ">" or ")", but avoid folding
 159         # on the comma where somebody uses "Lastname, Firstname".
 160         # We also try to keep the last and penultimate addresses in
 161         # the list on the same line if possible, hence the extra \z
 162         # Fall back to folding on spaces at $lim + 1 chars
 163         my $lim = COLS - 8; # 8 = "\t" display width
 164         my $too_long = $lim + 1;
 165         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 166         $_[0] = join("\n\t",
 167                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 168                                 .{1,$lim}(?:,|\z)|
 169                                 .{1,$lim}|
 170                                 .{$too_long,}?)(?:\s|\z)/xgo));
 171 }
 172
 173 sub _hdr_names_html ($$) {
 174         my ($hdr, $field) = @_;
 175         my @vals = $hdr->header($field) or return '';
 176         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 177 }
 178
 179 sub nr_to_s ($$$) {
 180         my ($nr, $singular, $plural) = @_;
 181         return "0 $plural" if $nr == 0;
 182         $nr == 1 ? "$nr $singular" : "$nr $plural";
 183 }
 184
 185 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 186 # this is already inside a <pre>
 187 sub eml_entry {
 188         my ($ctx, $eml) = @_;
 189         my $smsg = delete $ctx->{smsg};
 190         my $subj = delete $smsg->{subject};
 191         my $mid_raw = $smsg->{mid};
 192         my $id = id_compress($mid_raw, 1);
 193         my $id_m = 'm'.$id;
 194         my $root_anchor = $ctx->{root_anchor} || '';
 195         my $irt;
 196         my $obfs_ibx = $ctx->{-obfs_ibx};
 197
 198         $subj = '(no subject)' if $subj eq '';
 199         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 200         $subj = '<b>'.ascii_html($subj).'</b>';
 201         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 202         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 203         $rv .= $subj . "\n";
 204         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 205         my @tocc;
 206         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 207
 208         # Deleting these fields saves about 400K as we iterate across 1K msgs
 209         delete @$smsg{qw(ts blob)};
 210
 211         my $from = _hdr_names_html($eml, 'From');
 212         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 213         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 214         my $upfx = $ctx->{-upfx};
 215         my $mhref = $upfx . mid_href($mid_raw) . '/';
 216         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 217         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 218         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 219         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 220         my ($tlen, $clen) = (length($to), length($cc));
 221         my $to_cc = '';
 222         if (($tlen + $clen) > COLS) {
 223                 $to_cc .= '  To: '.$to."\n" if $tlen;
 224                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 225         } else {
 226                 if ($tlen) {
 227                         $to_cc .= '  To: '.$to;
 228                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 229                 } else {
 230                         $to_cc .= '  Cc: '.$cc if $clen;
 231                 }
 232                 $to_cc .= "\n";
 233         }
 234         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 235         $rv .= $to_cc;
 236
 237         my $mapping = $ctx->{mapping};
 238         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 239                 my $href = $upfx . mid_href($irt) . '/';
 240                 my $html = ascii_html($irt);
 241                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 242         }
 243         say { $ctx->zfh } $rv;
 244
 245         # scan through all parts, looking for displayable text
 246         $ctx->{mhref} = $mhref;
 247         $ctx->{changed_href} = "#e$id"; # for diffstat "files? changed,"
 248         $eml->each_part(\&add_text_body, $ctx, 1); # expensive
 249
 250         # add the footer
 251         $rv = "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 252                 "<a\nhref=\"$mhref\">permalink</a>" .
 253                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 254                 " <a\nhref=\"${mhref}#R\">reply</a>";
 255
 256         delete($ctx->{-qry}) and
 257                 $rv .= qq[ <a\nhref="${mhref}#related">related</a>];
 258
 259         my $hr;
 260         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 261                 $rv .= "\t[relevance $pct%]";
 262                 $hr = 1;
 263         } elsif ($mapping) {
 264                 my $nested = 'nested';
 265                 my $flat = 'flat';
 266                 if ($ctx->{flat}) {
 267                         $hr = 1;
 268                         $flat = "<b>$flat</b>";
 269                 } else {
 270                         $nested = "<b>$nested</b>";
 271                 }
 272                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 273                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 274                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 275         } else {
 276                 $hr = $ctx->{-hr};
 277         }
 278
 279         # do we have more messages? start a new <pre> if so
 280         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 281         $rv;
 282 }
 283
 284 sub pad_link ($$;$) {
 285         my ($mid, $level, $s) = @_;
 286         $s ||= '...';
 287         my $href = defined($mid) ?
 288                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 289                 "($s)\n";
 290         (' 'x19).indent_for($level).th_pfx($level).$href;
 291 }
 292
 293 sub _skel_hdr {
 294         # my ($mapping, $mid) = @_;
 295         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 296 }
 297
 298 sub _th_index_lite {
 299         my ($mid_raw, $irt, $id, $ctx) = @_;
 300         my $rv = '';
 301         my $mapping = $ctx->{mapping} or return $rv;
 302         my $pad = '  ';
 303         my $mid_map = $mapping->{$mid_raw} //
 304                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 305         my ($attr, $node, $idx, $level) = @$mid_map;
 306         my $children = $node->{children};
 307         my $nr_c = scalar @$children;
 308         my $nr_s = 0;
 309         my $siblings;
 310         # delete saves about 200KB on a 1K message thread
 311         if (my $refs = delete $node->{references}) {
 312                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 313         }
 314         my $irt_map = $mapping->{$$irt} if defined $$irt;
 315         if (defined $irt_map) {
 316                 $siblings = $irt_map->[1]->{children};
 317                 $nr_s = scalar(@$siblings) - 1;
 318                 $rv .= $pad . $irt_map->[0];
 319                 if ($idx > 0) {
 320                         my $prev = $siblings->[$idx - 1];
 321                         my $pmid = $prev->{mid};
 322                         if ($idx > 2) {
 323                                 my $s = ($idx - 1). ' preceding siblings ...';
 324                                 $rv .= pad_link($pmid, $level, $s);
 325                         } elsif ($idx == 2) {
 326                                 $rv .= $pad . _skel_hdr($mapping,
 327                                                 $siblings->[0] ?
 328                                                 $siblings->[0]->{mid} : undef);
 329                         }
 330                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 331                 }
 332         }
 333         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 334         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 335         chop $attr; # remove "\n"
 336         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 337         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 338         $rv .= "<b>@ $attr</b>\n";
 339         if ($nr_c) {
 340                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 341                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 342                 if ($nr_c > 2) {
 343                         my $s = ($nr_c - 1). ' more replies';
 344                         $rv .= pad_link($cmid, $level + 1, $s);
 345                 } elsif (my $cn = $children->[1]) {
 346                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 347                 }
 348         }
 349
 350         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 351         if ($next) {
 352                 my $nmid = $next->{mid};
 353                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 354                 my $nnext = $nr_s - $idx;
 355                 if ($nnext > 2) {
 356                         my $s = ($nnext - 1).' subsequent siblings';
 357                         $rv .= pad_link($nmid, $level, $s);
 358                 } elsif (my $nn = $siblings->[$idx + 2]) {
 359                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 360                 }
 361         }
 362         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 363 }
 364
 365 # non-recursive thread walker
 366 sub walk_thread ($$$) {
 367         my ($rootset, $ctx, $cb) = @_;
 368         my @q = map { (0, $_, -1) } @$rootset;
 369         while (@q) {
 370                 my ($level, $node, $i) = splice(@q, 0, 3);
 371                 defined $node or next;
 372                 $cb->($ctx, $level, $node, $i) or return;
 373                 ++$level;
 374                 $i = 0;
 375                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 376         }
 377 }
 378
 379 sub pre_thread  { # walk_thread callback
 380         my ($ctx, $level, $node, $idx) = @_;
 381         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 382         skel_dump($ctx, $level, $node);
 383 }
 384
 385 sub thread_eml_entry {
 386         my ($ctx, $eml) = @_;
 387         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 388         print { $ctx->zfh } $beg, '<pre>';
 389         print { $ctx->{zfh} } eml_entry($ctx, $eml), '</pre>', $end;
 390 }
 391
 392 sub next_in_queue ($$) {
 393         my ($q, $ghost_ok) = @_;
 394         while (@$q) {
 395                 my ($level, $smsg) = splice(@$q, 0, 2);
 396                 my $cl = $level + 1;
 397                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 398                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 399         }
 400         undef;
 401 }
 402
 403 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 404         my ($ctx, $eml) = @_;
 405         return thread_eml_entry($ctx, $eml) if $eml;
 406         return unless exists($ctx->{skel});
 407         my $ghost_ok = $ctx->{nr}++;
 408         while (1) {
 409                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 410                 if ($smsg) {
 411                         if (exists $smsg->{blob}) { # next message for cat-file
 412                                 $ctx->{level} = $lvl;
 413                                 if (!$ghost_ok) { # first non-ghost
 414                                         $ctx->{-title_html} =
 415                                                 ascii_html($smsg->{subject});
 416                                         print { $ctx->zfh } $ctx->html_top;
 417                                 }
 418                                 return $smsg;
 419                         }
 420                         # buffer the ghost entry and loop
 421                         print { $ctx->zfh } ghost_index_entry($ctx, $lvl, $smsg)
 422                 } else { # all done
 423                         print { $ctx->zfh } thread_adj_level($ctx, 0),
 424                                                 ${delete($ctx->{skel})};
 425                         return;
 426                 }
 427         }
 428 }
 429
 430 sub stream_thread ($$) {
 431         my ($rootset, $ctx) = @_;
 432         @{$ctx->{-queue}} = map { (0, $_) } @$rootset;
 433         PublicInbox::WwwStream::aresponse($ctx, \&stream_thread_i);
 434 }
 435
 436 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 437 sub thread_html {
 438         my ($ctx) = @_;
 439         $ctx->{-upfx} = '../../';
 440         my $mid = $ctx->{mid};
 441         my $ibx = $ctx->{ibx};
 442         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 443         return missing_thread($ctx) if $nr == 0;
 444
 445         # link $INBOX_DIR/description text to "index_topics" view around
 446         # the newest message in this thread
 447         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 448         my $t_fmt = fmt_ts($ctx->{-t_max});
 449
 450         my $skel = '<hr><pre>';
 451         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 452         $skel .= <<EOF;
 453 , other threads:[<a
 454 href="../../?t=$t">~$t_fmt UTC</a> | <a
 455 href="../../">newest</a>]
 456
 457 EOF
 458         $skel .= "<b\nid=t>Thread overview:</b> ";
 459         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 460         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 461         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 462         $skel .= "-- links below jump to the message on this page --\n";
 463         $ctx->{cur_level} = 0;
 464         $ctx->{skel} = \$skel;
 465         $ctx->{prev_attr} = '';
 466         $ctx->{prev_level} = 0;
 467         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 468         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 469         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 470                        .' in thread';
 471
 472         my $rootset = thread_results($ctx, $msgs);
 473
 474         # reduce hash lookups in pre_thread->skel_dump
 475         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 476         walk_thread($rootset, $ctx, \&pre_thread);
 477
 478         $skel .= '</pre>';
 479         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 480
 481         # flat display: lazy load the full message from smsg
 482         $ctx->{msgs} = $msgs;
 483         $ctx->{-html_tip} = '<pre>';
 484         PublicInbox::WwwStream::aresponse($ctx, \&thread_html_i);
 485 }
 486
 487 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 488         my ($ctx, $eml) = @_;
 489         if ($eml) {
 490                 my $smsg = $ctx->{smsg};
 491                 if (exists $ctx->{-html_tip}) {
 492                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 493                         print { $ctx->zfh } $ctx->html_top;
 494                 }
 495                 return eml_entry($ctx, $eml);
 496         } else {
 497                 while (my $smsg = shift @{$ctx->{msgs}}) {
 498                         return $smsg if exists($smsg->{blob});
 499                 }
 500                 my $skel = delete($ctx->{skel}) or return; # all done
 501                 print { $ctx->zfh } $$skel;
 502                 undef;
 503         }
 504 }
 505
 506 sub submsg_hdr ($$) {
 507         my ($ctx, $eml) = @_;
 508         my $s = "\n";
 509         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 510                 $s .= "$h: $_\n" for $eml->header($h);
 511         }
 512         obfuscate_addrs($ctx->{-obfs_ibx}, $s) if $ctx->{-obfs_ibx};
 513         ascii_html($s);
 514 }
 515
 516 sub attach_link ($$$$;$) {
 517         my ($ctx, $ct, $p, $fn, $err) = @_;
 518         my ($part, $depth, $idx) = @$p;
 519
 520         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 521         # downloads for 0-byte multipart attachments
 522         return unless $part->{bdy};
 523
 524         my $size = length($part->body);
 525         delete $part->{bdy}; # save memory
 526
 527         # hide attributes normally, unless we want to aid users in
 528         # spotting MUA problems:
 529         $ct =~ s/;.*// unless $err;
 530         $ct = ascii_html($ct);
 531         my $sfn;
 532         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 533                 $sfn = $fn;
 534         } elsif ($ct eq 'text/plain') {
 535                 $sfn = 'a.txt';
 536         } else {
 537                 $sfn = 'a.bin';
 538         }
 539         my $rv = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 540         $rv .= qq(<a\nhref="$ctx->{mhref}$idx-$sfn">);
 541         $rv .= <<EOF if $err;
 542 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 543 EOF
 544         $rv .= "[-- Attachment #$idx: ";
 545         my $desc = $part->header('Content-Description') // $fn // '';
 546         $rv .= ascii_html($desc)." --]\n[-- " if $desc ne '';
 547         $rv .= "Type: $ct, Size: $size bytes --]</a>\n";
 548         $rv .= submsg_hdr($ctx, $part) if $part->{is_submsg};
 549         $rv;
 550 }
 551
 552 sub add_text_body { # callback for each_part
 553         my ($p, $ctx) = @_;
 554         my $upfx = $ctx->{mhref};
 555         my $ibx = $ctx->{ibx};
 556         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 557         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 558         my ($part, $depth, $idx) = @$p;
 559         my $ct = $part->content_type || 'text/plain';
 560         my $fn = $part->filename;
 561         my ($s, $err) = msg_part_text($part, $ct);
 562         my $zfh = $ctx->zfh;
 563         $s // return print $zfh (attach_link($ctx, $ct, $p, $fn) // '');
 564         say $zfh submsg_hdr($ctx, $part) if $part->{is_submsg};
 565
 566         # makes no difference to browsers, and don't screw up filename
 567         # link generation in diffs with the extra '%0D'
 568         $s =~ s/\r+\n/\n/sg;
 569
 570         # will be escaped to `&#8226;' in HTML
 571         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 572
 573         # always support diff-highlighting, but we can't linkify hunk
 574         # headers for solver unless some coderepo are configured:
 575         my $diff;
 576         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 577                 # diffstat anchors do not link across attachments or messages,
 578                 # -apfx is just a stable prefix for making diffstat anchors
 579                 # linkable to the first diff hunk w/o crossing attachments
 580                 $idx =~ tr!.!/!; # compatibility with previous versions
 581                 $ctx->{-apfx} = $upfx . $idx;
 582
 583                 # do attr => filename mappings for diffstats in git diffs:
 584                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 585                 $diff = 1;
 586                 delete $ctx->{-long_path};
 587                 my $spfx;
 588                 # absolute URL (Atom feeds)
 589                 if ($ibx->{coderepo}) {
 590                         if (index($upfx, '//') >= 0) {
 591                                 $spfx = $upfx;
 592                                 $spfx =~ s!/([^/]*)/\z!/!;
 593                         } else {
 594                                 my $n_slash = $upfx =~ tr!/!/!;
 595                                 if ($n_slash == 0) {
 596                                         $spfx = '../';
 597                                 } elsif ($n_slash == 1) {
 598                                         $spfx = '';
 599                                 } else { # nslash == 2
 600                                         $spfx = '../../';
 601                                 }
 602                         }
 603                 }
 604                 $ctx->{-spfx} = $spfx;
 605         };
 606
 607         # split off quoted and unquoted blocks:
 608         my @sections = PublicInbox::MsgIter::split_quotes($s);
 609         undef $s; # free memory
 610         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 611                 # badly-encoded message with $err? tell the world about it!
 612                 say $zfh attach_link($ctx, $ct, $p, $fn, $err);
 613         }
 614         delete $part->{bdy}; # save memory
 615         for my $cur (@sections) { # $cur may be huge
 616                 if ($cur =~ /\A>/) {
 617                         # we use a <span> here to allow users to specify
 618                         # their own color for quoted text
 619                         print $zfh qq(<span\nclass="q">),
 620                                         $l->to_html($cur), '</span>';
 621                 } elsif ($diff) {
 622                         flush_diff($ctx, \$cur);
 623                 } else { # regular lines, OK
 624                         print $zfh $l->to_html($cur);
 625                 }
 626                 undef $cur; # free memory
 627         }
 628 }
 629
 630 sub _msg_page_prepare {
 631         my ($eml, $ctx) = @_;
 632         my $have_over = !!$ctx->{ibx}->over;
 633         my $mids = mids_for_index($eml);
 634         my $nr = $ctx->{nr}++;
 635         if ($nr) { # unlikely
 636                 if ($ctx->{chash} eq content_hash($eml)) {
 637                         warn "W: BUG? @$mids not deduplicated properly\n";
 638                         return;
 639                 }
 640                 $ctx->{-html_tip} =
 641 "<pre>WARNING: multiple messages have this Message-ID\n</pre><pre>";
 642         } else {
 643                 $ctx->{first_hdr} = $eml->header_obj;
 644                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 645                 $ctx->{-html_tip} = "<pre\nid=b>"; # anchor for body start
 646         }
 647         $ctx->{-upfx} = '../';
 648         my @title; # (Subject[0], From[0])
 649         my $hbuf = '';
 650         for my $v ($eml->header('From')) {
 651                 my @n = PublicInbox::Address::names($v);
 652                 $title[1] //= join(', ', @n);
 653                 $hbuf .= "From: $v\n" if $v ne '';
 654         }
 655         for my $h (qw(To Cc)) {
 656                 for my $v ($eml->header($h)) {
 657                         fold_addresses($v);
 658                         $hbuf .= "$h: $v\n" if $v ne '';
 659                 }
 660         }
 661         my @subj = $eml->header('Subject');
 662         $hbuf .= "Subject: $_\n" for @subj;
 663         $title[0] = $subj[0] // '(no subject)';
 664         $hbuf .= "Date: $_\n" for $eml->header('Date');
 665         $hbuf = ascii_html($hbuf);
 666         $ctx->{-title_html} = ascii_html(join(' - ', @title));
 667         if (my $obfs_ibx = $ctx->{-obfs_ibx}) {
 668                 obfuscate_addrs($obfs_ibx, $hbuf);
 669                 obfuscate_addrs($obfs_ibx, $ctx->{-title_html});
 670         }
 671
 672         # [thread overview] link is typically added after Date,
 673         # but added after Subject, or even nothing.
 674         if ($have_over) {
 675                 chop $hbuf; # drop "\n", or noop if $rv eq ''
 676                 $hbuf .= qq{\t<a\nhref="#r">[thread overview]</a>\n};
 677                 $hbuf =~ s!^Subject:\x20(.*?)(\n[A-Z]|\z)
 678                                 !Subject: <a\nhref="#r"\nid=t>$1</a>$2!msx or
 679                         $hbuf .= qq(<a\nhref="#r\nid=t></a>);
 680         }
 681         if (scalar(@$mids) == 1) { # common case
 682                 my $x = ascii_html($mids->[0]);
 683                 $hbuf .= qq[Message-ID: &lt;$x&gt; (<a href="raw">raw</a>)\n];
 684         }
 685         if (!$nr) { # first (and only) message, common case
 686                 print { $ctx->zfh } $ctx->html_top, $hbuf;
 687         } else {
 688                 delete $ctx->{-title_html};
 689                 print { $ctx->zfh } $ctx->{-html_tip}, $hbuf;
 690         }
 691         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 692         $hbuf = '';
 693         if (scalar(@$mids) != 1) { # unlikely, but it happens :<
 694                 # X-Alt-Message-ID can happen if a message is injected from
 695                 # public-inbox-nntpd because of multiple Message-ID headers.
 696                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 697                         $hbuf .= "$h: $_\n" for ($eml->header_raw($h));
 698                 }
 699                 $ctx->{-linkify}->linkify_mids('..', \$hbuf, 1); # escapes HTML
 700                 print { $ctx->{zfh} } $hbuf;
 701                 $hbuf = '';
 702         }
 703         my @irt = $eml->header_raw('In-Reply-To');
 704         my $refs;
 705         if (!@irt) {
 706                 $refs = references($eml);
 707                 $irt[0] = pop(@$refs) if scalar @$refs;
 708         }
 709         $hbuf .= "In-Reply-To: $_\n" for @irt;
 710
 711         # do not display References: if search is present,
 712         # we show the thread skeleton at the bottom, instead.
 713         if (!$have_over) {
 714                 $refs //= references($eml);
 715                 $hbuf .= 'References: <'.join(">\n\t<", @$refs).">\n" if @$refs;
 716         }
 717         $ctx->{-linkify}->linkify_mids('..', \$hbuf); # escapes HTML
 718         say { $ctx->{zfh} } $hbuf;
 719         1;
 720 }
 721
 722 sub SKEL_EXPAND () {
 723         qq(expand[<a\nhref="T/#u">flat</a>) .
 724                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 725                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 726                 qq(<a\nhref="t.atom">Atom feed</a>);
 727 }
 728
 729 sub thread_skel ($$$) {
 730         my ($skel, $ctx, $hdr) = @_;
 731         my $mid = mids($hdr)->[0];
 732         my $ibx = $ctx->{ibx};
 733         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 734         my $parent = in_reply_to($hdr);
 735         $$skel .= "\n<b>Thread overview: </b>";
 736         if ($nr <= 1) {
 737                 if (defined $parent) {
 738                         $$skel .= SKEL_EXPAND."\n ";
 739                         $$skel .= ghost_parent('../', $parent) . "\n";
 740                 } else {
 741                         $$skel .= "<a\nid=r>[no followups]</a> ".
 742                                         SKEL_EXPAND."\n";
 743                 }
 744                 $ctx->{next_msg} = undef;
 745                 $ctx->{parent_msg} = $parent;
 746                 return;
 747         }
 748
 749         $$skel .= $nr;
 750         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 751
 752         # nb: mutt only shows the first Subject in the index pane
 753         # when multiple Subject: headers are present, so we follow suit:
 754         my $subj = $hdr->header('Subject') // '';
 755         $subj = '(no subject)' if $subj eq '';
 756         $ctx->{cur} = $mid;
 757         $ctx->{prev_attr} = '';
 758         $ctx->{prev_level} = 0;
 759         $ctx->{skel} = $skel;
 760
 761         # reduce hash lookups in skel_dump
 762         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 763         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 764
 765         $ctx->{parent_msg} = $parent;
 766 }
 767
 768 # writes to zbuf
 769 sub html_footer {
 770         my ($ctx, $hdr) = @_;
 771         my $upfx = '../';
 772         my (@related, $skel);
 773         my $foot = '<pre>';
 774         my $qry = delete $ctx->{-qry};
 775         if ($qry && $ctx->{ibx}->isrch) {
 776                 my $q = ''; # search for either ancestor or descendent patches
 777                 for (@{$qry->{dfpre}}, @{$qry->{dfpost}}) {
 778                         chop if length > 7; # include 1 abbrev "older" patches
 779                         $q .= "dfblob:$_ ";
 780                 }
 781                 chop $q; # omit trailing SP
 782                 local $Text::Wrap::columns = COLS;
 783                 local $Text::Wrap::huge = 'overflow';
 784                 $q = wrap('', '', $q);
 785                 my $rows = ($q =~ tr/\n/\n/) + 1;
 786                 $q = ascii_html($q);
 787                 $related[0] = <<EOM;
 788 <form id=related
 789 action=$upfx
 790 ><pre>find likely ancestor, descendant, or conflicting patches for <a
 791 href=#t>this message</a>:
 792 <textarea name=q cols=${\COLS} rows=$rows>$q</textarea>
 793 <input type=submit value=search
 794 />\t(<a href=${upfx}_/text/help/#search>help</a>)</pre></form>
 795 EOM
 796         }
 797         if ($ctx->{ibx}->over) {
 798                 my $t = ts2str($ctx->{-t_max});
 799                 my $t_fmt = fmt_ts($ctx->{-t_max});
 800                 my $fallback = @related ? "\t" : "<a id=related>\t</a>";
 801                 $skel = <<EOF;
 802 ${fallback}other threads:[<a
 803 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 804 href="$upfx">newest</a>]
 805 EOF
 806                 thread_skel(\$skel, $ctx, $hdr);
 807                 my ($next, $prev);
 808                 my $parent = '       ';
 809                 $next = $prev = '    ';
 810
 811                 if (my $n = $ctx->{next_msg}) {
 812                         $n = mid_href($n);
 813                         $next = qq(<a\nhref="$upfx$n/"\nrel=next>next</a>);
 814                 }
 815                 my $par = $ctx->{parent_msg};
 816                 my $u = $par ? $upfx.mid_href($par).'/' : undef;
 817                 if (my $p = $ctx->{prev_msg}) {
 818                         $prev = mid_href($p);
 819                         if ($p && $par && $p eq $par) {
 820                                 $prev = qq(<a\nhref="$upfx$prev/"\n) .
 821                                         'rel=prev>prev parent</a>';
 822                                 $parent = '';
 823                         } else {
 824                                 $prev = qq(<a\nhref="$upfx$prev/"\n) .
 825                                         'rel=prev>prev</a>';
 826                                 $parent = qq( <a\nhref="$u">parent</a>) if $u;
 827                         }
 828                 } elsif ($u) { # unlikely
 829                         $parent = qq( <a\nhref="$u"\nrel=prev>parent</a>);
 830                 }
 831                 $foot .= "$next $prev$parent ";
 832         } else { # unindexed inboxes w/o over
 833                 $skel = qq( <a\nhref="$upfx">latest</a>);
 834         }
 835         # $skel may be big for big threads, don't append it to $foot
 836         print { $ctx->zfh } $foot, qq(<a\nhref="#R">reply</a>),
 837                                 $skel, '</pre>', @related,
 838                                 msg_reply($ctx, $hdr);
 839 }
 840
 841 sub ghost_parent {
 842         my ($upfx, $mid) = @_;
 843
 844         my $href = mid_href($mid);
 845         my $html = ascii_html($mid);
 846         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 847 }
 848
 849 sub indent_for {
 850         my ($level) = @_;
 851         $level ? INDENT x ($level - 1) : '';
 852 }
 853
 854 sub find_mid_root {
 855         my ($ctx, $level, $node, $idx) = @_;
 856         ++$ctx->{root_idx} if $level == 0;
 857         if ($node->{mid} eq $ctx->{mid}) {
 858                 $ctx->{found_mid_at} = $ctx->{root_idx};
 859                 return 0; # stop iterating
 860         }
 861         1;
 862 }
 863
 864 sub strict_loose_note ($) {
 865         my ($nr) = @_;
 866         my $msg =
 867 "  -- strict thread matches above, loose matches on Subject: below --\n";
 868
 869         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 870                 $msg .=
 871 "  -- use mbox.gz link to download all $nr messages --\n";
 872         }
 873         $msg;
 874 }
 875
 876 sub thread_results {
 877         my ($ctx, $msgs) = @_;
 878         require PublicInbox::SearchThread;
 879         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 880
 881         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 882         # and preserved in the future.  This bug is hidden by `sid' matches
 883         # in get_thread, so we never noticed it until now.  And even when
 884         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 885         # bump since reindexing is expensive and users may not do it
 886
 887         # loose threading could've returned too many results,
 888         # put the root the message we care about at the top:
 889         my $mid = $ctx->{mid};
 890         if (defined($mid) && scalar(@$rootset) > 1) {
 891                 $ctx->{root_idx} = -1;
 892                 my $nr = scalar @$msgs;
 893                 walk_thread($rootset, $ctx, \&find_mid_root);
 894                 my $idx = $ctx->{found_mid_at};
 895                 if (defined($idx) && $idx != 0) {
 896                         my $tip = splice(@$rootset, $idx, 1);
 897                         @$rootset = reverse @$rootset;
 898                         unshift @$rootset, $tip;
 899                         $ctx->{sl_note} = strict_loose_note($nr);
 900                 }
 901         }
 902         $rootset
 903 }
 904
 905 sub missing_thread {
 906         my ($ctx) = @_;
 907         require PublicInbox::ExtMsg;
 908         PublicInbox::ExtMsg::ext_msg($ctx);
 909 }
 910
 911 sub dedupe_subject {
 912         my ($prev_subj, $subj, $val) = @_;
 913
 914         my $omit; # '"' denotes identical text omitted
 915         my (@prev_pop, @curr_pop);
 916         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 917                 push(@prev_pop, pop(@$prev_subj));
 918                 push(@curr_pop, pop(@$subj));
 919                 $omit //= $val;
 920         }
 921         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 922         if (scalar(@curr_pop) == 1) {
 923                 $omit = undef;
 924                 push @$prev_subj, @prev_pop;
 925                 push @$subj, @curr_pop;
 926         }
 927         $omit // '';
 928 }
 929
 930 sub skel_dump { # walk_thread callback
 931         my ($ctx, $level, $smsg) = @_;
 932         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 933
 934         my $skel = $ctx->{skel};
 935         my $cur = $ctx->{cur};
 936         my $mid = $smsg->{mid};
 937
 938         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 939                 $$skel .= delete($ctx->{sl_note}) || '';
 940         }
 941
 942         my $f = ascii_html(delete $smsg->{from_name});
 943         my $obfs_ibx = $ctx->{-obfs_ibx};
 944         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 945
 946         my $d = fmt_ts($smsg->{ds});
 947         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 948         if (exists $ctx->{searchview}) {
 949                 if (defined(my $pct = $smsg->{pct})) {
 950                         $d .= (sprintf(' % 2u', $pct) . '%');
 951                 } else {
 952                         $unmatched = 1;
 953                         $d .= '    ';
 954                 }
 955         }
 956         $d .= ' ' . indent_for($level) . th_pfx($level);
 957         my $attr = $f;
 958         $ctx->{first_level} ||= $level;
 959
 960         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 961                 $ctx->{prev_attr} = $attr;
 962         }
 963         $ctx->{prev_level} = $level;
 964
 965         if ($cur) {
 966                 if ($cur eq $mid) {
 967                         delete $ctx->{cur};
 968                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 969                                  "$attr [this message]</a></b>\n";
 970                         return 1;
 971                 } else {
 972                         $ctx->{prev_msg} = $mid;
 973                 }
 974         } else {
 975                 $ctx->{next_msg} ||= $mid;
 976         }
 977
 978         # Subject is never undef, this mail was loaded from
 979         # our Xapian which would've resulted in '' if it were
 980         # really missing (and Filter rejects empty subjects)
 981         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 982         # remove common suffixes from the subject if it matches the previous,
 983         # so we do not show redundant text at the end.
 984         my $prev_subj = $ctx->{prev_subj} || [];
 985         $ctx->{prev_subj} = [ @subj ];
 986         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 987         my $end;
 988         if (@subj) {
 989                 my $subj = join(' ', @subj);
 990                 $subj = ascii_html($subj);
 991                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 992                 $end = "$subj</a> $omit$f\n"
 993         } else {
 994                 $end = "$f</a>\n";
 995         }
 996         my $m;
 997         my $id = '';
 998         my $mapping = $unmatched ? undef : $ctx->{mapping};
 999         if ($mapping) {
1000                 my $map = $mapping->{$mid};
1001                 $id = id_compress($mid, 1);
1002                 $m = '#m'.$id;
1003                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1004                 $id = "\nid=r".$id;
1005         } else {
1006                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1007         }
1008         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1009         1;
1010 }
1011
1012 sub _skel_ghost {
1013         my ($ctx, $level, $node) = @_;
1014
1015         my $mid = $node->{mid};
1016         my $d = '     [not found] ';
1017         $d .= '    '  if exists $ctx->{searchview};
1018         $d .= indent_for($level) . th_pfx($level);
1019         my $upfx = $ctx->{-upfx};
1020         my $href = $upfx . mid_href($mid) . '/';
1021         my $html = ascii_html($mid);
1022
1023         my $mapping = $ctx->{mapping};
1024         my $map = $mapping->{$mid} if $mapping;
1025         if ($map) {
1026                 my $id = id_compress($mid, 1);
1027                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1028                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1029         } else {
1030                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1031         }
1032         ${$ctx->{skel}} .= $d;
1033         1;
1034 }
1035
1036 sub sort_ds {
1037         @{$_[0]} = sort {
1038                 (eval { $a->topmost->{ds} } || 0) <=>
1039                 (eval { $b->topmost->{ds} } || 0)
1040         } @{$_[0]};
1041 }
1042
1043 # accumulate recent topics if search is supported
1044 # returns 200 if done, 404 if not
1045 sub acc_topic { # walk_thread callback
1046         my ($ctx, $level, $smsg) = @_;
1047         my $mid = $smsg->{mid};
1048         my $has_blob = $smsg->{blob} // do {
1049                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1050                         %$smsg = (%$smsg, %$by_mid);
1051                         1;
1052                 }
1053         };
1054         if ($has_blob) {
1055                 my $subj = subject_normalized($smsg->{subject});
1056                 $subj = '(no subject)' if $subj eq '';
1057                 my $ds = $smsg->{ds};
1058                 if ($level == 0) { # new, top-level topic
1059                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1060                         $ctx->{-cur_topic} = $topic;
1061                         push @{$ctx->{order}}, $topic;
1062                         return 1;
1063                 }
1064
1065                 # continue existing topic
1066                 my $topic = $ctx->{-cur_topic}; # should never be undef
1067                 $topic->[0] = $ds if $ds > $topic->[0];
1068                 $topic->[1]++; # bump N+ message counter
1069                 my $seen = $topic->[2];
1070                 if (scalar(@$topic) == 3) { # parent was a ghost
1071                         push @$topic, $subj;
1072                 } elsif (!defined($seen->{$subj})) {
1073                         push @$topic, $level, $subj; # @extra messages
1074                 }
1075                 $seen->{$subj} = $mid; # latest for subject
1076         } else { # ghost message
1077                 return 1 if $level != 0; # ignore child ghosts
1078                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1079                 push @{$ctx->{order}}, $topic;
1080         }
1081         1;
1082 }
1083
1084 sub dump_topics {
1085         my ($ctx) = @_;
1086         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1087         unless ($order) {
1088                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1089                 return 404;
1090         }
1091
1092         my @out;
1093         my $obfs_ibx = $ctx->{ibx}->{obfuscate} ? $ctx->{ibx} : undef;
1094         if (my $note = delete $ctx->{t_note}) {
1095                 push @out, $note; # "messages from ... to ..."
1096         }
1097         # sort by recency, this allows new posts to "bump" old topics...
1098         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1099                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1100                 @$topic = ();
1101                 next unless defined $top_subj;  # ghost topic
1102                 my $mid = delete $seen->{$top_subj};
1103                 my $href = mid_href($mid);
1104                 my $prev_subj = [ split(/ /, $top_subj) ];
1105                 $top_subj = ascii_html($top_subj);
1106                 $ds = fmt_ts($ds);
1107
1108                 # $n isn't the total number of posts on the topic,
1109                 # just the number of posts in the current results window
1110                 my $anchor;
1111                 if ($n == 1) {
1112                         $n = '';
1113                         $anchor = '#u'; # top of only message
1114                 } else {
1115                         $n = " ($n+ messages)";
1116                         $anchor = '#t'; # thread skeleton
1117                 }
1118
1119                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1120                         " $ds UTC $n\n";
1121                 while (@extra) {
1122                         my $level = shift @extra;
1123                         my $subj = shift @extra; # already normalized
1124                         $mid = delete $seen->{$subj};
1125                         my @subj = split(/ /, $subj);
1126                         my @next_prev = @subj; # full copy
1127                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1128                         $prev_subj = \@next_prev;
1129                         $subj = join(' ', @subj);
1130                         $subj = ascii_html($subj);
1131                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1132                         $href = mid_href($mid);
1133                         $s .= indent_for($level) . TCHILD;
1134                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1135                 }
1136                 push @out, $s;
1137         }
1138         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1139         200;
1140 }
1141
1142 sub str2ts ($) {
1143         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1144         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1145 }
1146
1147 sub pagination_footer ($$) {
1148         my ($ctx, $latest) = @_;
1149         my $next = $ctx->{next_page} || '';
1150         my $prev = $ctx->{prev_page} || '';
1151         if ($prev) {  # aligned padding for: 'next (older) | '
1152                 $next = $next ? "$next | " : '             | ';
1153                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1154         }
1155         ($next || $prev) ? "<hr><pre id=nav>page: $next$prev</pre>" : '';
1156 }
1157
1158 sub paginate_recent ($$) {
1159         my ($ctx, $lim) = @_;
1160         my $t = $ctx->{qp}->{t} || '';
1161         my $opts = { limit => $lim };
1162         my ($after, $before);
1163
1164         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1165         # if only $after exists "YYYYMMDD.." because "." could be skipped
1166         # if interpreted as an end-of-sentence
1167         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1168         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1169
1170         my $msgs = $ctx->{ibx}->over->recent($opts, $after, $before);
1171         if (defined($after) && scalar(@$msgs) < $lim) {
1172                 $after = $before = undef;
1173                 $msgs = $ctx->{ibx}->over->recent($opts);
1174         }
1175         my $more = scalar(@$msgs) == $lim;
1176         my ($newest, $oldest);
1177         if (@$msgs) {
1178                 $newest = $msgs->[0]->{ts};
1179                 $oldest = $msgs->[-1]->{ts};
1180                 # if we only had $after, our SQL query in ->recent ordered
1181                 if ($newest < $oldest) {
1182                         ($oldest, $newest) = ($newest, $oldest);
1183                         $more = undef if defined($after) && $after < $oldest;
1184                 }
1185                 if (defined($after // $before)) {
1186                         my $n = strftime('%Y-%m-%d %H:%M:%S', gmtime($newest));
1187                         my $o = strftime('%Y-%m-%d %H:%M:%S', gmtime($oldest));
1188                         $ctx->{t_note} = <<EOM;
1189  messages from $o to $n UTC [<a href="#nav">more...</a>]
1190 EOM
1191                         my $s = ts2str($newest);
1192                         $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1193                                                 'prev (newer)</a>';
1194                 }
1195         }
1196         if (defined($oldest) && $more) {
1197                 my $s = ts2str($oldest);
1198                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1199                                         'next (older)</a>';
1200         }
1201         $msgs;
1202 }
1203
1204 # GET /$INBOX - top-level inbox view for indexed inboxes
1205 sub index_topics {
1206         my ($ctx) = @_;
1207         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1208         walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic) if @$msgs;
1209         html_oneshot($ctx, dump_topics($ctx), pagination_footer($ctx, '.'));
1210 }
1211
1212 sub thread_adj_level {
1213         my ($ctx, $level) = @_;
1214
1215         my $max = $ctx->{cur_level};
1216         if ($level <= 0) {
1217                 return ('', '') if $max == 0; # flat output
1218
1219                 # reset existing lists
1220                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1221                 $ctx->{cur_level} = 0;
1222                 ("$beg</ul>", '');
1223         } elsif ($level == $max) { # continue existing list
1224                 qw(<li> </li>);
1225         } elsif ($level < $max) {
1226                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1227                 $ctx->{cur_level} = $level;
1228                 ("$beg<li>", '</li>');
1229         } else { # ($level > $max) # start a new level
1230                 $ctx->{cur_level} = $level;
1231                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1232                 ($beg, '</li>');
1233         }
1234 }
1235
1236 sub ghost_index_entry {
1237         my ($ctx, $level, $node) = @_;
1238         my ($beg, $end) = thread_adj_level($ctx,  $level);
1239         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1240                 . '</pre>' . $end;
1241 }
1242
1243 1;