lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use URI::Escape qw/uri_escape/;
   7 use CGI qw/escapeHTML/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 use constant MAX_INLINE_QUOTED => 5;
  12 use constant MAX_TRUNC_LEN => 72;
  13
  14 my $enc_utf8 = find_encoding('utf8');
  15 my $enc_ascii = find_encoding('us-ascii');
  16 my $enc_mime = find_encoding('MIME-Header');
  17
  18 # public functions:
  19 sub as_html {
  20         my ($class, $mime, $full_pfx) = @_;
  21
  22         headers_to_html_header($mime) .
  23                 multipart_text_as_html($mime, $full_pfx) .
  24                 '</pre></body></html>';
  25 }
  26
  27 sub as_feed_entry {
  28         my ($class, $mime, $full_pfx) = @_;
  29
  30         "<pre>" . multipart_text_as_html($mime, $full_pfx) . "</pre>";
  31 }
  32
  33
  34 # only private functions below.
  35
  36 sub enc_for {
  37         my ($ct) = @_;
  38         defined $ct or return $enc_utf8;
  39         my $ct_parsed = parse_content_type($ct);
  40         if ($ct_parsed) {
  41                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
  42                         my $enc = find_encoding($charset);
  43                         return $enc if $enc;
  44                 }
  45         }
  46         $enc_utf8;
  47 }
  48
  49 sub multipart_text_as_html {
  50         my ($mime, $full_pfx) = @_;
  51         my $rv = "";
  52         my $part_nr = 0;
  53         my $enc_msg = enc_for($mime->header("Content-Type"));
  54
  55         # scan through all parts, looking for displayable text
  56         $mime->walk_parts(sub {
  57                 my ($part) = @_;
  58                 return if $part->subparts; # walk_parts already recurses
  59                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  60
  61                 if ($part_nr > 0) {
  62                         my $fn = $part->filename;
  63                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  64                         $rv .= add_filename_line($enc->decode($fn));
  65                 }
  66
  67                 if (defined $full_pfx) {
  68                         $rv .= add_text_body_short($enc, $part, $part_nr,
  69                                                 $full_pfx);
  70                 } else {
  71                         $rv .= add_text_body_full($enc, $part, $part_nr);
  72                 }
  73                 $rv .= "\n" unless $rv =~ /\n\z/s;
  74                 ++$part_nr;
  75         });
  76         $rv;
  77 }
  78
  79 sub add_filename_line {
  80         my ($fn) = @_;
  81         my $len = 72;
  82         my $pad = "-";
  83
  84         $len -= length($fn);
  85         $pad x= ($len/2) if ($len > 0);
  86         "$pad " . ascii_html($fn) . " $pad\n";
  87 }
  88
  89 sub add_text_body_short {
  90         my ($enc, $part, $part_nr, $full_pfx) = @_;
  91         my $n = 0;
  92         my $s = ascii_html($enc->decode($part->body));
  93         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
  94                 my $cur = $1;
  95                 my @lines = split(/\n/, $cur);
  96                 if (@lines > MAX_INLINE_QUOTED) {
  97                         # show a short snippet of quoted text
  98                         $cur = join(' ', @lines);
  99                         $cur =~ s/^&gt;\s*//;
 100
 101                         my @sum = split(/\s+/, $cur);
 102                         $cur = '';
 103                         do {
 104                                 my $tmp = shift(@sum);
 105                                 my $len = length($tmp) + length($cur);
 106                                 if ($len > MAX_TRUNC_LEN) {
 107                                         @sum = ();
 108                                 } else {
 109                                         $cur .= $tmp . ' ';
 110                                 }
 111                         } while (@sum && length($cur) < MAX_TRUNC_LEN);
 112                         $cur =~ s/ \z/ .../;
 113                         "&gt; &lt;<a href=\"${full_pfx}#q${part_nr}_" . $n++ .
 114                                 "\">$cur<\/a>&gt;\n";
 115                 } else {
 116                         $cur;
 117                 }
 118         !emg;
 119         $s;
 120 }
 121
 122 sub add_text_body_full {
 123         my ($enc, $part, $part_nr) = @_;
 124         my $n = 0;
 125         my $s = ascii_html($enc->decode($part->body));
 126         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 127                 my $cur = $1;
 128                 my @lines = split(/\n/, $cur);
 129                 if (@lines > MAX_INLINE_QUOTED) {
 130                         "<a name=q${part_nr}_" . $n++ . ">$cur</a>";
 131                 } else {
 132                         $cur;
 133                 }
 134         !emg;
 135         $s;
 136 }
 137
 138 sub trim_message_id {
 139         my ($mid) = @_;
 140         $mid =~ s/\A\s*<//;
 141         $mid =~ s/>\s*\z//;
 142         my $html = ascii_html($mid);
 143         my $href = ascii_html(uri_escape($mid));
 144
 145         ($html, $href);
 146 }
 147
 148 sub ascii_html {
 149         $enc_ascii->encode(escapeHTML($_[0]), Encode::HTMLCREF);
 150 }
 151
 152 sub headers_to_html_header {
 153         my ($simple) = @_;
 154
 155         my $rv = "";
 156         my @title;
 157         foreach my $h (qw(From To Cc Subject Date)) {
 158                 my $v = $simple->header($h);
 159                 defined $v or next;
 160                 $v =~ tr/\n/ /s;
 161                 $v =~ tr/\r//d;
 162                 my $raw = $enc_mime->decode($v);
 163                 $v = ascii_html($raw);
 164                 $rv .= "$h: $v\n";
 165
 166                 if ($h eq 'From') {
 167                         my @from = Email::Address->parse($raw);
 168                         $raw = $from[0]->name;
 169                         unless (defined($raw) && length($raw)) {
 170                                 $raw = '<' . $from[0]->address . '>';
 171                         }
 172                         $title[1] = ascii_html($raw);
 173
 174                 } elsif ($h eq 'Subject') {
 175                         $title[0] = $v;
 176                 }
 177         }
 178
 179         my $mid = $simple->header('Message-ID');
 180         if (defined $mid) {
 181                 my ($html, $href) = trim_message_id($mid);
 182                 $rv .= "Message-ID: &lt;$html&gt; ";
 183                 $rv .= "(<a href=\"$href.txt\">original</a>)\n";
 184         }
 185
 186         my $irp = $simple->header('In-Reply-To');
 187         if (defined $irp) {
 188                 my ($html, $href) = trim_message_id($irp);
 189                 $rv .= "In-Reply-To: &lt;";
 190                 $rv .= "<a href=\"$href.html\">$html</a>&gt;\n";
 191         }
 192         $rv .= "\n";
 193
 194         ("<html><head><title>".  join(' - ', @title) .
 195          '</title></head><body><pre style="white-space:pre-wrap">' .  $rv);
 196 }
 197
 198 1;