lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use URI::Escape qw/uri_escape_utf8/;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::Hval qw/ascii_html/;
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw/mid_clean id_compress mid_mime mid_escape/;
  14 use PublicInbox::MsgIter;
  15 use PublicInbox::Address;
  16 use PublicInbox::WwwStream;
  17 require POSIX;
  18
  19 use constant INDENT => '  ';
  20 use constant TCHILD => '` ';
  21 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  22
  23 # public functions: (unstable)
  24 sub msg_html {
  25         my ($ctx, $mime) = @_;
  26         my $hdr = $mime->header_obj;
  27         my $tip = _msg_html_prepare($hdr, $ctx);
  28         PublicInbox::WwwStream->response($ctx, 200, sub {
  29                 my ($nr, undef) = @_;
  30                 if ($nr == 1) {
  31                         $tip . multipart_text_as_html($mime, '') . '</pre><hr>'
  32                 } elsif ($nr == 2) {
  33                         # fake an EOF if generating the footer fails;
  34                         # we want to at least show the message if something
  35                         # here crashes:
  36                         eval {
  37                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  38                                 '</pre>' . msg_reply($ctx, $hdr)
  39                         };
  40                 } else {
  41                         undef
  42                 }
  43         });
  44 }
  45
  46 # /$INBOX/$MESSAGE_ID/#R
  47 sub msg_reply {
  48         my ($ctx, $hdr) = @_;
  49         my $se_url =
  50          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  51         my $p_url =
  52          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  53
  54         my $info = '';
  55         if (my $url = $ctx->{-inbox}->{infourl}) {
  56                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
  57                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  58         }
  59
  60         my ($arg, $link) = mailto_arg_link($hdr);
  61         push @$arg, '/path/to/YOUR_REPLY';
  62         $arg = ascii_html(join(" \\\n    ", '', @$arg));
  63         <<EOF
  64 <hr><pre
  65 id=R><b>Reply instructions:</b>
  66
  67 You may reply publically to <a
  68 href=#t>this message</a> via plain-text email
  69 using any one of the following methods:
  70
  71 * Save the following mbox file, import it into your mail client,
  72   and reply-to-all from there: <a
  73 href=raw>mbox</a>
  74
  75   Avoid top-posting and favor interleaved quoting:
  76   <a
  77 href="$p_url">$p_url</a>
  78 $info
  79 * Reply to all the recipients using the <b>--to</b>, <b>--cc</b>,
  80   and <b>--in-reply-to</b> switches of git-send-email(1):
  81
  82   git send-email$arg
  83
  84   <a
  85 href="$se_url">$se_url</a>
  86
  87 * If your mail client supports setting the <b>In-Reply-To</b> header
  88   via mailto: links, try the <a
  89 href="$link">mailto: link</a></pre>
  90 EOF
  91 }
  92
  93 sub in_reply_to {
  94         my ($hdr) = @_;
  95         my $irt = $hdr->header_raw('In-Reply-To');
  96
  97         return mid_clean($irt) if defined $irt && $irt ne '';
  98
  99         my $refs = $hdr->header_raw('References');
 100         if ($refs && $refs =~ /<([^>]+)>\s*\z/s) {
 101                 return $1;
 102         }
 103         undef;
 104 }
 105
 106 sub _hdr_names ($$) {
 107         my ($hdr, $field) = @_;
 108         my $val = $hdr->header($field) or return '';
 109         ascii_html(join(', ', PublicInbox::Address::names($val)));
 110 }
 111
 112 sub nr_to_s ($$$) {
 113         my ($nr, $singular, $plural) = @_;
 114         return "0 $plural" if $nr == 0;
 115         $nr == 1 ? "$nr $singular" : "$nr $plural";
 116 }
 117
 118 # this is already inside a <pre>
 119 sub index_entry {
 120         my ($mime, $ctx, $more) = @_;
 121         my $srch = $ctx->{srch};
 122         my $hdr = $mime->header_obj;
 123         my $subj = $hdr->header('Subject');
 124
 125         my $mid_raw = mid_clean(mid_mime($mime));
 126         my $id = id_compress($mid_raw, 1);
 127         my $id_m = 'm'.$id;
 128
 129         my $root_anchor = $ctx->{root_anchor} || '';
 130         my $irt = in_reply_to($hdr);
 131
 132         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 133         $subj = '<b>'.ascii_html($subj).'</b>';
 134         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 135         $rv .= $subj . "\n";
 136         $rv .= _th_index_lite($mid_raw, $irt, $id, $ctx);
 137         my @tocc;
 138         foreach my $f (qw(To Cc)) {
 139                 my $dst = _hdr_names($hdr, $f);
 140                 push @tocc, "$f: $dst" if $dst ne '';
 141         }
 142         $rv .= "From: "._hdr_names($hdr, 'From').' @ '._msg_date($hdr)." UTC";
 143         my $upfx = $ctx->{-upfx};
 144         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 145         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 146         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 147         $rv .= '  '.join('; +', @tocc) . "\n" if @tocc;
 148
 149         my $mapping = $ctx->{mapping};
 150         if (!$mapping && $irt) {
 151                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 152                 my $href = $upfx . $mirt->{href}. '/';
 153                 my $html = $mirt->as_html;
 154                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 155         }
 156         $rv .= "\n";
 157
 158         # scan through all parts, looking for displayable text
 159         msg_iter($mime, sub { $rv .= add_text_body($mhref, $_[0]) });
 160
 161         # add the footer
 162         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 163                 "<a\nhref=\"$mhref\">permalink</a>" .
 164                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 165                 " <a\nhref=\"${mhref}#R\">reply</a>";
 166
 167         my $hr;
 168         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 169                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 170                 $hr = 1;
 171         } elsif ($mapping) {
 172                 my $threaded = 'threaded';
 173                 my $flat = 'flat';
 174                 my $end = '';
 175                 if ($ctx->{flat}) {
 176                         $hr = 1;
 177                         $flat = "<b>$flat</b>";
 178                 } else {
 179                         $threaded = "<b>$threaded</b>";
 180                 }
 181                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 182                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$threaded</a>]";
 183                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 184         } else {
 185                 $hr = $ctx->{-hr};
 186         }
 187
 188         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 189         $rv;
 190 }
 191
 192 sub pad_link ($$;$) {
 193         my ($mid, $level, $s) = @_;
 194         $s ||= '...';
 195         my $id = id_compress($mid, 1);
 196         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 197 }
 198
 199 sub _th_index_lite {
 200         my ($mid_raw, $irt, $id, $ctx) = @_;
 201         my $rv = '';
 202         my $mapping = $ctx->{mapping} or return $rv;
 203         my $pad = '  ';
 204         # map = [children, attr, node, idx, level]
 205         my $map = $mapping->{$mid_raw};
 206         my $nr_c = scalar @{$map->[0]};
 207         my $nr_s = 0;
 208         my $level = $map->[4];
 209         my $idx = $map->[3];
 210         my $irt_map = $mapping->{$irt} if defined $irt;
 211         if (defined $irt_map) {
 212                 my $siblings = $irt_map->[0];
 213                 $nr_s = scalar(@$siblings) - 1;
 214                 $rv .= $pad . $irt_map->[1];
 215                 if ($idx > 0) {
 216                         my $prev = $siblings->[$idx - 1];
 217                         my $pmid = $prev->messageid;
 218                         if ($idx > 2) {
 219                                 my $s = ($idx - 1). ' preceding siblings ...';
 220                                 $rv .= pad_link($pmid, $level, $s);
 221                         } elsif ($idx == 2) {
 222                                 my $ppmid = $siblings->[0]->messageid;
 223                                 $rv .= $pad . $mapping->{$ppmid}->[1];
 224                         }
 225                         $rv .= $pad . $mapping->{$pmid}->[1];
 226                 }
 227         }
 228         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 229         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 230         my $this = $map->[1];
 231         $this =~ s!\n\z!</b>\n!s;
 232         $this =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 233         $this =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 234         $rv .= "<b>@ $this";
 235         my $node = $map->[2];
 236         if (my $child = $node->child) {
 237                 my $cmid = $child->messageid;
 238                 $rv .= $pad . $mapping->{$cmid}->[1];
 239                 if ($nr_c > 2) {
 240                         my $s = ($nr_c - 1). ' more replies';
 241                         $rv .= pad_link($cmid, $level + 1, $s);
 242                 } elsif (my $cn = $child->next) {
 243                         $rv .= $pad . $mapping->{$cn->messageid}->[1];
 244                 }
 245         }
 246         if (my $next = $node->next) {
 247                 my $nmid = $next->messageid;
 248                 $rv .= $pad . $mapping->{$nmid}->[1];
 249                 my $nnext = $nr_s - $idx;
 250                 if ($nnext > 2) {
 251                         my $s = ($nnext - 1).' subsequent siblings';
 252                         $rv .= pad_link($nmid, $level, $s);
 253                 } elsif (my $nn = $next->next) {
 254                         $rv .= $pad . $mapping->{$nn->messageid}->[1];
 255                 }
 256         }
 257         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 258 }
 259
 260 sub walk_thread {
 261         my ($th, $ctx, $cb) = @_;
 262         my @q = map { (0, $_) } $th->rootset;
 263         while (@q) {
 264                 my $level = shift @q;
 265                 my $node = shift @q or next;
 266                 $cb->($ctx, $level, $node);
 267                 unshift @q, $level+1, $node->child, $level, $node->next;
 268         }
 269 }
 270
 271 sub pre_thread  {
 272         my ($ctx, $level, $node) = @_;
 273         my $mapping = $ctx->{mapping};
 274         my $idx = -1;
 275         if (my $parent = $node->parent) {
 276                 my $m = $mapping->{$parent->messageid}->[0];
 277                 $idx = scalar @$m;
 278                 push @$m, $node;
 279         }
 280         $mapping->{$node->messageid} = [ [], '', $node, $idx, $level ];
 281         skel_dump($ctx, $level, $node);
 282 }
 283
 284 sub thread_index_entry {
 285         my ($ctx, $level, $mime) = @_;
 286         my ($beg, $end) = thread_adj_level($ctx, $level);
 287         $beg . '<pre>' . index_entry($mime, $ctx, 0) . '</pre>' . $end;
 288 }
 289
 290 sub stream_thread ($$) {
 291         my ($th, $ctx) = @_;
 292         my $inbox = $ctx->{-inbox};
 293         my $mime;
 294         my @q = map { (0, $_) } $th->rootset;
 295         my $level;
 296         while (@q) {
 297                 $level = shift @q;
 298                 my $node = shift @q or next;
 299                 unshift @q, $level+1, $node->child, $level, $node->next;
 300                 $mime = $inbox->msg_by_mid($node->messageid) and last;
 301         }
 302         return missing_thread($ctx) unless $mime;
 303
 304         $mime = Email::MIME->new($mime);
 305         $ctx->{-title_html} = ascii_html($mime->header('Subject'));
 306         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $mime);
 307         PublicInbox::WwwStream->response($ctx, 200, sub {
 308                 return unless $ctx;
 309                 while (@q) {
 310                         $level = shift @q;
 311                         my $node = shift @q or next;
 312                         unshift @q, $level+1, $node->child, $level, $node->next;
 313                         my $mid = $node->messageid;
 314                         if ($mime = $inbox->msg_by_mid($mid)) {
 315                                 $mime = Email::MIME->new($mime);
 316                                 return thread_index_entry($ctx, $level, $mime);
 317                         } else {
 318                                 return ghost_index_entry($ctx, $level, $mid);
 319                         }
 320                 }
 321                 my $ret = join('', thread_adj_level($ctx, 0));
 322                 $ret .= ${$ctx->{dst}}; # skel
 323                 $ctx = undef;
 324                 $ret;
 325         });
 326 }
 327
 328 sub thread_html {
 329         my ($ctx) = @_;
 330         my $mid = $ctx->{mid};
 331         my $sres = $ctx->{srch}->get_thread($mid, { asc => 1 });
 332         my $msgs = load_results($sres);
 333         my $nr = $sres->{total};
 334         return missing_thread($ctx) if $nr == 0;
 335         my $skel = '<hr><pre>';
 336         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 337         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 338         $skel .= "<b\nid=t>Thread overview:</b> ";
 339         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 340         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 341         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 342         $skel .= "-- links below jump to the message on this page --\n";
 343         $ctx->{-upfx} = '../../';
 344         $ctx->{cur_level} = 0;
 345         $ctx->{dst} = \$skel;
 346         $ctx->{prev_attr} = '';
 347         $ctx->{prev_level} = 0;
 348         $ctx->{root_anchor} = anchor_for($mid);
 349         $ctx->{seen} = {};
 350         $ctx->{mapping} = {};
 351         $ctx->{s_nr} = "$nr+ messages in thread";
 352
 353         my $th = thread_results($msgs);
 354         walk_thread($th, $ctx, *pre_thread);
 355         $skel .= '</pre>';
 356         return stream_thread($th, $ctx) unless $ctx->{flat};
 357
 358         # flat display: lazy load the full message from mini_mime:
 359         my $inbox = $ctx->{-inbox};
 360         my $mime;
 361         while ($mime = shift @$msgs) {
 362                 $mime = $inbox->msg_by_mid(mid_clean(mid_mime($mime))) and last;
 363         }
 364         return missing_thread($ctx) unless $mime;
 365         $mime = Email::MIME->new($mime);
 366         $ctx->{-title_html} = ascii_html($mime->header('Subject'));
 367         $ctx->{-html_tip} = '<pre>'.index_entry($mime, $ctx, scalar @$msgs);
 368         $mime = undef;
 369         PublicInbox::WwwStream->response($ctx, 200, sub {
 370                 return unless $msgs;
 371                 while ($mime = shift @$msgs) {
 372                         $mid = mid_clean(mid_mime($mime));
 373                         $mime = $inbox->msg_by_mid($mid) and last;
 374                 }
 375                 if ($mime) {
 376                         $mime = Email::MIME->new($mime);
 377                         return index_entry($mime, $ctx, scalar @$msgs);
 378                 }
 379                 $msgs = undef;
 380                 $skel;
 381         });
 382 }
 383
 384 sub multipart_text_as_html {
 385         my ($mime, $upfx) = @_;
 386         my $rv = "";
 387
 388         # scan through all parts, looking for displayable text
 389         msg_iter($mime, sub {
 390                 my ($p) = @_;
 391                 $rv .= add_text_body($upfx, $p);
 392         });
 393         $rv;
 394 }
 395
 396 sub flush_quote {
 397         my ($s, $l, $quot) = @_;
 398
 399         # show everything in the full version with anchor from
 400         # short version (see above)
 401         my $rv = $l->linkify_1(join('', @$quot));
 402         @$quot = ();
 403
 404         # we use a <span> here to allow users to specify their own
 405         # color for quoted text
 406         $rv = $l->linkify_2(ascii_html($rv));
 407         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 408 }
 409
 410 sub attach_link ($$$$;$) {
 411         my ($upfx, $ct, $p, $fn, $err) = @_;
 412         my ($part, $depth, @idx) = @$p;
 413         my $nl = $idx[-1] > 1 ? "\n" : '';
 414         my $idx = join('.', @idx);
 415         my $size = bytes::length($part->body);
 416
 417         # hide attributes normally, unless we want to aid users in
 418         # spotting MUA problems:
 419         $ct =~ s/;.*// unless $err;
 420         $ct = ascii_html($ct);
 421         my $desc = $part->header('Content-Description');
 422         $desc = $fn unless defined $desc;
 423         $desc = '' unless defined $desc;
 424         my $sfn;
 425         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 426                 $sfn = $fn;
 427         } elsif ($ct eq 'text/plain') {
 428                 $sfn = 'a.txt';
 429         } else {
 430                 $sfn = 'a.bin';
 431         }
 432         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 433         if ($err) {
 434                 $ret .=
 435 "[-- Warning: decoded text below may be mangled --]\n";
 436         }
 437         $ret .= "[-- Attachment #$idx: ";
 438         my $ts = "Type: $ct, Size: $size bytes";
 439         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 440         $ret .= "</a>\n";
 441 }
 442
 443 sub add_text_body {
 444         my ($upfx, $p) = @_; # from msg_iter: [ Email::MIME, depth, @idx ]
 445         my ($part, $depth, @idx) = @$p;
 446         my $ct = $part->content_type || 'text/plain';
 447         my $fn = $part->filename;
 448
 449         if ($ct =~ m!\btext/x?html\b!i) {
 450                 return attach_link($upfx, $ct, $p, $fn);
 451         }
 452
 453         my $s = eval { $part->body_str };
 454
 455         # badly-encoded message? tell the world about it!
 456         my $err = $@;
 457         if ($err) {
 458                 if ($ct =~ m!\btext/plain\b!i) {
 459                         # Try to assume UTF-8 because Alpine seems to
 460                         # do wacky things and set charset=X-UNKNOWN
 461                         $part->charset_set('UTF-8');
 462                         $s = eval { $part->body_str };
 463
 464                         # If forcing charset=UTF-8 failed,
 465                         # attach_link will warn further down...
 466                         $s = $part->body if $@;
 467                 } else {
 468                         return attach_link($upfx, $ct, $p, $fn);
 469                 }
 470         }
 471
 472         my @lines = split(/^/m, $s);
 473         $s = '';
 474         if (defined($fn) || $depth > 0 || $err) {
 475                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 476                 $s .= "\n";
 477         }
 478         my @quot;
 479         my $l = PublicInbox::Linkify->new;
 480         while (defined(my $cur = shift @lines)) {
 481                 if ($cur !~ /^>/) {
 482                         # show the previously buffered quote inline
 483                         flush_quote(\$s, $l, \@quot) if @quot;
 484
 485                         # regular line, OK
 486                         $cur = $l->linkify_1($cur);
 487                         $cur = ascii_html($cur);
 488                         $s .= $l->linkify_2($cur);
 489                 } else {
 490                         push @quot, $cur;
 491                 }
 492         }
 493
 494         my $end = "\n";
 495         if (@quot) {
 496                 $end = '';
 497                 flush_quote(\$s, $l, \@quot);
 498         }
 499         $s =~ s/[ \t]+$//sgm; # kill per-line trailing whitespace
 500         $s =~ s/\A\n+//s; # kill leading blank lines
 501         $s =~ s/\s+\z//s; # kill all trailing spaces
 502         $s .= $end;
 503 }
 504
 505 sub _msg_html_prepare {
 506         my ($hdr, $ctx) = @_;
 507         my $srch = $ctx->{srch} if $ctx;
 508         my $atom = '';
 509         my $rv = "<pre\nid=b>"; # anchor for body start
 510
 511         if ($srch) {
 512                 $ctx->{-upfx} = '../';
 513         }
 514         my @title;
 515         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 516         $mid = PublicInbox::Hval->new_msgid($mid);
 517         foreach my $h (qw(From To Cc Subject Date)) {
 518                 my $v = $hdr->header($h);
 519                 defined($v) && ($v ne '') or next;
 520                 $v = PublicInbox::Hval->new($v);
 521
 522                 if ($h eq 'From') {
 523                         my @n = PublicInbox::Address::names($v->raw);
 524                         $title[1] = ascii_html(join(', ', @n));
 525                 } elsif ($h eq 'Subject') {
 526                         $title[0] = $v->as_html;
 527                         if ($srch) {
 528                                 $rv .= qq($h: <a\nhref="#r"\nid=t>);
 529                                 $rv .= $v->as_html . "</a>\n";
 530                                 next;
 531                         }
 532                 }
 533                 $v = $v->as_html;
 534                 $v =~ s/(\@[^,]+,) /$1\n\t/g if ($h eq 'Cc' || $h eq 'To');
 535                 $rv .= "$h: $v\n";
 536
 537         }
 538         $title[0] ||= '(no subject)';
 539         $ctx->{-title_html} = join(' - ', @title);
 540         $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 541         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 542         $rv .= _parent_headers($hdr, $srch);
 543         $rv .= "\n";
 544 }
 545
 546 sub thread_skel {
 547         my ($dst, $ctx, $hdr, $tpfx) = @_;
 548         my $srch = $ctx->{srch};
 549         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 550         my $sres = $srch->get_thread($mid);
 551         my $nr = $sres->{total};
 552         my $expand = qq(<a\nhref="${tpfx}T/#u">expand</a> ) .
 553                         qq(/ <a\nhref="${tpfx}t.mbox.gz">mbox.gz</a> ) .
 554                         qq(/ <a\nhref="${tpfx}t.atom">Atom feed</a>);
 555
 556         my $parent = in_reply_to($hdr);
 557         $$dst .= "\n<b>Thread overview: </b>";
 558         if ($nr <= 1) {
 559                 if (defined $parent) {
 560                         $$dst .= "($expand)\n ";
 561                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 562                 } else {
 563                         $$dst .= "[no followups, yet] ($expand)\n";
 564                 }
 565                 $ctx->{next_msg} = undef;
 566                 $ctx->{parent_msg} = $parent;
 567                 return;
 568         }
 569
 570         $$dst .= "$nr+ messages in thread ($expand";
 571         $$dst .= qq! / <a\nhref="#b">[top]</a>)\n!;
 572
 573         my $subj = $srch->subject_path($hdr->header('Subject'));
 574         $ctx->{seen} = { $subj => 1 };
 575         $ctx->{cur} = $mid;
 576         $ctx->{prev_attr} = '';
 577         $ctx->{prev_level} = 0;
 578         $ctx->{dst} = $dst;
 579         walk_thread(thread_results(load_results($sres)), $ctx, *skel_dump);
 580         $ctx->{parent_msg} = $parent;
 581 }
 582
 583 sub _parent_headers {
 584         my ($hdr, $srch) = @_;
 585         my $rv = '';
 586
 587         my $irt = in_reply_to($hdr);
 588         if (defined $irt) {
 589                 my $v = PublicInbox::Hval->new_msgid($irt);
 590                 my $html = $v->as_html;
 591                 my $href = $v->{href};
 592                 $rv .= "In-Reply-To: &lt;";
 593                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 594         }
 595
 596         # do not display References: if search is present,
 597         # we show the thread skeleton at the bottom, instead.
 598         return $rv if $srch;
 599
 600         my $refs = $hdr->header_raw('References');
 601         if ($refs) {
 602                 # avoid redundant URLs wasting bandwidth
 603                 my %seen;
 604                 $seen{$irt} = 1 if defined $irt;
 605                 my @refs;
 606                 my @raw_refs = ($refs =~ /<([^>]+)>/g);
 607                 foreach my $ref (@raw_refs) {
 608                         next if $seen{$ref};
 609                         $seen{$ref} = 1;
 610                         push @refs, linkify_ref_nosrch($ref);
 611                 }
 612
 613                 if (@refs) {
 614                         $rv .= 'References: '. join("\n\t", @refs) . "\n";
 615                 }
 616         }
 617         $rv;
 618 }
 619
 620 sub squote_maybe ($) {
 621         my ($val) = @_;
 622         if ($val =~ m{([^\w@\./,\%\+\-])}) {
 623                 $val =~ s/(['!])/'\\$1'/g; # '!' for csh
 624                 return "'$val'";
 625         }
 626         $val;
 627 }
 628
 629 sub mailto_arg_link {
 630         my ($hdr) = @_;
 631         my %cc; # everyone else
 632         my $to; # this is the From address
 633
 634         foreach my $h (qw(From To Cc)) {
 635                 my $v = $hdr->header($h);
 636                 defined($v) && ($v ne '') or next;
 637                 my @addrs = PublicInbox::Address::emails($v);
 638                 foreach my $address (@addrs) {
 639                         my $dst = lc($address);
 640                         $cc{$dst} ||= $address;
 641                         $to ||= $dst;
 642                 }
 643         }
 644         my @arg;
 645
 646         my $subj = $hdr->header('Subject') || '';
 647         $subj = "Re: $subj" unless $subj =~ /\bRe:/i;
 648         my $mid = $hdr->header_raw('Message-ID');
 649         push @arg, '--in-reply-to='.squote_maybe(mid_clean($mid));
 650         my $irt = mid_escape($mid);
 651         delete $cc{$to};
 652         push @arg, "--to=$to";
 653         $to = uri_escape_utf8($to);
 654         $subj = uri_escape_utf8($subj);
 655         my @cc = sort values %cc;
 656         push(@arg, map { "--cc=$_" } @cc);
 657         my $cc = uri_escape_utf8(join(',', @cc));
 658         my $href = "mailto:$to?In-Reply-To=$irt&Cc=${cc}&Subject=$subj";
 659         $href =~ s/%20/+/g;
 660
 661         (\@arg, ascii_html($href));
 662 }
 663
 664 sub html_footer {
 665         my ($hdr, $standalone, $ctx, $rhref) = @_;
 666
 667         my $srch = $ctx->{srch} if $ctx;
 668         my $upfx = '../';
 669         my $tpfx = '';
 670         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 671         my $irt = '';
 672         if ($idx && $srch) {
 673                 $idx .= "\n";
 674                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 675                 my ($next, $prev);
 676                 my $parent = '       ';
 677                 $next = $prev = '    ';
 678
 679                 if (my $n = $ctx->{next_msg}) {
 680                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 681                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 682                 }
 683                 my $u;
 684                 my $par = $ctx->{parent_msg};
 685                 if ($par) {
 686                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 687                         $u = "$upfx$u/";
 688                 }
 689                 if (my $p = $ctx->{prev_msg}) {
 690                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 691                         if ($p && $par && $p eq $par) {
 692                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 693                                         'rel=prev>prev parent</a>';
 694                                 $parent = '';
 695                         } else {
 696                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 697                                         'rel=prev>prev</a>';
 698                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 699                         }
 700                 } elsif ($u) { # unlikely
 701                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 702                 }
 703                 $irt = "$next $prev$parent ";
 704         } else {
 705                 $irt = '';
 706         }
 707         $rhref ||= '#R';
 708         $irt .= qq(<a\nhref="$rhref">reply</a>);
 709         $irt .= $idx;
 710 }
 711
 712 sub linkify_ref_nosrch {
 713         my $v = PublicInbox::Hval->new_msgid($_[0]);
 714         my $html = $v->as_html;
 715         my $href = $v->{href};
 716         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 717 }
 718
 719 sub anchor_for {
 720         my ($msgid) = @_;
 721         'm' . id_compress($msgid, 1);
 722 }
 723
 724 sub ghost_parent {
 725         my ($upfx, $mid) = @_;
 726
 727         $mid = PublicInbox::Hval->new_msgid($mid);
 728         my $href = $mid->{href};
 729         my $html = $mid->as_html;
 730         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 731 }
 732
 733 sub indent_for {
 734         my ($level) = @_;
 735         INDENT x ($level - 1);
 736 }
 737
 738 sub load_results {
 739         my ($sres) = @_;
 740
 741         [ map { $_->mini_mime } @{delete $sres->{msgs}} ];
 742 }
 743
 744 sub msg_timestamp {
 745         my ($hdr) = @_;
 746         my $ts = eval { str2time($hdr->header('Date')) };
 747         defined($ts) ? $ts : 0;
 748 }
 749
 750 sub thread_results {
 751         my ($msgs) = @_;
 752         require PublicInbox::SearchThread;
 753         my $th = PublicInbox::SearchThread->new($msgs);
 754         $th->thread;
 755         $th->order(*sort_ts);
 756         $th
 757 }
 758
 759 sub missing_thread {
 760         my ($ctx) = @_;
 761         require PublicInbox::ExtMsg;
 762         PublicInbox::ExtMsg::ext_msg($ctx);
 763 }
 764
 765 sub _msg_date {
 766         my ($hdr) = @_;
 767         my $ts = $hdr->header('X-PI-TS') || msg_timestamp($hdr);
 768         fmt_ts($ts);
 769 }
 770
 771 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 772
 773 sub _skel_header {
 774         my ($ctx, $hdr, $level) = @_;
 775
 776         my $dst = $ctx->{dst};
 777         my $cur = $ctx->{cur};
 778         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 779         my $f = ascii_html($hdr->header('X-PI-From'));
 780         my $d = _msg_date($hdr) . ' ' . indent_for($level) . th_pfx($level);
 781         my $attr = $f;
 782         $ctx->{first_level} ||= $level;
 783
 784         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 785                 $ctx->{prev_attr} = $attr;
 786         }
 787         $ctx->{prev_level} = $level;
 788
 789         if ($cur) {
 790                 if ($cur eq $mid) {
 791                         delete $ctx->{cur};
 792                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 793                                  "$attr [this message]</a></b>\n";
 794                         return;
 795                 } else {
 796                         $ctx->{prev_msg} = $mid;
 797                 }
 798         } else {
 799                 $ctx->{next_msg} ||= $mid;
 800         }
 801
 802         # Subject is never undef, this mail was loaded from
 803         # our Xapian which would've resulted in '' if it were
 804         # really missing (and Filter rejects empty subjects)
 805         my $s = $hdr->header('Subject');
 806         my $h = $ctx->{srch}->subject_path($s);
 807         if ($ctx->{seen}->{$h}) {
 808                 $s = undef;
 809         } else {
 810                 $ctx->{seen}->{$h} = 1;
 811                 $s = PublicInbox::Hval->new($s);
 812                 $s = $s->as_html;
 813         }
 814         my $m;
 815         my $id = '';
 816         my $mapping = $ctx->{mapping};
 817         my $end = defined($s) ? "$s</a> $f\n" : "$f</a>\n";
 818         if ($mapping) {
 819                 my $map = $mapping->{$mid};
 820                 $id = id_compress($mid, 1);
 821                 $m = '#m'.$id;
 822                 $map->[1] = "$d<a\nhref=\"$m\">$end";
 823                 $id = "\nid=r".$id;
 824         } else {
 825                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 826         }
 827         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 828 }
 829
 830 sub skel_dump {
 831         my ($ctx, $level, $node) = @_;
 832         if (my $mime = $node->message) {
 833                 _skel_header($ctx, $mime->header_obj, $level);
 834         } else {
 835                 my $mid = $node->messageid;
 836                 my $dst = $ctx->{dst};
 837                 my $mapping = $ctx->{mapping};
 838                 my $map = $mapping->{$mid} if $mapping;
 839                 my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
 840                                     : '     [not found] ';
 841                 $d .= indent_for($level) . th_pfx($level);
 842                 my $upfx = $ctx->{-upfx};
 843                 my $m = PublicInbox::Hval->new_msgid($mid);
 844                 my $href = $upfx . $m->{href} . '/';
 845                 my $html = $m->as_html;
 846
 847                 if ($map) {
 848                         my $id = id_compress($mid, 1);
 849                         $map->[1] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 850                         $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
 851                 } else {
 852                         $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
 853                 }
 854                 $$dst .= $d;
 855         }
 856 }
 857
 858 sub sort_ts {
 859         sort {
 860                 (eval { $a->topmost->message->header('X-PI-TS') } || 0) <=>
 861                 (eval { $b->topmost->message->header('X-PI-TS') } || 0)
 862         } @_;
 863 }
 864
 865 sub _tryload_ghost ($$) {
 866         my ($srch, $mid) = @_;
 867         my $smsg = $srch->lookup_mail($mid) or return;
 868         $smsg->mini_mime;
 869 }
 870
 871 # accumulate recent topics if search is supported
 872 # returns 200 if done, 404 if not
 873 sub acc_topic {
 874         my ($ctx, $level, $node) = @_;
 875         my $srch = $ctx->{srch};
 876         my $mid = $node->messageid;
 877         my $x = $node->message || _tryload_ghost($srch, $mid);
 878         my ($subj, $ts);
 879         my $topic;
 880         if ($x) {
 881                 $x = $x->header_obj;
 882                 $subj = $x->header('Subject') || '';
 883                 $subj = $srch->subject_normalized($subj);
 884                 $ts = $x->header('X-PI-TS');
 885                 if ($level == 0) {
 886                         $topic = [ $ts, 1, { $subj => $mid }, $subj ];
 887                         $ctx->{-cur_topic} = $topic;
 888                         push @{$ctx->{order}}, $topic;
 889                         return;
 890                 }
 891
 892                 $topic = $ctx->{-cur_topic}; # should never be undef
 893                 $topic->[0] = $ts if $ts > $topic->[0];
 894                 $topic->[1]++;
 895                 my $seen = $topic->[2];
 896                 if (scalar(@$topic) == 3) { # parent was a ghost
 897                         push @$topic, $subj;
 898                 } elsif (!$seen->{$subj}) {
 899                         push @$topic, $level, $subj;
 900                 }
 901                 $seen->{$subj} = $mid; # latest for subject
 902         } else { # ghost message
 903                 return if $level != 0; # ignore child ghosts
 904                 $topic = [ -666, 0, {} ];
 905                 $ctx->{-cur_topic} = $topic;
 906                 push @{$ctx->{order}}, $topic;
 907         }
 908 }
 909
 910 sub dump_topics {
 911         my ($ctx) = @_;
 912         my $order = delete $ctx->{order}; # [ ts, subj1, subj2, subj3, ... ]
 913         if (!@$order) {
 914                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
 915                 return 404;
 916         }
 917
 918         my @out;
 919
 920         # sort by recency, this allows new posts to "bump" old topics...
 921         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
 922                 my ($ts, $n, $seen, $top, @ex) = @$topic;
 923                 @$topic = ();
 924                 next unless defined $top;  # ghost topic
 925                 my $mid = delete $seen->{$top};
 926                 my $href = mid_escape($mid);
 927                 $top = PublicInbox::Hval->new($top)->as_html;
 928                 $ts = fmt_ts($ts);
 929
 930                 # $n isn't the total number of posts on the topic,
 931                 # just the number of posts in the current results window
 932                 my $anchor;
 933                 if ($n == 1) {
 934                         $n = '';
 935                         $anchor = '#u'; # top of only message
 936                 } else {
 937                         $n = " ($n+ messages)";
 938                         $anchor = '#t'; # thread skeleton
 939                 }
 940
 941                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
 942                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
 943                 my $s = "<a\nhref=\"$href/T/$anchor\"><b>$top</b></a>\n" .
 944                         " $ts UTC $n - $mbox / $atom\n";
 945                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
 946                         my $level = $ex[$i];
 947                         my $sub = $ex[$i + 1];
 948                         $mid = delete $seen->{$sub};
 949                         $sub = PublicInbox::Hval->new($sub)->as_html;
 950                         $href = mid_escape($mid);
 951                         $s .= indent_for($level) . TCHILD;
 952                         $s .= "<a\nhref=\"$href/T/#u\">$sub</a>\n";
 953                 }
 954                 push @out, $s;
 955         }
 956         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
 957         200;
 958 }
 959
 960 sub index_nav { # callback for WwwStream
 961         my (undef, $ctx) = @_;
 962         delete $ctx->{qp} or return;
 963         my ($next, $prev);
 964         $next = $prev = '    ';
 965         my $latest = '';
 966
 967         my $next_o = $ctx->{-next_o};
 968         if ($next_o) {
 969                 $next = qq!<a\nhref="?o=$next_o"\nrel=next>next</a>!;
 970         }
 971         if (my $cur_o = $ctx->{-cur_o}) {
 972                 $latest = qq! <a\nhref=.>latest</a>!;
 973
 974                 my $o = $cur_o - ($next_o - $cur_o);
 975                 if ($o > 0) {
 976                         $prev = qq!<a\nhref="?o=$o"\nrel=prev>prev</a>!;
 977                 } elsif ($o == 0) {
 978                         $prev = qq!<a\nhref=.\nrel=prev>prev</a>!;
 979                 }
 980         }
 981         "<hr><pre>page: $next $prev$latest</pre>";
 982 }
 983
 984 sub index_topics {
 985         my ($ctx) = @_;
 986         my ($off) = (($ctx->{qp}->{o} || '0') =~ /(\d+)/);
 987         my $opts = { offset => $off, limit => 200 };
 988
 989         $ctx->{order} = [];
 990         my $sres = $ctx->{srch}->query('', $opts);
 991         my $nr = scalar @{$sres->{msgs}};
 992         if ($nr) {
 993                 $sres = load_results($sres);
 994                 walk_thread(thread_results($sres), $ctx, *acc_topic);
 995         }
 996         $ctx->{-next_o} = $off+ $nr;
 997         $ctx->{-cur_o} = $off;
 998         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
 999 }
1000
1001 sub thread_adj_level {
1002         my ($ctx, $level) = @_;
1003
1004         my $max = $ctx->{cur_level};
1005         if ($level <= 0) {
1006                 return ('', '') if $max == 0; # flat output
1007
1008                 # reset existing lists
1009                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1010                 $ctx->{cur_level} = 0;
1011                 ("$beg</ul>", '');
1012         } elsif ($level == $max) { # continue existing list
1013                 qw(<li> </li>);
1014         } elsif ($level < $max) {
1015                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1016                 $ctx->{cur_level} = $level;
1017                 ("$beg<li>", '</li>');
1018         } else { # ($level > $max) # start a new level
1019                 $ctx->{cur_level} = $level;
1020                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1021                 ($beg, '</li>');
1022         }
1023 }
1024
1025 sub ghost_index_entry {
1026         my ($ctx, $level, $mid) = @_;
1027         my ($beg, $end) = thread_adj_level($ctx,  $level);
1028         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $mid) . '</pre>' . $end;
1029 }
1030
1031 1;