lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::Smsg qw(subject_normalized);
  23 use constant COLS => 72;
  24 use constant INDENT => '  ';
  25 use constant TCHILD => '` ';
  26 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  27
  28 sub msg_page_i {
  29         my ($nr, $ctx) = @_;
  30         if (my $more = delete $ctx->{more}) { # unlikely
  31                 # fake an EOF if $more retrieval fails;
  32                 eval { msg_page_more($ctx, $nr, @$more) };
  33         } elsif (my $hdr = delete $ctx->{hdr}) {
  34                 # fake an EOF if generating the footer fails;
  35                 # we want to at least show the message if something
  36                 # here crashes:
  37                 eval { html_footer($ctx, $hdr) };
  38         } else {
  39                 undef
  40         }
  41 }
  42
  43 # public functions: (unstable)
  44
  45 sub msg_page {
  46         my ($ctx) = @_;
  47         my $mid = $ctx->{mid};
  48         my $ibx = $ctx->{-inbox};
  49         my ($smsg, $first, $next);
  50         if (my $over = $ibx->over) {
  51                 my ($id, $prev);
  52                 $smsg = $over->next_by_mid($mid, \$id, \$prev) or return;
  53                 $first = $ibx->msg_by_smsg($smsg) or return;
  54                 $next = $over->next_by_mid($mid, \$id, \$prev);
  55                 $ctx->{more} = [ $id, $prev, $next ] if $next;
  56         } else {
  57                 $first = $ibx->msg_by_mid($mid) or return;
  58         }
  59         my $mime = PublicInbox::MIME->new($first);
  60         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  61         my $hdr = $ctx->{hdr} = $mime->header_obj;
  62         $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx, 0);
  63         $ctx->{smsg} = $smsg;
  64         # $next cannot be true w/o $smsg being defined:
  65         $ctx->{mhref} = $next ? '../'.mid_href($smsg->{mid}).'/' : '';
  66         multipart_text_as_html($mime, $ctx);
  67         $ctx->{-html_tip} = (${delete $ctx->{obuf}} .= '</pre><hr>');
  68         PublicInbox::WwwStream->response($ctx, 200, \&msg_page_i);
  69 }
  70
  71 sub msg_page_more { # cold
  72         my ($ctx, $nr, $id, $prev, $smsg) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         my $next = $ibx->over->next_by_mid($ctx->{mid}, \$id, \$prev);
  75         $ctx->{more} = [ $id, $prev, $next ] if $next;
  76         $smsg = $ibx->smsg_mime($smsg) or return '';
  77         $ctx->{mhref} = '../' . mid_href($smsg->{mid}) . '/';
  78         my $mime = delete $smsg->{mime};
  79         $ctx->{obuf} = _msg_page_prepare_obuf($mime->header_obj, $ctx, $nr);
  80         multipart_text_as_html($mime, $ctx);
  81         ${delete $ctx->{obuf}} .= '</pre><hr>';
  82 }
  83
  84 # /$INBOX/$MESSAGE_ID/#R
  85 sub msg_reply ($$) {
  86         my ($ctx, $hdr) = @_;
  87         my $se_url =
  88          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  89         my $p_url =
  90          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  91
  92         my $info = '';
  93         my $ibx = $ctx->{-inbox};
  94         if (my $url = $ibx->{infourl}) {
  95                 $url = prurl($ctx->{env}, $url);
  96                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  97         }
  98
  99         my ($arg, $link, $reply_to_all) =
 100                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 101         if (ref($arg) eq 'SCALAR') {
 102                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 103         }
 104
 105         # mailto: link only works if address obfuscation is disabled
 106         if ($link) {
 107                 $link = <<EOF;
 108
 109 * If your mail client supports setting the <b>In-Reply-To</b> header
 110   via mailto: links, try the <a
 111 href="$link">mailto: link</a>
 112 EOF
 113         }
 114
 115         push @$arg, '/path/to/YOUR_REPLY';
 116         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 117         <<EOF
 118 <hr><pre
 119 id=R><b>Reply instructions:</b>
 120
 121 You may reply publicly to <a
 122 href=#t>this message</a> via plain-text email
 123 using any one of the following methods:
 124
 125 * Save the following mbox file, import it into your mail client,
 126   and $reply_to_all from there: <a
 127 href=raw>mbox</a>
 128
 129   Avoid top-posting and favor interleaved quoting:
 130   <a
 131 href="$p_url">$p_url</a>
 132 $info
 133 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 134   switches of git-send-email(1):
 135
 136   git send-email$arg
 137
 138   <a
 139 href="$se_url">$se_url</a>
 140 $link</pre>
 141 EOF
 142 }
 143
 144 sub in_reply_to {
 145         my ($hdr) = @_;
 146         my $refs = references($hdr);
 147         $refs->[-1];
 148 }
 149
 150 sub fold_addresses ($) {
 151         return $_[0] if length($_[0]) <= COLS;
 152         # try to fold on commas after non-word chars before $lim chars,
 153         # Try to get the "," preceded by ">" or ")", but avoid folding
 154         # on the comma where somebody uses "Lastname, Firstname".
 155         # We also try to keep the last and penultimate addresses in
 156         # the list on the same line if possible, hence the extra \z
 157         # Fall back to folding on spaces at $lim + 1 chars
 158         my $lim = COLS - 8; # 8 = "\t" display width
 159         my $too_long = $lim + 1;
 160         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 161         $_[0] = join("\n\t",
 162                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 163                                 .{1,$lim}(?:,|\z)|
 164                                 .{1,$lim}|
 165                                 .{$too_long,}?)(?:\s|\z)/xgo));
 166 }
 167
 168 sub _hdr_names_html ($$) {
 169         my ($hdr, $field) = @_;
 170         my @vals = $hdr->header($field) or return '';
 171         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 172 }
 173
 174 sub nr_to_s ($$$) {
 175         my ($nr, $singular, $plural) = @_;
 176         return "0 $plural" if $nr == 0;
 177         $nr == 1 ? "$nr $singular" : "$nr $plural";
 178 }
 179
 180 # human-friendly format
 181 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 182
 183 # this is already inside a <pre>
 184 sub index_entry {
 185         my ($smsg, $ctx, $more) = @_;
 186         my $subj = $smsg->subject;
 187         my $mid_raw = $smsg->mid;
 188         my $id = id_compress($mid_raw, 1);
 189         my $id_m = 'm'.$id;
 190
 191         my $root_anchor = $ctx->{root_anchor} || '';
 192         my $irt;
 193         my $obfs_ibx = $ctx->{-obfs_ibx};
 194
 195         $subj = '(no subject)' if $subj eq '';
 196         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 197         $subj = '<b>'.ascii_html($subj).'</b>';
 198         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 199         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 200         $rv .= $subj . "\n";
 201         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 202         my @tocc;
 203         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 204         # deleting {mime} is critical to memory use,
 205         # the rest of the fields saves about 400K as we iterate across 1K msgs
 206         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 207
 208         my $hdr = $mime->header_obj;
 209         my $from = _hdr_names_html($hdr, 'From');
 210         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 211         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 212         my $upfx = $ctx->{-upfx};
 213         my $mhref = $upfx . mid_href($mid_raw) . '/';
 214         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 215         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 216         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 217         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 218         my ($tlen, $clen) = (length($to), length($cc));
 219         my $to_cc = '';
 220         if (($tlen + $clen) > COLS) {
 221                 $to_cc .= '  To: '.$to."\n" if $tlen;
 222                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 223         } else {
 224                 if ($tlen) {
 225                         $to_cc .= '  To: '.$to;
 226                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 227                 } else {
 228                         $to_cc .= '  Cc: '.$cc if $clen;
 229                 }
 230                 $to_cc .= "\n";
 231         }
 232         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 233         $rv .= $to_cc;
 234
 235         my $mapping = $ctx->{mapping};
 236         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 237                 my $href = $upfx . mid_href($irt) . '/';
 238                 my $html = ascii_html($irt);
 239                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 240         }
 241         $rv .= "\n";
 242
 243         # scan through all parts, looking for displayable text
 244         $ctx->{mhref} = $mhref;
 245         $ctx->{obuf} = \$rv;
 246         msg_iter($mime, \&add_text_body, $ctx, 1);
 247         delete $ctx->{obuf};
 248
 249         # add the footer
 250         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 251                 "<a\nhref=\"$mhref\">permalink</a>" .
 252                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 253                 " <a\nhref=\"${mhref}#R\">reply</a>";
 254
 255         my $hr;
 256         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 257                 $rv .= "\t[relevance $pct%]";
 258                 $hr = 1;
 259         } elsif ($mapping) {
 260                 my $nested = 'nested';
 261                 my $flat = 'flat';
 262                 my $end = '';
 263                 if ($ctx->{flat}) {
 264                         $hr = 1;
 265                         $flat = "<b>$flat</b>";
 266                 } else {
 267                         $nested = "<b>$nested</b>";
 268                 }
 269                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 270                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 271                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 272         } else {
 273                 $hr = $ctx->{-hr};
 274         }
 275
 276         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 277         $rv;
 278 }
 279
 280 sub pad_link ($$;$) {
 281         my ($mid, $level, $s) = @_;
 282         $s ||= '...';
 283         my $id = id_compress($mid, 1);
 284         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 285 }
 286
 287 sub _th_index_lite {
 288         my ($mid_raw, $irt, $id, $ctx) = @_;
 289         my $rv = '';
 290         my $mapping = $ctx->{mapping} or return $rv;
 291         my $pad = '  ';
 292         my $mid_map = $mapping->{$mid_raw};
 293         defined $mid_map or
 294                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 295         my ($attr, $node, $idx, $level) = @$mid_map;
 296         my $children = $node->{children};
 297         my $nr_c = scalar @$children;
 298         my $nr_s = 0;
 299         my $siblings;
 300         # delete saves about 200KB on a 1K message thread
 301         if (my $refs = delete $node->{references}) {
 302                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 303         }
 304         my $irt_map = $mapping->{$$irt} if defined $$irt;
 305         if (defined $irt_map) {
 306                 $siblings = $irt_map->[1]->{children};
 307                 $nr_s = scalar(@$siblings) - 1;
 308                 $rv .= $pad . $irt_map->[0];
 309                 if ($idx > 0) {
 310                         my $prev = $siblings->[$idx - 1];
 311                         my $pmid = $prev->{mid};
 312                         if ($idx > 2) {
 313                                 my $s = ($idx - 1). ' preceding siblings ...';
 314                                 $rv .= pad_link($pmid, $level, $s);
 315                         } elsif ($idx == 2) {
 316                                 my $ppmid = $siblings->[0]->{mid};
 317                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 318                         }
 319                         $rv .= $pad . $mapping->{$pmid}->[0];
 320                 }
 321         }
 322         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 323         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 324         $attr =~ s!\n\z!</b>\n!s;
 325         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 326         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 327         $rv .= "<b>@ $attr";
 328         if ($nr_c) {
 329                 my $cmid = $children->[0]->{mid};
 330                 $rv .= $pad . $mapping->{$cmid}->[0];
 331                 if ($nr_c > 2) {
 332                         my $s = ($nr_c - 1). ' more replies';
 333                         $rv .= pad_link($cmid, $level + 1, $s);
 334                 } elsif (my $cn = $children->[1]) {
 335                         $rv .= $pad . $mapping->{$cn->{mid}}->[0];
 336                 }
 337         }
 338
 339         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 340         if ($next) {
 341                 my $nmid = $next->{mid};
 342                 $rv .= $pad . $mapping->{$nmid}->[0];
 343                 my $nnext = $nr_s - $idx;
 344                 if ($nnext > 2) {
 345                         my $s = ($nnext - 1).' subsequent siblings';
 346                         $rv .= pad_link($nmid, $level, $s);
 347                 } elsif (my $nn = $siblings->[$idx + 2]) {
 348                         $rv .= $pad . $mapping->{$nn->{mid}}->[0];
 349                 }
 350         }
 351         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 352 }
 353
 354 # non-recursive thread walker
 355 sub walk_thread ($$$) {
 356         my ($rootset, $ctx, $cb) = @_;
 357         my @q = map { (0, $_, -1) } @$rootset;
 358         while (@q) {
 359                 my ($level, $node, $i) = splice(@q, 0, 3);
 360                 defined $node or next;
 361                 $cb->($ctx, $level, $node, $i) or return;
 362                 ++$level;
 363                 $i = 0;
 364                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 365         }
 366 }
 367
 368 sub pre_thread  { # walk_thread callback
 369         my ($ctx, $level, $node, $idx) = @_;
 370         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 371         skel_dump($ctx, $level, $node);
 372 }
 373
 374 sub thread_index_entry {
 375         my ($ctx, $level, $smsg) = @_;
 376         my ($beg, $end) = thread_adj_level($ctx, $level);
 377         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 378 }
 379
 380 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 381         my ($nr, $ctx) = @_;
 382         return unless exists($ctx->{skel});
 383         my $q = $ctx->{-queue};
 384         while (@$q) {
 385                 my $level = shift @$q;
 386                 my $node = shift @$q or next;
 387                 my $cl = $level + 1;
 388                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 389                 if ($ctx->{-inbox}->smsg_mime($node)) {
 390                         return thread_index_entry($ctx, $level, $node);
 391                 } else {
 392                         return ghost_index_entry($ctx, $level, $node);
 393                 }
 394         }
 395         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{skel}};
 396 }
 397
 398 sub stream_thread ($$) {
 399         my ($rootset, $ctx) = @_;
 400         my $ibx = $ctx->{-inbox};
 401         my @q = map { (0, $_) } @$rootset;
 402         my ($smsg, $level);
 403         while (@q) {
 404                 $level = shift @q;
 405                 my $node = shift @q or next;
 406                 my $cl = $level + 1;
 407                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 408                 $smsg = $ibx->smsg_mime($node) and last;
 409         }
 410         return missing_thread($ctx) unless $smsg;
 411
 412         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 413         $ctx->{-title_html} = ascii_html($smsg->{subject});
 414         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 415         $ctx->{-queue} = \@q;
 416         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 417 }
 418
 419 # /$INBOX/$MESSAGE_ID/t/
 420 sub thread_html {
 421         my ($ctx) = @_;
 422         my $mid = $ctx->{mid};
 423         my $ibx = $ctx->{-inbox};
 424         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 425         return missing_thread($ctx) if $nr == 0;
 426         my $skel = '<hr><pre>';
 427         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 428         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 429         $skel .= "<b\nid=t>Thread overview:</b> ";
 430         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 431         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 432         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 433         $skel .= "-- links below jump to the message on this page --\n";
 434         $ctx->{-upfx} = '../../';
 435         $ctx->{cur_level} = 0;
 436         $ctx->{skel} = \$skel;
 437         $ctx->{prev_attr} = '';
 438         $ctx->{prev_level} = 0;
 439         $ctx->{root_anchor} = anchor_for($mid);
 440         $ctx->{mapping} = {};
 441         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 442                        .' in thread';
 443
 444         my $rootset = thread_results($ctx, $msgs);
 445
 446         # reduce hash lookups in pre_thread->skel_dump
 447         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 448         walk_thread($rootset, $ctx, \&pre_thread);
 449
 450         $skel .= '</pre>';
 451         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 452
 453         # flat display: lazy load the full message from smsg
 454         my $smsg;
 455         while (my $m = shift @$msgs) {
 456                 $smsg = $ibx->smsg_mime($m) and last;
 457         }
 458         return missing_thread($ctx) unless $smsg;
 459         $ctx->{-title_html} = ascii_html($smsg->{subject});
 460         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 461         $ctx->{msgs} = $msgs;
 462         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 463 }
 464
 465 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 466         my ($nr, $ctx) = @_;
 467         my $msgs = $ctx->{msgs} or return;
 468         while (my $smsg = shift @$msgs) {
 469                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 470                 return index_entry($smsg, $ctx, scalar @$msgs);
 471         }
 472         my ($skel) = delete @$ctx{qw(skel msgs)};
 473         $$skel;
 474 }
 475
 476 sub multipart_text_as_html {
 477         # ($mime, $ctx) = @_; # msg_iter will do "$_[0] = undef"
 478
 479         # scan through all parts, looking for displayable text
 480         msg_iter($_[0], \&add_text_body, $_[1], 1);
 481 }
 482
 483 sub attach_link ($$$$;$) {
 484         my ($ctx, $ct, $p, $fn, $err) = @_;
 485         my ($part, $depth, @idx) = @$p;
 486         my $nl = $idx[-1] > 1 ? "\n" : '';
 487         my $idx = join('.', @idx);
 488         my $size = bytes::length($part->body);
 489
 490         # hide attributes normally, unless we want to aid users in
 491         # spotting MUA problems:
 492         $ct =~ s/;.*// unless $err;
 493         $ct = ascii_html($ct);
 494         my $sfn;
 495         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 496                 $sfn = $fn;
 497         } elsif ($ct eq 'text/plain') {
 498                 $sfn = 'a.txt';
 499         } else {
 500                 $sfn = 'a.bin';
 501         }
 502         my $rv = $ctx->{obuf};
 503         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 504         if ($err) {
 505                 $$rv .= <<EOF;
 506 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 507 EOF
 508         }
 509         $$rv .= "[-- Attachment #$idx: ";
 510         my $ts = "Type: $ct, Size: $size bytes";
 511         my $desc = $part->header('Content-Description') // $fn // '';
 512         $desc = ascii_html($desc);
 513         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 514         $$rv .= "</a>\n";
 515         undef;
 516 }
 517
 518 sub add_text_body { # callback for msg_iter
 519         my ($p, $ctx) = @_;
 520         my $upfx = $ctx->{mhref};
 521         my $ibx = $ctx->{-inbox};
 522         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 523         my ($part, $depth, @idx) = @$p;
 524         my $ct = $part->content_type || 'text/plain';
 525         my $fn = $part->filename;
 526         my ($s, $err) = msg_part_text($part, $ct);
 527         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 528
 529         # makes no difference to browsers, and don't screw up filename
 530         # link generation in diffs with the extra '%0D'
 531         $s =~ s/\r\n/\n/sg;
 532
 533         # will be escaped to `&#8226;' in HTML
 534         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 535
 536         # always support diff-highlighting, but we can't linkify hunk
 537         # headers for solver unless some coderepo are configured:
 538         my $diff;
 539         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 540                 # diffstat anchors do not link across attachments or messages:
 541                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 542                 $ctx->{-apfx} = join('/', @idx);
 543                 $ctx->{-anchors} = {}; # attr => filename
 544                 $diff = 1;
 545                 delete $ctx->{-long_path};
 546                 my $spfx;
 547                 if ($ibx->{-repo_objs}) {
 548                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 549                                 $spfx = $upfx;
 550                                 $spfx =~ s!/([^/]*)/\z!/!;
 551                         } else {
 552                                 my $n_slash = $upfx =~ tr!/!/!;
 553                                 if ($n_slash == 0) {
 554                                         $spfx = '../';
 555                                 } elsif ($n_slash == 1) {
 556                                         $spfx = '';
 557                                 } else { # nslash == 2
 558                                         $spfx = '../../';
 559                                 }
 560                         }
 561                 }
 562                 $ctx->{-spfx} = $spfx;
 563         };
 564
 565         # some editors don't put trailing newlines at the end:
 566         $s .= "\n" unless $s =~ /\n\z/s;
 567
 568         # split off quoted and unquoted blocks:
 569         my @sections = PublicInbox::MsgIter::split_quotes($s);
 570         undef $s; # free memory
 571         my $rv = $ctx->{obuf};
 572         if (defined($fn) || $depth > 0 || $err) {
 573                 # badly-encoded message with $err? tell the world about it!
 574                 attach_link($ctx, $ct, $p, $fn, $err);
 575                 $$rv .= "\n";
 576         }
 577         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 578         foreach my $cur (@sections) {
 579                 if ($cur =~ /\A>/) {
 580                         # we use a <span> here to allow users to specify
 581                         # their own color for quoted text
 582                         $$rv .= qq(<span\nclass="q">);
 583                         $$rv .= $l->to_html($cur);
 584                         $$rv .= '</span>';
 585                 } elsif ($diff) {
 586                         flush_diff($ctx, \$cur);
 587                 } else {
 588                         # regular lines, OK
 589                         $$rv .= $l->to_html($cur);
 590                 }
 591                 undef $cur; # free memory
 592         }
 593 }
 594
 595 sub _msg_page_prepare_obuf {
 596         my ($hdr, $ctx, $nr) = @_;
 597         my $over = $ctx->{-inbox}->over;
 598         my $obfs_ibx = $ctx->{-obfs_ibx};
 599         my $rv = '';
 600         my $mids = mids_for_index($hdr);
 601         if ($nr == 0) {
 602                 if ($ctx->{more}) {
 603                         $rv .=
 604 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 605                 }
 606                 $rv .= "<pre\nid=b>"; # anchor for body start
 607         } else {
 608                 $rv .= '<pre>';
 609         }
 610         if ($over) {
 611                 $ctx->{-upfx} = '../';
 612         }
 613         my @title; # (Subject[0], From[0])
 614         for my $v ($hdr->header('From')) {
 615                 my @n = PublicInbox::Address::names($v);
 616                 $v = ascii_html($v);
 617                 $title[1] //= ascii_html(join(', ', @n));
 618                 if ($obfs_ibx) {
 619                         obfuscate_addrs($obfs_ibx, $v);
 620                         obfuscate_addrs($obfs_ibx, $title[1]);
 621                 }
 622                 $rv .= "From: $v\n" if $v ne '';
 623         }
 624         foreach my $h (qw(To Cc)) {
 625                 for my $v ($hdr->header($h)) {
 626                         fold_addresses($v);
 627                         $v = ascii_html($v);
 628                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 629                         $rv .= "$h: $v\n" if $v ne '';
 630                 }
 631         }
 632         my @subj = $hdr->header('Subject');
 633         if (@subj) {
 634                 my $v = ascii_html(shift @subj);
 635                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 636                 $rv .= 'Subject: ';
 637                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 638                 $title[0] = $v;
 639                 for $v (@subj) { # multi-Subject message :<
 640                         $v = ascii_html($v);
 641                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 642                         $rv .= "Subject: $v\n";
 643                 }
 644         } else { # dummy anchor for thread skeleton at bottom of page
 645                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 646                 $title[0] = '(no subject)';
 647         }
 648         for my $v ($hdr->header('Date')) {
 649                 $v = ascii_html($v);
 650                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 651                 $rv .= "Date: $v\n";
 652         }
 653         $ctx->{-title_html} = join(' - ', @title);
 654         if (scalar(@$mids) == 1) { # common case
 655                 my $mhtml = ascii_html($mids->[0]);
 656                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 657                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 658         } else {
 659                 # X-Alt-Message-ID can happen if a message is injected from
 660                 # public-inbox-nntpd because of multiple Message-ID headers.
 661                 my $lnk = PublicInbox::Linkify->new;
 662                 my $s = '';
 663                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 664                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 665                 }
 666                 $lnk->linkify_mids('..', \$s, 1);
 667                 $rv .= $s;
 668         }
 669         $rv .= _parent_headers($hdr, $over);
 670         $rv .= "\n";
 671         \$rv;
 672 }
 673
 674 sub SKEL_EXPAND () {
 675         qq(expand[<a\nhref="T/#u">flat</a>) .
 676                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 677                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 678                 qq(<a\nhref="t.atom">Atom feed</a>);
 679 }
 680
 681 sub thread_skel ($$$) {
 682         my ($skel, $ctx, $hdr) = @_;
 683         my $mid = mids($hdr)->[0];
 684         my $ibx = $ctx->{-inbox};
 685         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 686         my $parent = in_reply_to($hdr);
 687         $$skel .= "\n<b>Thread overview: </b>";
 688         if ($nr <= 1) {
 689                 if (defined $parent) {
 690                         $$skel .= SKEL_EXPAND."\n ";
 691                         $$skel .= ghost_parent('../', $parent) . "\n";
 692                 } else {
 693                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 694                 }
 695                 $ctx->{next_msg} = undef;
 696                 $ctx->{parent_msg} = $parent;
 697                 return;
 698         }
 699
 700         $$skel .= $nr;
 701         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 702
 703         # nb: mutt only shows the first Subject in the index pane
 704         # when multiple Subject: headers are present, so we follow suit:
 705         my $subj = $hdr->header('Subject') // '';
 706         $subj = '(no subject)' if $subj eq '';
 707         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 708         $ctx->{cur} = $mid;
 709         $ctx->{prev_attr} = '';
 710         $ctx->{prev_level} = 0;
 711         $ctx->{skel} = $skel;
 712
 713         # reduce hash lookups in skel_dump
 714         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 715         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 716
 717         $ctx->{parent_msg} = $parent;
 718 }
 719
 720 sub _parent_headers {
 721         my ($hdr, $over) = @_;
 722         my $rv = '';
 723         my @irt = $hdr->header_raw('In-Reply-To');
 724         my $refs;
 725         if (@irt) {
 726                 my $lnk = PublicInbox::Linkify->new;
 727                 $rv .= "In-Reply-To: $_\n" for @irt;
 728                 $lnk->linkify_mids('..', \$rv);
 729         } else {
 730                 $refs = references($hdr);
 731                 my $irt = pop @$refs;
 732                 if (defined $irt) {
 733                         my $html = ascii_html($irt);
 734                         my $href = mid_href($irt);
 735                         $rv .= "In-Reply-To: &lt;";
 736                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 737                 }
 738         }
 739
 740         # do not display References: if search is present,
 741         # we show the thread skeleton at the bottom, instead.
 742         return $rv if $over;
 743
 744         $refs //= references($hdr);
 745         if (@$refs) {
 746                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 747                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 748         }
 749         $rv;
 750 }
 751
 752 # returns a string buffer via ->getline
 753 sub html_footer {
 754         my ($ctx, $hdr) = @_;
 755         my $ibx = $ctx->{-inbox};
 756         my $upfx = '../';
 757         my $skel = " <a\nhref=\"$upfx\">index</a>";
 758         my $rv = '<pre>';
 759         if ($ibx->over) {
 760                 $skel .= "\n";
 761                 thread_skel(\$skel, $ctx, $hdr);
 762                 my ($next, $prev);
 763                 my $parent = '       ';
 764                 $next = $prev = '    ';
 765
 766                 if (my $n = $ctx->{next_msg}) {
 767                         $n = mid_href($n);
 768                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 769                 }
 770                 my $u;
 771                 my $par = $ctx->{parent_msg};
 772                 if ($par) {
 773                         $u = mid_href($par);
 774                         $u = "$upfx$u/";
 775                 }
 776                 if (my $p = $ctx->{prev_msg}) {
 777                         $prev = mid_href($p);
 778                         if ($p && $par && $p eq $par) {
 779                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 780                                         'rel=prev>prev parent</a>';
 781                                 $parent = '';
 782                         } else {
 783                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 784                                         'rel=prev>prev</a>';
 785                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 786                         }
 787                 } elsif ($u) { # unlikely
 788                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 789                 }
 790                 $rv .= "$next $prev$parent ";
 791         }
 792         $rv .= qq(<a\nhref="#R">reply</a>);
 793         $rv .= $skel;
 794         $rv .= '</pre>';
 795         $rv .= msg_reply($ctx, $hdr);
 796 }
 797
 798 sub linkify_ref_no_over {
 799         my ($mid) = @_;
 800         my $href = mid_href($mid);
 801         my $html = ascii_html($mid);
 802         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 803 }
 804
 805 sub anchor_for {
 806         my ($msgid) = @_;
 807         'm' . id_compress($msgid, 1);
 808 }
 809
 810 sub ghost_parent {
 811         my ($upfx, $mid) = @_;
 812
 813         my $href = mid_href($mid);
 814         my $html = ascii_html($mid);
 815         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 816 }
 817
 818 sub indent_for {
 819         my ($level) = @_;
 820         $level ? INDENT x ($level - 1) : '';
 821 }
 822
 823 sub find_mid_root {
 824         my ($ctx, $level, $node, $idx) = @_;
 825         ++$ctx->{root_idx} if $level == 0;
 826         if ($node->{mid} eq $ctx->{mid}) {
 827                 $ctx->{found_mid_at} = $ctx->{root_idx};
 828                 return 0;
 829         }
 830         1;
 831 }
 832
 833 sub strict_loose_note ($) {
 834         my ($nr) = @_;
 835         my $msg =
 836 "  -- strict thread matches above, loose matches on Subject: below --\n";
 837
 838         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 839                 $msg .=
 840 "  -- use mbox.gz link to download all $nr messages --\n";
 841         }
 842         $msg;
 843 }
 844
 845 sub thread_results {
 846         my ($ctx, $msgs) = @_;
 847         require PublicInbox::SearchThread;
 848         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 849
 850         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 851         # and preserved in the future.  This bug is hidden by `sid' matches
 852         # in get_thread, so we never noticed it until now.  And even when
 853         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 854         # bump since reindexing is expensive and users may not do it
 855
 856         # loose threading could've returned too many results,
 857         # put the root the message we care about at the top:
 858         my $mid = $ctx->{mid};
 859         if (defined($mid) && scalar(@$rootset) > 1) {
 860                 $ctx->{root_idx} = -1;
 861                 my $nr = scalar @$msgs;
 862                 walk_thread($rootset, $ctx, \&find_mid_root);
 863                 my $idx = $ctx->{found_mid_at};
 864                 if (defined($idx) && $idx != 0) {
 865                         my $tip = splice(@$rootset, $idx, 1);
 866                         @$rootset = reverse @$rootset;
 867                         unshift @$rootset, $tip;
 868                         $ctx->{sl_note} = strict_loose_note($nr);
 869                 }
 870         }
 871         $rootset
 872 }
 873
 874 sub missing_thread {
 875         my ($ctx) = @_;
 876         require PublicInbox::ExtMsg;
 877         PublicInbox::ExtMsg::ext_msg($ctx);
 878 }
 879
 880 sub dedupe_subject {
 881         my ($prev_subj, $subj, $val) = @_;
 882
 883         my $omit; # '"' denotes identical text omitted
 884         my (@prev_pop, @curr_pop);
 885         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 886                 push(@prev_pop, pop(@$prev_subj));
 887                 push(@curr_pop, pop(@$subj));
 888                 $omit //= $val;
 889         }
 890         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 891         if (scalar(@curr_pop) == 1) {
 892                 $omit = undef;
 893                 push @$prev_subj, @prev_pop;
 894                 push @$subj, @curr_pop;
 895         }
 896         $omit // '';
 897 }
 898
 899 sub skel_dump { # walk_thread callback
 900         my ($ctx, $level, $smsg) = @_;
 901         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 902
 903         my $skel = $ctx->{skel};
 904         my $cur = $ctx->{cur};
 905         my $mid = $smsg->{mid};
 906
 907         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 908                 $$skel .= delete($ctx->{sl_note}) || '';
 909         }
 910
 911         my $f = ascii_html($smsg->{from_name});
 912         my $obfs_ibx = $ctx->{-obfs_ibx};
 913         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 914
 915         my $d = fmt_ts($smsg->{ds});
 916         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 917         if (exists $ctx->{searchview}) {
 918                 if (defined(my $pct = $smsg->{pct})) {
 919                         $d .= (sprintf(' % 2u', $pct) . '%');
 920                 } else {
 921                         $unmatched = 1;
 922                         $d .= '    ';
 923                 }
 924         }
 925         $d .= ' ' . indent_for($level) . th_pfx($level);
 926         my $attr = $f;
 927         $ctx->{first_level} ||= $level;
 928
 929         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 930                 $ctx->{prev_attr} = $attr;
 931         }
 932         $ctx->{prev_level} = $level;
 933
 934         if ($cur) {
 935                 if ($cur eq $mid) {
 936                         delete $ctx->{cur};
 937                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 938                                  "$attr [this message]</a></b>\n";
 939                         return 1;
 940                 } else {
 941                         $ctx->{prev_msg} = $mid;
 942                 }
 943         } else {
 944                 $ctx->{next_msg} ||= $mid;
 945         }
 946
 947         # Subject is never undef, this mail was loaded from
 948         # our Xapian which would've resulted in '' if it were
 949         # really missing (and Filter rejects empty subjects)
 950         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 951         # remove common suffixes from the subject if it matches the previous,
 952         # so we do not show redundant text at the end.
 953         my $prev_subj = $ctx->{prev_subj} || [];
 954         $ctx->{prev_subj} = [ @subj ];
 955         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 956         my $end;
 957         if (@subj) {
 958                 my $subj = join(' ', @subj);
 959                 $subj = ascii_html($subj);
 960                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 961                 $end = "$subj</a> $omit$f\n"
 962         } else {
 963                 $end = "$f</a>\n";
 964         }
 965         my $m;
 966         my $id = '';
 967         my $mapping = $unmatched ? undef : $ctx->{mapping};
 968         if ($mapping) {
 969                 my $map = $mapping->{$mid};
 970                 $id = id_compress($mid, 1);
 971                 $m = '#m'.$id;
 972                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 973                 $id = "\nid=r".$id;
 974         } else {
 975                 $m = $ctx->{-upfx}.mid_href($mid).'/';
 976         }
 977         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 978         1;
 979 }
 980
 981 sub _skel_ghost {
 982         my ($ctx, $level, $node) = @_;
 983
 984         my $mid = $node->{mid};
 985         my $d = '     [not found] ';
 986         $d .= '    '  if exists $ctx->{searchview};
 987         $d .= indent_for($level) . th_pfx($level);
 988         my $upfx = $ctx->{-upfx};
 989         my $href = $upfx . mid_href($mid) . '/';
 990         my $html = ascii_html($mid);
 991
 992         my $mapping = $ctx->{mapping};
 993         my $map = $mapping->{$mid} if $mapping;
 994         if ($map) {
 995                 my $id = id_compress($mid, 1);
 996                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 997                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
 998         } else {
 999                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1000         }
1001         ${$ctx->{skel}} .= $d;
1002         1;
1003 }
1004
1005 sub sort_ds {
1006         [ sort {
1007                 (eval { $a->topmost->{ds} } || 0) <=>
1008                 (eval { $b->topmost->{ds} } || 0)
1009         } @{$_[0]} ];
1010 }
1011
1012 # accumulate recent topics if search is supported
1013 # returns 200 if done, 404 if not
1014 sub acc_topic { # walk_thread callback
1015         my ($ctx, $level, $smsg) = @_;
1016         my $mid = $smsg->{mid};
1017         my $has_blob = $smsg->{blob} // do {
1018                 if (my $by_mid = $ctx->{-inbox}->smsg_by_mid($mid)) {
1019                         %$smsg = (%$smsg, %$by_mid);
1020                         1;
1021                 }
1022         };
1023         if ($has_blob) {
1024                 my $subj = subject_normalized($smsg->{subject});
1025                 $subj = '(no subject)' if $subj eq '';
1026                 my $ds = $smsg->{ds};
1027                 if ($level == 0) { # new, top-level topic
1028                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1029                         $ctx->{-cur_topic} = $topic;
1030                         push @{$ctx->{order}}, $topic;
1031                         return 1;
1032                 }
1033
1034                 # continue existing topic
1035                 my $topic = $ctx->{-cur_topic}; # should never be undef
1036                 $topic->[0] = $ds if $ds > $topic->[0];
1037                 $topic->[1]++; # bump N+ message counter
1038                 my $seen = $topic->[2];
1039                 if (scalar(@$topic) == 3) { # parent was a ghost
1040                         push @$topic, $subj;
1041                 } elsif (!defined($seen->{$subj})) {
1042                         push @$topic, $level, $subj; # @extra messages
1043                 }
1044                 $seen->{$subj} = $mid; # latest for subject
1045         } else { # ghost message
1046                 return 1 if $level != 0; # ignore child ghosts
1047                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1048                 push @{$ctx->{order}}, $topic;
1049         }
1050         1;
1051 }
1052
1053 sub dump_topics {
1054         my ($ctx) = @_;
1055         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1056         unless ($order) {
1057                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1058                 return 404;
1059         }
1060
1061         my @out;
1062         my $ibx = $ctx->{-inbox};
1063         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1064
1065         # sort by recency, this allows new posts to "bump" old topics...
1066         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1067                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1068                 @$topic = ();
1069                 next unless defined $top_subj;  # ghost topic
1070                 my $mid = delete $seen->{$top_subj};
1071                 my $href = mid_href($mid);
1072                 my $prev_subj = [ split(/ /, $top_subj) ];
1073                 $top_subj = ascii_html($top_subj);
1074                 $ds = fmt_ts($ds);
1075
1076                 # $n isn't the total number of posts on the topic,
1077                 # just the number of posts in the current results window
1078                 my $anchor;
1079                 if ($n == 1) {
1080                         $n = '';
1081                         $anchor = '#u'; # top of only message
1082                 } else {
1083                         $n = " ($n+ messages)";
1084                         $anchor = '#t'; # thread skeleton
1085                 }
1086
1087                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1088                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1089                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1090                         " $ds UTC $n - $mbox / $atom\n";
1091                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1092                         my $level = $extra[$i];
1093                         my $subj = $extra[$i + 1]; # already normalized
1094                         $mid = delete $seen->{$subj};
1095                         my @subj = split(/ /, $subj);
1096                         my @next_prev = @subj; # full copy
1097                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1098                         $prev_subj = \@next_prev;
1099                         $subj = ascii_html($subj);
1100                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1101                         $href = mid_href($mid);
1102                         $s .= indent_for($level) . TCHILD;
1103                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1104                 }
1105                 push @out, $s;
1106         }
1107         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1108         200;
1109 }
1110
1111 # only for the t= query parameter passed to overview DB
1112 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1113
1114 sub str2ts ($) {
1115         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1116         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1117 }
1118
1119 sub pagination_footer ($$) {
1120         my ($ctx, $latest) = @_;
1121         delete $ctx->{qp} or return;
1122         my $next = $ctx->{next_page} || '';
1123         my $prev = $ctx->{prev_page} || '';
1124         if ($prev) {
1125                 $next = $next ? "$next " : '     ';
1126                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1127         }
1128         "<hr><pre>page: $next$prev</pre>";
1129 }
1130
1131 sub index_nav { # callback for WwwStream
1132         my (undef, $ctx) = @_;
1133         pagination_footer($ctx, '.')
1134 }
1135
1136 sub paginate_recent ($$) {
1137         my ($ctx, $lim) = @_;
1138         my $t = $ctx->{qp}->{t} || '';
1139         my $opts = { limit => $lim };
1140         my ($after, $before);
1141
1142         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1143         # if only $after exists "YYYYMMDD.." because "." could be skipped
1144         # if interpreted as an end-of-sentence
1145         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1146         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1147
1148         my $ibx = $ctx->{-inbox};
1149         my $msgs = $ibx->recent($opts, $after, $before);
1150         my $nr = scalar @$msgs;
1151         if ($nr < $lim && defined($after)) {
1152                 $after = $before = undef;
1153                 $msgs = $ibx->recent($opts);
1154                 $nr = scalar @$msgs;
1155         }
1156         my $more = $nr == $lim;
1157         my ($newest, $oldest);
1158         if ($nr) {
1159                 $newest = $msgs->[0]->{ts};
1160                 $oldest = $msgs->[-1]->{ts};
1161                 # if we only had $after, our SQL query in ->recent ordered
1162                 if ($newest < $oldest) {
1163                         ($oldest, $newest) = ($newest, $oldest);
1164                         $more = 0 if defined($after) && $after < $oldest;
1165                 }
1166         }
1167         if (defined($oldest) && $more) {
1168                 my $s = ts2str($oldest);
1169                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1170         }
1171         if (defined($newest) && (defined($before) || defined($after))) {
1172                 my $s = ts2str($newest);
1173                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1174         }
1175         $msgs;
1176 }
1177
1178 sub index_topics {
1179         my ($ctx) = @_;
1180         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1181         if (@$msgs) {
1182                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1183         }
1184         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), \&index_nav);
1185 }
1186
1187 sub thread_adj_level {
1188         my ($ctx, $level) = @_;
1189
1190         my $max = $ctx->{cur_level};
1191         if ($level <= 0) {
1192                 return ('', '') if $max == 0; # flat output
1193
1194                 # reset existing lists
1195                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1196                 $ctx->{cur_level} = 0;
1197                 ("$beg</ul>", '');
1198         } elsif ($level == $max) { # continue existing list
1199                 qw(<li> </li>);
1200         } elsif ($level < $max) {
1201                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1202                 $ctx->{cur_level} = $level;
1203                 ("$beg<li>", '</li>');
1204         } else { # ($level > $max) # start a new level
1205                 $ctx->{cur_level} = $level;
1206                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1207                 ($beg, '</li>');
1208         }
1209 }
1210
1211 sub ghost_index_entry {
1212         my ($ctx, $level, $node) = @_;
1213         my ($beg, $end) = thread_adj_level($ctx,  $level);
1214         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid})
1215                 . '</pre>' . $end;
1216 }
1217
1218 1;