lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::Smsg qw(subject_normalized);
  23 use constant COLS => 72;
  24 use constant INDENT => '  ';
  25 use constant TCHILD => '` ';
  26 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  27
  28 sub msg_page_i {
  29         my ($nr, $ctx) = @_;
  30         if (my $more = delete $ctx->{more}) { # unlikely
  31                 # fake an EOF if $more retrieval fails;
  32                 eval { msg_page_more($ctx, $nr, @$more) };
  33         } elsif (my $hdr = delete $ctx->{hdr}) {
  34                 # fake an EOF if generating the footer fails;
  35                 # we want to at least show the message if something
  36                 # here crashes:
  37                 eval { html_footer($ctx, $hdr) };
  38         } else {
  39                 undef
  40         }
  41 }
  42
  43 # public functions: (unstable)
  44
  45 sub msg_page {
  46         my ($ctx) = @_;
  47         my $mid = $ctx->{mid};
  48         my $ibx = $ctx->{-inbox};
  49         my ($smsg, $first, $next);
  50         if (my $over = $ibx->over) {
  51                 my ($id, $prev);
  52                 $smsg = $over->next_by_mid($mid, \$id, \$prev) or return;
  53                 $first = $ibx->msg_by_smsg($smsg) or return;
  54                 $next = $over->next_by_mid($mid, \$id, \$prev);
  55                 $ctx->{more} = [ $id, $prev, $next ] if $next;
  56         } else {
  57                 $first = $ibx->msg_by_mid($mid) or return;
  58         }
  59         my $mime = PublicInbox::MIME->new($first);
  60         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  61         my $hdr = $ctx->{hdr} = $mime->header_obj;
  62         $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx, 0);
  63         $ctx->{smsg} = $smsg;
  64         # $next cannot be true w/o $smsg being defined:
  65         $ctx->{mhref} = $next ? '../'.mid_href($smsg->{mid}).'/' : '';
  66         multipart_text_as_html($mime, $ctx);
  67         $ctx->{-html_tip} = (${delete $ctx->{obuf}} .= '</pre><hr>');
  68         PublicInbox::WwwStream->response($ctx, 200, \&msg_page_i);
  69 }
  70
  71 sub msg_page_more { # cold
  72         my ($ctx, $nr, $id, $prev, $smsg) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         my $next = $ibx->over->next_by_mid($ctx->{mid}, \$id, \$prev);
  75         $ctx->{more} = [ $id, $prev, $next ] if $next;
  76         $smsg = $ibx->smsg_mime($smsg) or return '';
  77         $ctx->{mhref} = '../' . mid_href($smsg->{mid}) . '/';
  78         my $mime = delete $smsg->{mime};
  79         $ctx->{obuf} = _msg_page_prepare_obuf($mime->header_obj, $ctx, $nr);
  80         multipart_text_as_html($mime, $ctx);
  81         ${delete $ctx->{obuf}} .= '</pre><hr>';
  82 }
  83
  84 # /$INBOX/$MESSAGE_ID/#R
  85 sub msg_reply ($$) {
  86         my ($ctx, $hdr) = @_;
  87         my $se_url =
  88          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  89         my $p_url =
  90          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  91
  92         my $info = '';
  93         my $ibx = $ctx->{-inbox};
  94         if (my $url = $ibx->{infourl}) {
  95                 $url = prurl($ctx->{env}, $url);
  96                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  97         }
  98
  99         my ($arg, $link, $reply_to_all) =
 100                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 101         if (ref($arg) eq 'SCALAR') {
 102                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 103         }
 104
 105         # mailto: link only works if address obfuscation is disabled
 106         if ($link) {
 107                 $link = <<EOF;
 108
 109 * If your mail client supports setting the <b>In-Reply-To</b> header
 110   via mailto: links, try the <a
 111 href="$link">mailto: link</a>
 112 EOF
 113         }
 114
 115         push @$arg, '/path/to/YOUR_REPLY';
 116         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 117         <<EOF
 118 <hr><pre
 119 id=R><b>Reply instructions:</b>
 120
 121 You may reply publicly to <a
 122 href=#t>this message</a> via plain-text email
 123 using any one of the following methods:
 124
 125 * Save the following mbox file, import it into your mail client,
 126   and $reply_to_all from there: <a
 127 href=raw>mbox</a>
 128
 129   Avoid top-posting and favor interleaved quoting:
 130   <a
 131 href="$p_url">$p_url</a>
 132 $info
 133 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 134   switches of git-send-email(1):
 135
 136   git send-email$arg
 137
 138   <a
 139 href="$se_url">$se_url</a>
 140 $link</pre>
 141 EOF
 142 }
 143
 144 sub in_reply_to {
 145         my ($hdr) = @_;
 146         my $refs = references($hdr);
 147         $refs->[-1];
 148 }
 149
 150 sub fold_addresses ($) {
 151         return $_[0] if length($_[0]) <= COLS;
 152         # try to fold on commas after non-word chars before $lim chars,
 153         # Try to get the "," preceeded by ">" or ")", but avoid folding
 154         # on the comma where somebody uses "Lastname, Firstname".
 155         # We also try to keep the last and penultimate addresses in
 156         # the list on the same line if possible, hence the extra \z
 157         # Fall back to folding on spaces at $lim + 1 chars
 158         my $lim = COLS - 8; # 8 = "\t" display width
 159         my $too_long = $lim + 1;
 160         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 161         $_[0] = join("\n\t",
 162                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 163                                 .{1,$lim}(?:,|\z)|
 164                                 .{1,$lim}|
 165                                 .{$too_long,}?)(?:\s|\z)/xgo));
 166 }
 167
 168 sub _hdr_names_html ($$) {
 169         my ($hdr, $field) = @_;
 170         my @vals = $hdr->header($field) or return '';
 171         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 172 }
 173
 174 sub nr_to_s ($$$) {
 175         my ($nr, $singular, $plural) = @_;
 176         return "0 $plural" if $nr == 0;
 177         $nr == 1 ? "$nr $singular" : "$nr $plural";
 178 }
 179
 180 # human-friendly format
 181 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 182
 183 # this is already inside a <pre>
 184 sub index_entry {
 185         my ($smsg, $ctx, $more) = @_;
 186         my $subj = $smsg->subject;
 187         my $mid_raw = $smsg->mid;
 188         my $id = id_compress($mid_raw, 1);
 189         my $id_m = 'm'.$id;
 190
 191         my $root_anchor = $ctx->{root_anchor} || '';
 192         my $irt;
 193         my $obfs_ibx = $ctx->{-obfs_ibx};
 194
 195         $subj = '(no subject)' if $subj eq '';
 196         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 197         $subj = '<b>'.ascii_html($subj).'</b>';
 198         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 199         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 200         $rv .= $subj . "\n";
 201         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 202         my @tocc;
 203         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 204         # deleting {mime} is critical to memory use,
 205         # the rest of the fields saves about 400K as we iterate across 1K msgs
 206         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 207
 208         my $hdr = $mime->header_obj;
 209         my $from = _hdr_names_html($hdr, 'From');
 210         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 211         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 212         my $upfx = $ctx->{-upfx};
 213         my $mhref = $upfx . mid_href($mid_raw) . '/';
 214         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 215         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 216         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 217         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 218         my ($tlen, $clen) = (length($to), length($cc));
 219         my $to_cc = '';
 220         if (($tlen + $clen) > COLS) {
 221                 $to_cc .= '  To: '.$to."\n" if $tlen;
 222                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 223         } else {
 224                 if ($tlen) {
 225                         $to_cc .= '  To: '.$to;
 226                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 227                 } else {
 228                         $to_cc .= '  Cc: '.$cc if $clen;
 229                 }
 230                 $to_cc .= "\n";
 231         }
 232         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 233         $rv .= $to_cc;
 234
 235         my $mapping = $ctx->{mapping};
 236         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 237                 my $href = $upfx . mid_href($irt) . '/';
 238                 my $html = ascii_html($irt);
 239                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 240         }
 241         $rv .= "\n";
 242
 243         # scan through all parts, looking for displayable text
 244         $ctx->{mhref} = $mhref;
 245         $ctx->{obuf} = \$rv;
 246         msg_iter($mime, \&add_text_body, $ctx, 1);
 247         delete $ctx->{obuf};
 248
 249         # add the footer
 250         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 251                 "<a\nhref=\"$mhref\">permalink</a>" .
 252                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 253                 " <a\nhref=\"${mhref}#R\">reply</a>";
 254
 255         my $hr;
 256         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 257                 $rv .= "\t[relevance $pct%]";
 258                 $hr = 1;
 259         } elsif ($mapping) {
 260                 my $nested = 'nested';
 261                 my $flat = 'flat';
 262                 my $end = '';
 263                 if ($ctx->{flat}) {
 264                         $hr = 1;
 265                         $flat = "<b>$flat</b>";
 266                 } else {
 267                         $nested = "<b>$nested</b>";
 268                 }
 269                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 270                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 271                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 272         } else {
 273                 $hr = $ctx->{-hr};
 274         }
 275
 276         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 277         $rv;
 278 }
 279
 280 sub pad_link ($$;$) {
 281         my ($mid, $level, $s) = @_;
 282         $s ||= '...';
 283         my $id = id_compress($mid, 1);
 284         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 285 }
 286
 287 sub _th_index_lite {
 288         my ($mid_raw, $irt, $id, $ctx) = @_;
 289         my $rv = '';
 290         my $mapping = $ctx->{mapping} or return $rv;
 291         my $pad = '  ';
 292         my $mid_map = $mapping->{$mid_raw};
 293         defined $mid_map or
 294                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 295         my ($attr, $node, $idx, $level) = @$mid_map;
 296         my $children = $node->{children};
 297         my $nr_c = scalar @$children;
 298         my $nr_s = 0;
 299         my $siblings;
 300         if (my $smsg = $node->{smsg}) {
 301                 # delete saves about 200KB on a 1K message thread
 302                 if (my $refs = delete $smsg->{references}) {
 303                         ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 304                 }
 305         }
 306         my $irt_map = $mapping->{$$irt} if defined $$irt;
 307         if (defined $irt_map) {
 308                 $siblings = $irt_map->[1]->{children};
 309                 $nr_s = scalar(@$siblings) - 1;
 310                 $rv .= $pad . $irt_map->[0];
 311                 if ($idx > 0) {
 312                         my $prev = $siblings->[$idx - 1];
 313                         my $pmid = $prev->{id};
 314                         if ($idx > 2) {
 315                                 my $s = ($idx - 1). ' preceding siblings ...';
 316                                 $rv .= pad_link($pmid, $level, $s);
 317                         } elsif ($idx == 2) {
 318                                 my $ppmid = $siblings->[0]->{id};
 319                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 320                         }
 321                         $rv .= $pad . $mapping->{$pmid}->[0];
 322                 }
 323         }
 324         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 325         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 326         $attr =~ s!\n\z!</b>\n!s;
 327         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 328         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 329         $rv .= "<b>@ $attr";
 330         if ($nr_c) {
 331                 my $cmid = $children->[0]->{id};
 332                 $rv .= $pad . $mapping->{$cmid}->[0];
 333                 if ($nr_c > 2) {
 334                         my $s = ($nr_c - 1). ' more replies';
 335                         $rv .= pad_link($cmid, $level + 1, $s);
 336                 } elsif (my $cn = $children->[1]) {
 337                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 338                 }
 339         }
 340
 341         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 342         if ($next) {
 343                 my $nmid = $next->{id};
 344                 $rv .= $pad . $mapping->{$nmid}->[0];
 345                 my $nnext = $nr_s - $idx;
 346                 if ($nnext > 2) {
 347                         my $s = ($nnext - 1).' subsequent siblings';
 348                         $rv .= pad_link($nmid, $level, $s);
 349                 } elsif (my $nn = $siblings->[$idx + 2]) {
 350                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 351                 }
 352         }
 353         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 354 }
 355
 356 # non-recursive thread walker
 357 sub walk_thread ($$$) {
 358         my ($rootset, $ctx, $cb) = @_;
 359         my @q = map { (0, $_, -1) } @$rootset;
 360         while (@q) {
 361                 my ($level, $node, $i) = splice(@q, 0, 3);
 362                 defined $node or next;
 363                 $cb->($ctx, $level, $node, $i) or return;
 364                 ++$level;
 365                 $i = 0;
 366                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 367         }
 368 }
 369
 370 sub pre_thread  { # walk_thread callback
 371         my ($ctx, $level, $node, $idx) = @_;
 372         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 373         skel_dump($ctx, $level, $node);
 374 }
 375
 376 sub thread_index_entry {
 377         my ($ctx, $level, $smsg) = @_;
 378         my ($beg, $end) = thread_adj_level($ctx, $level);
 379         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 380 }
 381
 382 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 383         my ($nr, $ctx) = @_;
 384         return unless exists($ctx->{skel});
 385         my $q = $ctx->{-queue};
 386         while (@$q) {
 387                 my $level = shift @$q;
 388                 my $node = shift @$q or next;
 389                 my $cl = $level + 1;
 390                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 391                 if (my $smsg = $ctx->{-inbox}->smsg_mime($node->{smsg})) {
 392                         return thread_index_entry($ctx, $level, $smsg);
 393                 } else {
 394                         return ghost_index_entry($ctx, $level, $node);
 395                 }
 396         }
 397         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{skel}};
 398 }
 399
 400 sub stream_thread ($$) {
 401         my ($rootset, $ctx) = @_;
 402         my $ibx = $ctx->{-inbox};
 403         my @q = map { (0, $_) } @$rootset;
 404         my ($smsg, $level);
 405         while (@q) {
 406                 $level = shift @q;
 407                 my $node = shift @q or next;
 408                 my $cl = $level + 1;
 409                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 410                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 411         }
 412         return missing_thread($ctx) unless $smsg;
 413
 414         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 415         $ctx->{-title_html} = ascii_html($smsg->{subject});
 416         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 417         $ctx->{-queue} = \@q;
 418         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 419 }
 420
 421 # /$INBOX/$MESSAGE_ID/t/
 422 sub thread_html {
 423         my ($ctx) = @_;
 424         my $mid = $ctx->{mid};
 425         my $ibx = $ctx->{-inbox};
 426         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 427         return missing_thread($ctx) if $nr == 0;
 428         my $skel = '<hr><pre>';
 429         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 430         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 431         $skel .= "<b\nid=t>Thread overview:</b> ";
 432         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 433         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 434         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 435         $skel .= "-- links below jump to the message on this page --\n";
 436         $ctx->{-upfx} = '../../';
 437         $ctx->{cur_level} = 0;
 438         $ctx->{skel} = \$skel;
 439         $ctx->{prev_attr} = '';
 440         $ctx->{prev_level} = 0;
 441         $ctx->{root_anchor} = anchor_for($mid);
 442         $ctx->{mapping} = {};
 443         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 444                        .' in thread';
 445
 446         my $rootset = thread_results($ctx, $msgs);
 447
 448         # reduce hash lookups in pre_thread->skel_dump
 449         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 450         walk_thread($rootset, $ctx, \&pre_thread);
 451
 452         $skel .= '</pre>';
 453         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 454
 455         # flat display: lazy load the full message from smsg
 456         my $smsg;
 457         while (my $m = shift @$msgs) {
 458                 $smsg = $ibx->smsg_mime($m) and last;
 459         }
 460         return missing_thread($ctx) unless $smsg;
 461         $ctx->{-title_html} = ascii_html($smsg->{subject});
 462         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 463         $ctx->{msgs} = $msgs;
 464         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 465 }
 466
 467 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 468         my ($nr, $ctx) = @_;
 469         my $msgs = $ctx->{msgs} or return;
 470         while (my $smsg = shift @$msgs) {
 471                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 472                 return index_entry($smsg, $ctx, scalar @$msgs);
 473         }
 474         my ($skel) = delete @$ctx{qw(skel msgs)};
 475         $$skel;
 476 }
 477
 478 sub multipart_text_as_html {
 479         # ($mime, $ctx) = @_; # msg_iter will do "$_[0] = undef"
 480
 481         # scan through all parts, looking for displayable text
 482         msg_iter($_[0], \&add_text_body, $_[1], 1);
 483 }
 484
 485 sub flush_quote {
 486         my ($s, $l, $quot) = @_;
 487
 488         my $rv = $l->to_html($$quot);
 489
 490         # we use a <span> here to allow users to specify their own
 491         # color for quoted text
 492         $$quot = undef;
 493         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 494 }
 495
 496 sub attach_link ($$$$;$) {
 497         my ($ctx, $ct, $p, $fn, $err) = @_;
 498         my ($part, $depth, @idx) = @$p;
 499         my $nl = $idx[-1] > 1 ? "\n" : '';
 500         my $idx = join('.', @idx);
 501         my $size = bytes::length($part->body);
 502
 503         # hide attributes normally, unless we want to aid users in
 504         # spotting MUA problems:
 505         $ct =~ s/;.*// unless $err;
 506         $ct = ascii_html($ct);
 507         my $desc = $part->header('Content-Description');
 508         $desc = $fn unless defined $desc;
 509         $desc = '' unless defined $desc;
 510         my $sfn;
 511         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 512                 $sfn = $fn;
 513         } elsif ($ct eq 'text/plain') {
 514                 $sfn = 'a.txt';
 515         } else {
 516                 $sfn = 'a.bin';
 517         }
 518         my $rv = $ctx->{obuf};
 519         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 520         if ($err) {
 521                 $$rv .= "[-- Warning: decoded text below may be mangled --]\n";
 522         }
 523         $$rv .= "[-- Attachment #$idx: ";
 524         my $ts = "Type: $ct, Size: $size bytes";
 525         $desc = ascii_html($desc);
 526         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 527         $$rv .= "</a>\n";
 528         undef;
 529 }
 530
 531 sub add_text_body { # callback for msg_iter
 532         my ($p, $ctx) = @_;
 533         my $upfx = $ctx->{mhref};
 534         my $ibx = $ctx->{-inbox};
 535         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 536         my ($part, $depth, @idx) = @$p;
 537         my $ct = $part->content_type || 'text/plain';
 538         my $fn = $part->filename;
 539         my ($s, $err) = msg_part_text($part, $ct);
 540         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 541
 542         # makes no difference to browsers, and don't screw up filename
 543         # link generation in diffs with the extra '%0D'
 544         $s =~ s/\r\n/\n/sg;
 545
 546         # always support diff-highlighting, but we can't linkify hunk
 547         # headers for solver unless some coderepo are configured:
 548         my $diff;
 549         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 550                 # diffstat anchors do not link across attachments or messages:
 551                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 552                 $ctx->{-apfx} = join('/', @idx);
 553                 $ctx->{-anchors} = {}; # attr => filename
 554                 $diff = 1;
 555                 delete $ctx->{-long_path};
 556                 my $spfx;
 557                 if ($ibx->{-repo_objs}) {
 558                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 559                                 $spfx = $upfx;
 560                                 $spfx =~ s!/([^/]*)/\z!/!;
 561                         } else {
 562                                 my $n_slash = $upfx =~ tr!/!/!;
 563                                 if ($n_slash == 0) {
 564                                         $spfx = '../';
 565                                 } elsif ($n_slash == 1) {
 566                                         $spfx = '';
 567                                 } else { # nslash == 2
 568                                         $spfx = '../../';
 569                                 }
 570                         }
 571                 }
 572                 $ctx->{-spfx} = $spfx;
 573         };
 574
 575         # some editors don't put trailing newlines at the end:
 576         $s .= "\n" unless $s =~ /\n\z/s;
 577
 578         # split off quoted and unquoted blocks:
 579         my @sections = PublicInbox::MsgIter::split_quotes($s);
 580         $s = '';
 581         my $rv = $ctx->{obuf};
 582         if (defined($fn) || $depth > 0 || $err) {
 583                 # badly-encoded message with $err? tell the world about it!
 584                 attach_link($ctx, $ct, $p, $fn, $err);
 585                 $$rv .= "\n";
 586         }
 587         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 588         foreach my $cur (@sections) {
 589                 if ($cur =~ /\A>/) {
 590                         flush_quote($rv, $l, \$cur);
 591                 } elsif ($diff) {
 592                         flush_diff($rv, $ctx, \$cur);
 593                 } else {
 594                         # regular lines, OK
 595                         $$rv .= $l->to_html($cur);
 596                         $cur = undef;
 597                 }
 598         }
 599
 600         obfuscate_addrs($ibx, $$rv) if $ibx->{obfuscate};
 601 }
 602
 603 sub _msg_page_prepare_obuf {
 604         my ($hdr, $ctx, $nr) = @_;
 605         my $over = $ctx->{-inbox}->over;
 606         my $obfs_ibx = $ctx->{-obfs_ibx};
 607         my $rv = '';
 608         my $mids = mids_for_index($hdr);
 609         if ($nr == 0) {
 610                 if ($ctx->{more}) {
 611                         $rv .=
 612 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 613                 }
 614                 $rv .= "<pre\nid=b>"; # anchor for body start
 615         } else {
 616                 $rv .= '<pre>';
 617         }
 618         if ($over) {
 619                 $ctx->{-upfx} = '../';
 620         }
 621         my @title; # (Subject[0], From[0])
 622         for my $v ($hdr->header('From')) {
 623                 my @n = PublicInbox::Address::names($v);
 624                 $v = ascii_html($v);
 625                 $title[1] //= ascii_html(join(', ', @n));
 626                 if ($obfs_ibx) {
 627                         obfuscate_addrs($obfs_ibx, $v);
 628                         obfuscate_addrs($obfs_ibx, $title[1]);
 629                 }
 630                 $rv .= "From: $v\n" if $v ne '';
 631         }
 632         foreach my $h (qw(To Cc)) {
 633                 for my $v ($hdr->header($h)) {
 634                         fold_addresses($v);
 635                         $v = ascii_html($v);
 636                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 637                         $rv .= "$h: $v\n" if $v ne '';
 638                 }
 639         }
 640         my @subj = $hdr->header('Subject');
 641         if (@subj) {
 642                 my $v = ascii_html(shift @subj);
 643                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 644                 $rv .= 'Subject: ';
 645                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 646                 $title[0] = $v;
 647                 for $v (@subj) { # multi-Subject message :<
 648                         $v = ascii_html($v);
 649                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 650                         $rv .= "Subject: $v\n";
 651                 }
 652         } else { # dummy anchor for thread skeleton at bottom of page
 653                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 654                 $title[0] = '(no subject)';
 655         }
 656         for my $v ($hdr->header('Date')) {
 657                 $v = ascii_html($v);
 658                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 659                 $rv .= "Date: $v\n";
 660         }
 661         $ctx->{-title_html} = join(' - ', @title);
 662         if (scalar(@$mids) == 1) { # common case
 663                 my $mhtml = ascii_html($mids->[0]);
 664                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 665                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 666         } else {
 667                 # X-Alt-Message-ID can happen if a message is injected from
 668                 # public-inbox-nntpd because of multiple Message-ID headers.
 669                 my $lnk = PublicInbox::Linkify->new;
 670                 my $s = '';
 671                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 672                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 673                 }
 674                 $lnk->linkify_mids('..', \$s, 1);
 675                 $rv .= $s;
 676         }
 677         $rv .= _parent_headers($hdr, $over);
 678         $rv .= "\n";
 679         \$rv;
 680 }
 681
 682 sub SKEL_EXPAND () {
 683         qq(expand[<a\nhref="T/#u">flat</a>) .
 684                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 685                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 686                 qq(<a\nhref="t.atom">Atom feed</a>);
 687 }
 688
 689 sub thread_skel ($$$) {
 690         my ($skel, $ctx, $hdr) = @_;
 691         my $mid = mids($hdr)->[0];
 692         my $ibx = $ctx->{-inbox};
 693         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 694         my $parent = in_reply_to($hdr);
 695         $$skel .= "\n<b>Thread overview: </b>";
 696         if ($nr <= 1) {
 697                 if (defined $parent) {
 698                         $$skel .= SKEL_EXPAND."\n ";
 699                         $$skel .= ghost_parent('../', $parent) . "\n";
 700                 } else {
 701                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 702                 }
 703                 $ctx->{next_msg} = undef;
 704                 $ctx->{parent_msg} = $parent;
 705                 return;
 706         }
 707
 708         $$skel .= $nr;
 709         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 710
 711         # nb: mutt only shows the first Subject in the index pane
 712         # when multiple Subject: headers are present, so we follow suit:
 713         my $subj = $hdr->header('Subject') // '';
 714         $subj = '(no subject)' if $subj eq '';
 715         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 716         $ctx->{cur} = $mid;
 717         $ctx->{prev_attr} = '';
 718         $ctx->{prev_level} = 0;
 719         $ctx->{skel} = $skel;
 720
 721         # reduce hash lookups in skel_dump
 722         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 723         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 724
 725         $ctx->{parent_msg} = $parent;
 726 }
 727
 728 sub _parent_headers {
 729         my ($hdr, $over) = @_;
 730         my $rv = '';
 731         my @irt = $hdr->header_raw('In-Reply-To');
 732         my $refs;
 733         if (@irt) {
 734                 my $lnk = PublicInbox::Linkify->new;
 735                 $rv .= "In-Reply-To: $_\n" for @irt;
 736                 $lnk->linkify_mids('..', \$rv);
 737         } else {
 738                 $refs = references($hdr);
 739                 my $irt = pop @$refs;
 740                 if (defined $irt) {
 741                         my $html = ascii_html($irt);
 742                         my $href = mid_href($irt);
 743                         $rv .= "In-Reply-To: &lt;";
 744                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 745                 }
 746         }
 747
 748         # do not display References: if search is present,
 749         # we show the thread skeleton at the bottom, instead.
 750         return $rv if $over;
 751
 752         $refs //= references($hdr);
 753         if (@$refs) {
 754                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 755                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 756         }
 757         $rv;
 758 }
 759
 760 # returns a string buffer via ->getline
 761 sub html_footer {
 762         my ($ctx, $hdr) = @_;
 763         my $ibx = $ctx->{-inbox};
 764         my $upfx = '../';
 765         my $skel = " <a\nhref=\"$upfx\">index</a>";
 766         my $rv = '<pre>';
 767         if ($ibx->over) {
 768                 $skel .= "\n";
 769                 thread_skel(\$skel, $ctx, $hdr);
 770                 my ($next, $prev);
 771                 my $parent = '       ';
 772                 $next = $prev = '    ';
 773
 774                 if (my $n = $ctx->{next_msg}) {
 775                         $n = mid_href($n);
 776                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 777                 }
 778                 my $u;
 779                 my $par = $ctx->{parent_msg};
 780                 if ($par) {
 781                         $u = mid_href($par);
 782                         $u = "$upfx$u/";
 783                 }
 784                 if (my $p = $ctx->{prev_msg}) {
 785                         $prev = mid_href($p);
 786                         if ($p && $par && $p eq $par) {
 787                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 788                                         'rel=prev>prev parent</a>';
 789                                 $parent = '';
 790                         } else {
 791                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 792                                         'rel=prev>prev</a>';
 793                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 794                         }
 795                 } elsif ($u) { # unlikely
 796                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 797                 }
 798                 $rv .= "$next $prev$parent ";
 799         }
 800         $rv .= qq(<a\nhref="#R">reply</a>);
 801         $rv .= $skel;
 802         $rv .= '</pre>';
 803         $rv .= msg_reply($ctx, $hdr);
 804 }
 805
 806 sub linkify_ref_no_over {
 807         my ($mid) = @_;
 808         my $href = mid_href($mid);
 809         my $html = ascii_html($mid);
 810         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 811 }
 812
 813 sub anchor_for {
 814         my ($msgid) = @_;
 815         'm' . id_compress($msgid, 1);
 816 }
 817
 818 sub ghost_parent {
 819         my ($upfx, $mid) = @_;
 820
 821         my $href = mid_href($mid);
 822         my $html = ascii_html($mid);
 823         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 824 }
 825
 826 sub indent_for {
 827         my ($level) = @_;
 828         $level ? INDENT x ($level - 1) : '';
 829 }
 830
 831 sub find_mid_root {
 832         my ($ctx, $level, $node, $idx) = @_;
 833         ++$ctx->{root_idx} if $level == 0;
 834         if ($node->{id} eq $ctx->{mid}) {
 835                 $ctx->{found_mid_at} = $ctx->{root_idx};
 836                 return 0;
 837         }
 838         1;
 839 }
 840
 841 sub strict_loose_note ($) {
 842         my ($nr) = @_;
 843         my $msg =
 844 "  -- strict thread matches above, loose matches on Subject: below --\n";
 845
 846         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 847                 $msg .=
 848 "  -- use mbox.gz link to download all $nr messages --\n";
 849         }
 850         $msg;
 851 }
 852
 853 sub thread_results {
 854         my ($ctx, $msgs) = @_;
 855         require PublicInbox::SearchThread;
 856         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 857
 858         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 859         # and preserved in the future.  This bug is hidden by `sid' matches
 860         # in get_thread, so we never noticed it until now.  And even when
 861         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 862         # bump since reindexing is expensive and users may not do it
 863
 864         # loose threading could've returned too many results,
 865         # put the root the message we care about at the top:
 866         my $mid = $ctx->{mid};
 867         if (defined($mid) && scalar(@$rootset) > 1) {
 868                 $ctx->{root_idx} = -1;
 869                 my $nr = scalar @$msgs;
 870                 walk_thread($rootset, $ctx, \&find_mid_root);
 871                 my $idx = $ctx->{found_mid_at};
 872                 if (defined($idx) && $idx != 0) {
 873                         my $tip = splice(@$rootset, $idx, 1);
 874                         @$rootset = reverse @$rootset;
 875                         unshift @$rootset, $tip;
 876                         $ctx->{sl_note} = strict_loose_note($nr);
 877                 }
 878         }
 879         $rootset
 880 }
 881
 882 sub missing_thread {
 883         my ($ctx) = @_;
 884         require PublicInbox::ExtMsg;
 885         PublicInbox::ExtMsg::ext_msg($ctx);
 886 }
 887
 888 sub dedupe_subject {
 889         my ($prev_subj, $subj, $val) = @_;
 890
 891         my $omit = ''; # '"' denotes identical text omitted
 892         my (@prev_pop, @curr_pop);
 893         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 894                 push(@prev_pop, pop(@$prev_subj));
 895                 push(@curr_pop, pop(@$subj));
 896                 $omit ||= $val;
 897         }
 898         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 899         if (scalar(@curr_pop) == 1) {
 900                 $omit = '';
 901                 push @$prev_subj, @prev_pop;
 902                 push @$subj, @curr_pop;
 903         }
 904         $omit;
 905 }
 906
 907 sub skel_dump { # walk_thread callback
 908         my ($ctx, $level, $node) = @_;
 909         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 910
 911         my $skel = $ctx->{skel};
 912         my $cur = $ctx->{cur};
 913         my $mid = $smsg->{mid};
 914
 915         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 916                 $$skel .= delete($ctx->{sl_note}) || '';
 917         }
 918
 919         my $f = ascii_html($smsg->{from_name});
 920         my $obfs_ibx = $ctx->{-obfs_ibx};
 921         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 922
 923         my $d = fmt_ts($smsg->{ds});
 924         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 925         if (exists $ctx->{searchview}) {
 926                 if (defined(my $pct = $smsg->{pct})) {
 927                         $d .= (sprintf(' % 2u', $pct) . '%');
 928                 } else {
 929                         $unmatched = 1;
 930                         $d .= '    ';
 931                 }
 932         }
 933         $d .= ' ' . indent_for($level) . th_pfx($level);
 934         my $attr = $f;
 935         $ctx->{first_level} ||= $level;
 936
 937         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 938                 $ctx->{prev_attr} = $attr;
 939         }
 940         $ctx->{prev_level} = $level;
 941
 942         if ($cur) {
 943                 if ($cur eq $mid) {
 944                         delete $ctx->{cur};
 945                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 946                                  "$attr [this message]</a></b>\n";
 947                         return 1;
 948                 } else {
 949                         $ctx->{prev_msg} = $mid;
 950                 }
 951         } else {
 952                 $ctx->{next_msg} ||= $mid;
 953         }
 954
 955         # Subject is never undef, this mail was loaded from
 956         # our Xapian which would've resulted in '' if it were
 957         # really missing (and Filter rejects empty subjects)
 958         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 959         # remove common suffixes from the subject if it matches the previous,
 960         # so we do not show redundant text at the end.
 961         my $prev_subj = $ctx->{prev_subj} || [];
 962         $ctx->{prev_subj} = [ @subj ];
 963         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 964         my $end;
 965         if (@subj) {
 966                 my $subj = join(' ', @subj);
 967                 $subj = ascii_html($subj);
 968                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 969                 $end = "$subj</a> $omit$f\n"
 970         } else {
 971                 $end = "$f</a>\n";
 972         }
 973         my $m;
 974         my $id = '';
 975         my $mapping = $unmatched ? undef : $ctx->{mapping};
 976         if ($mapping) {
 977                 my $map = $mapping->{$mid};
 978                 $id = id_compress($mid, 1);
 979                 $m = '#m'.$id;
 980                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 981                 $id = "\nid=r".$id;
 982         } else {
 983                 $m = $ctx->{-upfx}.mid_href($mid).'/';
 984         }
 985         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 986         1;
 987 }
 988
 989 sub _skel_ghost {
 990         my ($ctx, $level, $node) = @_;
 991
 992         my $mid = $node->{id};
 993         my $d = '     [not found] ';
 994         $d .= '    '  if exists $ctx->{searchview};
 995         $d .= indent_for($level) . th_pfx($level);
 996         my $upfx = $ctx->{-upfx};
 997         my $href = $upfx . mid_href($mid) . '/';
 998         my $html = ascii_html($mid);
 999
1000         my $mapping = $ctx->{mapping};
1001         my $map = $mapping->{$mid} if $mapping;
1002         if ($map) {
1003                 my $id = id_compress($mid, 1);
1004                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1005                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1006         } else {
1007                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1008         }
1009         ${$ctx->{skel}} .= $d;
1010         1;
1011 }
1012
1013 sub sort_ds {
1014         [ sort {
1015                 (eval { $a->topmost->{smsg}->{ds} } || 0) <=>
1016                 (eval { $b->topmost->{smsg}->{ds} } || 0)
1017         } @{$_[0]} ];
1018 }
1019
1020 # accumulate recent topics if search is supported
1021 # returns 200 if done, 404 if not
1022 sub acc_topic { # walk_thread callback
1023         my ($ctx, $level, $node) = @_;
1024         my $mid = $node->{id};
1025         my $smsg = $node->{smsg} // $ctx->{-inbox}->smsg_by_mid($mid);
1026         if ($smsg) {
1027                 my $subj = subject_normalized($smsg->{subject});
1028                 $subj = '(no subject)' if $subj eq '';
1029                 my $ds = $smsg->{ds};
1030                 if ($level == 0) { # new, top-level topic
1031                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1032                         $ctx->{-cur_topic} = $topic;
1033                         push @{$ctx->{order}}, $topic;
1034                         return 1;
1035                 }
1036
1037                 # continue existing topic
1038                 my $topic = $ctx->{-cur_topic}; # should never be undef
1039                 $topic->[0] = $ds if $ds > $topic->[0];
1040                 $topic->[1]++; # bump N+ message counter
1041                 my $seen = $topic->[2];
1042                 if (scalar(@$topic) == 3) { # parent was a ghost
1043                         push @$topic, $subj;
1044                 } elsif (!defined($seen->{$subj})) {
1045                         push @$topic, $level, $subj; # @extra messages
1046                 }
1047                 $seen->{$subj} = $mid; # latest for subject
1048         } else { # ghost message
1049                 return 1 if $level != 0; # ignore child ghosts
1050                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1051                 push @{$ctx->{order}}, $topic;
1052         }
1053         1;
1054 }
1055
1056 sub dump_topics {
1057         my ($ctx) = @_;
1058         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1059         unless ($order) {
1060                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1061                 return 404;
1062         }
1063
1064         my @out;
1065         my $ibx = $ctx->{-inbox};
1066         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1067
1068         # sort by recency, this allows new posts to "bump" old topics...
1069         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1070                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1071                 @$topic = ();
1072                 next unless defined $top_subj;  # ghost topic
1073                 my $mid = delete $seen->{$top_subj};
1074                 my $href = mid_href($mid);
1075                 my $prev_subj = [ split(/ /, $top_subj) ];
1076                 $top_subj = ascii_html($top_subj);
1077                 $ds = fmt_ts($ds);
1078
1079                 # $n isn't the total number of posts on the topic,
1080                 # just the number of posts in the current results window
1081                 my $anchor;
1082                 if ($n == 1) {
1083                         $n = '';
1084                         $anchor = '#u'; # top of only message
1085                 } else {
1086                         $n = " ($n+ messages)";
1087                         $anchor = '#t'; # thread skeleton
1088                 }
1089
1090                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1091                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1092                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1093                         " $ds UTC $n - $mbox / $atom\n";
1094                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1095                         my $level = $extra[$i];
1096                         my $subj = $extra[$i + 1]; # already normalized
1097                         $mid = delete $seen->{$subj};
1098                         my @subj = split(/ /, $subj);
1099                         my @next_prev = @subj; # full copy
1100                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1101                         $prev_subj = \@next_prev;
1102                         $subj = ascii_html($subj);
1103                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1104                         $href = mid_href($mid);
1105                         $s .= indent_for($level) . TCHILD;
1106                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1107                 }
1108                 push @out, $s;
1109         }
1110         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1111         200;
1112 }
1113
1114 # only for the t= query parameter passed to overview DB
1115 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1116
1117 sub str2ts ($) {
1118         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1119         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1120 }
1121
1122 sub pagination_footer ($$) {
1123         my ($ctx, $latest) = @_;
1124         delete $ctx->{qp} or return;
1125         my $next = $ctx->{next_page} || '';
1126         my $prev = $ctx->{prev_page} || '';
1127         if ($prev) {
1128                 $next = $next ? "$next " : '     ';
1129                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1130         }
1131         "<hr><pre>page: $next$prev</pre>";
1132 }
1133
1134 sub index_nav { # callback for WwwStream
1135         my (undef, $ctx) = @_;
1136         pagination_footer($ctx, '.')
1137 }
1138
1139 sub paginate_recent ($$) {
1140         my ($ctx, $lim) = @_;
1141         my $t = $ctx->{qp}->{t} || '';
1142         my $opts = { limit => $lim };
1143         my ($after, $before);
1144
1145         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1146         # if only $after exists "YYYYMMDD.." because "." could be skipped
1147         # if interpreted as an end-of-sentence
1148         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1149         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1150
1151         my $ibx = $ctx->{-inbox};
1152         my $msgs = $ibx->recent($opts, $after, $before);
1153         my $nr = scalar @$msgs;
1154         if ($nr < $lim && defined($after)) {
1155                 $after = $before = undef;
1156                 $msgs = $ibx->recent($opts);
1157                 $nr = scalar @$msgs;
1158         }
1159         my $more = $nr == $lim;
1160         my ($newest, $oldest);
1161         if ($nr) {
1162                 $newest = $msgs->[0]->{ts};
1163                 $oldest = $msgs->[-1]->{ts};
1164                 # if we only had $after, our SQL query in ->recent ordered
1165                 if ($newest < $oldest) {
1166                         ($oldest, $newest) = ($newest, $oldest);
1167                         $more = 0 if defined($after) && $after < $oldest;
1168                 }
1169         }
1170         if (defined($oldest) && $more) {
1171                 my $s = ts2str($oldest);
1172                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1173         }
1174         if (defined($newest) && (defined($before) || defined($after))) {
1175                 my $s = ts2str($newest);
1176                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1177         }
1178         $msgs;
1179 }
1180
1181 sub index_topics {
1182         my ($ctx) = @_;
1183         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1184         if (@$msgs) {
1185                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1186         }
1187         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), \&index_nav);
1188 }
1189
1190 sub thread_adj_level {
1191         my ($ctx, $level) = @_;
1192
1193         my $max = $ctx->{cur_level};
1194         if ($level <= 0) {
1195                 return ('', '') if $max == 0; # flat output
1196
1197                 # reset existing lists
1198                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1199                 $ctx->{cur_level} = 0;
1200                 ("$beg</ul>", '');
1201         } elsif ($level == $max) { # continue existing list
1202                 qw(<li> </li>);
1203         } elsif ($level < $max) {
1204                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1205                 $ctx->{cur_level} = $level;
1206                 ("$beg<li>", '</li>');
1207         } else { # ($level > $max) # start a new level
1208                 $ctx->{cur_level} = $level;
1209                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1210                 ($beg, '</li>');
1211         }
1212 }
1213
1214 sub ghost_index_entry {
1215         my ($ctx, $level, $node) = @_;
1216         my ($beg, $end) = thread_adj_level($ctx,  $level);
1217         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1218                 . '</pre>' . $end;
1219 }
1220
1221 1;