lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use URI::Escape qw/uri_escape_utf8/;
   7 use Date::Parse qw/str2time/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 use PublicInbox::Hval;
  12 use PublicInbox::MID qw/mid_clean mid_compress mid2path/;
  13 use Digest::SHA qw/sha1_hex/;
  14 my $SALT = rand;
  15 require POSIX;
  16
  17 # TODO: make these constants tunable
  18 use constant MAX_INLINE_QUOTED => 12; # half an 80x24 terminal
  19 use constant MAX_TRUNC_LEN => 72;
  20 use constant PRE_WRAP => "<pre\nstyle=\"white-space:pre-wrap\">";
  21 use constant T_ANCHOR => '#u';
  22 use constant INDENT => '  ';
  23
  24 *ascii_html = *PublicInbox::Hval::ascii_html;
  25
  26 my $enc_utf8 = find_encoding('UTF-8');
  27
  28 # public functions:
  29 sub msg_html {
  30         my ($ctx, $mime, $full_pfx, $footer) = @_;
  31         if (defined $footer) {
  32                 $footer = "\n" . $footer;
  33         } else {
  34                 $footer = '';
  35         }
  36         headers_to_html_header($mime, $full_pfx, $ctx) .
  37                 multipart_text_as_html($mime, $full_pfx) .
  38                 '</pre><hr />' . PRE_WRAP .
  39                 html_footer($mime, 1, $full_pfx, $ctx) .
  40                 $footer .
  41                 '</pre></body></html>';
  42 }
  43
  44 sub feed_entry {
  45         my ($class, $mime, $full_pfx) = @_;
  46
  47         PRE_WRAP . multipart_text_as_html($mime, $full_pfx) . '</pre>';
  48 }
  49
  50 sub in_reply_to {
  51         my ($header_obj) = @_;
  52         my $irt = $header_obj->header('In-Reply-To');
  53
  54         return mid_clean($irt) if (defined $irt);
  55
  56         my $refs = $header_obj->header('References');
  57         if ($refs && $refs =~ /<([^>]+)>\s*\z/s) {
  58                 return $1;
  59         }
  60         undef;
  61 }
  62
  63 # this is already inside a <pre>
  64 sub index_entry {
  65         my ($fh, $mime, $level, $state) = @_;
  66         my $midx = $state->{anchor_idx}++;
  67         my $ctx = $state->{ctx};
  68         my $srch = $ctx->{srch};
  69         my ($prev, $next) = ($midx - 1, $midx + 1);
  70         my $part_nr = 0;
  71         my $enc = enc_for($mime->header("Content-Type"));
  72         my $subj = $mime->header('Subject');
  73         my $header_obj = $mime->header_obj;
  74
  75         my $mid_raw = $header_obj->header('Message-ID');
  76         my $id = anchor_for($mid_raw);
  77         my $seen = $state->{seen};
  78         $seen->{$id} = "#$id"; # save the anchor for children, later
  79
  80         my $mid = PublicInbox::Hval->new_msgid($mid_raw);
  81         my $from = PublicInbox::Hval->new_oneline($mime->header('From'))->raw;
  82         my @from = Email::Address->parse($from);
  83         $from = $from[0]->name;
  84
  85         $from = PublicInbox::Hval->new_oneline($from)->as_html;
  86         $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
  87         my $more = 'permalink';
  88         my $root_anchor = $state->{root_anchor} || '';
  89         my $path = $root_anchor ? '../../' : '';
  90         my $href = $mid->as_href;
  91         my $irt = in_reply_to($header_obj);
  92         my $parent_anchor = $seen->{anchor_for($irt)} if defined $irt;
  93
  94         if ($srch) {
  95                 my $t = $ctx->{flat} ? 'T' : 't';
  96                 $subj = "<a\nhref=\"${path}$href/$t/#u\">$subj</a>";
  97         }
  98         if ($root_anchor eq $id) {
  99                 $subj = "<u\nid=\"u\">$subj</u>";
 100         }
 101
 102         my $ts = _msg_date($mime);
 103         my $rv = "<table\nsummary=l$level><tr>";
 104         if ($level) {
 105                 $rv .= '<td><pre>' . (INDENT x $level) . '</pre></td>';
 106         }
 107         $rv .= "<td\nid=s$midx>" . PRE_WRAP;
 108         $rv .= "<b\nid=\"$id\">$subj</b>\n";
 109         $rv .= "- by $from @ $ts UTC - ";
 110         $rv .= "<a\nhref=\"#s$next\">next</a>";
 111         if ($prev >= 0) {
 112                 $rv .= "/<a\nhref=\"#s$prev\">prev</a>";
 113         }
 114         $fh->write($rv .= "\n\n");
 115
 116         my ($fhref, $more_ref);
 117         my $mhref = "${path}$href/";
 118
 119         # show full message if it's our root message
 120         if ($root_anchor ne $id) {
 121                 $fhref = "${path}$href/f/";
 122                 $more_ref = \$more;
 123         }
 124         # scan through all parts, looking for displayable text
 125         $mime->walk_parts(sub {
 126                 index_walk($fh, $_[0], $enc, \$part_nr, $fhref, $more_ref);
 127         });
 128         $mime->body_set('');
 129
 130         my $txt = "${path}$href/raw";
 131         $rv = "\n<a\nhref=\"$mhref\">$more</a> <a\nhref=\"$txt\">raw</a> ";
 132         $rv .= html_footer($mime, 0, undef, $ctx);
 133
 134         if (defined $irt) {
 135                 unless (defined $parent_anchor) {
 136                         my $v = PublicInbox::Hval->new_msgid($irt, 1);
 137                         $v = $v->as_href;
 138                         $parent_anchor = "${path}$v/";
 139                 }
 140                 $rv .= " <a\nhref=\"$parent_anchor\">parent</a>";
 141         }
 142         if ($srch) {
 143                 if ($ctx->{flat}) {
 144                         $rv .= " [<a\nhref=\"${path}$href/t/#u\">threaded</a>" .
 145                                 "|<b>flat</b>]";
 146                 } else {
 147                         $rv .= " [<b>threaded</b>|" .
 148                                 "<a\nhref=\"${path}$href/T/#u\">flat</a>]";
 149                 }
 150         }
 151
 152         $fh->write($rv .= '</pre></td></tr></table>');
 153 }
 154
 155 sub thread_html {
 156         my ($ctx, $foot, $srch) = @_;
 157         sub { emit_thread_html($_[0], $ctx, $foot, $srch) }
 158 }
 159
 160 # only private functions below.
 161
 162 sub emit_thread_html {
 163         my ($cb, $ctx, $foot, $srch) = @_;
 164         my $mid = $ctx->{mid};
 165         my $res = $srch->get_thread($mid);
 166         my $msgs = load_results($res);
 167         my $nr = scalar @$msgs;
 168         return missing_thread($cb, $ctx) if $nr == 0;
 169         my $flat = $ctx->{flat};
 170         my $orig_cb = $cb;
 171         my $seen = {};
 172         my $state = {
 173                 ctx => $ctx,
 174                 seen => $seen,
 175                 root_anchor => anchor_for($mid),
 176                 anchor_idx => 0,
 177         };
 178
 179         require PublicInbox::GitCatFile;
 180         my $git = PublicInbox::GitCatFile->new($ctx->{git_dir});
 181         if ($flat) {
 182                 pre_anchor_entry($seen, $_) for (@$msgs);
 183                 __thread_entry(\$cb, $git, $state, $_, 0) for (@$msgs);
 184         } else {
 185                 my $th = thread_results($msgs);
 186                 thread_entry(\$cb, $git, $state, $_, 0) for $th->rootset;
 187         }
 188         $git = undef;
 189         Email::Address->purge_cache;
 190
 191         # there could be a race due to a message being deleted in git
 192         # but still being in the Xapian index:
 193         return missing_thread($cb, $ctx) if ($orig_cb eq $cb);
 194
 195         my $final_anchor = $state->{anchor_idx};
 196         my $next = "<a\nid=\"s$final_anchor\">";
 197         $next .= $final_anchor == 1 ? 'only message in' : 'end of';
 198         $next .= " thread</a>, back to <a\nhref=\"../../\">index</a>";
 199         $next .= "\ndownload thread: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 200         $next .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>";
 201         $cb->write("<hr />" . PRE_WRAP . $next . "\n\n". $foot .
 202                    "</pre></body></html>");
 203         $cb->close;
 204 }
 205
 206 sub index_walk {
 207         my ($fh, $part, $enc, $part_nr, $fhref, $more) = @_;
 208         my $s = add_text_body($enc, $part, $part_nr, $fhref);
 209
 210         if ($more) {
 211                 # drop the remainder of git patches, they're usually better
 212                 # to review when the full message is viewed
 213                 $s =~ s!^---+\n.*\z!!ms and $$more = 'more...';
 214
 215                 # Drop signatures
 216                 $s =~ s/^-- \n.*\z//ms and $$more = 'more...';
 217         }
 218
 219         # kill any leading or trailing whitespace lines
 220         $s =~ s/^\s*$//sgm;
 221         $s =~ s/\s+\z//s;
 222
 223         if ($s ne '') {
 224                 # kill per-line trailing whitespace
 225                 $s =~ s/[ \t]+$//sgm;
 226                 $s .= "\n" unless $s =~ /\n\z/s;
 227         }
 228         $fh->write($s);
 229 }
 230
 231 sub enc_for {
 232         my ($ct, $default) = @_;
 233         $default ||= $enc_utf8;
 234         defined $ct or return $default;
 235         my $ct_parsed = parse_content_type($ct);
 236         if ($ct_parsed) {
 237                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
 238                         my $enc = find_encoding($charset);
 239                         return $enc if $enc;
 240                 }
 241         }
 242         $default;
 243 }
 244
 245 sub multipart_text_as_html {
 246         my ($mime, $full_pfx, $srch) = @_;
 247         my $rv = "";
 248         my $part_nr = 0;
 249         my $enc = enc_for($mime->header("Content-Type"));
 250
 251         # scan through all parts, looking for displayable text
 252         $mime->walk_parts(sub {
 253                 my ($part) = @_;
 254                 $rv .= add_text_body($enc, $part, \$part_nr, $full_pfx, 1);
 255         });
 256         $mime->body_set('');
 257         $rv;
 258 }
 259
 260 sub add_filename_line {
 261         my ($enc, $fn) = @_;
 262         my $len = 72;
 263         my $pad = "-";
 264         $fn = $enc->decode($fn);
 265         $len -= length($fn);
 266         $pad x= ($len/2) if ($len > 0);
 267         "$pad " . ascii_html($fn) . " $pad\n";
 268 }
 269
 270 my $LINK_RE = qr!\b((?:ftp|https?|nntp)://
 271                  [\@:\w\.-]+/
 272                  ?[\@\w\+\&\?\.\%\;/#=-]*)!x;
 273
 274 sub linkify_1 {
 275         my ($link_map, $s) = @_;
 276         $s =~ s!$LINK_RE!
 277                 my $url = $1;
 278                 # salt this, as this could be exploited to show
 279                 # links in the HTML which don't show up in the raw mail.
 280                 my $key = sha1_hex($url . $SALT);
 281                 $link_map->{$key} = $url;
 282                 'PI-LINK-'. $key;
 283         !ge;
 284         $s;
 285 }
 286
 287 sub linkify_2 {
 288         my ($link_map, $s) = @_;
 289
 290         # Added "PI-LINK-" prefix to avoid false-positives on git commits
 291         $s =~ s!\bPI-LINK-([a-f0-9]{40})\b!
 292                 my $key = $1;
 293                 my $url = $link_map->{$key};
 294                 if (defined $url) {
 295                         $url = ascii_html($url);
 296                         "<a\nhref=\"$url\">$url</a>";
 297                 } else {
 298                         # false positive or somebody tried to mess with us
 299                         $key;
 300                 }
 301         !ge;
 302         $s;
 303 }
 304
 305 sub flush_quote {
 306         my ($quot, $n, $part_nr, $full_pfx, $final, $do_anchor) = @_;
 307
 308         if ($full_pfx) {
 309                 if (!$final && scalar(@$quot) <= MAX_INLINE_QUOTED) {
 310                         # show quote inline
 311                         my %l;
 312                         my $rv = join('', map { linkify_1(\%l, $_) } @$quot);
 313                         @$quot = ();
 314                         $rv = ascii_html($rv);
 315                         return linkify_2(\%l, $rv);
 316                 }
 317
 318                 # show a short snippet of quoted text and link to full version:
 319                 @$quot = map { s/^(?:>\s*)+//gm; $_ } @$quot;
 320                 my $cur = join(' ', @$quot);
 321                 @$quot = split(/\s+/, $cur);
 322                 $cur = '';
 323                 do {
 324                         my $tmp = shift(@$quot);
 325                         my $len = length($tmp) + length($cur);
 326                         if ($len > MAX_TRUNC_LEN) {
 327                                 @$quot = ();
 328                         } else {
 329                                 $cur .= $tmp . ' ';
 330                         }
 331                 } while (@$quot && length($cur) < MAX_TRUNC_LEN);
 332                 @$quot = ();
 333                 $cur =~ s/ \z/ .../s;
 334                 $cur = ascii_html($cur);
 335                 my $nr = ++$$n;
 336                 "&gt; [<a\nhref=\"$full_pfx#q${part_nr}_$nr\">$cur</a>]\n";
 337         } else {
 338                 # show everything in the full version with anchor from
 339                 # short version (see above)
 340                 my %l;
 341                 my $rv .= join('', map { linkify_1(\%l, $_) } @$quot);
 342                 @$quot = ();
 343                 $rv = ascii_html($rv);
 344                 return linkify_2(\%l, $rv) unless $do_anchor;
 345                 my $nr = ++$$n;
 346                 "<a\nid=q${part_nr}_$nr></a>" . linkify_2(\%l, $rv);
 347         }
 348 }
 349
 350 sub add_text_body {
 351         my ($enc_msg, $part, $part_nr, $full_pfx, $do_anchor) = @_;
 352         return '' if $part->subparts;
 353
 354         my $ct = $part->content_type;
 355         # account for filter bugs...
 356         if (defined $ct && $ct =~ m!\btext/[xh]+tml\b!i) {
 357                 $part->body_set('');
 358                 return '';
 359         }
 360         my $enc = enc_for($ct, $enc_msg);
 361         my $n = 0;
 362         my $nr = 0;
 363         my $s = $part->body;
 364         $part->body_set('');
 365         $s = $enc->decode($s);
 366         my @lines = split(/^/m, $s);
 367         $s = '';
 368
 369         if ($$part_nr > 0) {
 370                 my $fn = $part->filename;
 371                 defined($fn) or $fn = "part #" . ($$part_nr + 1);
 372                 $s .= add_filename_line($enc, $fn);
 373         }
 374
 375         my @quot;
 376         while (defined(my $cur = shift @lines)) {
 377                 if ($cur !~ /^>/) {
 378                         # show the previously buffered quote inline
 379                         if (scalar @quot) {
 380                                 $s .= flush_quote(\@quot, \$n, $$part_nr,
 381                                                   $full_pfx, 0, $do_anchor);
 382                         }
 383
 384                         # regular line, OK
 385                         my %l;
 386                         $cur = linkify_1(\%l, $cur);
 387                         $cur = ascii_html($cur);
 388                         $s .= linkify_2(\%l, $cur);
 389                 } else {
 390                         push @quot, $cur;
 391                 }
 392         }
 393         if (scalar @quot) {
 394                 $s .= flush_quote(\@quot, \$n, $$part_nr, $full_pfx, 1,
 395                                   $do_anchor);
 396         }
 397         $s .= "\n" unless $s =~ /\n\z/s;
 398         ++$$part_nr;
 399         $s;
 400 }
 401
 402 sub headers_to_html_header {
 403         my ($mime, $full_pfx, $ctx) = @_;
 404         my $srch = $ctx->{srch} if $ctx;
 405         my $rv = "";
 406         my @title;
 407         my $header_obj = $mime->header_obj;
 408         my $mid = $header_obj->header('Message-ID');
 409         $mid = PublicInbox::Hval->new_msgid($mid);
 410         my $mid_href = $mid->as_href;
 411         foreach my $h (qw(From To Cc Subject Date)) {
 412                 my $v = $mime->header($h);
 413                 defined($v) && ($v ne '') or next;
 414                 $v = PublicInbox::Hval->new_oneline($v);
 415
 416                 if ($h eq 'From') {
 417                         my @from = Email::Address->parse($v->raw);
 418                         $title[1] = ascii_html($from[0]->name);
 419                 } elsif ($h eq 'Subject') {
 420                         $title[0] = $v->as_html;
 421                         if ($srch) {
 422                                 my $p = $full_pfx ? '' : '../';
 423                                 $rv .= "$h: <a\nid=\"t\"\nhref=\"${p}t/#u\">";
 424                                 $rv .= $v->as_html . "</a>\n";
 425                                 next;
 426                         }
 427                 }
 428                 $rv .= "$h: " . $v->as_html . "\n";
 429
 430         }
 431         $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 432         my $raw_ref = $full_pfx ? 'raw' : '../raw';
 433         $rv .= "(<a\nhref=\"$raw_ref\">raw</a>)\n";
 434         if ($srch) {
 435                 $rv .= "<a\nhref=\"#r\">References: [see below]</a>\n";
 436         } else {
 437                 $rv .= _parent_headers_nosrch($header_obj);
 438         }
 439         $rv .= "\n";
 440
 441         ("<html><head><title>".  join(' - ', @title) .
 442          '</title></head><body>' . PRE_WRAP . $rv);
 443 }
 444
 445 sub thread_inline {
 446         my ($dst, $ctx, $cur, $full_pfx) = @_;
 447         my $srch = $ctx->{srch};
 448         my $mid = mid_clean($cur->header('Message-ID'));
 449         my $res = $srch->get_thread($mid);
 450         my $nr = $res->{total};
 451
 452         if ($nr <= 1) {
 453                 $$dst .= "\n[no followups, yet]\n";
 454                 return (undef, in_reply_to($cur));
 455         }
 456         my $upfx = $full_pfx ? '' : '../';
 457
 458         $$dst .= "\n\n~$nr messages in thread: ".
 459                  "(<a\nhref=\"${upfx}t/#u\">expand</a>)\n";
 460         my $subj = $srch->subject_path($cur->header('Subject'));
 461         my $parent = in_reply_to($cur);
 462         my $state = {
 463                 seen => { $subj => 1 },
 464                 srch => $srch,
 465                 cur => $mid,
 466                 parent_cmp => defined $parent ? $parent : '',
 467                 parent => $parent,
 468                 prev_attr => '',
 469                 prev_level => 0,
 470         };
 471         for (thread_results(load_results($res))->rootset) {
 472                 inline_dump($dst, $state, $upfx, $_, 0);
 473         }
 474         ($state->{next_msg}, $state->{parent});
 475 }
 476
 477 sub _parent_headers_nosrch {
 478         my ($header_obj) = @_;
 479         my $rv = '';
 480
 481         my $irt = in_reply_to($header_obj);
 482         if (defined $irt) {
 483                 my $v = PublicInbox::Hval->new_msgid($irt, 1);
 484                 my $html = $v->as_html;
 485                 my $href = $v->as_href;
 486                 $rv .= "In-Reply-To: &lt;";
 487                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 488         }
 489
 490         my $refs = $header_obj->header('References');
 491         if ($refs) {
 492                 # avoid redundant URLs wasting bandwidth
 493                 my %seen;
 494                 $seen{$irt} = 1 if defined $irt;
 495                 my @refs;
 496                 my @raw_refs = ($refs =~ /<([^>]+)>/g);
 497                 foreach my $ref (@raw_refs) {
 498                         next if $seen{$ref};
 499                         $seen{$ref} = 1;
 500                         push @refs, linkify_ref_nosrch($ref);
 501                 }
 502
 503                 if (@refs) {
 504                         $rv .= 'References: '. join(' ', @refs) . "\n";
 505                 }
 506         }
 507         $rv;
 508 }
 509
 510 sub html_footer {
 511         my ($mime, $standalone, $full_pfx, $ctx) = @_;
 512         my %cc; # everyone else
 513         my $to; # this is the From address
 514
 515         foreach my $h (qw(From To Cc)) {
 516                 my $v = $mime->header($h);
 517                 defined($v) && ($v ne '') or next;
 518                 my @addrs = Email::Address->parse($v);
 519                 foreach my $recip (@addrs) {
 520                         my $address = $recip->address;
 521                         my $dst = lc($address);
 522                         $cc{$dst} ||= $address;
 523                         $to ||= $dst;
 524                 }
 525         }
 526         Email::Address->purge_cache if $standalone;
 527
 528         my $subj = $mime->header('Subject') || '';
 529         $subj = "Re: $subj" unless $subj =~ /\bRe:/i;
 530         my $mid = $mime->header('Message-ID');
 531         my $irt = uri_escape_utf8($mid);
 532         delete $cc{$to};
 533         $to = uri_escape_utf8($to);
 534         $subj = uri_escape_utf8($subj);
 535
 536         my $cc = uri_escape_utf8(join(',', sort values %cc));
 537         my $href = "mailto:$to?In-Reply-To=$irt&Cc=${cc}&Subject=$subj";
 538
 539         my $srch = $ctx->{srch} if $ctx;
 540         my $upfx = $full_pfx ? '../' : '../../';
 541         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 542         if ($idx && $srch) {
 543                 my ($next, $p) = thread_inline(\$idx, $ctx, $mime, $full_pfx);
 544                 if (defined $p) {
 545                         $p = PublicInbox::Hval->new_oneline($p);
 546                         $p = $p->as_href;
 547                         $irt = "<a\nhref=\"$upfx$p/\">parent</a> ";
 548                 } else {
 549                         $irt = ' ' x length('parent ');
 550                 }
 551                 if ($next) {
 552                         $irt .= "<a\nhref=\"$upfx$next/\">next</a> ";
 553                 } else {
 554                         $irt .= '     ';
 555                 }
 556         } else {
 557                 $irt = '';
 558         }
 559
 560         "$irt<a\nhref=\"" . ascii_html($href) . '">reply</a>' . $idx;
 561 }
 562
 563 sub linkify_ref_nosrch {
 564         my $v = PublicInbox::Hval->new_msgid($_[0], 1);
 565         my $html = $v->as_html;
 566         my $href = $v->as_href;
 567         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 568 }
 569
 570 sub anchor_for {
 571         my ($msgid) = @_;
 572         my $id = $msgid;
 573         if ($id !~ /\A[a-f0-9]{40}\z/) {
 574                 $id = mid_compress(mid_clean($id), 1);
 575         }
 576         'm' . $id;
 577 }
 578
 579 sub thread_html_head {
 580         my ($cb, $mime) = @_;
 581         $$cb = $$cb->([200, ['Content-Type'=> 'text/html; charset=UTF-8']]);
 582
 583         my $s = PublicInbox::Hval->new_oneline($mime->header('Subject'));
 584         $s = $s->as_html;
 585         $$cb->write("<html><head><title>$s</title></head><body>");
 586 }
 587
 588 sub pre_anchor_entry {
 589         my ($seen, $mime) = @_;
 590         my $id = anchor_for($mime->header('Message-ID'));
 591         $seen->{$id} = "#$id"; # save the anchor for children, later
 592 }
 593
 594 sub ghost_parent {
 595         my ($upfx, $mid) = @_;
 596         # 'subject dummy' is used internally by Mail::Thread
 597         return '[no common parent]' if ($mid eq 'subject dummy');
 598
 599         $mid = PublicInbox::Hval->new_msgid($mid);
 600         my $href = $mid->as_href;
 601         my $html = $mid->as_html;
 602         qq{[parent not found: &lt;<a\nhref="$upfx../$href/">$html</a>&gt;]};
 603 }
 604
 605 sub __thread_entry {
 606         my ($cb, $git, $state, $mime, $level) = @_;
 607
 608         # lazy load the full message from mini_mime:
 609         $mime = eval {
 610                 my $path = mid2path(mid_clean($mime->header('Message-ID')));
 611                 Email::MIME->new($git->cat_file('HEAD:'.$path));
 612         } or return;
 613
 614         if ($state->{anchor_idx} == 0) {
 615                 thread_html_head($cb, $mime, $state);
 616         }
 617
 618         if (my $ghost = delete $state->{ghost}) {
 619                 # n.b. ghost messages may only be parents, not children
 620                 foreach my $g (@$ghost) {
 621                         $$cb->write("<table\nsummary=ghost><tr><td>" .
 622                                 (INDENT x $g->[1]) . "</td><td>" .
 623                                 PRE_WRAP . ghost_parent('../', $g->[0]) .
 624                                 '</pre></td></table>');
 625                 }
 626         }
 627         index_entry($$cb, $mime, $level, $state);
 628         1;
 629 }
 630
 631 sub __ghost_entry {
 632         my ($state, $node, $level) = @_;
 633         my $ghost = $state->{ghost} ||= [];
 634         push @$ghost, [ $node->messageid, $level ];
 635 }
 636
 637 sub thread_entry {
 638         my ($cb, $git, $state, $node, $level) = @_;
 639         return unless $node;
 640         if (my $mime = $node->message) {
 641                 unless (__thread_entry($cb, $git, $state, $mime, $level)) {
 642                         __ghost_entry($state, $node, $level);
 643                 }
 644         } else {
 645                 __ghost_entry($state, $node, $level);
 646         }
 647
 648         thread_entry($cb, $git, $state, $node->child, $level + 1);
 649         thread_entry($cb, $git, $state, $node->next, $level);
 650 }
 651
 652 sub load_results {
 653         my ($res) = @_;
 654
 655         [ map { $_->mini_mime } @{delete $res->{msgs}} ];
 656 }
 657
 658 sub msg_timestamp {
 659         my ($mime) = @_;
 660         my $ts = eval { str2time($mime->header('Date')) };
 661         defined($ts) ? $ts : 0;
 662 }
 663
 664 sub thread_results {
 665         my ($msgs, $nosubject) = @_;
 666         require PublicInbox::Thread;
 667         my $th = PublicInbox::Thread->new(@$msgs);
 668         no warnings 'once';
 669         $Mail::Thread::nosubject = $nosubject;
 670         $th->thread;
 671         $th->order(*sort_ts);
 672         $th
 673 }
 674
 675 sub missing_thread {
 676         my ($cb, $ctx) = @_;
 677         require PublicInbox::ExtMsg;
 678
 679         $cb->(PublicInbox::ExtMsg::ext_msg($ctx))
 680 }
 681
 682 sub _msg_date {
 683         my ($mime) = @_;
 684         my $ts = $mime->header('X-PI-TS') || msg_timestamp($mime);
 685         POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
 686 }
 687
 688 sub _inline_header {
 689         my ($dst, $state, $upfx, $mime, $level) = @_;
 690         my $pfx = INDENT x ($level - 1);
 691         my $dot = $level == 0 ? '' : '` ';
 692
 693         my $cur = $state->{cur};
 694         my $mid = mid_clean($mime->header('Message-ID'));
 695         my $f = $mime->header('X-PI-From');
 696         my $d = _msg_date($mime);
 697         $f = PublicInbox::Hval->new($f)->as_html;
 698         $d = PublicInbox::Hval->new($d)->as_html;
 699         my $attr = "$f @ $d";
 700         $state->{first_level} ||= $level;
 701         if ($attr ne $state->{prev_attr} || $state->{prev_level} > $level) {
 702                 $state->{prev_attr} = $attr;
 703                 $attr = ' - ' . $attr;
 704                 $attr .= ' UTC' if $level >= $state->{first_level};
 705         } else {
 706                 $attr = '';
 707         }
 708         $state->{prev_level} = $level;
 709
 710         if ($cur) {
 711                 if ($cur eq $mid) {
 712                         delete $state->{cur};
 713                         $$dst .= "$pfx$dot<b><a\nid=\"r\"\nhref=\"#t\">".
 714                                  "[this message]</a></b>$attr\n";
 715
 716                         return;
 717                 }
 718         } else {
 719                 $state->{next_msg} ||= $mid;
 720         }
 721
 722         # Subject is never undef, this mail was loaded from
 723         # our Xapian which would've resulted in '' if it were
 724         # really missing (and Filter rejects empty subjects)
 725         my $s = $mime->header('Subject');
 726         my $h = $state->{srch}->subject_path($s);
 727         if ($state->{seen}->{$h}) {
 728                 $s = undef;
 729         } else {
 730                 $state->{seen}->{$h} = 1;
 731                 $s = PublicInbox::Hval->new($s);
 732                 $s = $s->as_html;
 733         }
 734         my $m = PublicInbox::Hval->new_msgid($mid);
 735         $m = $upfx . '../' . $m->as_href . '/';
 736         if (defined $s) {
 737                 $$dst .= "$pfx$dot<a\nhref=\"$m\">$s</a>$attr\n";
 738         } else {
 739                 $$dst .= "$pfx$dot<a\nhref=\"$m\">$f @ $d</a>\n";
 740         }
 741 }
 742
 743 sub inline_dump {
 744         my ($dst, $state, $upfx, $node, $level) = @_;
 745         return unless $node;
 746         if (my $mime = $node->message) {
 747                 my $mid = mid_clean($mime->header('Message-ID'));
 748                 if ($mid eq $state->{parent_cmp}) {
 749                         $state->{parent} = $mid;
 750                 }
 751                 _inline_header($dst, $state, $upfx, $mime, $level);
 752         } else {
 753                 my $dot = $level == 0 ? '' : '` ';
 754                 my $pfx = (INDENT x $level) . $dot;
 755                 $$dst .= $pfx . ghost_parent($upfx, $node->messageid) . "\n";
 756         }
 757         inline_dump($dst, $state, $upfx, $node->child, $level+1);
 758         inline_dump($dst, $state, $upfx, $node->next, $level);
 759 }
 760
 761 sub sort_ts {
 762         sort {
 763                 (eval { $a->topmost->message->header('X-PI-TS') } || 0) <=>
 764                 (eval { $b->topmost->message->header('X-PI-TS') } || 0)
 765         } @_;
 766 }
 767
 768 sub rsort_ts {
 769         sort {
 770                 (eval { $b->topmost->message->header('X-PI-TS') } || 0) <=>
 771                 (eval { $a->topmost->message->header('X-PI-TS') } || 0)
 772         } @_;
 773 }
 774
 775 # accumulate recent topics if search is supported
 776 # returns 1 if done, undef if not
 777 sub add_topic {
 778         my ($state, $node, $level) = @_;
 779         return unless $node;
 780         my $child_adjust = 1;
 781
 782         if (my $x = $node->message) {
 783                 $x = $x->header_obj;
 784                 my ($topic, $subj);
 785
 786                 $subj = $x->header('Subject');
 787                 $subj = $state->{srch}->subject_normalized($subj);
 788                 $topic = $subj;
 789
 790                 # kill "[PATCH v2]" etc. for summarization
 791                 $topic =~ s/\A\s*\[[^\]]+\]\s*//g;
 792                 $topic = substr($topic, 0, 30);
 793
 794                 if (++$state->{subjs}->{$topic} == 1) {
 795                         push @{$state->{order}}, [ $level, $subj, $topic ];
 796                 }
 797
 798                 my $mid = mid_clean($x->header('Message-ID'));
 799
 800                 my $u = $x->header('X-PI-From');
 801                 my $ts = $x->header('X-PI-TS');
 802                 $state->{latest}->{$topic} = [ $mid, $u, $ts ];
 803         } else {
 804                 # ghost message, do not bump level
 805                 $child_adjust = 0;
 806         }
 807
 808         add_topic($state, $node->child, $level + $child_adjust);
 809         add_topic($state, $node->next, $level);
 810 }
 811
 812 sub dump_topics {
 813         my ($state) = @_;
 814         my $order = $state->{order};
 815         my $subjs = $state->{subjs};
 816         my $latest = $state->{latest};
 817         return "\n[No recent topics]</pre>" unless (scalar @$order);
 818         my $dst = '';
 819         my $pfx;
 820         my $prev = 0;
 821         my $prev_attr = '';
 822         while (defined(my $info = shift @$order)) {
 823                 my ($level, $subj, $topic) = @$info;
 824                 my $n = delete $subjs->{$topic};
 825                 my ($mid, $u, $ts) = @{delete $latest->{$topic}};
 826                 $mid = PublicInbox::Hval->new($mid)->as_href;
 827                 $subj = PublicInbox::Hval->new($subj)->as_html;
 828                 $u = PublicInbox::Hval->new($u)->as_html;
 829                 $pfx = INDENT x ($level - 1);
 830                 my $nl = $level == $prev ? "\n" : '';
 831                 my $dot = $level == 0 ? '' : '` ';
 832                 $dst .= "$nl$pfx$dot<a\nhref=\"$mid/t/#u\"><b>$subj</b></a>\n";
 833
 834                 my $attr;
 835                 $ts = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
 836                 if ($n == 1) {
 837                         $attr = "created by $u @ $ts UTC";
 838                         $n = "\n";
 839                 } else {
 840                         # $n isn't the total number of posts on the topic,
 841                         # just the number of posts in the current results
 842                         # window, so leave it unlabeled
 843                         $attr = "updated by $u @ $ts UTC";
 844                         $n = " ($n)\n";
 845                 }
 846                 if ($level == 0 || $attr ne $prev_attr) {
 847                         $pfx .= INDENT if $level > 0;
 848                         $dst .= "$pfx- ". $attr . $n;
 849                         $prev_attr = $attr;
 850                 }
 851         }
 852         $dst .= '</pre>';
 853 }
 854
 855 sub emit_index_topics {
 856         my ($state, $fh) = @_;
 857         my $off = $state->{ctx}->{cgi}->param('o');
 858         $off = 0 unless defined $off;
 859         $state->{order} = [];
 860         $state->{subjs} = {};
 861         $state->{latest} = {};
 862         my $max = 25;
 863         my %opts = ( offset => int $off, limit => $max * 4 );
 864         while (scalar @{$state->{order}} < $max) {
 865                 my $res = $state->{srch}->query('', \%opts);
 866                 my $nr = scalar @{$res->{msgs}} or last;
 867
 868                 for (rsort_ts(thread_results(load_results($res), 1)->rootset)) {
 869                         add_topic($state, $_, 0);
 870                 }
 871                 $opts{offset} += $nr;
 872         }
 873
 874         $fh->write(dump_topics($state));
 875         $opts{offset};
 876 }
 877
 878 1;