lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw/id_compress mid_escape mids mids_for_index references/;
  14 use PublicInbox::MsgIter;
  15 use PublicInbox::Address;
  16 use PublicInbox::WwwStream;
  17 use PublicInbox::Reply;
  18 use PublicInbox::ViewDiff qw(flush_diff);
  19 use POSIX qw(strftime);
  20 use Time::Local qw(timegm);
  21 use PublicInbox::SearchMsg qw(subject_normalized);
  22 use constant COLS => 72;
  23 use constant INDENT => '  ';
  24 use constant TCHILD => '` ';
  25 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  26
  27 sub msg_html_i {
  28         my ($nr, $ctx) = @_;
  29         my $more = $ctx->{more};
  30         if ($nr == 1) {
  31                 # $more cannot be true w/o $smsg being defined:
  32                 my $upfx = $more ? '../'.mid_escape($ctx->{smsg}->mid).'/' : '';
  33                 $ctx->{tip} .
  34                         multipart_text_as_html(delete $ctx->{mime}, $upfx,
  35                                                 $ctx) . '</pre><hr>'
  36         } elsif ($more && @$more) {
  37                 ++$ctx->{end_nr};
  38                 msg_html_more($ctx, $more, $nr);
  39         } elsif ($nr == $ctx->{end_nr}) {
  40                 # fake an EOF if generating the footer fails;
  41                 # we want to at least show the message if something
  42                 # here crashes:
  43                 eval {
  44                         my $hdr = delete($ctx->{hdr});
  45                         '<pre>' . html_footer($hdr, 1, $ctx) .
  46                         '</pre>' . msg_reply($ctx, $hdr)
  47                 };
  48         } else {
  49                 undef
  50         }
  51 }
  52
  53 # public functions: (unstable)
  54
  55 sub msg_html {
  56         my ($ctx, $mime, $more, $smsg) = @_;
  57         my $ibx = $ctx->{-inbox};
  58         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  59         my $hdr = $ctx->{hdr} = $mime->header_obj;
  60         $ctx->{tip} = _msg_html_prepare($hdr, $ctx, $more, 0);
  61         $ctx->{more} = $more;
  62         $ctx->{end_nr} = 2;
  63         $ctx->{smsg} = $smsg;
  64         $ctx->{mime} = $mime;
  65         PublicInbox::WwwStream->response($ctx, 200, \&msg_html_i);
  66 }
  67
  68 sub msg_page {
  69         my ($ctx) = @_;
  70         my $mid = $ctx->{mid};
  71         my $ibx = $ctx->{-inbox};
  72         my ($first, $more);
  73         my $smsg;
  74         if (my $over = $ibx->over) {
  75                 my ($id, $prev);
  76                 $smsg = $over->next_by_mid($mid, \$id, \$prev);
  77                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  78                 if ($first) {
  79                         my $next = $over->next_by_mid($mid, \$id, \$prev);
  80                         $more = [ $id, $prev, $next ] if $next;
  81                 }
  82                 return unless $first;
  83         } else {
  84                 $first = $ibx->msg_by_mid($mid) or return;
  85         }
  86         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  87 }
  88
  89 sub msg_html_more {
  90         my ($ctx, $more, $nr) = @_;
  91         my $str = eval {
  92                 my ($id, $prev, $smsg) = @$more;
  93                 my $mid = $ctx->{mid};
  94                 my $ibx = $ctx->{-inbox};
  95                 $smsg = $ibx->smsg_mime($smsg);
  96                 my $next = $ibx->over->next_by_mid($mid, \$id, \$prev);
  97                 @$more = $next ? ($id, $prev, $next) : ();
  98                 if ($smsg) {
  99                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
 100                         my $mime = delete $smsg->{mime};
 101                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
 102                                 multipart_text_as_html($mime, $upfx, $ctx) .
 103                                 '</pre><hr>'
 104                 } else {
 105                         '';
 106                 }
 107         };
 108         if ($@) {
 109                 warn "Error lookup up additional messages: $@\n";
 110                 $str = '<pre>Error looking up additional messages</pre>';
 111         }
 112         $str;
 113 }
 114
 115 # /$INBOX/$MESSAGE_ID/#R
 116 sub msg_reply {
 117         my ($ctx, $hdr) = @_;
 118         my $se_url =
 119          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 120         my $p_url =
 121          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 122
 123         my $info = '';
 124         my $ibx = $ctx->{-inbox};
 125         if (my $url = $ibx->{infourl}) {
 126                 $url = prurl($ctx->{env}, $url);
 127                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 128         }
 129
 130         my ($arg, $link, $reply_to_all) =
 131                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 132         if (ref($arg) eq 'SCALAR') {
 133                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 134         }
 135
 136         # mailto: link only works if address obfuscation is disabled
 137         if ($link) {
 138                 $link = <<EOF;
 139
 140 * If your mail client supports setting the <b>In-Reply-To</b> header
 141   via mailto: links, try the <a
 142 href="$link">mailto: link</a>
 143 EOF
 144         }
 145
 146         push @$arg, '/path/to/YOUR_REPLY';
 147         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 148         <<EOF
 149 <hr><pre
 150 id=R><b>Reply instructions:</b>
 151
 152 You may reply publicly to <a
 153 href=#t>this message</a> via plain-text email
 154 using any one of the following methods:
 155
 156 * Save the following mbox file, import it into your mail client,
 157   and $reply_to_all from there: <a
 158 href=raw>mbox</a>
 159
 160   Avoid top-posting and favor interleaved quoting:
 161   <a
 162 href="$p_url">$p_url</a>
 163 $info
 164 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 165   switches of git-send-email(1):
 166
 167   git send-email$arg
 168
 169   <a
 170 href="$se_url">$se_url</a>
 171 $link</pre>
 172 EOF
 173 }
 174
 175 sub in_reply_to {
 176         my ($hdr) = @_;
 177         my $refs = references($hdr);
 178         $refs->[-1];
 179 }
 180
 181 sub fold_addresses ($) {
 182         return $_[0] if length($_[0]) <= COLS;
 183         # try to fold on commas after non-word chars before $lim chars,
 184         # Try to get the "," preceeded by ">" or ")", but avoid folding
 185         # on the comma where somebody uses "Lastname, Firstname".
 186         # We also try to keep the last and penultimate addresses in
 187         # the list on the same line if possible, hence the extra \z
 188         # Fall back to folding on spaces at $lim + 1 chars
 189         my $lim = COLS - 8; # 8 = "\t" display width
 190         my $too_long = $lim + 1;
 191         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 192         $_[0] = join("\n\t",
 193                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 194                                 .{1,$lim}(?:,|\z)|
 195                                 .{1,$lim}|
 196                                 .{$too_long,}?)(?:\s|\z)/xgo));
 197 }
 198
 199 sub _hdr_names_html ($$) {
 200         my ($hdr, $field) = @_;
 201         my @vals = $hdr->header($field) or return '';
 202         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 203 }
 204
 205 sub nr_to_s ($$$) {
 206         my ($nr, $singular, $plural) = @_;
 207         return "0 $plural" if $nr == 0;
 208         $nr == 1 ? "$nr $singular" : "$nr $plural";
 209 }
 210
 211 # human-friendly format
 212 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 213
 214 # this is already inside a <pre>
 215 sub index_entry {
 216         my ($smsg, $ctx, $more) = @_;
 217         my $subj = $smsg->subject;
 218         my $mid_raw = $smsg->mid;
 219         my $id = id_compress($mid_raw, 1);
 220         my $id_m = 'm'.$id;
 221
 222         my $root_anchor = $ctx->{root_anchor} || '';
 223         my $irt;
 224         my $obfs_ibx = $ctx->{-obfs_ibx};
 225
 226         $subj = '(no subject)' if $subj eq '';
 227         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 228         $subj = '<b>'.ascii_html($subj).'</b>';
 229         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 230         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 231         $rv .= $subj . "\n";
 232         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 233         my @tocc;
 234         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 235         # deleting {mime} is critical to memory use,
 236         # the rest of the fields saves about 400K as we iterate across 1K msgs
 237         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 238
 239         my $hdr = $mime->header_obj;
 240         my $from = _hdr_names_html($hdr, 'From');
 241         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 242         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 243         my $upfx = $ctx->{-upfx};
 244         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 245         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 246         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 247         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 248         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 249         my ($tlen, $clen) = (length($to), length($cc));
 250         my $to_cc = '';
 251         if (($tlen + $clen) > COLS) {
 252                 $to_cc .= '  To: '.$to."\n" if $tlen;
 253                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 254         } else {
 255                 if ($tlen) {
 256                         $to_cc .= '  To: '.$to;
 257                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 258                 } else {
 259                         $to_cc .= '  Cc: '.$cc if $clen;
 260                 }
 261                 $to_cc .= "\n";
 262         }
 263         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 264         $rv .= $to_cc;
 265
 266         my $mapping = $ctx->{mapping};
 267         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 268                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 269                 my $href = $upfx . $mirt->{href}. '/';
 270                 my $html = $mirt->as_html;
 271                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 272         }
 273         $rv .= "\n";
 274
 275         # scan through all parts, looking for displayable text
 276         $ctx->{mhref} = $mhref;
 277         $ctx->{rv} = \$rv;
 278         msg_iter($mime, \&add_text_body, $ctx, 1);
 279         delete $ctx->{rv};
 280
 281         # add the footer
 282         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 283                 "<a\nhref=\"$mhref\">permalink</a>" .
 284                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 285                 " <a\nhref=\"${mhref}#R\">reply</a>";
 286
 287         my $hr;
 288         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 289                 $rv .= "\t[relevance $pct%]";
 290                 $hr = 1;
 291         } elsif ($mapping) {
 292                 my $nested = 'nested';
 293                 my $flat = 'flat';
 294                 my $end = '';
 295                 if ($ctx->{flat}) {
 296                         $hr = 1;
 297                         $flat = "<b>$flat</b>";
 298                 } else {
 299                         $nested = "<b>$nested</b>";
 300                 }
 301                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 302                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 303                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 304         } else {
 305                 $hr = $ctx->{-hr};
 306         }
 307
 308         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 309         $rv;
 310 }
 311
 312 sub pad_link ($$;$) {
 313         my ($mid, $level, $s) = @_;
 314         $s ||= '...';
 315         my $id = id_compress($mid, 1);
 316         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 317 }
 318
 319 sub _th_index_lite {
 320         my ($mid_raw, $irt, $id, $ctx) = @_;
 321         my $rv = '';
 322         my $mapping = $ctx->{mapping} or return $rv;
 323         my $pad = '  ';
 324         my $mid_map = $mapping->{$mid_raw};
 325         defined $mid_map or
 326                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 327         my ($attr, $node, $idx, $level) = @$mid_map;
 328         my $children = $node->{children};
 329         my $nr_c = scalar @$children;
 330         my $nr_s = 0;
 331         my $siblings;
 332         if (my $smsg = $node->{smsg}) {
 333                 # delete saves about 200KB on a 1K message thread
 334                 if (my $refs = delete $smsg->{references}) {
 335                         ($$irt) = ($refs =~ m/<([^>]+)>\z/);
 336                 }
 337         }
 338         my $irt_map = $mapping->{$$irt} if defined $$irt;
 339         if (defined $irt_map) {
 340                 $siblings = $irt_map->[1]->{children};
 341                 $nr_s = scalar(@$siblings) - 1;
 342                 $rv .= $pad . $irt_map->[0];
 343                 if ($idx > 0) {
 344                         my $prev = $siblings->[$idx - 1];
 345                         my $pmid = $prev->{id};
 346                         if ($idx > 2) {
 347                                 my $s = ($idx - 1). ' preceding siblings ...';
 348                                 $rv .= pad_link($pmid, $level, $s);
 349                         } elsif ($idx == 2) {
 350                                 my $ppmid = $siblings->[0]->{id};
 351                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 352                         }
 353                         $rv .= $pad . $mapping->{$pmid}->[0];
 354                 }
 355         }
 356         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 357         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 358         $attr =~ s!\n\z!</b>\n!s;
 359         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 360         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 361         $rv .= "<b>@ $attr";
 362         if ($nr_c) {
 363                 my $cmid = $children->[0]->{id};
 364                 $rv .= $pad . $mapping->{$cmid}->[0];
 365                 if ($nr_c > 2) {
 366                         my $s = ($nr_c - 1). ' more replies';
 367                         $rv .= pad_link($cmid, $level + 1, $s);
 368                 } elsif (my $cn = $children->[1]) {
 369                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 370                 }
 371         }
 372
 373         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 374         if ($next) {
 375                 my $nmid = $next->{id};
 376                 $rv .= $pad . $mapping->{$nmid}->[0];
 377                 my $nnext = $nr_s - $idx;
 378                 if ($nnext > 2) {
 379                         my $s = ($nnext - 1).' subsequent siblings';
 380                         $rv .= pad_link($nmid, $level, $s);
 381                 } elsif (my $nn = $siblings->[$idx + 2]) {
 382                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 383                 }
 384         }
 385         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 386 }
 387
 388 sub walk_thread {
 389         my ($rootset, $ctx, $cb) = @_;
 390         my @q = map { (0, $_, -1) } @$rootset;
 391         while (@q) {
 392                 my ($level, $node, $i) = splice(@q, 0, 3);
 393                 defined $node or next;
 394                 $cb->($ctx, $level, $node, $i) or return;
 395                 ++$level;
 396                 $i = 0;
 397                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 398         }
 399 }
 400
 401 sub pre_thread  {
 402         my ($ctx, $level, $node, $idx) = @_;
 403         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 404         skel_dump($ctx, $level, $node);
 405 }
 406
 407 sub thread_index_entry {
 408         my ($ctx, $level, $smsg) = @_;
 409         my ($beg, $end) = thread_adj_level($ctx, $level);
 410         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 411 }
 412
 413 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 414         my ($nr, $ctx) = @_;
 415         return unless exists($ctx->{dst});
 416         my $q = $ctx->{-queue};
 417         while (@$q) {
 418                 my $level = shift @$q;
 419                 my $node = shift @$q or next;
 420                 my $cl = $level + 1;
 421                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 422                 if (my $smsg = $ctx->{-inbox}->smsg_mime($node->{smsg})) {
 423                         return thread_index_entry($ctx, $level, $smsg);
 424                 } else {
 425                         return ghost_index_entry($ctx, $level, $node);
 426                 }
 427         }
 428         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{dst}}; # skel
 429 }
 430
 431 sub stream_thread ($$) {
 432         my ($rootset, $ctx) = @_;
 433         my $ibx = $ctx->{-inbox};
 434         my @q = map { (0, $_) } @$rootset;
 435         my ($smsg, $level);
 436         while (@q) {
 437                 $level = shift @q;
 438                 my $node = shift @q or next;
 439                 my $cl = $level + 1;
 440                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 441                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 442         }
 443         return missing_thread($ctx) unless $smsg;
 444
 445         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 446         $ctx->{-title_html} = ascii_html($smsg->subject);
 447         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 448         $ctx->{-queue} = \@q;
 449         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 450 }
 451
 452 sub thread_html {
 453         my ($ctx) = @_;
 454         my $mid = $ctx->{mid};
 455         my $ibx = $ctx->{-inbox};
 456         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 457         return missing_thread($ctx) if $nr == 0;
 458         my $skel = '<hr><pre>';
 459         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 460         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 461         $skel .= "<b\nid=t>Thread overview:</b> ";
 462         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 463         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 464         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 465         $skel .= "-- links below jump to the message on this page --\n";
 466         $ctx->{-upfx} = '../../';
 467         $ctx->{cur_level} = 0;
 468         $ctx->{dst} = \$skel;
 469         $ctx->{prev_attr} = '';
 470         $ctx->{prev_level} = 0;
 471         $ctx->{root_anchor} = anchor_for($mid);
 472         $ctx->{mapping} = {};
 473         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 474                        .' in thread';
 475
 476         my $rootset = thread_results($ctx, $msgs);
 477
 478         # reduce hash lookups in pre_thread->skel_dump
 479         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 480         walk_thread($rootset, $ctx, *pre_thread);
 481
 482         $skel .= '</pre>';
 483         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 484
 485         # flat display: lazy load the full message from smsg
 486         my $smsg;
 487         while (my $m = shift @$msgs) {
 488                 $smsg = $ibx->smsg_mime($m) and last;
 489         }
 490         return missing_thread($ctx) unless $smsg;
 491         $ctx->{-title_html} = ascii_html($smsg->subject);
 492         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 493         $ctx->{msgs} = $msgs;
 494         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 495 }
 496
 497 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 498         my ($nr, $ctx) = @_;
 499         my $msgs = $ctx->{msgs} or return;
 500         while (my $smsg = shift @$msgs) {
 501                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 502                 return index_entry($smsg, $ctx, scalar @$msgs);
 503         }
 504         my ($skel) = delete @$ctx{qw(dst msgs)};
 505         $$skel;
 506 }
 507
 508 sub multipart_text_as_html {
 509         my (undef, $mhref, $ctx) = @_; # $mime = $_[0]
 510         $ctx->{mhref} = $mhref;
 511         $ctx->{rv} = \(my $rv = '');
 512
 513         # scan through all parts, looking for displayable text
 514         msg_iter($_[0], \&add_text_body, $ctx, 1);
 515         ${delete $ctx->{rv}};
 516 }
 517
 518 sub flush_quote {
 519         my ($s, $l, $quot) = @_;
 520
 521         # show everything in the full version with anchor from
 522         # short version (see above)
 523         my $rv = $l->linkify_1($$quot);
 524
 525         # we use a <span> here to allow users to specify their own
 526         # color for quoted text
 527         $rv = $l->linkify_2(ascii_html($rv));
 528         $$quot = undef;
 529         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 530 }
 531
 532 sub attach_link ($$$$;$) {
 533         my ($ctx, $ct, $p, $fn, $err) = @_;
 534         my ($part, $depth, @idx) = @$p;
 535         my $nl = $idx[-1] > 1 ? "\n" : '';
 536         my $idx = join('.', @idx);
 537         my $size = bytes::length($part->body);
 538
 539         # hide attributes normally, unless we want to aid users in
 540         # spotting MUA problems:
 541         $ct =~ s/;.*// unless $err;
 542         $ct = ascii_html($ct);
 543         my $desc = $part->header('Content-Description');
 544         $desc = $fn unless defined $desc;
 545         $desc = '' unless defined $desc;
 546         my $sfn;
 547         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 548                 $sfn = $fn;
 549         } elsif ($ct eq 'text/plain') {
 550                 $sfn = 'a.txt';
 551         } else {
 552                 $sfn = 'a.bin';
 553         }
 554         my $rv = $ctx->{rv};
 555         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 556         if ($err) {
 557                 $$rv .= "[-- Warning: decoded text below may be mangled --]\n";
 558         }
 559         $$rv .= "[-- Attachment #$idx: ";
 560         my $ts = "Type: $ct, Size: $size bytes";
 561         $desc = ascii_html($desc);
 562         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 563         $$rv .= "</a>\n";
 564         undef;
 565 }
 566
 567 sub add_text_body { # callback for msg_iter
 568         my ($p, $ctx) = @_;
 569         my $upfx = $ctx->{mhref};
 570         my $ibx = $ctx->{-inbox};
 571         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 572         my ($part, $depth, @idx) = @$p;
 573         my $ct = $part->content_type || 'text/plain';
 574         my $fn = $part->filename;
 575         my ($s, $err) = msg_part_text($part, $ct);
 576         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 577
 578         # makes no difference to browsers, and don't screw up filename
 579         # link generation in diffs with the extra '%0D'
 580         $s =~ s/\r\n/\n/sg;
 581
 582         # always support diff-highlighting, but we can't linkify hunk
 583         # headers for solver unless some coderepo are configured:
 584         my $diff;
 585         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 586                 # diffstat anchors do not link across attachments or messages:
 587                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 588                 $ctx->{-apfx} = join('/', @idx);
 589                 $ctx->{-anchors} = {}; # attr => filename
 590                 $ctx->{-diff} = $diff = [];
 591                 delete $ctx->{-long_path};
 592                 my $spfx;
 593                 if ($ibx->{-repo_objs}) {
 594                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 595                                 $spfx = $upfx;
 596                                 $spfx =~ s!/([^/]*)/\z!/!;
 597                         } else {
 598                                 my $n_slash = $upfx =~ tr!/!/!;
 599                                 if ($n_slash == 0) {
 600                                         $spfx = '../';
 601                                 } elsif ($n_slash == 1) {
 602                                         $spfx = '';
 603                                 } else { # nslash == 2
 604                                         $spfx = '../../';
 605                                 }
 606                         }
 607                 }
 608                 $ctx->{-spfx} = $spfx;
 609         };
 610
 611         # some editors don't put trailing newlines at the end:
 612         $s .= "\n" unless $s =~ /\n\z/s;
 613
 614         # split off quoted and unquoted blocks:
 615         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 616         $s = '';
 617         my $rv = $ctx->{rv};
 618         if (defined($fn) || $depth > 0 || $err) {
 619                 # badly-encoded message with $err? tell the world about it!
 620                 attach_link($ctx, $ct, $p, $fn, $err);
 621                 $$rv .= "\n";
 622         }
 623         my $l = PublicInbox::Linkify->new;
 624         foreach my $cur (@sections) {
 625                 if ($cur =~ /\A>/) {
 626                         flush_quote($rv, $l, \$cur);
 627                 } elsif ($diff) {
 628                         @$diff = split(/^/m, $cur);
 629                         $cur = undef;
 630                         flush_diff($rv, $ctx, $l);
 631                 } else {
 632                         # regular lines, OK
 633                         $l->linkify_1($cur);
 634                         $$rv .= $l->linkify_2(ascii_html($cur));
 635                         $cur = undef;
 636                 }
 637         }
 638
 639         obfuscate_addrs($ibx, $$rv) if $ibx->{obfuscate};
 640 }
 641
 642 sub _msg_html_prepare {
 643         my ($hdr, $ctx, $more, $nr) = @_;
 644         my $atom = '';
 645         my $over = $ctx->{-inbox}->over;
 646         my $obfs_ibx = $ctx->{-obfs_ibx};
 647         my $rv = '';
 648         my $mids = mids_for_index($hdr);
 649         if ($nr == 0) {
 650                 if ($more) {
 651                         $rv .=
 652 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 653                 }
 654                 $rv .= "<pre\nid=b>"; # anchor for body start
 655         } else {
 656                 $rv .= '<pre>';
 657         }
 658         if ($over) {
 659                 $ctx->{-upfx} = '../';
 660         }
 661         my @title; # (Subject[0], From[0])
 662         for my $v ($hdr->header('From')) {
 663                 $v = PublicInbox::Hval->new($v);
 664                 my @n = PublicInbox::Address::names($v->raw);
 665                 $title[1] //= ascii_html(join(', ', @n));
 666                 $v = $v->as_html;
 667                 if ($obfs_ibx) {
 668                         obfuscate_addrs($obfs_ibx, $v);
 669                         obfuscate_addrs($obfs_ibx, $title[1]);
 670                 }
 671                 $rv .= "From: $v\n" if $v ne '';
 672         }
 673         foreach my $h (qw(To Cc)) {
 674                 for my $v ($hdr->header($h)) {
 675                         fold_addresses($v);
 676                         $v = ascii_html($v);
 677                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 678                         $rv .= "$h: $v\n" if $v ne '';
 679                 }
 680         }
 681         my @subj = $hdr->header('Subject');
 682         if (@subj) {
 683                 for my $v (@subj) {
 684                         $v = ascii_html($v);
 685                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 686                         $rv .= 'Subject: ';
 687                         if ($over) {
 688                                 $rv .= qq(<a\nhref="#r"\nid=t>$v</a>\n);
 689                         } else {
 690                                 $rv .= "$v\n";
 691                         }
 692                         $title[0] //= $v;
 693                 }
 694         } else { # dummy anchor for thread skeleton at bottom of page
 695                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 696                 $title[0] = '(no subject)';
 697         }
 698         for my $v ($hdr->header('Date')) {
 699                 $v = ascii_html($v);
 700                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 701                 $rv .= "Date: $v\n";
 702         }
 703         $ctx->{-title_html} = join(' - ', @title);
 704         if (scalar(@$mids) == 1) { # common case
 705                 my $mid = PublicInbox::Hval->new_msgid($mids->[0]);
 706                 my $mhtml = $mid->as_html;
 707                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 708                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 709         } else {
 710                 # X-Alt-Message-ID can happen if a message is injected from
 711                 # public-inbox-nntpd because of multiple Message-ID headers.
 712                 my $lnk = PublicInbox::Linkify->new;
 713                 my $s = '';
 714                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 715                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 716                 }
 717                 $lnk->linkify_mids('..', \$s, 1);
 718                 $rv .= $s;
 719         }
 720         $rv .= _parent_headers($hdr, $over);
 721         $rv .= "\n";
 722 }
 723
 724 sub thread_skel {
 725         my ($dst, $ctx, $hdr, $tpfx) = @_;
 726         my $mid = mids($hdr)->[0];
 727         my $ibx = $ctx->{-inbox};
 728         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 729         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 730                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 731                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 732                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 733
 734         my $parent = in_reply_to($hdr);
 735         $$dst .= "\n<b>Thread overview: </b>";
 736         if ($nr <= 1) {
 737                 if (defined $parent) {
 738                         $$dst .= "$expand\n ";
 739                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 740                 } else {
 741                         $$dst .= "[no followups] $expand\n";
 742                 }
 743                 $ctx->{next_msg} = undef;
 744                 $ctx->{parent_msg} = $parent;
 745                 return;
 746         }
 747
 748         $$dst .= "$nr+ messages / $expand";
 749         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 750
 751         # nb: mutt only shows the first Subject in the index pane
 752         # when multiple Subject: headers are present, so we follow suit:
 753         my $subj = $hdr->header('Subject') // '';
 754         $subj = '(no subject)' if $subj eq '';
 755         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 756         $ctx->{cur} = $mid;
 757         $ctx->{prev_attr} = '';
 758         $ctx->{prev_level} = 0;
 759         $ctx->{dst} = $dst;
 760
 761         # reduce hash lookups in skel_dump
 762         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 763         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 764
 765         $ctx->{parent_msg} = $parent;
 766 }
 767
 768 sub _parent_headers {
 769         my ($hdr, $over) = @_;
 770         my $rv = '';
 771         my @irt = $hdr->header_raw('In-Reply-To');
 772         my $refs;
 773         if (@irt) {
 774                 my $lnk = PublicInbox::Linkify->new;
 775                 $rv .= "In-Reply-To: $_\n" for @irt;
 776                 $lnk->linkify_mids('..', \$rv);
 777         } else {
 778                 $refs = references($hdr);
 779                 my $irt = pop @$refs;
 780                 if (defined $irt) {
 781                         my $v = PublicInbox::Hval->new_msgid($irt);
 782                         my $html = $v->as_html;
 783                         my $href = $v->{href};
 784                         $rv .= "In-Reply-To: &lt;";
 785                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 786                 }
 787         }
 788
 789         # do not display References: if search is present,
 790         # we show the thread skeleton at the bottom, instead.
 791         return $rv if $over;
 792
 793         $refs //= references($hdr);
 794         if (@$refs) {
 795                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 796                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 797         }
 798         $rv;
 799 }
 800
 801 sub html_footer {
 802         my ($hdr, $standalone, $ctx, $rhref) = @_;
 803
 804         my $ibx = $ctx->{-inbox} if $ctx;
 805         my $upfx = '../';
 806         my $tpfx = '';
 807         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 808         my $irt = '';
 809         if ($idx && $ibx->over) {
 810                 $idx .= "\n";
 811                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 812                 my ($next, $prev);
 813                 my $parent = '       ';
 814                 $next = $prev = '    ';
 815
 816                 if (my $n = $ctx->{next_msg}) {
 817                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 818                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 819                 }
 820                 my $u;
 821                 my $par = $ctx->{parent_msg};
 822                 if ($par) {
 823                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 824                         $u = "$upfx$u/";
 825                 }
 826                 if (my $p = $ctx->{prev_msg}) {
 827                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 828                         if ($p && $par && $p eq $par) {
 829                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 830                                         'rel=prev>prev parent</a>';
 831                                 $parent = '';
 832                         } else {
 833                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 834                                         'rel=prev>prev</a>';
 835                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 836                         }
 837                 } elsif ($u) { # unlikely
 838                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 839                 }
 840                 $irt = "$next $prev$parent ";
 841         } else {
 842                 $irt = '';
 843         }
 844         $rhref ||= '#R';
 845         $irt .= qq(<a\nhref="$rhref">reply</a>);
 846         $irt .= $idx;
 847 }
 848
 849 sub linkify_ref_no_over {
 850         my $v = PublicInbox::Hval->new_msgid($_[0]);
 851         my $html = $v->as_html;
 852         my $href = $v->{href};
 853         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 854 }
 855
 856 sub anchor_for {
 857         my ($msgid) = @_;
 858         'm' . id_compress($msgid, 1);
 859 }
 860
 861 sub ghost_parent {
 862         my ($upfx, $mid) = @_;
 863
 864         $mid = PublicInbox::Hval->new_msgid($mid);
 865         my $href = $mid->{href};
 866         my $html = $mid->as_html;
 867         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 868 }
 869
 870 sub indent_for {
 871         my ($level) = @_;
 872         $level ? INDENT x ($level - 1) : '';
 873 }
 874
 875 sub find_mid_root {
 876         my ($ctx, $level, $node, $idx) = @_;
 877         ++$ctx->{root_idx} if $level == 0;
 878         if ($node->{id} eq $ctx->{mid}) {
 879                 $ctx->{found_mid_at} = $ctx->{root_idx};
 880                 return 0;
 881         }
 882         1;
 883 }
 884
 885 sub strict_loose_note ($) {
 886         my ($nr) = @_;
 887         my $msg =
 888 "  -- strict thread matches above, loose matches on Subject: below --\n";
 889
 890         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 891                 $msg .=
 892 "  -- use mbox.gz link to download all $nr messages --\n";
 893         }
 894         $msg;
 895 }
 896
 897 sub thread_results {
 898         my ($ctx, $msgs) = @_;
 899         require PublicInbox::SearchThread;
 900         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 901
 902         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 903         # and preserved in the future.  This bug is hidden by `sid' matches
 904         # in get_thread, so we never noticed it until now.  And even when
 905         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 906         # bump since reindexing is expensive and users may not do it
 907
 908         # loose threading could've returned too many results,
 909         # put the root the message we care about at the top:
 910         my $mid = $ctx->{mid};
 911         if (defined($mid) && scalar(@$rootset) > 1) {
 912                 $ctx->{root_idx} = -1;
 913                 my $nr = scalar @$msgs;
 914                 walk_thread($rootset, $ctx, *find_mid_root);
 915                 my $idx = $ctx->{found_mid_at};
 916                 if (defined($idx) && $idx != 0) {
 917                         my $tip = splice(@$rootset, $idx, 1);
 918                         @$rootset = reverse @$rootset;
 919                         unshift @$rootset, $tip;
 920                         $ctx->{sl_note} = strict_loose_note($nr);
 921                 }
 922         }
 923         $rootset
 924 }
 925
 926 sub missing_thread {
 927         my ($ctx) = @_;
 928         require PublicInbox::ExtMsg;
 929         PublicInbox::ExtMsg::ext_msg($ctx);
 930 }
 931
 932 sub dedupe_subject {
 933         my ($prev_subj, $subj, $val) = @_;
 934
 935         my $omit = ''; # '"' denotes identical text omitted
 936         my (@prev_pop, @curr_pop);
 937         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 938                 push(@prev_pop, pop(@$prev_subj));
 939                 push(@curr_pop, pop(@$subj));
 940                 $omit ||= $val;
 941         }
 942         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 943         if (scalar(@curr_pop) == 1) {
 944                 $omit = '';
 945                 push @$prev_subj, @prev_pop;
 946                 push @$subj, @curr_pop;
 947         }
 948         $omit;
 949 }
 950
 951 sub skel_dump {
 952         my ($ctx, $level, $node) = @_;
 953         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 954
 955         my $dst = $ctx->{dst};
 956         my $cur = $ctx->{cur};
 957         my $mid = $smsg->{mid};
 958
 959         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 960                 $$dst .= delete $ctx->{sl_note} || '';
 961         }
 962
 963         my $f = ascii_html($smsg->from_name);
 964         my $obfs_ibx = $ctx->{-obfs_ibx};
 965         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 966
 967         my $d = fmt_ts($smsg->{ds});
 968         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 969         if (exists $ctx->{searchview}) {
 970                 if (defined(my $pct = $smsg->{pct})) {
 971                         $d .= (sprintf(' % 2u', $pct) . '%');
 972                 } else {
 973                         $unmatched = 1;
 974                         $d .= '    ';
 975                 }
 976         }
 977         $d .= ' ' . indent_for($level) . th_pfx($level);
 978         my $attr = $f;
 979         $ctx->{first_level} ||= $level;
 980
 981         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 982                 $ctx->{prev_attr} = $attr;
 983         }
 984         $ctx->{prev_level} = $level;
 985
 986         if ($cur) {
 987                 if ($cur eq $mid) {
 988                         delete $ctx->{cur};
 989                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 990                                  "$attr [this message]</a></b>\n";
 991                         return 1;
 992                 } else {
 993                         $ctx->{prev_msg} = $mid;
 994                 }
 995         } else {
 996                 $ctx->{next_msg} ||= $mid;
 997         }
 998
 999         # Subject is never undef, this mail was loaded from
