lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::Smsg qw(subject_normalized);
  23 use constant COLS => 72;
  24 use constant INDENT => '  ';
  25 use constant TCHILD => '` ';
  26 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  27
  28 sub msg_page_i {
  29         my ($nr, $ctx) = @_;
  30         if (my $more = delete $ctx->{more}) { # unlikely
  31                 # fake an EOF if $more retrieval fails;
  32                 eval { msg_page_more($ctx, $nr, @$more) };
  33         } elsif (my $hdr = delete $ctx->{hdr}) {
  34                 # fake an EOF if generating the footer fails;
  35                 # we want to at least show the message if something
  36                 # here crashes:
  37                 eval { html_footer($ctx, $hdr) };
  38         } else {
  39                 undef
  40         }
  41 }
  42
  43 # public functions: (unstable)
  44
  45 sub msg_page {
  46         my ($ctx) = @_;
  47         my $mid = $ctx->{mid};
  48         my $ibx = $ctx->{-inbox};
  49         my ($smsg, $first, $next);
  50         if (my $over = $ibx->over) {
  51                 my ($id, $prev);
  52                 $smsg = $over->next_by_mid($mid, \$id, \$prev) or return;
  53                 $first = $ibx->msg_by_smsg($smsg) or return;
  54                 $next = $over->next_by_mid($mid, \$id, \$prev);
  55                 $ctx->{more} = [ $id, $prev, $next ] if $next;
  56         } else {
  57                 $first = $ibx->msg_by_mid($mid) or return;
  58         }
  59         my $mime = PublicInbox::MIME->new($first);
  60         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  61         my $hdr = $ctx->{hdr} = $mime->header_obj;
  62         $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx, 0);
  63         $ctx->{smsg} = $smsg;
  64         # $next cannot be true w/o $smsg being defined:
  65         $ctx->{mhref} = $next ? '../'.mid_href($smsg->{mid}).'/' : '';
  66         multipart_text_as_html($mime, $ctx);
  67         $ctx->{-html_tip} = (${delete $ctx->{obuf}} .= '</pre><hr>');
  68         PublicInbox::WwwStream->response($ctx, 200, \&msg_page_i);
  69 }
  70
  71 sub msg_page_more { # cold
  72         my ($ctx, $nr, $id, $prev, $smsg) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         my $next = $ibx->over->next_by_mid($ctx->{mid}, \$id, \$prev);
  75         $ctx->{more} = [ $id, $prev, $next ] if $next;
  76         $smsg = $ibx->smsg_mime($smsg) or return '';
  77         $ctx->{mhref} = '../' . mid_href($smsg->{mid}) . '/';
  78         my $mime = delete $smsg->{mime};
  79         $ctx->{obuf} = _msg_page_prepare_obuf($mime->header_obj, $ctx, $nr);
  80         multipart_text_as_html($mime, $ctx);
  81         ${delete $ctx->{obuf}} .= '</pre><hr>';
  82 }
  83
  84 # /$INBOX/$MESSAGE_ID/#R
  85 sub msg_reply ($$) {
  86         my ($ctx, $hdr) = @_;
  87         my $se_url =
  88          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  89         my $p_url =
  90          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  91
  92         my $info = '';
  93         my $ibx = $ctx->{-inbox};
  94         if (my $url = $ibx->{infourl}) {
  95                 $url = prurl($ctx->{env}, $url);
  96                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  97         }
  98
  99         my ($arg, $link, $reply_to_all) =
 100                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 101         if (ref($arg) eq 'SCALAR') {
 102                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 103         }
 104
 105         # mailto: link only works if address obfuscation is disabled
 106         if ($link) {
 107                 $link = <<EOF;
 108
 109 * If your mail client supports setting the <b>In-Reply-To</b> header
 110   via mailto: links, try the <a
 111 href="$link">mailto: link</a>
 112 EOF
 113         }
 114
 115         push @$arg, '/path/to/YOUR_REPLY';
 116         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 117         <<EOF
 118 <hr><pre
 119 id=R><b>Reply instructions:</b>
 120
 121 You may reply publicly to <a
 122 href=#t>this message</a> via plain-text email
 123 using any one of the following methods:
 124
 125 * Save the following mbox file, import it into your mail client,
 126   and $reply_to_all from there: <a
 127 href=raw>mbox</a>
 128
 129   Avoid top-posting and favor interleaved quoting:
 130   <a
 131 href="$p_url">$p_url</a>
 132 $info
 133 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 134   switches of git-send-email(1):
 135
 136   git send-email$arg
 137
 138   <a
 139 href="$se_url">$se_url</a>
 140 $link</pre>
 141 EOF
 142 }
 143
 144 sub in_reply_to {
 145         my ($hdr) = @_;
 146         my $refs = references($hdr);
 147         $refs->[-1];
 148 }
 149
 150 sub fold_addresses ($) {
 151         return $_[0] if length($_[0]) <= COLS;
 152         # try to fold on commas after non-word chars before $lim chars,
 153         # Try to get the "," preceeded by ">" or ")", but avoid folding
 154         # on the comma where somebody uses "Lastname, Firstname".
 155         # We also try to keep the last and penultimate addresses in
 156         # the list on the same line if possible, hence the extra \z
 157         # Fall back to folding on spaces at $lim + 1 chars
 158         my $lim = COLS - 8; # 8 = "\t" display width
 159         my $too_long = $lim + 1;
 160         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 161         $_[0] = join("\n\t",
 162                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 163                                 .{1,$lim}(?:,|\z)|
 164                                 .{1,$lim}|
 165                                 .{$too_long,}?)(?:\s|\z)/xgo));
 166 }
 167
 168 sub _hdr_names_html ($$) {
 169         my ($hdr, $field) = @_;
 170         my @vals = $hdr->header($field) or return '';
 171         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 172 }
 173
 174 sub nr_to_s ($$$) {
 175         my ($nr, $singular, $plural) = @_;
 176         return "0 $plural" if $nr == 0;
 177         $nr == 1 ? "$nr $singular" : "$nr $plural";
 178 }
 179
 180 # human-friendly format
 181 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 182
 183 # this is already inside a <pre>
 184 sub index_entry {
 185         my ($smsg, $ctx, $more) = @_;
 186         my $subj = $smsg->subject;
 187         my $mid_raw = $smsg->mid;
 188         my $id = id_compress($mid_raw, 1);
 189         my $id_m = 'm'.$id;
 190
 191         my $root_anchor = $ctx->{root_anchor} || '';
 192         my $irt;
 193         my $obfs_ibx = $ctx->{-obfs_ibx};
 194
 195         $subj = '(no subject)' if $subj eq '';
 196         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 197         $subj = '<b>'.ascii_html($subj).'</b>';
 198         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 199         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 200         $rv .= $subj . "\n";
 201         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 202         my @tocc;
 203         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 204         # deleting {mime} is critical to memory use,
 205         # the rest of the fields saves about 400K as we iterate across 1K msgs
 206         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 207
 208         my $hdr = $mime->header_obj;
 209         my $from = _hdr_names_html($hdr, 'From');
 210         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 211         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 212         my $upfx = $ctx->{-upfx};
 213         my $mhref = $upfx . mid_href($mid_raw) . '/';
 214         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 215         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 216         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 217         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 218         my ($tlen, $clen) = (length($to), length($cc));
 219         my $to_cc = '';
 220         if (($tlen + $clen) > COLS) {
 221                 $to_cc .= '  To: '.$to."\n" if $tlen;
 222                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 223         } else {
 224                 if ($tlen) {
 225                         $to_cc .= '  To: '.$to;
 226                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 227                 } else {
 228                         $to_cc .= '  Cc: '.$cc if $clen;
 229                 }
 230                 $to_cc .= "\n";
 231         }
 232         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 233         $rv .= $to_cc;
 234
 235         my $mapping = $ctx->{mapping};
 236         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 237                 my $href = $upfx . mid_href($irt) . '/';
 238                 my $html = ascii_html($irt);
 239                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 240         }
 241         $rv .= "\n";
 242
 243         # scan through all parts, looking for displayable text
 244         $ctx->{mhref} = $mhref;
 245         $ctx->{obuf} = \$rv;
 246         msg_iter($mime, \&add_text_body, $ctx, 1);
 247         delete $ctx->{obuf};
 248
 249         # add the footer
 250         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 251                 "<a\nhref=\"$mhref\">permalink</a>" .
 252                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 253                 " <a\nhref=\"${mhref}#R\">reply</a>";
 254
 255         my $hr;
 256         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 257                 $rv .= "\t[relevance $pct%]";
 258                 $hr = 1;
 259         } elsif ($mapping) {
 260                 my $nested = 'nested';
 261                 my $flat = 'flat';
 262                 my $end = '';
 263                 if ($ctx->{flat}) {
 264                         $hr = 1;
 265                         $flat = "<b>$flat</b>";
 266                 } else {
 267                         $nested = "<b>$nested</b>";
 268                 }
 269                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 270                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 271                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 272         } else {
 273                 $hr = $ctx->{-hr};
 274         }
 275
 276         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 277         $rv;
 278 }
 279
 280 sub pad_link ($$;$) {
 281         my ($mid, $level, $s) = @_;
 282         $s ||= '...';
 283         my $id = id_compress($mid, 1);
 284         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 285 }
 286
 287 sub _th_index_lite {
 288         my ($mid_raw, $irt, $id, $ctx) = @_;
 289         my $rv = '';
 290         my $mapping = $ctx->{mapping} or return $rv;
 291         my $pad = '  ';
 292         my $mid_map = $mapping->{$mid_raw};
 293         defined $mid_map or
 294                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 295         my ($attr, $node, $idx, $level) = @$mid_map;
 296         my $children = $node->{children};
 297         my $nr_c = scalar @$children;
 298         my $nr_s = 0;
 299         my $siblings;
 300         if (my $smsg = $node->{smsg}) {
 301                 # delete saves about 200KB on a 1K message thread
 302                 if (my $refs = delete $smsg->{references}) {
 303                         ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 304                 }
 305         }
 306         my $irt_map = $mapping->{$$irt} if defined $$irt;
 307         if (defined $irt_map) {
 308                 $siblings = $irt_map->[1]->{children};
 309                 $nr_s = scalar(@$siblings) - 1;
 310                 $rv .= $pad . $irt_map->[0];
 311                 if ($idx > 0) {
 312                         my $prev = $siblings->[$idx - 1];
 313                         my $pmid = $prev->{id};
 314                         if ($idx > 2) {
 315                                 my $s = ($idx - 1). ' preceding siblings ...';
 316                                 $rv .= pad_link($pmid, $level, $s);
 317                         } elsif ($idx == 2) {
 318                                 my $ppmid = $siblings->[0]->{id};
 319                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 320                         }
 321                         $rv .= $pad . $mapping->{$pmid}->[0];
 322                 }
 323         }
 324         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 325         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 326         $attr =~ s!\n\z!</b>\n!s;
 327         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 328         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 329         $rv .= "<b>@ $attr";
 330         if ($nr_c) {
 331                 my $cmid = $children->[0]->{id};
 332                 $rv .= $pad . $mapping->{$cmid}->[0];
 333                 if ($nr_c > 2) {
 334                         my $s = ($nr_c - 1). ' more replies';
 335                         $rv .= pad_link($cmid, $level + 1, $s);
 336                 } elsif (my $cn = $children->[1]) {
 337                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 338                 }
 339         }
 340
 341         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 342         if ($next) {
 343                 my $nmid = $next->{id};
 344                 $rv .= $pad . $mapping->{$nmid}->[0];
 345                 my $nnext = $nr_s - $idx;
 346                 if ($nnext > 2) {
 347                         my $s = ($nnext - 1).' subsequent siblings';
 348                         $rv .= pad_link($nmid, $level, $s);
 349                 } elsif (my $nn = $siblings->[$idx + 2]) {
 350                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 351                 }
 352         }
 353         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 354 }
 355
 356 # non-recursive thread walker
 357 sub walk_thread ($$$) {
 358         my ($rootset, $ctx, $cb) = @_;
 359         my @q = map { (0, $_, -1) } @$rootset;
 360         while (@q) {
 361                 my ($level, $node, $i) = splice(@q, 0, 3);
 362                 defined $node or next;
 363                 $cb->($ctx, $level, $node, $i) or return;
 364                 ++$level;
 365                 $i = 0;
 366                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 367         }
 368 }
 369
 370 sub pre_thread  { # walk_thread callback
 371         my ($ctx, $level, $node, $idx) = @_;
 372         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 373         skel_dump($ctx, $level, $node);
 374 }
 375
 376 sub thread_index_entry {
 377         my ($ctx, $level, $smsg) = @_;
 378         my ($beg, $end) = thread_adj_level($ctx, $level);
 379         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 380 }
 381
 382 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 383         my ($nr, $ctx) = @_;
 384         return unless exists($ctx->{skel});
 385         my $q = $ctx->{-queue};
 386         while (@$q) {
 387                 my $level = shift @$q;
 388                 my $node = shift @$q or next;
 389                 my $cl = $level + 1;
 390                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 391                 if (my $smsg = $ctx->{-inbox}->smsg_mime($node->{smsg})) {
 392                         return thread_index_entry($ctx, $level, $smsg);
 393                 } else {
 394                         return ghost_index_entry($ctx, $level, $node);
 395                 }
 396         }
 397         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{skel}};
 398 }
 399
 400 sub stream_thread ($$) {
 401         my ($rootset, $ctx) = @_;
 402         my $ibx = $ctx->{-inbox};
 403         my @q = map { (0, $_) } @$rootset;
 404         my ($smsg, $level);
 405         while (@q) {
 406                 $level = shift @q;
 407                 my $node = shift @q or next;
 408                 my $cl = $level + 1;
 409                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 410                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 411         }
 412         return missing_thread($ctx) unless $smsg;
 413
 414         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 415         $ctx->{-title_html} = ascii_html($smsg->{subject});
 416         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 417         $ctx->{-queue} = \@q;
 418         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 419 }
 420
 421 # /$INBOX/$MESSAGE_ID/t/
 422 sub thread_html {
 423         my ($ctx) = @_;
 424         my $mid = $ctx->{mid};
 425         my $ibx = $ctx->{-inbox};
 426         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 427         return missing_thread($ctx) if $nr == 0;
 428         my $skel = '<hr><pre>';
 429         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 430         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 431         $skel .= "<b\nid=t>Thread overview:</b> ";
 432         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 433         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 434         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 435         $skel .= "-- links below jump to the message on this page --\n";
 436         $ctx->{-upfx} = '../../';
 437         $ctx->{cur_level} = 0;
 438         $ctx->{skel} = \$skel;
 439         $ctx->{prev_attr} = '';
 440         $ctx->{prev_level} = 0;
 441         $ctx->{root_anchor} = anchor_for($mid);
 442         $ctx->{mapping} = {};
 443         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 444                        .' in thread';
 445
 446         my $rootset = thread_results($ctx, $msgs);
 447
 448         # reduce hash lookups in pre_thread->skel_dump
 449         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 450         walk_thread($rootset, $ctx, \&pre_thread);
 451
 452         $skel .= '</pre>';
 453         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 454
 455         # flat display: lazy load the full message from smsg
 456         my $smsg;
 457         while (my $m = shift @$msgs) {
 458                 $smsg = $ibx->smsg_mime($m) and last;
 459         }
 460         return missing_thread($ctx) unless $smsg;
 461         $ctx->{-title_html} = ascii_html($smsg->{subject});
 462         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 463         $ctx->{msgs} = $msgs;
 464         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 465 }
 466
 467 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 468         my ($nr, $ctx) = @_;
 469         my $msgs = $ctx->{msgs} or return;
 470         while (my $smsg = shift @$msgs) {
 471                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 472                 return index_entry($smsg, $ctx, scalar @$msgs);
 473         }
 474         my ($skel) = delete @$ctx{qw(skel msgs)};
 475         $$skel;
 476 }
 477
 478 sub multipart_text_as_html {
 479         # ($mime, $ctx) = @_; # msg_iter will do "$_[0] = undef"
 480
 481         # scan through all parts, looking for displayable text
 482         msg_iter($_[0], \&add_text_body, $_[1], 1);
 483 }
 484
 485 sub attach_link ($$$$;$) {
 486         my ($ctx, $ct, $p, $fn, $err) = @_;
 487         my ($part, $depth, @idx) = @$p;
 488         my $nl = $idx[-1] > 1 ? "\n" : '';
 489         my $idx = join('.', @idx);
 490         my $size = bytes::length($part->body);
 491
 492         # hide attributes normally, unless we want to aid users in
 493         # spotting MUA problems:
 494         $ct =~ s/;.*// unless $err;
 495         $ct = ascii_html($ct);
 496         my $sfn;
 497         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 498                 $sfn = $fn;
 499         } elsif ($ct eq 'text/plain') {
 500                 $sfn = 'a.txt';
 501         } else {
 502                 $sfn = 'a.bin';
 503         }
 504         my $rv = $ctx->{obuf};
 505         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 506         if ($err) {
 507                 $$rv .= <<EOF;
 508 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 509 EOF
 510         }
 511         $$rv .= "[-- Attachment #$idx: ";
 512         my $ts = "Type: $ct, Size: $size bytes";
 513         my $desc = $part->header('Content-Description') // $fn // '';
 514         $desc = ascii_html($desc);
 515         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 516         $$rv .= "</a>\n";
 517         undef;
 518 }
 519
 520 sub add_text_body { # callback for msg_iter
 521         my ($p, $ctx) = @_;
 522         my $upfx = $ctx->{mhref};
 523         my $ibx = $ctx->{-inbox};
 524         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 525         my ($part, $depth, @idx) = @$p;
 526         my $ct = $part->content_type || 'text/plain';
 527         my $fn = $part->filename;
 528         my ($s, $err) = msg_part_text($part, $ct);
 529         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 530
 531         # makes no difference to browsers, and don't screw up filename
 532         # link generation in diffs with the extra '%0D'
 533         $s =~ s/\r\n/\n/sg;
 534
 535         # will be escaped to `&#8226;' in HTML
 536         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 537
 538         # always support diff-highlighting, but we can't linkify hunk
 539         # headers for solver unless some coderepo are configured:
 540         my $diff;
 541         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 542                 # diffstat anchors do not link across attachments or messages:
 543                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 544                 $ctx->{-apfx} = join('/', @idx);
 545                 $ctx->{-anchors} = {}; # attr => filename
 546                 $diff = 1;
 547                 delete $ctx->{-long_path};
 548                 my $spfx;
 549                 if ($ibx->{-repo_objs}) {
 550                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 551                                 $spfx = $upfx;
 552                                 $spfx =~ s!/([^/]*)/\z!/!;
 553                         } else {
 554                                 my $n_slash = $upfx =~ tr!/!/!;
 555                                 if ($n_slash == 0) {
 556                                         $spfx = '../';
 557                                 } elsif ($n_slash == 1) {
 558                                         $spfx = '';
 559                                 } else { # nslash == 2
 560                                         $spfx = '../../';
 561                                 }
 562                         }
 563                 }
 564                 $ctx->{-spfx} = $spfx;
 565         };
 566
 567         # some editors don't put trailing newlines at the end:
 568         $s .= "\n" unless $s =~ /\n\z/s;
 569
 570         # split off quoted and unquoted blocks:
 571         my @sections = PublicInbox::MsgIter::split_quotes($s);
 572         undef $s; # free memory
 573         my $rv = $ctx->{obuf};
 574         if (defined($fn) || $depth > 0 || $err) {
 575                 # badly-encoded message with $err? tell the world about it!
 576                 attach_link($ctx, $ct, $p, $fn, $err);
 577                 $$rv .= "\n";
 578         }
 579         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 580         foreach my $cur (@sections) {
 581                 if ($cur =~ /\A>/) {
 582                         # we use a <span> here to allow users to specify
 583                         # their own color for quoted text
 584                         $$rv .= qq(<span\nclass="q">);
 585                         $$rv .= $l->to_html($cur);
 586                         $$rv .= '</span>';
 587                 } elsif ($diff) {
 588                         flush_diff($ctx, \$cur);
 589                 } else {
 590                         # regular lines, OK
 591                         $$rv .= $l->to_html($cur);
 592                 }
 593                 undef $cur; # free memory
 594         }
 595 }
 596
 597 sub _msg_page_prepare_obuf {
 598         my ($hdr, $ctx, $nr) = @_;
 599         my $over = $ctx->{-inbox}->over;
 600         my $obfs_ibx = $ctx->{-obfs_ibx};
 601         my $rv = '';
 602         my $mids = mids_for_index($hdr);
 603         if ($nr == 0) {
 604                 if ($ctx->{more}) {
 605                         $rv .=
 606 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 607                 }
 608                 $rv .= "<pre\nid=b>"; # anchor for body start
 609         } else {
 610                 $rv .= '<pre>';
 611         }
 612         if ($over) {
 613                 $ctx->{-upfx} = '../';
 614         }
 615         my @title; # (Subject[0], From[0])
 616         for my $v ($hdr->header('From')) {
 617                 my @n = PublicInbox::Address::names($v);
 618                 $v = ascii_html($v);
 619                 $title[1] //= ascii_html(join(', ', @n));
 620                 if ($obfs_ibx) {
 621                         obfuscate_addrs($obfs_ibx, $v);
 622                         obfuscate_addrs($obfs_ibx, $title[1]);
 623                 }
 624                 $rv .= "From: $v\n" if $v ne '';
 625         }
 626         foreach my $h (qw(To Cc)) {
 627                 for my $v ($hdr->header($h)) {
 628                         fold_addresses($v);
 629                         $v = ascii_html($v);
 630                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 631                         $rv .= "$h: $v\n" if $v ne '';
 632                 }
 633         }
 634         my @subj = $hdr->header('Subject');
 635         if (@subj) {
 636                 my $v = ascii_html(shift @subj);
 637                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 638                 $rv .= 'Subject: ';
 639                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 640                 $title[0] = $v;
 641                 for $v (@subj) { # multi-Subject message :<
 642                         $v = ascii_html($v);
 643                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 644                         $rv .= "Subject: $v\n";
 645                 }
 646         } else { # dummy anchor for thread skeleton at bottom of page
 647                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 648                 $title[0] = '(no subject)';
 649         }
 650         for my $v ($hdr->header('Date')) {
 651                 $v = ascii_html($v);
 652                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 653                 $rv .= "Date: $v\n";
 654         }
 655         $ctx->{-title_html} = join(' - ', @title);
 656         if (scalar(@$mids) == 1) { # common case
 657                 my $mhtml = ascii_html($mids->[0]);
 658                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 659                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 660         } else {
 661                 # X-Alt-Message-ID can happen if a message is injected from
 662                 # public-inbox-nntpd because of multiple Message-ID headers.
 663                 my $lnk = PublicInbox::Linkify->new;
 664                 my $s = '';
 665                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 666                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 667                 }
 668                 $lnk->linkify_mids('..', \$s, 1);
 669                 $rv .= $s;
 670         }
 671         $rv .= _parent_headers($hdr, $over);
 672         $rv .= "\n";
 673         \$rv;
 674 }
 675
 676 sub SKEL_EXPAND () {
 677         qq(expand[<a\nhref="T/#u">flat</a>) .
 678                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 679                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 680                 qq(<a\nhref="t.atom">Atom feed</a>);
 681 }
 682
 683 sub thread_skel ($$$) {
 684         my ($skel, $ctx, $hdr) = @_;
 685         my $mid = mids($hdr)->[0];
 686         my $ibx = $ctx->{-inbox};
 687         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 688         my $parent = in_reply_to($hdr);
 689         $$skel .= "\n<b>Thread overview: </b>";
 690         if ($nr <= 1) {
 691                 if (defined $parent) {
 692                         $$skel .= SKEL_EXPAND."\n ";
 693                         $$skel .= ghost_parent('../', $parent) . "\n";
 694                 } else {
 695                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 696                 }
 697                 $ctx->{next_msg} = undef;
 698                 $ctx->{parent_msg} = $parent;
 699                 return;
 700         }
 701
 702         $$skel .= $nr;
 703         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 704
 705         # nb: mutt only shows the first Subject in the index pane
 706         # when multiple Subject: headers are present, so we follow suit:
 707         my $subj = $hdr->header('Subject') // '';
 708         $subj = '(no subject)' if $subj eq '';
 709         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 710         $ctx->{cur} = $mid;
 711         $ctx->{prev_attr} = '';
 712         $ctx->{prev_level} = 0;
 713         $ctx->{skel} = $skel;
 714
 715         # reduce hash lookups in skel_dump
 716         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 717         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 718
 719         $ctx->{parent_msg} = $parent;
 720 }
 721
 722 sub _parent_headers {
 723         my ($hdr, $over) = @_;
 724         my $rv = '';
 725         my @irt = $hdr->header_raw('In-Reply-To');
 726         my $refs;
 727         if (@irt) {
 728                 my $lnk = PublicInbox::Linkify->new;
 729                 $rv .= "In-Reply-To: $_\n" for @irt;
 730                 $lnk->linkify_mids('..', \$rv);
 731         } else {
 732                 $refs = references($hdr);
 733                 my $irt = pop @$refs;
 734                 if (defined $irt) {
 735                         my $html = ascii_html($irt);
 736                         my $href = mid_href($irt);
 737                         $rv .= "In-Reply-To: &lt;";
 738                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 739                 }
 740         }
 741
 742         # do not display References: if search is present,
 743         # we show the thread skeleton at the bottom, instead.
 744         return $rv if $over;
 745
 746         $refs //= references($hdr);
 747         if (@$refs) {
 748                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 749                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 750         }
 751         $rv;
 752 }
 753
 754 # returns a string buffer via ->getline
 755 sub html_footer {
 756         my ($ctx, $hdr) = @_;
 757         my $ibx = $ctx->{-inbox};
 758         my $upfx = '../';
 759         my $skel = " <a\nhref=\"$upfx\">index</a>";
 760         my $rv = '<pre>';
 761         if ($ibx->over) {
 762                 $skel .= "\n";
 763                 thread_skel(\$skel, $ctx, $hdr);
 764                 my ($next, $prev);
 765                 my $parent = '       ';
 766                 $next = $prev = '    ';
 767
 768                 if (my $n = $ctx->{next_msg}) {
 769                         $n = mid_href($n);
 770                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 771                 }
 772                 my $u;
 773                 my $par = $ctx->{parent_msg};
 774                 if ($par) {
 775                         $u = mid_href($par);
 776                         $u = "$upfx$u/";
 777                 }
 778                 if (my $p = $ctx->{prev_msg}) {
 779                         $prev = mid_href($p);
 780                         if ($p && $par && $p eq $par) {
 781                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 782                                         'rel=prev>prev parent</a>';
 783                                 $parent = '';
 784                         } else {
 785                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 786                                         'rel=prev>prev</a>';
 787                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 788                         }
 789                 } elsif ($u) { # unlikely
 790                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 791                 }
 792                 $rv .= "$next $prev$parent ";
 793         }
 794         $rv .= qq(<a\nhref="#R">reply</a>);
 795         $rv .= $skel;
 796         $rv .= '</pre>';
 797         $rv .= msg_reply($ctx, $hdr);
 798 }
 799
 800 sub linkify_ref_no_over {
 801         my ($mid) = @_;
 802         my $href = mid_href($mid);
 803         my $html = ascii_html($mid);
 804         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 805 }
 806
 807 sub anchor_for {
 808         my ($msgid) = @_;
 809         'm' . id_compress($msgid, 1);
 810 }
 811
 812 sub ghost_parent {
 813         my ($upfx, $mid) = @_;
 814
 815         my $href = mid_href($mid);
 816         my $html = ascii_html($mid);
 817         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 818 }
 819
 820 sub indent_for {
 821         my ($level) = @_;
 822         $level ? INDENT x ($level - 1) : '';
 823 }
 824
 825 sub find_mid_root {
 826         my ($ctx, $level, $node, $idx) = @_;
 827         ++$ctx->{root_idx} if $level == 0;
 828         if ($node->{id} eq $ctx->{mid}) {
 829                 $ctx->{found_mid_at} = $ctx->{root_idx};
 830                 return 0;
 831         }
 832         1;
 833 }
 834
 835 sub strict_loose_note ($) {
 836         my ($nr) = @_;
 837         my $msg =
 838 "  -- strict thread matches above, loose matches on Subject: below --\n";
 839
 840         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 841                 $msg .=
 842 "  -- use mbox.gz link to download all $nr messages --\n";
 843         }
 844         $msg;
 845 }
 846
 847 sub thread_results {
 848         my ($ctx, $msgs) = @_;
 849         require PublicInbox::SearchThread;
 850         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 851
 852         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 853         # and preserved in the future.  This bug is hidden by `sid' matches
 854         # in get_thread, so we never noticed it until now.  And even when
 855         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 856         # bump since reindexing is expensive and users may not do it
 857
 858         # loose threading could've returned too many results,
 859         # put the root the message we care about at the top:
 860         my $mid = $ctx->{mid};
 861         if (defined($mid) && scalar(@$rootset) > 1) {
 862                 $ctx->{root_idx} = -1;
 863                 my $nr = scalar @$msgs;
 864                 walk_thread($rootset, $ctx, \&find_mid_root);
 865                 my $idx = $ctx->{found_mid_at};
 866                 if (defined($idx) && $idx != 0) {
 867                         my $tip = splice(@$rootset, $idx, 1);
 868                         @$rootset = reverse @$rootset;
 869                         unshift @$rootset, $tip;
 870                         $ctx->{sl_note} = strict_loose_note($nr);
 871                 }
 872         }
 873         $rootset
 874 }
 875
 876 sub missing_thread {
 877         my ($ctx) = @_;
 878         require PublicInbox::ExtMsg;
 879         PublicInbox::ExtMsg::ext_msg($ctx);
 880 }
 881
 882 sub dedupe_subject {
 883         my ($prev_subj, $subj, $val) = @_;
 884
 885         my $omit; # '"' denotes identical text omitted
 886         my (@prev_pop, @curr_pop);
 887         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 888                 push(@prev_pop, pop(@$prev_subj));
 889                 push(@curr_pop, pop(@$subj));
 890                 $omit //= $val;
 891         }
 892         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 893         if (scalar(@curr_pop) == 1) {
 894                 $omit = undef;
 895                 push @$prev_subj, @prev_pop;
 896                 push @$subj, @curr_pop;
 897         }
 898         $omit // '';
 899 }
 900
 901 sub skel_dump { # walk_thread callback
 902         my ($ctx, $level, $node) = @_;
 903         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 904
 905         my $skel = $ctx->{skel};
 906         my $cur = $ctx->{cur};
 907         my $mid = $smsg->{mid};
 908
 909         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 910                 $$skel .= delete($ctx->{sl_note}) || '';
 911         }
 912
 913         my $f = ascii_html($smsg->{from_name});
 914         my $obfs_ibx = $ctx->{-obfs_ibx};
 915         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 916
 917         my $d = fmt_ts($smsg->{ds});
 918         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 919         if (exists $ctx->{searchview}) {
 920                 if (defined(my $pct = $smsg->{pct})) {
 921                         $d .= (sprintf(' % 2u', $pct) . '%');
 922                 } else {
 923                         $unmatched = 1;
 924                         $d .= '    ';
 925                 }
 926         }
 927         $d .= ' ' . indent_for($level) . th_pfx($level);
 928         my $attr = $f;
 929         $ctx->{first_level} ||= $level;
 930
 931         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 932                 $ctx->{prev_attr} = $attr;
 933         }
 934         $ctx->{prev_level} = $level;
 935
 936         if ($cur) {
 937                 if ($cur eq $mid) {
 938                         delete $ctx->{cur};
 939                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 940                                  "$attr [this message]</a></b>\n";
 941                         return 1;
 942                 } else {
 943                         $ctx->{prev_msg} = $mid;
 944                 }
 945         } else {
 946                 $ctx->{next_msg} ||= $mid;
 947         }
 948
 949         # Subject is never undef, this mail was loaded from
 950         # our Xapian which would've resulted in '' if it were
 951         # really missing (and Filter rejects empty subjects)
 952         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 953         # remove common suffixes from the subject if it matches the previous,
 954         # so we do not show redundant text at the end.
 955         my $prev_subj = $ctx->{prev_subj} || [];
 956         $ctx->{prev_subj} = [ @subj ];
 957         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 958         my $end;
 959         if (@subj) {
 960                 my $subj = join(' ', @subj);
 961                 $subj = ascii_html($subj);
 962                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 963                 $end = "$subj</a> $omit$f\n"
 964         } else {
 965                 $end = "$f</a>\n";
 966         }
 967         my $m;
 968         my $id = '';
 969         my $mapping = $unmatched ? undef : $ctx->{mapping};
 970         if ($mapping) {
 971                 my $map = $mapping->{$mid};
 972                 $id = id_compress($mid, 1);
 973                 $m = '#m'.$id;
 974                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 975                 $id = "\nid=r".$id;
 976         } else {
 977                 $m = $ctx->{-upfx}.mid_href($mid).'/';
 978         }
 979         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 980         1;
 981 }
 982
 983 sub _skel_ghost {
 984         my ($ctx, $level, $node) = @_;
 985
 986         my $mid = $node->{id};
 987         my $d = '     [not found] ';
 988         $d .= '    '  if exists $ctx->{searchview};
 989         $d .= indent_for($level) . th_pfx($level);
 990         my $upfx = $ctx->{-upfx};
 991         my $href = $upfx . mid_href($mid) . '/';
 992         my $html = ascii_html($mid);
 993
 994         my $mapping = $ctx->{mapping};
 995         my $map = $mapping->{$mid} if $mapping;
 996         if ($map) {
 997                 my $id = id_compress($mid, 1);
 998                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 999                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1000         } else {
1001                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1002         }
1003         ${$ctx->{skel}} .= $d;
1004         1;
1005 }
1006
1007 sub sort_ds {
1008         [ sort {
1009                 (eval { $a->topmost->{smsg}->{ds} } || 0) <=>
1010                 (eval { $b->topmost->{smsg}->{ds} } || 0)
1011         } @{$_[0]} ];
1012 }
1013
1014 # accumulate recent topics if search is supported
1015 # returns 200 if done, 404 if not
1016 sub acc_topic { # walk_thread callback
1017         my ($ctx, $level, $node) = @_;
1018         my $mid = $node->{id};
1019         my $smsg = $node->{smsg} // $ctx->{-inbox}->smsg_by_mid($mid);
1020         if ($smsg) {
1021                 my $subj = subject_normalized($smsg->{subject});
1022                 $subj = '(no subject)' if $subj eq '';
1023                 my $ds = $smsg->{ds};
1024                 if ($level == 0) { # new, top-level topic
1025                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1026                         $ctx->{-cur_topic} = $topic;
1027                         push @{$ctx->{order}}, $topic;
1028                         return 1;
1029                 }
1030
1031                 # continue existing topic
1032                 my $topic = $ctx->{-cur_topic}; # should never be undef
1033                 $topic->[0] = $ds if $ds > $topic->[0];
1034                 $topic->[1]++; # bump N+ message counter
1035                 my $seen = $topic->[2];
1036                 if (scalar(@$topic) == 3) { # parent was a ghost
1037                         push @$topic, $subj;
1038                 } elsif (!defined($seen->{$subj})) {
1039                         push @$topic, $level, $subj; # @extra messages
1040                 }
1041                 $seen->{$subj} = $mid; # latest for subject
1042         } else { # ghost message
1043                 return 1 if $level != 0; # ignore child ghosts
1044                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1045                 push @{$ctx->{order}}, $topic;
1046         }
1047         1;
1048 }
1049
1050 sub dump_topics {
1051         my ($ctx) = @_;
1052         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1053         unless ($order) {
1054                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1055                 return 404;
1056         }
1057
1058         my @out;
1059         my $ibx = $ctx->{-inbox};
1060         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1061
1062         # sort by recency, this allows new posts to "bump" old topics...
1063         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1064                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1065                 @$topic = ();
1066                 next unless defined $top_subj;  # ghost topic
1067                 my $mid = delete $seen->{$top_subj};
1068                 my $href = mid_href($mid);
1069                 my $prev_subj = [ split(/ /, $top_subj) ];
1070                 $top_subj = ascii_html($top_subj);
1071                 $ds = fmt_ts($ds);
1072
1073                 # $n isn't the total number of posts on the topic,
1074                 # just the number of posts in the current results window
1075                 my $anchor;
1076                 if ($n == 1) {
1077                         $n = '';
1078                         $anchor = '#u'; # top of only message
1079                 } else {
1080                         $n = " ($n+ messages)";
1081                         $anchor = '#t'; # thread skeleton
1082                 }
1083
1084                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1085                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1086                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1087                         " $ds UTC $n - $mbox / $atom\n";
1088                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1089                         my $level = $extra[$i];
1090                         my $subj = $extra[$i + 1]; # already normalized
1091                         $mid = delete $seen->{$subj};
1092                         my @subj = split(/ /, $subj);
1093                         my @next_prev = @subj; # full copy
1094                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1095                         $prev_subj = \@next_prev;
1096                         $subj = ascii_html($subj);
1097                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1098                         $href = mid_href($mid);
1099                         $s .= indent_for($level) . TCHILD;
1100                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1101                 }
1102                 push @out, $s;
1103         }
1104         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1105         200;
1106 }
1107
1108 # only for the t= query parameter passed to overview DB
1109 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1110
1111 sub str2ts ($) {
1112         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1113         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1114 }
1115
1116 sub pagination_footer ($$) {
1117         my ($ctx, $latest) = @_;
1118         delete $ctx->{qp} or return;
1119         my $next = $ctx->{next_page} || '';
1120         my $prev = $ctx->{prev_page} || '';
1121         if ($prev) {
1122                 $next = $next ? "$next " : '     ';
1123                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1124         }
1125         "<hr><pre>page: $next$prev</pre>";
1126 }
1127
1128 sub index_nav { # callback for WwwStream
1129         my (undef, $ctx) = @_;
1130         pagination_footer($ctx, '.')
1131 }
1132
1133 sub paginate_recent ($$) {
1134         my ($ctx, $lim) = @_;
1135         my $t = $ctx->{qp}->{t} || '';
1136         my $opts = { limit => $lim };
1137         my ($after, $before);
1138
1139         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1140         # if only $after exists "YYYYMMDD.." because "." could be skipped
1141         # if interpreted as an end-of-sentence
1142         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1143         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1144
1145         my $ibx = $ctx->{-inbox};
1146         my $msgs = $ibx->recent($opts, $after, $before);
1147         my $nr = scalar @$msgs;
1148         if ($nr < $lim && defined($after)) {
1149                 $after = $before = undef;
1150                 $msgs = $ibx->recent($opts);
1151                 $nr = scalar @$msgs;
1152         }
1153         my $more = $nr == $lim;
1154         my ($newest, $oldest);
1155         if ($nr) {
1156                 $newest = $msgs->[0]->{ts};
1157                 $oldest = $msgs->[-1]->{ts};
1158                 # if we only had $after, our SQL query in ->recent ordered
1159                 if ($newest < $oldest) {
1160                         ($oldest, $newest) = ($newest, $oldest);
1161                         $more = 0 if defined($after) && $after < $oldest;
1162                 }
1163         }
1164         if (defined($oldest) && $more) {
1165                 my $s = ts2str($oldest);
1166                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1167         }
1168         if (defined($newest) && (defined($before) || defined($after))) {
1169                 my $s = ts2str($newest);
1170                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1171         }
1172         $msgs;
1173 }
1174
1175 sub index_topics {
1176         my ($ctx) = @_;
1177         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1178         if (@$msgs) {
1179                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1180         }
1181         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), \&index_nav);
1182 }
1183
1184 sub thread_adj_level {
1185         my ($ctx, $level) = @_;
1186
1187         my $max = $ctx->{cur_level};
1188         if ($level <= 0) {
1189                 return ('', '') if $max == 0; # flat output
1190
1191                 # reset existing lists
1192                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1193                 $ctx->{cur_level} = 0;
1194                 ("$beg</ul>", '');
1195         } elsif ($level == $max) { # continue existing list
1196                 qw(<li> </li>);
1197         } elsif ($level < $max) {
1198                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1199                 $ctx->{cur_level} = $level;
1200                 ("$beg<li>", '</li>');
1201         } else { # ($level > $max) # start a new level
1202                 $ctx->{cur_level} = $level;
1203                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1204                 ($beg, '</li>');
1205         }
1206 }
1207
1208 sub ghost_index_entry {
1209         my ($ctx, $level, $node) = @_;
1210         my ($beg, $end) = thread_adj_level($ctx,  $level);
1211         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1212                 . '</pre>' . $end;
1213 }
1214
1215 1;