lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use PublicInbox::Eml;
  21 use POSIX qw(strftime);
  22 use Time::Local qw(timegm);
  23 use PublicInbox::Smsg qw(subject_normalized);
  24 use constant COLS => 72;
  25 use constant INDENT => '  ';
  26 use constant TCHILD => '` ';
  27 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  28
  29 sub msg_page_i {
  30         my ($ctx, $eml) = @_;
  31         if ($eml) { # called by WwwStream::async_eml or getline
  32                 my $smsg = $ctx->{smsg};
  33                 $ctx->{smsg} = $ctx->{over}->next_by_mid(@{$ctx->{next_arg}});
  34                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  35                                 "../${\mid_href($smsg->{mid})}/" : '';
  36                 my $hdr = $eml->header_obj;
  37                 my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx);
  38                 multipart_text_as_html($eml, $ctx);
  39                 delete $ctx->{obuf};
  40                 $$obuf .= '</pre><hr>';
  41                 $$obuf .= html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  42                 $$obuf;
  43         } else { # called by WwwStream::async_next or getline
  44                 $ctx->{smsg}; # may be undef
  45         }
  46 }
  47
  48 # /$INBOX/$MESSAGE_ID/ for unindexed v1 inboxes
  49 sub no_over_i {
  50         my ($ctx) = @_;
  51         my $eml = delete $ctx->{eml} or return;
  52         my $hdr = $eml->header_obj;
  53         $ctx->{mhref} = '';
  54         my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx);
  55         multipart_text_as_html($eml, $ctx);
  56         delete $ctx->{obuf};
  57         $$obuf .= '</pre><hr>';
  58         eval { $$obuf .= html_footer($ctx, $hdr) };
  59         $$obuf
  60 }
  61
  62 sub no_over_html ($) {
  63         my ($ctx) = @_;
  64         my $bref = $ctx->{-inbox}->msg_by_mid($ctx->{mid}) or return; # 404
  65         $ctx->{eml} = PublicInbox::Eml->new($bref);
  66         PublicInbox::WwwStream::response($ctx, 200, \&no_over_i);
  67 }
  68
  69 # public functions: (unstable)
  70
  71 sub msg_page {
  72         my ($ctx) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  75         my $over = $ctx->{over} = $ibx->over or return no_over_html($ctx);
  76         my ($id, $prev);
  77         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  78         $ctx->{smsg} = $over->next_by_mid(@$next_arg) or return; # undef == 404
  79         PublicInbox::WwwStream::aresponse($ctx, 200, \&msg_page_i);
  80 }
  81
  82 # /$INBOX/$MESSAGE_ID/#R
  83 sub msg_reply ($$) {
  84         my ($ctx, $hdr) = @_;
  85         my $se_url =
  86          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  87         my $p_url =
  88          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  89
  90         my $info = '';
  91         my $ibx = $ctx->{-inbox};
  92         if (my $url = $ibx->{infourl}) {
  93                 $url = prurl($ctx->{env}, $url);
  94                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  95         }
  96
  97         my ($arg, $link, $reply_to_all) =
  98                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
  99         if (ref($arg) eq 'SCALAR') {
 100                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 101         }
 102
 103         # mailto: link only works if address obfuscation is disabled
 104         if ($link) {
 105                 $link = <<EOF;
 106
 107 * If your mail client supports setting the <b>In-Reply-To</b> header
 108   via mailto: links, try the <a
 109 href="$link">mailto: link</a>
 110 EOF
 111         }
 112
 113         push @$arg, '/path/to/YOUR_REPLY';
 114         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 115         <<EOF
 116 <hr><pre
 117 id=R><b>Reply instructions:</b>
 118
 119 You may reply publicly to <a
 120 href=#t>this message</a> via plain-text email
 121 using any one of the following methods:
 122
 123 * Save the following mbox file, import it into your mail client,
 124   and $reply_to_all from there: <a
 125 href=raw>mbox</a>
 126
 127   Avoid top-posting and favor interleaved quoting:
 128   <a
 129 href="$p_url">$p_url</a>
 130 $info
 131 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 132   switches of git-send-email(1):
 133
 134   git send-email$arg
 135
 136   <a
 137 href="$se_url">$se_url</a>
 138 $link</pre>
 139 EOF
 140 }
 141
 142 sub in_reply_to {
 143         my ($hdr) = @_;
 144         my $refs = references($hdr);
 145         $refs->[-1];
 146 }
 147
 148 sub fold_addresses ($) {
 149         return $_[0] if length($_[0]) <= COLS;
 150         # try to fold on commas after non-word chars before $lim chars,
 151         # Try to get the "," preceded by ">" or ")", but avoid folding
 152         # on the comma where somebody uses "Lastname, Firstname".
 153         # We also try to keep the last and penultimate addresses in
 154         # the list on the same line if possible, hence the extra \z
 155         # Fall back to folding on spaces at $lim + 1 chars
 156         my $lim = COLS - 8; # 8 = "\t" display width
 157         my $too_long = $lim + 1;
 158         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 159         $_[0] = join("\n\t",
 160                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 161                                 .{1,$lim}(?:,|\z)|
 162                                 .{1,$lim}|
 163                                 .{$too_long,}?)(?:\s|\z)/xgo));
 164 }
 165
 166 sub _hdr_names_html ($$) {
 167         my ($hdr, $field) = @_;
 168         my @vals = $hdr->header($field) or return '';
 169         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 170 }
 171
 172 sub nr_to_s ($$$) {
 173         my ($nr, $singular, $plural) = @_;
 174         return "0 $plural" if $nr == 0;
 175         $nr == 1 ? "$nr $singular" : "$nr $plural";
 176 }
 177
 178 # human-friendly format
 179 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 180
 181 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 182 # this is already inside a <pre>
 183 sub eml_entry {
 184         my ($ctx, $smsg, $eml, $more) = @_;
 185         my $subj = delete $smsg->{subject};
 186         my $mid_raw = $smsg->{mid};
 187         my $id = id_compress($mid_raw, 1);
 188         my $id_m = 'm'.$id;
 189         my $root_anchor = $ctx->{root_anchor} || '';
 190         my $irt;
 191         my $obfs_ibx = $ctx->{-obfs_ibx};
 192
 193         $subj = '(no subject)' if $subj eq '';
 194         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 195         $subj = '<b>'.ascii_html($subj).'</b>';
 196         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 197         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 198         $rv .= $subj . "\n";
 199         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 200         my @tocc;
 201         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 202
 203         # Deleting these fields saves about 400K as we iterate across 1K msgs
 204         delete @$smsg{qw(ts blob)};
 205
 206         my $hdr = $eml->header_obj;
 207         my $from = _hdr_names_html($hdr, 'From');
 208         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 209         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 210         my $upfx = $ctx->{-upfx};
 211         my $mhref = $upfx . mid_href($mid_raw) . '/';
 212         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 213         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 214         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 215         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 216         my ($tlen, $clen) = (length($to), length($cc));
 217         my $to_cc = '';
 218         if (($tlen + $clen) > COLS) {
 219                 $to_cc .= '  To: '.$to."\n" if $tlen;
 220                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 221         } else {
 222                 if ($tlen) {
 223                         $to_cc .= '  To: '.$to;
 224                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 225                 } else {
 226                         $to_cc .= '  Cc: '.$cc if $clen;
 227                 }
 228                 $to_cc .= "\n";
 229         }
 230         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 231         $rv .= $to_cc;
 232
 233         my $mapping = $ctx->{mapping};
 234         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 235                 my $href = $upfx . mid_href($irt) . '/';
 236                 my $html = ascii_html($irt);
 237                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 238         }
 239         $rv .= "\n";
 240
 241         # scan through all parts, looking for displayable text
 242         $ctx->{mhref} = $mhref;
 243         $ctx->{obuf} = \$rv;
 244         $eml->each_part(\&add_text_body, $ctx, 1);
 245         delete $ctx->{obuf};
 246
 247         # add the footer
 248         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 249                 "<a\nhref=\"$mhref\">permalink</a>" .
 250                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 251                 " <a\nhref=\"${mhref}#R\">reply</a>";
 252
 253         my $hr;
 254         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 255                 $rv .= "\t[relevance $pct%]";
 256                 $hr = 1;
 257         } elsif ($mapping) {
 258                 my $nested = 'nested';
 259                 my $flat = 'flat';
 260                 my $end = '';
 261                 if ($ctx->{flat}) {
 262                         $hr = 1;
 263                         $flat = "<b>$flat</b>";
 264                 } else {
 265                         $nested = "<b>$nested</b>";
 266                 }
 267                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 268                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 269                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 270         } else {
 271                 $hr = $ctx->{-hr};
 272         }
 273
 274         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 275         $rv;
 276 }
 277
 278 sub pad_link ($$;$) {
 279         my ($mid, $level, $s) = @_;
 280         $s ||= '...';
 281         my $id = id_compress($mid, 1);
 282         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 283 }
 284
 285 sub _th_index_lite {
 286         my ($mid_raw, $irt, $id, $ctx) = @_;
 287         my $rv = '';
 288         my $mapping = $ctx->{mapping} or return $rv;
 289         my $pad = '  ';
 290         my $mid_map = $mapping->{$mid_raw};
 291         defined $mid_map or
 292                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 293         my ($attr, $node, $idx, $level) = @$mid_map;
 294         my $children = $node->{children};
 295         my $nr_c = scalar @$children;
 296         my $nr_s = 0;
 297         my $siblings;
 298         # delete saves about 200KB on a 1K message thread
 299         if (my $refs = delete $node->{references}) {
 300                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 301         }
 302         my $irt_map = $mapping->{$$irt} if defined $$irt;
 303         if (defined $irt_map) {
 304                 $siblings = $irt_map->[1]->{children};
 305                 $nr_s = scalar(@$siblings) - 1;
 306                 $rv .= $pad . $irt_map->[0];
 307                 if ($idx > 0) {
 308                         my $prev = $siblings->[$idx - 1];
 309                         my $pmid = $prev->{mid};
 310                         if ($idx > 2) {
 311                                 my $s = ($idx - 1). ' preceding siblings ...';
 312                                 $rv .= pad_link($pmid, $level, $s);
 313                         } elsif ($idx == 2) {
 314                                 my $ppmid = $siblings->[0]->{mid};
 315                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 316                         }
 317                         $rv .= $pad . $mapping->{$pmid}->[0];
 318                 }
 319         }
 320         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 321         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 322         $attr =~ s!\n\z!</b>\n!s;
 323         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 324         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 325         $rv .= "<b>@ $attr";
 326         if ($nr_c) {
 327                 my $cmid = $children->[0]->{mid};
 328                 $rv .= $pad . $mapping->{$cmid}->[0];
 329                 if ($nr_c > 2) {
 330                         my $s = ($nr_c - 1). ' more replies';
 331                         $rv .= pad_link($cmid, $level + 1, $s);
 332                 } elsif (my $cn = $children->[1]) {
 333                         $rv .= $pad . $mapping->{$cn->{mid}}->[0];
 334                 }
 335         }
 336
 337         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 338         if ($next) {
 339                 my $nmid = $next->{mid};
 340                 $rv .= $pad . $mapping->{$nmid}->[0];
 341                 my $nnext = $nr_s - $idx;
 342                 if ($nnext > 2) {
 343                         my $s = ($nnext - 1).' subsequent siblings';
 344                         $rv .= pad_link($nmid, $level, $s);
 345                 } elsif (my $nn = $siblings->[$idx + 2]) {
 346                         $rv .= $pad . $mapping->{$nn->{mid}}->[0];
 347                 }
 348         }
 349         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 350 }
 351
 352 # non-recursive thread walker
 353 sub walk_thread ($$$) {
 354         my ($rootset, $ctx, $cb) = @_;
 355         my @q = map { (0, $_, -1) } @$rootset;
 356         while (@q) {
 357                 my ($level, $node, $i) = splice(@q, 0, 3);
 358                 defined $node or next;
 359                 $cb->($ctx, $level, $node, $i) or return;
 360                 ++$level;
 361                 $i = 0;
 362                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 363         }
 364 }
 365
 366 sub pre_thread  { # walk_thread callback
 367         my ($ctx, $level, $node, $idx) = @_;
 368         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 369         skel_dump($ctx, $level, $node);
 370 }
 371
 372 sub thread_eml_entry {
 373         my ($ctx, $level, $smsg, $eml) = @_;
 374         my ($beg, $end) = thread_adj_level($ctx, $level);
 375         $beg . '<pre>' . eml_entry($ctx, $smsg, $eml, 0) . '</pre>' . $end;
 376 }
 377
 378 sub next_in_queue ($;$) {
 379         my ($q, $ghost_ok) = @_;
 380         while (@$q) {
 381                 my ($level, $smsg) = splice(@$q, 0, 2);
 382                 my $cl = $level + 1;
 383                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 384                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 385         }
 386         undef;
 387 }
 388
 389 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 390         my ($ctx) = @_;
 391         return unless exists($ctx->{skel});
 392         my $nr = $ctx->{nr}++;
 393         my ($level, $smsg) = next_in_queue($ctx->{-queue}, $nr);
 394
 395         $smsg or return
 396                 join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{skel}};
 397
 398         my $eml = $ctx->{-inbox}->smsg_eml($smsg) or return
 399                 ghost_index_entry($ctx, $level, $smsg);
 400
 401         if ($nr == 0) {
 402                 $ctx->{-title_html} = ascii_html($smsg->{subject});
 403                 $ctx->html_top . thread_eml_entry($ctx, $level, $smsg, $eml);
 404         } else {
 405                 thread_eml_entry($ctx, $level, $smsg, $eml);
 406         }
 407 }
 408
 409 sub stream_thread ($$) {
 410         my ($rootset, $ctx) = @_;
 411         $ctx->{-queue} = [ map { (0, $_) } @$rootset ];
 412         PublicInbox::WwwStream::response($ctx, 200, \&stream_thread_i);
 413 }
 414
 415 # /$INBOX/$MESSAGE_ID/t/
 416 sub thread_html {
 417         my ($ctx) = @_;
 418         my $mid = $ctx->{mid};
 419         my $ibx = $ctx->{-inbox};
 420         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 421         return missing_thread($ctx) if $nr == 0;
 422         my $skel = '<hr><pre>';
 423         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 424         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 425         $skel .= "<b\nid=t>Thread overview:</b> ";
 426         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 427         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 428         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 429         $skel .= "-- links below jump to the message on this page --\n";
 430         $ctx->{-upfx} = '../../';
 431         $ctx->{cur_level} = 0;
 432         $ctx->{skel} = \$skel;
 433         $ctx->{prev_attr} = '';
 434         $ctx->{prev_level} = 0;
 435         $ctx->{root_anchor} = anchor_for($mid);
 436         $ctx->{mapping} = {};
 437         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 438                        .' in thread';
 439
 440         my $rootset = thread_results($ctx, $msgs);
 441
 442         # reduce hash lookups in pre_thread->skel_dump
 443         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 444         walk_thread($rootset, $ctx, \&pre_thread);
 445
 446         $skel .= '</pre>';
 447         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 448
 449         # flat display: lazy load the full message from smsg
 450         $ctx->{msgs} = $msgs;
 451         $ctx->{-html_tip} = '<pre>';
 452         PublicInbox::WwwStream::response($ctx, 200, \&thread_html_i);
 453 }
 454
 455 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 456         my ($ctx) = @_;
 457         my $msgs = $ctx->{msgs} or return;
 458         while (my $smsg = shift @$msgs) {
 459                 my $eml = $ctx->{-inbox}->smsg_eml($smsg) or next;
 460                 if (exists $ctx->{-html_tip}) {
 461                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 462                         return $ctx->html_top .
 463                                 eml_entry($ctx, $smsg, $eml, scalar @$msgs);
 464                 }
 465                 return eml_entry($ctx, $smsg, $eml, scalar @$msgs);
 466         }
 467         my ($skel) = delete @$ctx{qw(skel msgs)};
 468         $$skel;
 469 }
 470
 471 sub multipart_text_as_html {
 472         # ($mime, $ctx) = @_; # each_part may do "$_[0] = undef"
 473
 474         # scan through all parts, looking for displayable text
 475         $_[0]->each_part(\&add_text_body, $_[1], 1);
 476 }
 477
 478 sub submsg_hdr ($$) {
 479         my ($ctx, $eml) = @_;
 480         my $obfs_ibx = $ctx->{-obfs_ibx};
 481         my $rv = $ctx->{obuf};
 482         $$rv .= "\n";
 483         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 484                 my @v = $eml->header($h);
 485                 for my $v (@v) {
 486                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 487                         $v = ascii_html($v);
 488                         $$rv .= "$h: $v\n";
 489                 }
 490         }
 491 }
 492
 493 sub attach_link ($$$$;$) {
 494         my ($ctx, $ct, $p, $fn, $err) = @_;
 495         my ($part, $depth, $idx) = @$p;
 496
 497         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 498         # downloads for 0-byte multipart attachments
 499         return unless $part->{bdy};
 500
 501         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 502         my $size = bytes::length($part->body);
 503
 504         # hide attributes normally, unless we want to aid users in
 505         # spotting MUA problems:
 506         $ct =~ s/;.*// unless $err;
 507         $ct = ascii_html($ct);
 508         my $sfn;
 509         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 510                 $sfn = $fn;
 511         } elsif ($ct eq 'text/plain') {
 512                 $sfn = 'a.txt';
 513         } else {
 514                 $sfn = 'a.bin';
 515         }
 516         my $rv = $ctx->{obuf};
 517         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 518         if ($err) {
 519                 $$rv .= <<EOF;
 520 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 521 EOF
 522         }
 523         $$rv .= "[-- Attachment #$idx: ";
 524         my $ts = "Type: $ct, Size: $size bytes";
 525         my $desc = $part->header('Content-Description') // $fn // '';
 526         $desc = ascii_html($desc);
 527         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 528         $$rv .= "</a>\n";
 529
 530         submsg_hdr($ctx, $part) if $part->{is_submsg};
 531
 532         undef;
 533 }
 534
 535 sub add_text_body { # callback for each_part
 536         my ($p, $ctx) = @_;
 537         my $upfx = $ctx->{mhref};
 538         my $ibx = $ctx->{-inbox};
 539         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 540         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 541         my ($part, $depth, $idx) = @$p;
 542         my $ct = $part->content_type || 'text/plain';
 543         my $fn = $part->filename;
 544         my ($s, $err) = msg_part_text($part, $ct);
 545         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 546
 547         my $rv = $ctx->{obuf};
 548         if ($part->{is_submsg}) {
 549                 submsg_hdr($ctx, $part);
 550                 $$rv .= "\n";
 551         }
 552
 553         # makes no difference to browsers, and don't screw up filename
 554         # link generation in diffs with the extra '%0D'
 555         $s =~ s/\r\n/\n/sg;
 556
 557         # will be escaped to `&#8226;' in HTML
 558         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 559
 560         # always support diff-highlighting, but we can't linkify hunk
 561         # headers for solver unless some coderepo are configured:
 562         my $diff;
 563         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 564                 # diffstat anchors do not link across attachments or messages,
 565                 # -apfx is just a stable prefix for making diffstat anchors
 566                 # linkable to the first diff hunk w/o crossing attachments
 567                 $idx =~ tr!.!/!; # compatibility with previous versions
 568                 $ctx->{-apfx} = $upfx . $idx;
 569
 570                 # do attr => filename mappings for diffstats in git diffs:
 571                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 572                 $diff = 1;
 573                 delete $ctx->{-long_path};
 574                 my $spfx;
 575                 if ($ibx->{-repo_objs}) {
 576                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 577                                 $spfx = $upfx;
 578                                 $spfx =~ s!/([^/]*)/\z!/!;
 579                         } else {
 580                                 my $n_slash = $upfx =~ tr!/!/!;
 581                                 if ($n_slash == 0) {
 582                                         $spfx = '../';
 583                                 } elsif ($n_slash == 1) {
 584                                         $spfx = '';
 585                                 } else { # nslash == 2
 586                                         $spfx = '../../';
 587                                 }
 588                         }
 589                 }
 590                 $ctx->{-spfx} = $spfx;
 591         };
 592
 593         # some editors don't put trailing newlines at the end:
 594         $s .= "\n" unless $s =~ /\n\z/s;
 595
 596         # split off quoted and unquoted blocks:
 597         my @sections = PublicInbox::MsgIter::split_quotes($s);
 598         undef $s; # free memory
 599         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 600                 # badly-encoded message with $err? tell the world about it!
 601                 attach_link($ctx, $ct, $p, $fn, $err);
 602                 $$rv .= "\n";
 603         }
 604         foreach my $cur (@sections) {
 605                 if ($cur =~ /\A>/) {
 606                         # we use a <span> here to allow users to specify
 607                         # their own color for quoted text
 608                         $$rv .= qq(<span\nclass="q">);
 609                         $$rv .= $l->to_html($cur);
 610                         $$rv .= '</span>';
 611                 } elsif ($diff) {
 612                         flush_diff($ctx, \$cur);
 613                 } else {
 614                         # regular lines, OK
 615                         $$rv .= $l->to_html($cur);
 616                 }
 617                 undef $cur; # free memory
 618         }
 619 }
 620
 621 sub _msg_page_prepare_obuf {
 622         my ($hdr, $ctx) = @_;
 623         my $over = $ctx->{-inbox}->over;
 624         my $obfs_ibx = $ctx->{-obfs_ibx};
 625         my $rv = '';
 626         my $mids = mids_for_index($hdr);
 627         my $nr = $ctx->{nr}++;
 628         if ($nr) { # unlikely
 629                 $rv .= '<pre>';
 630         } else {
 631                 $ctx->{first_hdr} = $hdr;
 632                 if ($ctx->{smsg}) {
 633                         $rv .=
 634 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 635                 }
 636                 $rv .= "<pre\nid=b>"; # anchor for body start
 637         }
 638         $ctx->{-upfx} = '../' if $over;
 639         my @title; # (Subject[0], From[0])
 640         for my $v ($hdr->header('From')) {
 641                 my @n = PublicInbox::Address::names($v);
 642                 $v = ascii_html($v);
 643                 $title[1] //= ascii_html(join(', ', @n));
 644                 if ($obfs_ibx) {
 645                         obfuscate_addrs($obfs_ibx, $v);
 646                         obfuscate_addrs($obfs_ibx, $title[1]);
 647                 }
 648                 $rv .= "From: $v\n" if $v ne '';
 649         }
 650         foreach my $h (qw(To Cc)) {
 651                 for my $v ($hdr->header($h)) {
 652                         fold_addresses($v);
 653                         $v = ascii_html($v);
 654                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 655                         $rv .= "$h: $v\n" if $v ne '';
 656                 }
 657         }
 658         my @subj = $hdr->header('Subject');
 659         if (@subj) {
 660                 my $v = ascii_html(shift @subj);
 661                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 662                 $rv .= 'Subject: ';
 663                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 664                 $title[0] = $v;
 665                 for $v (@subj) { # multi-Subject message :<
 666                         $v = ascii_html($v);
 667                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 668                         $rv .= "Subject: $v\n";
 669                 }
 670         } else { # dummy anchor for thread skeleton at bottom of page
 671                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 672                 $title[0] = '(no subject)';
 673         }
 674         for my $v ($hdr->header('Date')) {
 675                 $v = ascii_html($v);
 676                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 677                 $rv .= "Date: $v\n";
 678         }
 679         if (!$nr) { # first (and only) message, common case
 680                 $ctx->{-title_html} = join(' - ', @title);
 681                 $rv = $ctx->html_top . $rv;
 682         }
 683         if (scalar(@$mids) == 1) { # common case
 684                 my $mhtml = ascii_html($mids->[0]);
 685                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 686                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 687         } else {
 688                 # X-Alt-Message-ID can happen if a message is injected from
 689                 # public-inbox-nntpd because of multiple Message-ID headers.
 690                 my $lnk = PublicInbox::Linkify->new;
 691                 my $s = '';
 692                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 693                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 694                 }
 695                 $lnk->linkify_mids('..', \$s, 1);
 696                 $rv .= $s;
 697         }
 698         $rv .= _parent_headers($hdr, $over);
 699         $rv .= "\n";
 700         \$rv;
 701 }
 702
 703 sub SKEL_EXPAND () {
 704         qq(expand[<a\nhref="T/#u">flat</a>) .
 705                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 706                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 707                 qq(<a\nhref="t.atom">Atom feed</a>);
 708 }
 709
 710 sub thread_skel ($$$) {
 711         my ($skel, $ctx, $hdr) = @_;
 712         my $mid = mids($hdr)->[0];
 713         my $ibx = $ctx->{-inbox};
 714         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 715         my $parent = in_reply_to($hdr);
 716         $$skel .= "\n<b>Thread overview: </b>";
 717         if ($nr <= 1) {
 718                 if (defined $parent) {
 719                         $$skel .= SKEL_EXPAND."\n ";
 720                         $$skel .= ghost_parent('../', $parent) . "\n";
 721                 } else {
 722                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 723                 }
 724                 $ctx->{next_msg} = undef;
 725                 $ctx->{parent_msg} = $parent;
 726                 return;
 727         }
 728
 729         $$skel .= $nr;
 730         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 731
 732         # nb: mutt only shows the first Subject in the index pane
 733         # when multiple Subject: headers are present, so we follow suit:
 734         my $subj = $hdr->header('Subject') // '';
 735         $subj = '(no subject)' if $subj eq '';
 736         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 737         $ctx->{cur} = $mid;
 738         $ctx->{prev_attr} = '';
 739         $ctx->{prev_level} = 0;
 740         $ctx->{skel} = $skel;
 741
 742         # reduce hash lookups in skel_dump
 743         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 744         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 745
 746         $ctx->{parent_msg} = $parent;
 747 }
 748
 749 sub _parent_headers {
 750         my ($hdr, $over) = @_;
 751         my $rv = '';
 752         my @irt = $hdr->header_raw('In-Reply-To');
 753         my $refs;
 754         if (@irt) {
 755                 my $lnk = PublicInbox::Linkify->new;
 756                 $rv .= "In-Reply-To: $_\n" for @irt;
 757                 $lnk->linkify_mids('..', \$rv);
 758         } else {
 759                 $refs = references($hdr);
 760                 my $irt = pop @$refs;
 761                 if (defined $irt) {
 762                         my $html = ascii_html($irt);
 763                         my $href = mid_href($irt);
 764                         $rv .= "In-Reply-To: &lt;";
 765                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 766                 }
 767         }
 768
 769         # do not display References: if search is present,
 770         # we show the thread skeleton at the bottom, instead.
 771         return $rv if $over;
 772
 773         $refs //= references($hdr);
 774         if (@$refs) {
 775                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 776                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 777         }
 778         $rv;
 779 }
 780
 781 # returns a string buffer via ->getline
 782 sub html_footer {
 783         my ($ctx, $hdr) = @_;
 784         my $ibx = $ctx->{-inbox};
 785         my $upfx = '../';
 786         my $skel = " <a\nhref=\"$upfx\">index</a>";
 787         my $rv = '<pre>';
 788         if ($ibx->over) {
 789                 $skel .= "\n";
 790                 thread_skel(\$skel, $ctx, $hdr);
 791                 my ($next, $prev);
 792                 my $parent = '       ';
 793                 $next = $prev = '    ';
 794
 795                 if (my $n = $ctx->{next_msg}) {
 796                         $n = mid_href($n);
 797                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 798                 }
 799                 my $u;
 800                 my $par = $ctx->{parent_msg};
 801                 if ($par) {
 802                         $u = mid_href($par);
 803                         $u = "$upfx$u/";
 804                 }
 805                 if (my $p = $ctx->{prev_msg}) {
 806                         $prev = mid_href($p);
 807                         if ($p && $par && $p eq $par) {
 808                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 809                                         'rel=prev>prev parent</a>';
 810                                 $parent = '';
 811                         } else {
 812                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 813                                         'rel=prev>prev</a>';
 814                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 815                         }
 816                 } elsif ($u) { # unlikely
 817                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 818                 }
 819                 $rv .= "$next $prev$parent ";
 820         }
 821         $rv .= qq(<a\nhref="#R">reply</a>);
 822         $rv .= $skel;
 823         $rv .= '</pre>';
 824         $rv .= msg_reply($ctx, $hdr);
 825 }
 826
 827 sub linkify_ref_no_over {
 828         my ($mid) = @_;
 829         my $href = mid_href($mid);
 830         my $html = ascii_html($mid);
 831         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 832 }
 833
 834 sub anchor_for {
 835         my ($msgid) = @_;
 836         'm' . id_compress($msgid, 1);
 837 }
 838
 839 sub ghost_parent {
 840         my ($upfx, $mid) = @_;
 841
 842         my $href = mid_href($mid);
 843         my $html = ascii_html($mid);
 844         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 845 }
 846
 847 sub indent_for {
 848         my ($level) = @_;
 849         $level ? INDENT x ($level - 1) : '';
 850 }
 851
 852 sub find_mid_root {
 853         my ($ctx, $level, $node, $idx) = @_;
 854         ++$ctx->{root_idx} if $level == 0;
 855         if ($node->{mid} eq $ctx->{mid}) {
 856                 $ctx->{found_mid_at} = $ctx->{root_idx};
 857                 return 0;
 858         }
 859         1;
 860 }
 861
 862 sub strict_loose_note ($) {
 863         my ($nr) = @_;
 864         my $msg =
 865 "  -- strict thread matches above, loose matches on Subject: below --\n";
 866
 867         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 868                 $msg .=
 869 "  -- use mbox.gz link to download all $nr messages --\n";
 870         }
 871         $msg;
 872 }
 873
 874 sub thread_results {
 875         my ($ctx, $msgs) = @_;
 876         require PublicInbox::SearchThread;
 877         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 878
 879         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 880         # and preserved in the future.  This bug is hidden by `sid' matches
 881         # in get_thread, so we never noticed it until now.  And even when
 882         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 883         # bump since reindexing is expensive and users may not do it
 884
 885         # loose threading could've returned too many results,
 886         # put the root the message we care about at the top:
 887         my $mid = $ctx->{mid};
 888         if (defined($mid) && scalar(@$rootset) > 1) {
 889                 $ctx->{root_idx} = -1;
 890                 my $nr = scalar @$msgs;
 891                 walk_thread($rootset, $ctx, \&find_mid_root);
 892                 my $idx = $ctx->{found_mid_at};
 893                 if (defined($idx) && $idx != 0) {
 894                         my $tip = splice(@$rootset, $idx, 1);
 895                         @$rootset = reverse @$rootset;
 896                         unshift @$rootset, $tip;
 897                         $ctx->{sl_note} = strict_loose_note($nr);
 898                 }
 899         }
 900         $rootset
 901 }
 902
 903 sub missing_thread {
 904         my ($ctx) = @_;
 905         require PublicInbox::ExtMsg;
 906         PublicInbox::ExtMsg::ext_msg($ctx);
 907 }
 908
 909 sub dedupe_subject {
 910         my ($prev_subj, $subj, $val) = @_;
 911
 912         my $omit; # '"' denotes identical text omitted
 913         my (@prev_pop, @curr_pop);
 914         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 915                 push(@prev_pop, pop(@$prev_subj));
 916                 push(@curr_pop, pop(@$subj));
 917                 $omit //= $val;
 918         }
 919         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 920         if (scalar(@curr_pop) == 1) {
 921                 $omit = undef;
 922                 push @$prev_subj, @prev_pop;
 923                 push @$subj, @curr_pop;
 924         }
 925         $omit // '';
 926 }
 927
 928 sub skel_dump { # walk_thread callback
 929         my ($ctx, $level, $smsg) = @_;
 930         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 931
 932         my $skel = $ctx->{skel};
 933         my $cur = $ctx->{cur};
 934         my $mid = $smsg->{mid};
 935
 936         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 937                 $$skel .= delete($ctx->{sl_note}) || '';
 938         }
 939
 940         my $f = ascii_html($smsg->{from_name});
 941         my $obfs_ibx = $ctx->{-obfs_ibx};
 942         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 943
 944         my $d = fmt_ts($smsg->{ds});
 945         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 946         if (exists $ctx->{searchview}) {
 947                 if (defined(my $pct = $smsg->{pct})) {
 948                         $d .= (sprintf(' % 2u', $pct) . '%');
 949                 } else {
 950                         $unmatched = 1;
 951                         $d .= '    ';
 952                 }
 953         }
 954         $d .= ' ' . indent_for($level) . th_pfx($level);
 955         my $attr = $f;
 956         $ctx->{first_level} ||= $level;
 957
 958         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 959                 $ctx->{prev_attr} = $attr;
 960         }
 961         $ctx->{prev_level} = $level;
 962
 963         if ($cur) {
 964                 if ($cur eq $mid) {
 965                         delete $ctx->{cur};
 966                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 967                                  "$attr [this message]</a></b>\n";
 968                         return 1;
 969                 } else {
 970                         $ctx->{prev_msg} = $mid;
 971                 }
 972         } else {
 973                 $ctx->{next_msg} ||= $mid;
 974         }
 975
 976         # Subject is never undef, this mail was loaded from
 977         # our Xapian which would've resulted in '' if it were
 978         # really missing (and Filter rejects empty subjects)
 979         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 980         # remove common suffixes from the subject if it matches the previous,
 981         # so we do not show redundant text at the end.
 982         my $prev_subj = $ctx->{prev_subj} || [];
 983         $ctx->{prev_subj} = [ @subj ];
 984         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 985         my $end;
 986         if (@subj) {
 987                 my $subj = join(' ', @subj);
 988                 $subj = ascii_html($subj);
 989                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 990                 $end = "$subj</a> $omit$f\n"
 991         } else {
 992                 $end = "$f</a>\n";
 993         }
 994         my $m;
 995         my $id = '';
 996         my $mapping = $unmatched ? undef : $ctx->{mapping};
 997         if ($mapping) {
 998                 my $map = $mapping->{$mid};
 999                 $id = id_compress($mid, 1);
1000                 $m = '#m'.$id;
1001                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1002                 $id = "\nid=r".$id;
1003         } else {
1004                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1005         }
1006         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1007         1;
1008 }
1009
1010 sub _skel_ghost {
1011         my ($ctx, $level, $node) = @_;
1012
1013         my $mid = $node->{mid};
1014         my $d = '     [not found] ';
1015         $d .= '    '  if exists $ctx->{searchview};
1016         $d .= indent_for($level) . th_pfx($level);
1017         my $upfx = $ctx->{-upfx};
1018         my $href = $upfx . mid_href($mid) . '/';
1019         my $html = ascii_html($mid);
1020
1021         my $mapping = $ctx->{mapping};
1022         my $map = $mapping->{$mid} if $mapping;
1023         if ($map) {
1024                 my $id = id_compress($mid, 1);
1025                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1026                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1027         } else {
1028                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1029         }
1030         ${$ctx->{skel}} .= $d;
1031         1;
1032 }
1033
1034 sub sort_ds {
1035         [ sort {
1036                 (eval { $a->topmost->{ds} } || 0) <=>
1037                 (eval { $b->topmost->{ds} } || 0)
1038         } @{$_[0]} ];
1039 }
1040
1041 # accumulate recent topics if search is supported
1042 # returns 200 if done, 404 if not
1043 sub acc_topic { # walk_thread callback
1044         my ($ctx, $level, $smsg) = @_;
1045         my $mid = $smsg->{mid};
1046         my $has_blob = $smsg->{blob} // do {
1047                 if (my $by_mid = $ctx->{-inbox}->smsg_by_mid($mid)) {
1048                         %$smsg = (%$smsg, %$by_mid);
1049                         1;
1050                 }
1051         };
1052         if ($has_blob) {
1053                 my $subj = subject_normalized($smsg->{subject});
1054                 $subj = '(no subject)' if $subj eq '';
1055                 my $ds = $smsg->{ds};
1056                 if ($level == 0) { # new, top-level topic
1057                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1058                         $ctx->{-cur_topic} = $topic;
1059                         push @{$ctx->{order}}, $topic;
1060                         return 1;
1061                 }
1062
1063                 # continue existing topic
1064                 my $topic = $ctx->{-cur_topic}; # should never be undef
1065                 $topic->[0] = $ds if $ds > $topic->[0];
1066                 $topic->[1]++; # bump N+ message counter
1067                 my $seen = $topic->[2];
1068                 if (scalar(@$topic) == 3) { # parent was a ghost
1069                         push @$topic, $subj;
1070                 } elsif (!defined($seen->{$subj})) {
1071                         push @$topic, $level, $subj; # @extra messages
1072                 }
1073                 $seen->{$subj} = $mid; # latest for subject
1074         } else { # ghost message
1075                 return 1 if $level != 0; # ignore child ghosts
1076                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1077                 push @{$ctx->{order}}, $topic;
1078         }
1079         1;
1080 }
1081
1082 sub dump_topics {
1083         my ($ctx) = @_;
1084         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1085         unless ($order) {
1086                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1087                 return 404;
1088         }
1089
1090         my @out;
1091         my $ibx = $ctx->{-inbox};
1092         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1093
1094         # sort by recency, this allows new posts to "bump" old topics...
1095         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1096                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1097                 @$topic = ();
1098                 next unless defined $top_subj;  # ghost topic
1099                 my $mid = delete $seen->{$top_subj};
1100                 my $href = mid_href($mid);
1101                 my $prev_subj = [ split(/ /, $top_subj) ];
1102                 $top_subj = ascii_html($top_subj);
1103                 $ds = fmt_ts($ds);
1104
1105                 # $n isn't the total number of posts on the topic,
1106                 # just the number of posts in the current results window
1107                 my $anchor;
1108                 if ($n == 1) {
1109                         $n = '';
1110                         $anchor = '#u'; # top of only message
1111                 } else {
1112                         $n = " ($n+ messages)";
1113                         $anchor = '#t'; # thread skeleton
1114                 }
1115
1116                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1117                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1118                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1119                         " $ds UTC $n - $mbox / $atom\n";
1120                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1121                         my $level = $extra[$i];
1122                         my $subj = $extra[$i + 1]; # already normalized
1123                         $mid = delete $seen->{$subj};
1124                         my @subj = split(/ /, $subj);
1125                         my @next_prev = @subj; # full copy
1126                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1127                         $prev_subj = \@next_prev;
1128                         $subj = join(' ', @subj);
1129                         $subj = ascii_html($subj);
1130                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1131                         $href = mid_href($mid);
1132                         $s .= indent_for($level) . TCHILD;
1133                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1134                 }
1135                 push @out, $s;
1136         }
1137         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1138         200;
1139 }
1140
1141 # only for the t= query parameter passed to overview DB
1142 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1143
1144 sub str2ts ($) {
1145         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1146         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1147 }
1148
1149 sub pagination_footer ($$) {
1150         my ($ctx, $latest) = @_;
1151         delete $ctx->{qp} or return;
1152         my $next = $ctx->{next_page} || '';
1153         my $prev = $ctx->{prev_page} || '';
1154         if ($prev) {
1155                 $next = $next ? "$next " : '     ';
1156                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1157         }
1158         "<hr><pre>page: $next$prev</pre>";
1159 }
1160
1161 sub index_nav { # callback for WwwStream::getline
1162         my ($ctx) = @_;
1163         return $ctx->html_top if exists $ctx->{-html_tip};
1164         pagination_footer($ctx, '.')
1165 }
1166
1167 sub paginate_recent ($$) {
1168         my ($ctx, $lim) = @_;
1169         my $t = $ctx->{qp}->{t} || '';
1170         my $opts = { limit => $lim };
1171         my ($after, $before);
1172
1173         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1174         # if only $after exists "YYYYMMDD.." because "." could be skipped
1175         # if interpreted as an end-of-sentence
1176         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1177         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1178
1179         my $ibx = $ctx->{-inbox};
1180         my $msgs = $ibx->recent($opts, $after, $before);
1181         my $nr = scalar @$msgs;
1182         if ($nr < $lim && defined($after)) {
1183                 $after = $before = undef;
1184                 $msgs = $ibx->recent($opts);
1185                 $nr = scalar @$msgs;
1186         }
1187         my $more = $nr == $lim;
1188         my ($newest, $oldest);
1189         if ($nr) {
1190                 $newest = $msgs->[0]->{ts};
1191                 $oldest = $msgs->[-1]->{ts};
1192                 # if we only had $after, our SQL query in ->recent ordered
1193                 if ($newest < $oldest) {
1194                         ($oldest, $newest) = ($newest, $oldest);
1195                         $more = 0 if defined($after) && $after < $oldest;
1196                 }
1197         }
1198         if (defined($oldest) && $more) {
1199                 my $s = ts2str($oldest);
1200                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1201         }
1202         if (defined($newest) && (defined($before) || defined($after))) {
1203                 my $s = ts2str($newest);
1204                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1205         }
1206         $msgs;
1207 }
1208
1209 sub index_topics {
1210         my ($ctx) = @_;
1211         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1212         if (@$msgs) {
1213                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1214         }
1215         PublicInbox::WwwStream::response($ctx, dump_topics($ctx), \&index_nav);
1216 }
1217
1218 sub thread_adj_level {
1219         my ($ctx, $level) = @_;
1220
1221         my $max = $ctx->{cur_level};
1222         if ($level <= 0) {
1223                 return ('', '') if $max == 0; # flat output
1224
1225                 # reset existing lists
1226                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1227                 $ctx->{cur_level} = 0;
1228                 ("$beg</ul>", '');
1229         } elsif ($level == $max) { # continue existing list
1230                 qw(<li> </li>);
1231         } elsif ($level < $max) {
1232                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1233                 $ctx->{cur_level} = $level;
1234                 ("$beg<li>", '</li>');
1235         } else { # ($level > $max) # start a new level
1236                 $ctx->{cur_level} = $level;
1237                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1238                 ($beg, '</li>');
1239         }
1240 }
1241
1242 sub ghost_index_entry {
1243         my ($ctx, $level, $node) = @_;
1244         my ($beg, $end) = thread_adj_level($ctx,  $level);
1245         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid})
1246                 . '</pre>' . $end;
1247 }
1248
1249 1;