1000         # our Xapian which would've resulted in '' if it were
1001         # really missing (and Filter rejects empty subjects)
1002         my @subj = split(/ /, subject_normalized($smsg->subject));
1003         # remove common suffixes from the subject if it matches the previous,
1004         # so we do not show redundant text at the end.
1005         my $prev_subj = $ctx->{prev_subj} || [];
1006         $ctx->{prev_subj} = [ @subj ];
1007         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1008         my $end;
1009         if (@subj) {
1010                 my $subj = join(' ', @subj);
1011                 $subj = ascii_html($subj);
1012                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1013                 $end = "$subj</a> $omit$f\n"
1014         } else {
1015                 $end = "$f</a>\n";
1016         }
1017         my $m;
1018         my $id = '';
1019         my $mapping = $unmatched ? undef : $ctx->{mapping};
1020         if ($mapping) {
1021                 my $map = $mapping->{$mid};
1022                 $id = id_compress($mid, 1);
1023                 $m = '#m'.$id;
1024                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1025                 $id = "\nid=r".$id;
1026         } else {
1027                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
1028         }
1029         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1030         1;
1031 }
1032
1033 sub _skel_ghost {
1034         my ($ctx, $level, $node) = @_;
1035
1036         my $mid = $node->{id};
1037         my $d = '     [not found] ';
1038         $d .= '    '  if exists $ctx->{searchview};
1039         $d .= indent_for($level) . th_pfx($level);
1040         my $upfx = $ctx->{-upfx};
1041         my $m = PublicInbox::Hval->new_msgid($mid);
1042         my $href = $upfx . $m->{href} . '/';
1043         my $html = $m->as_html;
1044
1045         my $mapping = $ctx->{mapping};
1046         my $map = $mapping->{$mid} if $mapping;
1047         if ($map) {
1048                 my $id = id_compress($mid, 1);
1049                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1050                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1051         } else {
1052                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1053         }
1054         my $dst = $ctx->{dst};
1055         $$dst .= $d;
1056         1;
1057 }
1058
1059 sub sort_ds {
1060         [ sort {
1061                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
1062                 (eval { $b->topmost->{smsg}->ds } || 0)
1063         } @{$_[0]} ];
1064 }
1065
1066 # accumulate recent topics if search is supported
1067 # returns 200 if done, 404 if not
1068 sub acc_topic {
1069         my ($ctx, $level, $node) = @_;
1070         my $mid = $node->{id};
1071         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
1072         my ($subj, $ds);
1073         my $topic;
1074         if ($x) {
1075                 $subj = $x->subject;
1076                 $subj = subject_normalized($subj);
1077                 $subj = '(no subject)' if $subj eq '';
1078                 $ds = $x->ds;
1079                 if ($level == 0) {
1080                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1081                         $ctx->{-cur_topic} = $topic;
1082                         push @{$ctx->{order}}, $topic;
1083                         return 1;
1084                 }
1085
1086                 $topic = $ctx->{-cur_topic}; # should never be undef
1087                 $topic->[0] = $ds if $ds > $topic->[0];
1088                 $topic->[1]++;
1089                 my $seen = $topic->[2];
1090                 if (scalar(@$topic) == 3) { # parent was a ghost
1091                         push @$topic, $subj;
1092                 } elsif (!$seen->{$subj}) {
1093                         push @$topic, $level, $subj;
1094                 }
1095                 $seen->{$subj} = $mid; # latest for subject
1096         } else { # ghost message
1097                 return 1 if $level != 0; # ignore child ghosts
1098                 $topic = [ -666, 0, {} ];
1099                 $ctx->{-cur_topic} = $topic;
1100                 push @{$ctx->{order}}, $topic;
1101         }
1102         1;
1103 }
1104
1105 sub dump_topics {
1106         my ($ctx) = @_;
1107         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1108         if (!@$order) {
1109                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1110                 return 404;
1111         }
1112
1113         my @out;
1114         my $ibx = $ctx->{-inbox};
1115         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1116
1117         # sort by recency, this allows new posts to "bump" old topics...
1118         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1119                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1120                 @$topic = ();
1121                 next unless defined $top;  # ghost topic
1122                 my $mid = delete $seen->{$top};
1123                 my $href = mid_escape($mid);
1124                 my $prev_subj = [ split(/ /, $top) ];
1125                 $top = PublicInbox::Hval->new($top)->as_html;
1126                 $ds = fmt_ts($ds);
1127
1128                 # $n isn't the total number of posts on the topic,
1129                 # just the number of posts in the current results window
1130                 my $anchor;
1131                 if ($n == 1) {
1132                         $n = '';
1133                         $anchor = '#u'; # top of only message
1134                 } else {
1135                         $n = " ($n+ messages)";
1136                         $anchor = '#t'; # thread skeleton
1137                 }
1138
1139                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1140                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1141                 my $s = "<a\nhref=\"$href/T/$anchor\">$top</a>\n" .
1142                         " $ds UTC $n - $mbox / $atom\n";
1143                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1144                         my $level = $ex[$i];
1145                         my $subj = $ex[$i + 1];
1146                         $mid = delete $seen->{$subj};
1147                         my @subj = split(/ /, subject_normalized($subj));
1148                         my @next_prev = @subj; # full copy
1149                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1150                         $prev_subj = \@next_prev;
1151                         $subj = ascii_html(join(' ', @subj));
1152                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1153                         $href = mid_escape($mid);
1154                         $s .= indent_for($level) . TCHILD;
1155                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1156                 }
1157                 push @out, $s;
1158         }
1159         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1160         200;
1161 }
1162
1163 # only for the t= query parameter passed to overview DB
1164 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1165
1166 sub str2ts ($) {
1167         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1168         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1169 }
1170
1171 sub pagination_footer ($$) {
1172         my ($ctx, $latest) = @_;
1173         delete $ctx->{qp} or return;
1174         my $next = $ctx->{next_page} || '';
1175         my $prev = $ctx->{prev_page} || '';
1176         if ($prev) {
1177                 $next = $next ? "$next " : '     ';
1178                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1179         }
1180         "<hr><pre>page: $next$prev</pre>";
1181 }
1182
1183 sub index_nav { # callback for WwwStream
1184         my (undef, $ctx) = @_;
1185         pagination_footer($ctx, '.')
1186 }
1187
1188 sub paginate_recent ($$) {
1189         my ($ctx, $lim) = @_;
1190         my $t = $ctx->{qp}->{t} || '';
1191         my $opts = { limit => $lim };
1192         my ($after, $before);
1193
1194         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1195         # if only $after exists "YYYYMMDD.." because "." could be skipped
1196         # if interpreted as an end-of-sentence
1197         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1198         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1199
1200         my $ibx = $ctx->{-inbox};
1201         my $msgs = $ibx->recent($opts, $after, $before);
1202         my $nr = scalar @$msgs;
1203         if ($nr < $lim && defined($after)) {
1204                 $after = $before = undef;
1205                 $msgs = $ibx->recent($opts);
1206                 $nr = scalar @$msgs;
1207         }
1208         my $more = $nr == $lim;
1209         my ($newest, $oldest);
1210         if ($nr) {
1211                 $newest = $msgs->[0]->{ts};
1212                 $oldest = $msgs->[-1]->{ts};
1213                 # if we only had $after, our SQL query in ->recent ordered
1214                 if ($newest < $oldest) {
1215                         ($oldest, $newest) = ($newest, $oldest);
1216                         $more = 0 if defined($after) && $after < $oldest;
1217                 }
1218         }
1219         if (defined($oldest) && $more) {
1220                 my $s = ts2str($oldest);
1221                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1222         }
1223         if (defined($newest) && (defined($before) || defined($after))) {
1224                 my $s = ts2str($newest);
1225                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1226         }
1227         $msgs;
1228 }
1229
1230 sub index_topics {
1231         my ($ctx) = @_;
1232         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1233         if (@$msgs) {
1234                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1235         }
1236         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1237 }
1238
1239 sub thread_adj_level {
1240         my ($ctx, $level) = @_;
1241
1242         my $max = $ctx->{cur_level};
1243         if ($level <= 0) {
1244                 return ('', '') if $max == 0; # flat output
1245
1246                 # reset existing lists
1247                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1248                 $ctx->{cur_level} = 0;
1249                 ("$beg</ul>", '');
1250         } elsif ($level == $max) { # continue existing list
1251                 qw(<li> </li>);
1252         } elsif ($level < $max) {
1253                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1254                 $ctx->{cur_level} = $level;
1255                 ("$beg<li>", '</li>');
1256         } else { # ($level > $max) # start a new level
1257                 $ctx->{cur_level} = $level;
1258                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1259                 ($beg, '</li>');
1260         }
1261 }
1262
1263 sub ghost_index_entry {
1264         my ($ctx, $level, $node) = @_;
1265         my ($beg, $end) = thread_adj_level($ctx,  $level);
1266         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1267                 . '</pre>' . $end;
1268 }
1269
1270 1;