lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use POSIX qw(strftime);
  21 use Time::Local qw(timegm);
  22 use PublicInbox::Smsg qw(subject_normalized);
  23 use constant COLS => 72;
  24 use constant INDENT => '  ';
  25 use constant TCHILD => '` ';
  26 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  27
  28 sub msg_page_i {
  29         my ($nr, $ctx) = @_;
  30         if (my $more = delete $ctx->{more}) { # unlikely
  31                 # fake an EOF if $more retrieval fails;
  32                 eval { msg_page_more($ctx, $nr, @$more) };
  33         } elsif (my $hdr = delete $ctx->{hdr}) {
  34                 # fake an EOF if generating the footer fails;
  35                 # we want to at least show the message if something
  36                 # here crashes:
  37                 eval { html_footer($ctx, $hdr) };
  38         } else {
  39                 undef
  40         }
  41 }
  42
  43 # public functions: (unstable)
  44
  45 sub msg_page {
  46         my ($ctx) = @_;
  47         my $mid = $ctx->{mid};
  48         my $ibx = $ctx->{-inbox};
  49         my ($smsg, $first, $next);
  50         if (my $over = $ibx->over) {
  51                 my ($id, $prev);
  52                 $smsg = $over->next_by_mid($mid, \$id, \$prev) or return;
  53                 $first = $ibx->msg_by_smsg($smsg) or return;
  54                 $next = $over->next_by_mid($mid, \$id, \$prev);
  55                 $ctx->{more} = [ $id, $prev, $next ] if $next;
  56         } else {
  57                 $first = $ibx->msg_by_mid($mid) or return;
  58         }
  59         my $mime = PublicInbox::MIME->new($first);
  60         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  61         my $hdr = $ctx->{hdr} = $mime->header_obj;
  62         $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx, 0);
  63         $ctx->{smsg} = $smsg;
  64         # $next cannot be true w/o $smsg being defined:
  65         $ctx->{mhref} = $next ? '../'.mid_href($smsg->{mid}).'/' : '';
  66         multipart_text_as_html($mime, $ctx);
  67         $ctx->{-html_tip} = (${delete $ctx->{obuf}} .= '</pre><hr>');
  68         PublicInbox::WwwStream->response($ctx, 200, \&msg_page_i);
  69 }
  70
  71 sub msg_page_more { # cold
  72         my ($ctx, $nr, $id, $prev, $smsg) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         my $next = $ibx->over->next_by_mid($ctx->{mid}, \$id, \$prev);
  75         $ctx->{more} = [ $id, $prev, $next ] if $next;
  76         $smsg = $ibx->smsg_mime($smsg) or return '';
  77         $ctx->{mhref} = '../' . mid_href($smsg->{mid}) . '/';
  78         my $mime = delete $smsg->{mime};
  79         $ctx->{obuf} = _msg_page_prepare_obuf($mime->header_obj, $ctx, $nr);
  80         multipart_text_as_html($mime, $ctx);
  81         ${delete $ctx->{obuf}} .= '</pre><hr>';
  82 }
  83
  84 # /$INBOX/$MESSAGE_ID/#R
  85 sub msg_reply ($$) {
  86         my ($ctx, $hdr) = @_;
  87         my $se_url =
  88          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  89         my $p_url =
  90          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  91
  92         my $info = '';
  93         my $ibx = $ctx->{-inbox};
  94         if (my $url = $ibx->{infourl}) {
  95                 $url = prurl($ctx->{env}, $url);
  96                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  97         }
  98
  99         my ($arg, $link, $reply_to_all) =
 100                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 101         if (ref($arg) eq 'SCALAR') {
 102                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 103         }
 104
 105         # mailto: link only works if address obfuscation is disabled
 106         if ($link) {
 107                 $link = <<EOF;
 108
 109 * If your mail client supports setting the <b>In-Reply-To</b> header
 110   via mailto: links, try the <a
 111 href="$link">mailto: link</a>
 112 EOF
 113         }
 114
 115         push @$arg, '/path/to/YOUR_REPLY';
 116         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 117         <<EOF
 118 <hr><pre
 119 id=R><b>Reply instructions:</b>
 120
 121 You may reply publicly to <a
 122 href=#t>this message</a> via plain-text email
 123 using any one of the following methods:
 124
 125 * Save the following mbox file, import it into your mail client,
 126   and $reply_to_all from there: <a
 127 href=raw>mbox</a>
 128
 129   Avoid top-posting and favor interleaved quoting:
 130   <a
 131 href="$p_url">$p_url</a>
 132 $info
 133 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 134   switches of git-send-email(1):
 135
 136   git send-email$arg
 137
 138   <a
 139 href="$se_url">$se_url</a>
 140 $link</pre>
 141 EOF
 142 }
 143
 144 sub in_reply_to {
 145         my ($hdr) = @_;
 146         my $refs = references($hdr);
 147         $refs->[-1];
 148 }
 149
 150 sub fold_addresses ($) {
 151         return $_[0] if length($_[0]) <= COLS;
 152         # try to fold on commas after non-word chars before $lim chars,
 153         # Try to get the "," preceeded by ">" or ")", but avoid folding
 154         # on the comma where somebody uses "Lastname, Firstname".
 155         # We also try to keep the last and penultimate addresses in
 156         # the list on the same line if possible, hence the extra \z
 157         # Fall back to folding on spaces at $lim + 1 chars
 158         my $lim = COLS - 8; # 8 = "\t" display width
 159         my $too_long = $lim + 1;
 160         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 161         $_[0] = join("\n\t",
 162                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 163                                 .{1,$lim}(?:,|\z)|
 164                                 .{1,$lim}|
 165                                 .{$too_long,}?)(?:\s|\z)/xgo));
 166 }
 167
 168 sub _hdr_names_html ($$) {
 169         my ($hdr, $field) = @_;
 170         my @vals = $hdr->header($field) or return '';
 171         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 172 }
 173
 174 sub nr_to_s ($$$) {
 175         my ($nr, $singular, $plural) = @_;
 176         return "0 $plural" if $nr == 0;
 177         $nr == 1 ? "$nr $singular" : "$nr $plural";
 178 }
 179
 180 # human-friendly format
 181 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 182
 183 # this is already inside a <pre>
 184 sub index_entry {
 185         my ($smsg, $ctx, $more) = @_;
 186         my $subj = $smsg->subject;
 187         my $mid_raw = $smsg->mid;
 188         my $id = id_compress($mid_raw, 1);
 189         my $id_m = 'm'.$id;
 190
 191         my $root_anchor = $ctx->{root_anchor} || '';
 192         my $irt;
 193         my $obfs_ibx = $ctx->{-obfs_ibx};
 194
 195         $subj = '(no subject)' if $subj eq '';
 196         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 197         $subj = '<b>'.ascii_html($subj).'</b>';
 198         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 199         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 200         $rv .= $subj . "\n";
 201         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 202         my @tocc;
 203         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 204         # deleting {mime} is critical to memory use,
 205         # the rest of the fields saves about 400K as we iterate across 1K msgs
 206         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 207
 208         my $hdr = $mime->header_obj;
 209         my $from = _hdr_names_html($hdr, 'From');
 210         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 211         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 212         my $upfx = $ctx->{-upfx};
 213         my $mhref = $upfx . mid_href($mid_raw) . '/';
 214         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 215         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 216         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 217         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 218         my ($tlen, $clen) = (length($to), length($cc));
 219         my $to_cc = '';
 220         if (($tlen + $clen) > COLS) {
 221                 $to_cc .= '  To: '.$to."\n" if $tlen;
 222                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 223         } else {
 224                 if ($tlen) {
 225                         $to_cc .= '  To: '.$to;
 226                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 227                 } else {
 228                         $to_cc .= '  Cc: '.$cc if $clen;
 229                 }
 230                 $to_cc .= "\n";
 231         }
 232         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 233         $rv .= $to_cc;
 234
 235         my $mapping = $ctx->{mapping};
 236         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 237                 my $href = $upfx . mid_href($irt) . '/';
 238                 my $html = ascii_html($irt);
 239                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 240         }
 241         $rv .= "\n";
 242
 243         # scan through all parts, looking for displayable text
 244         $ctx->{mhref} = $mhref;
 245         $ctx->{obuf} = \$rv;
 246         msg_iter($mime, \&add_text_body, $ctx, 1);
 247         delete $ctx->{obuf};
 248
 249         # add the footer
 250         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 251                 "<a\nhref=\"$mhref\">permalink</a>" .
 252                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 253                 " <a\nhref=\"${mhref}#R\">reply</a>";
 254
 255         my $hr;
 256         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 257                 $rv .= "\t[relevance $pct%]";
 258                 $hr = 1;
 259         } elsif ($mapping) {
 260                 my $nested = 'nested';
 261                 my $flat = 'flat';
 262                 my $end = '';
 263                 if ($ctx->{flat}) {
 264                         $hr = 1;
 265                         $flat = "<b>$flat</b>";
 266                 } else {
 267                         $nested = "<b>$nested</b>";
 268                 }
 269                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 270                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 271                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 272         } else {
 273                 $hr = $ctx->{-hr};
 274         }
 275
 276         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 277         $rv;
 278 }
 279
 280 sub pad_link ($$;$) {
 281         my ($mid, $level, $s) = @_;
 282         $s ||= '...';
 283         my $id = id_compress($mid, 1);
 284         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 285 }
 286
 287 sub _th_index_lite {
 288         my ($mid_raw, $irt, $id, $ctx) = @_;
 289         my $rv = '';
 290         my $mapping = $ctx->{mapping} or return $rv;
 291         my $pad = '  ';
 292         my $mid_map = $mapping->{$mid_raw};
 293         defined $mid_map or
 294                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 295         my ($attr, $node, $idx, $level) = @$mid_map;
 296         my $children = $node->{children};
 297         my $nr_c = scalar @$children;
 298         my $nr_s = 0;
 299         my $siblings;
 300         if (my $smsg = $node->{smsg}) {
 301                 # delete saves about 200KB on a 1K message thread
 302                 if (my $refs = delete $smsg->{references}) {
 303                         ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 304                 }
 305         }
 306         my $irt_map = $mapping->{$$irt} if defined $$irt;
 307         if (defined $irt_map) {
 308                 $siblings = $irt_map->[1]->{children};
 309                 $nr_s = scalar(@$siblings) - 1;
 310                 $rv .= $pad . $irt_map->[0];
 311                 if ($idx > 0) {
 312                         my $prev = $siblings->[$idx - 1];
 313                         my $pmid = $prev->{id};
 314                         if ($idx > 2) {
 315                                 my $s = ($idx - 1). ' preceding siblings ...';
 316                                 $rv .= pad_link($pmid, $level, $s);
 317                         } elsif ($idx == 2) {
 318                                 my $ppmid = $siblings->[0]->{id};
 319                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 320                         }
 321                         $rv .= $pad . $mapping->{$pmid}->[0];
 322                 }
 323         }
 324         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 325         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 326         $attr =~ s!\n\z!</b>\n!s;
 327         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 328         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 329         $rv .= "<b>@ $attr";
 330         if ($nr_c) {
 331                 my $cmid = $children->[0]->{id};
 332                 $rv .= $pad . $mapping->{$cmid}->[0];
 333                 if ($nr_c > 2) {
 334                         my $s = ($nr_c - 1). ' more replies';
 335                         $rv .= pad_link($cmid, $level + 1, $s);
 336                 } elsif (my $cn = $children->[1]) {
 337                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 338                 }
 339         }
 340
 341         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 342         if ($next) {
 343                 my $nmid = $next->{id};
 344                 $rv .= $pad . $mapping->{$nmid}->[0];
 345                 my $nnext = $nr_s - $idx;
 346                 if ($nnext > 2) {
 347                         my $s = ($nnext - 1).' subsequent siblings';
 348                         $rv .= pad_link($nmid, $level, $s);
 349                 } elsif (my $nn = $siblings->[$idx + 2]) {
 350                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 351                 }
 352         }
 353         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 354 }
 355
 356 # non-recursive thread walker
 357 sub walk_thread ($$$) {
 358         my ($rootset, $ctx, $cb) = @_;
 359         my @q = map { (0, $_, -1) } @$rootset;
 360         while (@q) {
 361                 my ($level, $node, $i) = splice(@q, 0, 3);
 362                 defined $node or next;
 363                 $cb->($ctx, $level, $node, $i) or return;
 364                 ++$level;
 365                 $i = 0;
 366                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 367         }
 368 }
 369
 370 sub pre_thread  { # walk_thread callback
 371         my ($ctx, $level, $node, $idx) = @_;
 372         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 373         skel_dump($ctx, $level, $node);
 374 }
 375
 376 sub thread_index_entry {
 377         my ($ctx, $level, $smsg) = @_;
 378         my ($beg, $end) = thread_adj_level($ctx, $level);
 379         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 380 }
 381
 382 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 383         my ($nr, $ctx) = @_;
 384         return unless exists($ctx->{skel});
 385         my $q = $ctx->{-queue};
 386         while (@$q) {
 387                 my $level = shift @$q;
 388                 my $node = shift @$q or next;
 389                 my $cl = $level + 1;
 390                 unshift @$q, map { ($cl, $_) } @{$node->{children}};
 391                 if (my $smsg = $ctx->{-inbox}->smsg_mime($node->{smsg})) {
 392                         return thread_index_entry($ctx, $level, $smsg);
 393                 } else {
 394                         return ghost_index_entry($ctx, $level, $node);
 395                 }
 396         }
 397         join('', thread_adj_level($ctx, 0)) . ${delete $ctx->{skel}};
 398 }
 399
 400 sub stream_thread ($$) {
 401         my ($rootset, $ctx) = @_;
 402         my $ibx = $ctx->{-inbox};
 403         my @q = map { (0, $_) } @$rootset;
 404         my ($smsg, $level);
 405         while (@q) {
 406                 $level = shift @q;
 407                 my $node = shift @q or next;
 408                 my $cl = $level + 1;
 409                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 410                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 411         }
 412         return missing_thread($ctx) unless $smsg;
 413
 414         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 415         $ctx->{-title_html} = ascii_html($smsg->{subject});
 416         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 417         $ctx->{-queue} = \@q;
 418         PublicInbox::WwwStream->response($ctx, 200, \&stream_thread_i);
 419 }
 420
 421 # /$INBOX/$MESSAGE_ID/t/
 422 sub thread_html {
 423         my ($ctx) = @_;
 424         my $mid = $ctx->{mid};
 425         my $ibx = $ctx->{-inbox};
 426         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 427         return missing_thread($ctx) if $nr == 0;
 428         my $skel = '<hr><pre>';
 429         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 430         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 431         $skel .= "<b\nid=t>Thread overview:</b> ";
 432         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 433         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 434         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 435         $skel .= "-- links below jump to the message on this page --\n";
 436         $ctx->{-upfx} = '../../';
 437         $ctx->{cur_level} = 0;
 438         $ctx->{skel} = \$skel;
 439         $ctx->{prev_attr} = '';
 440         $ctx->{prev_level} = 0;
 441         $ctx->{root_anchor} = anchor_for($mid);
 442         $ctx->{mapping} = {};
 443         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 444                        .' in thread';
 445
 446         my $rootset = thread_results($ctx, $msgs);
 447
 448         # reduce hash lookups in pre_thread->skel_dump
 449         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 450         walk_thread($rootset, $ctx, \&pre_thread);
 451
 452         $skel .= '</pre>';
 453         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 454
 455         # flat display: lazy load the full message from smsg
 456         my $smsg;
 457         while (my $m = shift @$msgs) {
 458                 $smsg = $ibx->smsg_mime($m) and last;
 459         }
 460         return missing_thread($ctx) unless $smsg;
 461         $ctx->{-title_html} = ascii_html($smsg->{subject});
 462         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 463         $ctx->{msgs} = $msgs;
 464         PublicInbox::WwwStream->response($ctx, 200, \&thread_html_i);
 465 }
 466
 467 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 468         my ($nr, $ctx) = @_;
 469         my $msgs = $ctx->{msgs} or return;
 470         while (my $smsg = shift @$msgs) {
 471                 $ctx->{-inbox}->smsg_mime($smsg) or next;
 472                 return index_entry($smsg, $ctx, scalar @$msgs);
 473         }
 474         my ($skel) = delete @$ctx{qw(skel msgs)};
 475         $$skel;
 476 }
 477
 478 sub multipart_text_as_html {
 479         # ($mime, $ctx) = @_; # msg_iter will do "$_[0] = undef"
 480
 481         # scan through all parts, looking for displayable text
 482         msg_iter($_[0], \&add_text_body, $_[1], 1);
 483 }
 484
 485 sub attach_link ($$$$;$) {
 486         my ($ctx, $ct, $p, $fn, $err) = @_;
 487         my ($part, $depth, @idx) = @$p;
 488         my $nl = $idx[-1] > 1 ? "\n" : '';
 489         my $idx = join('.', @idx);
 490         my $size = bytes::length($part->body);
 491
 492         # hide attributes normally, unless we want to aid users in
 493         # spotting MUA problems:
 494         $ct =~ s/;.*// unless $err;
 495         $ct = ascii_html($ct);
 496         my $sfn;
 497         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 498                 $sfn = $fn;
 499         } elsif ($ct eq 'text/plain') {
 500                 $sfn = 'a.txt';
 501         } else {
 502                 $sfn = 'a.bin';
 503         }
 504         my $rv = $ctx->{obuf};
 505         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 506         if ($err) {
 507                 $$rv .= <<EOF;
 508 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 509 EOF
 510         }
 511         $$rv .= "[-- Attachment #$idx: ";
 512         my $ts = "Type: $ct, Size: $size bytes";
 513         my $desc = $part->header('Content-Description') // $fn // '';
 514         $desc = ascii_html($desc);
 515         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 516         $$rv .= "</a>\n";
 517         undef;
 518 }
 519
 520 sub add_text_body { # callback for msg_iter
 521         my ($p, $ctx) = @_;
 522         my $upfx = $ctx->{mhref};
 523         my $ibx = $ctx->{-inbox};
 524         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 525         my ($part, $depth, @idx) = @$p;
 526         my $ct = $part->content_type || 'text/plain';
 527         my $fn = $part->filename;
 528         my ($s, $err) = msg_part_text($part, $ct);
 529         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 530
 531         # makes no difference to browsers, and don't screw up filename
 532         # link generation in diffs with the extra '%0D'
 533         $s =~ s/\r\n/\n/sg;
 534
 535         # always support diff-highlighting, but we can't linkify hunk
 536         # headers for solver unless some coderepo are configured:
 537         my $diff;
 538         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 539                 # diffstat anchors do not link across attachments or messages:
 540                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 541                 $ctx->{-apfx} = join('/', @idx);
 542                 $ctx->{-anchors} = {}; # attr => filename
 543                 $diff = 1;
 544                 delete $ctx->{-long_path};
 545                 my $spfx;
 546                 if ($ibx->{-repo_objs}) {
 547                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 548                                 $spfx = $upfx;
 549                                 $spfx =~ s!/([^/]*)/\z!/!;
 550                         } else {
 551                                 my $n_slash = $upfx =~ tr!/!/!;
 552                                 if ($n_slash == 0) {
 553                                         $spfx = '../';
 554                                 } elsif ($n_slash == 1) {
 555                                         $spfx = '';
 556                                 } else { # nslash == 2
 557                                         $spfx = '../../';
 558                                 }
 559                         }
 560                 }
 561                 $ctx->{-spfx} = $spfx;
 562         };
 563
 564         # some editors don't put trailing newlines at the end:
 565         $s .= "\n" unless $s =~ /\n\z/s;
 566
 567         # split off quoted and unquoted blocks:
 568         my @sections = PublicInbox::MsgIter::split_quotes($s);
 569         undef $s; # free memory
 570         my $rv = $ctx->{obuf};
 571         if (defined($fn) || $depth > 0 || $err) {
 572                 # badly-encoded message with $err? tell the world about it!
 573                 attach_link($ctx, $ct, $p, $fn, $err);
 574                 $$rv .= "\n";
 575         }
 576         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 577         foreach my $cur (@sections) {
 578                 if ($cur =~ /\A>/) {
 579                         # we use a <span> here to allow users to specify
 580                         # their own color for quoted text
 581                         $$rv .= qq(<span\nclass="q">);
 582                         $$rv .= $l->to_html($cur);
 583                         $$rv .= '</span>';
 584                 } elsif ($diff) {
 585                         flush_diff($ctx, \$cur);
 586                 } else {
 587                         # regular lines, OK
 588                         $$rv .= $l->to_html($cur);
 589                 }
 590                 undef $cur; # free memory
 591         }
 592
 593         obfuscate_addrs($ibx, $$rv) if $ibx->{obfuscate};
 594 }
 595
 596 sub _msg_page_prepare_obuf {
 597         my ($hdr, $ctx, $nr) = @_;
 598         my $over = $ctx->{-inbox}->over;
 599         my $obfs_ibx = $ctx->{-obfs_ibx};
 600         my $rv = '';
 601         my $mids = mids_for_index($hdr);
 602         if ($nr == 0) {
 603                 if ($ctx->{more}) {
 604                         $rv .=
 605 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 606                 }
 607                 $rv .= "<pre\nid=b>"; # anchor for body start
 608         } else {
 609                 $rv .= '<pre>';
 610         }
 611         if ($over) {
 612                 $ctx->{-upfx} = '../';
 613         }
 614         my @title; # (Subject[0], From[0])
 615         for my $v ($hdr->header('From')) {
 616                 my @n = PublicInbox::Address::names($v);
 617                 $v = ascii_html($v);
 618                 $title[1] //= ascii_html(join(', ', @n));
 619                 if ($obfs_ibx) {
 620                         obfuscate_addrs($obfs_ibx, $v);
 621                         obfuscate_addrs($obfs_ibx, $title[1]);
 622                 }
 623                 $rv .= "From: $v\n" if $v ne '';
 624         }
 625         foreach my $h (qw(To Cc)) {
 626                 for my $v ($hdr->header($h)) {
 627                         fold_addresses($v);
 628                         $v = ascii_html($v);
 629                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 630                         $rv .= "$h: $v\n" if $v ne '';
 631                 }
 632         }
 633         my @subj = $hdr->header('Subject');
 634         if (@subj) {
 635                 my $v = ascii_html(shift @subj);
 636                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 637                 $rv .= 'Subject: ';
 638                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 639                 $title[0] = $v;
 640                 for $v (@subj) { # multi-Subject message :<
 641                         $v = ascii_html($v);
 642                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 643                         $rv .= "Subject: $v\n";
 644                 }
 645         } else { # dummy anchor for thread skeleton at bottom of page
 646                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 647                 $title[0] = '(no subject)';
 648         }
 649         for my $v ($hdr->header('Date')) {
 650                 $v = ascii_html($v);
 651                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 652                 $rv .= "Date: $v\n";
 653         }
 654         $ctx->{-title_html} = join(' - ', @title);
 655         if (scalar(@$mids) == 1) { # common case
 656                 my $mhtml = ascii_html($mids->[0]);
 657                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 658                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 659         } else {
 660                 # X-Alt-Message-ID can happen if a message is injected from
 661                 # public-inbox-nntpd because of multiple Message-ID headers.
 662                 my $lnk = PublicInbox::Linkify->new;
 663                 my $s = '';
 664                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 665                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 666                 }
 667                 $lnk->linkify_mids('..', \$s, 1);
 668                 $rv .= $s;
 669         }
 670         $rv .= _parent_headers($hdr, $over);
 671         $rv .= "\n";
 672         \$rv;
 673 }
 674
 675 sub SKEL_EXPAND () {
 676         qq(expand[<a\nhref="T/#u">flat</a>) .
 677                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 678                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 679                 qq(<a\nhref="t.atom">Atom feed</a>);
 680 }
 681
 682 sub thread_skel ($$$) {
 683         my ($skel, $ctx, $hdr) = @_;
 684         my $mid = mids($hdr)->[0];
 685         my $ibx = $ctx->{-inbox};
 686         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 687         my $parent = in_reply_to($hdr);
 688         $$skel .= "\n<b>Thread overview: </b>";
 689         if ($nr <= 1) {
 690                 if (defined $parent) {
 691                         $$skel .= SKEL_EXPAND."\n ";
 692                         $$skel .= ghost_parent('../', $parent) . "\n";
 693                 } else {
 694                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 695                 }
 696                 $ctx->{next_msg} = undef;
 697                 $ctx->{parent_msg} = $parent;
 698                 return;
 699         }
 700
 701         $$skel .= $nr;
 702         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 703
 704         # nb: mutt only shows the first Subject in the index pane
 705         # when multiple Subject: headers are present, so we follow suit:
 706         my $subj = $hdr->header('Subject') // '';
 707         $subj = '(no subject)' if $subj eq '';
 708         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 709         $ctx->{cur} = $mid;
 710         $ctx->{prev_attr} = '';
 711         $ctx->{prev_level} = 0;
 712         $ctx->{skel} = $skel;
 713
 714         # reduce hash lookups in skel_dump
 715         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 716         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 717
 718         $ctx->{parent_msg} = $parent;
 719 }
 720
 721 sub _parent_headers {
 722         my ($hdr, $over) = @_;
 723         my $rv = '';
 724         my @irt = $hdr->header_raw('In-Reply-To');
 725         my $refs;
 726         if (@irt) {
 727                 my $lnk = PublicInbox::Linkify->new;
 728                 $rv .= "In-Reply-To: $_\n" for @irt;
 729                 $lnk->linkify_mids('..', \$rv);
 730         } else {
 731                 $refs = references($hdr);
 732                 my $irt = pop @$refs;
 733                 if (defined $irt) {
 734                         my $html = ascii_html($irt);
 735                         my $href = mid_href($irt);
 736                         $rv .= "In-Reply-To: &lt;";
 737                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 738                 }
 739         }
 740
 741         # do not display References: if search is present,
 742         # we show the thread skeleton at the bottom, instead.
 743         return $rv if $over;
 744
 745         $refs //= references($hdr);
 746         if (@$refs) {
 747                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 748                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 749         }
 750         $rv;
 751 }
 752
 753 # returns a string buffer via ->getline
 754 sub html_footer {
 755         my ($ctx, $hdr) = @_;
 756         my $ibx = $ctx->{-inbox};
 757         my $upfx = '../';
 758         my $skel = " <a\nhref=\"$upfx\">index</a>";
 759         my $rv = '<pre>';
 760         if ($ibx->over) {
 761                 $skel .= "\n";
 762                 thread_skel(\$skel, $ctx, $hdr);
 763                 my ($next, $prev);
 764                 my $parent = '       ';
 765                 $next = $prev = '    ';
 766
 767                 if (my $n = $ctx->{next_msg}) {
 768                         $n = mid_href($n);
 769                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 770                 }
 771                 my $u;
 772                 my $par = $ctx->{parent_msg};
 773                 if ($par) {
 774                         $u = mid_href($par);
 775                         $u = "$upfx$u/";
 776                 }
 777                 if (my $p = $ctx->{prev_msg}) {
 778                         $prev = mid_href($p);
 779                         if ($p && $par && $p eq $par) {
 780                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 781                                         'rel=prev>prev parent</a>';
 782                                 $parent = '';
 783                         } else {
 784                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 785                                         'rel=prev>prev</a>';
 786                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 787                         }
 788                 } elsif ($u) { # unlikely
 789                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 790                 }
 791                 $rv .= "$next $prev$parent ";
 792         }
 793         $rv .= qq(<a\nhref="#R">reply</a>);
 794         $rv .= $skel;
 795         $rv .= '</pre>';
 796         $rv .= msg_reply($ctx, $hdr);
 797 }
 798
 799 sub linkify_ref_no_over {
 800         my ($mid) = @_;
 801         my $href = mid_href($mid);
 802         my $html = ascii_html($mid);
 803         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 804 }
 805
 806 sub anchor_for {
 807         my ($msgid) = @_;
 808         'm' . id_compress($msgid, 1);
 809 }
 810
 811 sub ghost_parent {
 812         my ($upfx, $mid) = @_;
 813
 814         my $href = mid_href($mid);
 815         my $html = ascii_html($mid);
 816         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 817 }
 818
 819 sub indent_for {
 820         my ($level) = @_;
 821         $level ? INDENT x ($level - 1) : '';
 822 }
 823
 824 sub find_mid_root {
 825         my ($ctx, $level, $node, $idx) = @_;
 826         ++$ctx->{root_idx} if $level == 0;
 827         if ($node->{id} eq $ctx->{mid}) {
 828                 $ctx->{found_mid_at} = $ctx->{root_idx};
 829                 return 0;
 830         }
 831         1;
 832 }
 833
 834 sub strict_loose_note ($) {
 835         my ($nr) = @_;
 836         my $msg =
 837 "  -- strict thread matches above, loose matches on Subject: below --\n";
 838
 839         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 840                 $msg .=
 841 "  -- use mbox.gz link to download all $nr messages --\n";
 842         }
 843         $msg;
 844 }
 845
 846 sub thread_results {
 847         my ($ctx, $msgs) = @_;
 848         require PublicInbox::SearchThread;
 849         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 850
 851         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 852         # and preserved in the future.  This bug is hidden by `sid' matches
 853         # in get_thread, so we never noticed it until now.  And even when
 854         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 855         # bump since reindexing is expensive and users may not do it
 856
 857         # loose threading could've returned too many results,
 858         # put the root the message we care about at the top:
 859         my $mid = $ctx->{mid};
 860         if (defined($mid) && scalar(@$rootset) > 1) {
 861                 $ctx->{root_idx} = -1;
 862                 my $nr = scalar @$msgs;
 863                 walk_thread($rootset, $ctx, \&find_mid_root);
 864                 my $idx = $ctx->{found_mid_at};
 865                 if (defined($idx) && $idx != 0) {
 866                         my $tip = splice(@$rootset, $idx, 1);
 867                         @$rootset = reverse @$rootset;
 868                         unshift @$rootset, $tip;
 869                         $ctx->{sl_note} = strict_loose_note($nr);
 870                 }
 871         }
 872         $rootset
 873 }
 874
 875 sub missing_thread {
 876         my ($ctx) = @_;
 877         require PublicInbox::ExtMsg;
 878         PublicInbox::ExtMsg::ext_msg($ctx);
 879 }
 880
 881 sub dedupe_subject {
 882         my ($prev_subj, $subj, $val) = @_;
 883
 884         my $omit; # '"' denotes identical text omitted
 885         my (@prev_pop, @curr_pop);
 886         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 887                 push(@prev_pop, pop(@$prev_subj));
 888                 push(@curr_pop, pop(@$subj));
 889                 $omit //= $val;
 890         }
 891         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 892         if (scalar(@curr_pop) == 1) {
 893                 $omit = undef;
 894                 push @$prev_subj, @prev_pop;
 895                 push @$subj, @curr_pop;
 896         }
 897         $omit // '';
 898 }
 899
 900 sub skel_dump { # walk_thread callback
 901         my ($ctx, $level, $node) = @_;
 902         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 903
 904         my $skel = $ctx->{skel};
 905         my $cur = $ctx->{cur};
 906         my $mid = $smsg->{mid};
 907
 908         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 909                 $$skel .= delete($ctx->{sl_note}) || '';
 910         }
 911
 912         my $f = ascii_html($smsg->{from_name});
 913         my $obfs_ibx = $ctx->{-obfs_ibx};
 914         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 915
 916         my $d = fmt_ts($smsg->{ds});
 917         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 918         if (exists $ctx->{searchview}) {
 919                 if (defined(my $pct = $smsg->{pct})) {
 920                         $d .= (sprintf(' % 2u', $pct) . '%');
 921                 } else {
 922                         $unmatched = 1;
 923                         $d .= '    ';
 924                 }
 925         }
 926         $d .= ' ' . indent_for($level) . th_pfx($level);
 927         my $attr = $f;
 928         $ctx->{first_level} ||= $level;
 929
 930         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 931                 $ctx->{prev_attr} = $attr;
 932         }
 933         $ctx->{prev_level} = $level;
 934
 935         if ($cur) {
 936                 if ($cur eq $mid) {
 937                         delete $ctx->{cur};
 938                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 939                                  "$attr [this message]</a></b>\n";
 940                         return 1;
 941                 } else {
 942                         $ctx->{prev_msg} = $mid;
 943                 }
 944         } else {
 945                 $ctx->{next_msg} ||= $mid;
 946         }
 947
 948         # Subject is never undef, this mail was loaded from
 949         # our Xapian which would've resulted in '' if it were
 950         # really missing (and Filter rejects empty subjects)
 951         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 952         # remove common suffixes from the subject if it matches the previous,
 953         # so we do not show redundant text at the end.
 954         my $prev_subj = $ctx->{prev_subj} || [];
 955         $ctx->{prev_subj} = [ @subj ];
 956         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 957         my $end;
 958         if (@subj) {
 959                 my $subj = join(' ', @subj);
 960                 $subj = ascii_html($subj);
 961                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 962                 $end = "$subj</a> $omit$f\n"
 963         } else {
 964                 $end = "$f</a>\n";
 965         }
 966         my $m;
 967         my $id = '';
 968         my $mapping = $unmatched ? undef : $ctx->{mapping};
 969         if ($mapping) {
 970                 my $map = $mapping->{$mid};
 971                 $id = id_compress($mid, 1);
 972                 $m = '#m'.$id;
 973                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 974                 $id = "\nid=r".$id;
 975         } else {
 976                 $m = $ctx->{-upfx}.mid_href($mid).'/';
 977         }
 978         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 979         1;
 980 }
 981
 982 sub _skel_ghost {
 983         my ($ctx, $level, $node) = @_;
 984
 985         my $mid = $node->{id};
 986         my $d = '     [not found] ';
 987         $d .= '    '  if exists $ctx->{searchview};
 988         $d .= indent_for($level) . th_pfx($level);
 989         my $upfx = $ctx->{-upfx};
 990         my $href = $upfx . mid_href($mid) . '/';
 991         my $html = ascii_html($mid);
 992
 993         my $mapping = $ctx->{mapping};
 994         my $map = $mapping->{$mid} if $mapping;
 995         if ($map) {
 996                 my $id = id_compress($mid, 1);
 997                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 998                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
 999         } else {
1000                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1001         }
1002         ${$ctx->{skel}} .= $d;
1003         1;
1004 }
1005
1006 sub sort_ds {
1007         [ sort {
1008                 (eval { $a->topmost->{smsg}->{ds} } || 0) <=>
1009                 (eval { $b->topmost->{smsg}->{ds} } || 0)
1010         } @{$_[0]} ];
1011 }
1012
1013 # accumulate recent topics if search is supported
1014 # returns 200 if done, 404 if not
1015 sub acc_topic { # walk_thread callback
1016         my ($ctx, $level, $node) = @_;
1017         my $mid = $node->{id};
1018         my $smsg = $node->{smsg} // $ctx->{-inbox}->smsg_by_mid($mid);
1019         if ($smsg) {
1020                 my $subj = subject_normalized($smsg->{subject});
1021                 $subj = '(no subject)' if $subj eq '';
1022                 my $ds = $smsg->{ds};
1023                 if ($level == 0) { # new, top-level topic
1024                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1025                         $ctx->{-cur_topic} = $topic;
1026                         push @{$ctx->{order}}, $topic;
1027                         return 1;
1028                 }
1029
1030                 # continue existing topic
1031                 my $topic = $ctx->{-cur_topic}; # should never be undef
1032                 $topic->[0] = $ds if $ds > $topic->[0];
1033                 $topic->[1]++; # bump N+ message counter
1034                 my $seen = $topic->[2];
1035                 if (scalar(@$topic) == 3) { # parent was a ghost
1036                         push @$topic, $subj;
1037                 } elsif (!defined($seen->{$subj})) {
1038                         push @$topic, $level, $subj; # @extra messages
1039                 }
1040                 $seen->{$subj} = $mid; # latest for subject
1041         } else { # ghost message
1042                 return 1 if $level != 0; # ignore child ghosts
1043                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1044                 push @{$ctx->{order}}, $topic;
1045         }
1046         1;
1047 }
1048
1049 sub dump_topics {
1050         my ($ctx) = @_;
1051         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1052         unless ($order) {
1053                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1054                 return 404;
1055         }
1056
1057         my @out;
1058         my $ibx = $ctx->{-inbox};
1059         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1060
1061         # sort by recency, this allows new posts to "bump" old topics...
1062         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1063                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1064                 @$topic = ();
1065                 next unless defined $top_subj;  # ghost topic
1066                 my $mid = delete $seen->{$top_subj};
1067                 my $href = mid_href($mid);
1068                 my $prev_subj = [ split(/ /, $top_subj) ];
1069                 $top_subj = ascii_html($top_subj);
1070                 $ds = fmt_ts($ds);
1071
1072                 # $n isn't the total number of posts on the topic,
1073                 # just the number of posts in the current results window
1074                 my $anchor;
1075                 if ($n == 1) {
1076                         $n = '';
1077                         $anchor = '#u'; # top of only message
1078                 } else {
1079                         $n = " ($n+ messages)";
1080                         $anchor = '#t'; # thread skeleton
1081                 }
1082
1083                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1084                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1085                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1086                         " $ds UTC $n - $mbox / $atom\n";
1087                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1088                         my $level = $extra[$i];
1089                         my $subj = $extra[$i + 1]; # already normalized
1090                         $mid = delete $seen->{$subj};
1091                         my @subj = split(/ /, $subj);
1092                         my @next_prev = @subj; # full copy
1093                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1094                         $prev_subj = \@next_prev;
1095                         $subj = ascii_html($subj);
1096                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1097                         $href = mid_href($mid);
1098                         $s .= indent_for($level) . TCHILD;
1099                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1100                 }
1101                 push @out, $s;
1102         }
1103         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1104         200;
1105 }
1106
1107 # only for the t= query parameter passed to overview DB
1108 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1109
1110 sub str2ts ($) {
1111         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1112         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1113 }
1114
1115 sub pagination_footer ($$) {
1116         my ($ctx, $latest) = @_;
1117         delete $ctx->{qp} or return;
1118         my $next = $ctx->{next_page} || '';
1119         my $prev = $ctx->{prev_page} || '';
1120         if ($prev) {
1121                 $next = $next ? "$next " : '     ';
1122                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1123         }
1124         "<hr><pre>page: $next$prev</pre>";
1125 }
1126
1127 sub index_nav { # callback for WwwStream
1128         my (undef, $ctx) = @_;
1129         pagination_footer($ctx, '.')
1130 }
1131
1132 sub paginate_recent ($$) {
1133         my ($ctx, $lim) = @_;
1134         my $t = $ctx->{qp}->{t} || '';
1135         my $opts = { limit => $lim };
1136         my ($after, $before);
1137
1138         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1139         # if only $after exists "YYYYMMDD.." because "." could be skipped
1140         # if interpreted as an end-of-sentence
1141         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1142         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1143
1144         my $ibx = $ctx->{-inbox};
1145         my $msgs = $ibx->recent($opts, $after, $before);
1146         my $nr = scalar @$msgs;
1147         if ($nr < $lim && defined($after)) {
1148                 $after = $before = undef;
1149                 $msgs = $ibx->recent($opts);
1150                 $nr = scalar @$msgs;
1151         }
1152         my $more = $nr == $lim;
1153         my ($newest, $oldest);
1154         if ($nr) {
1155                 $newest = $msgs->[0]->{ts};
1156                 $oldest = $msgs->[-1]->{ts};
1157                 # if we only had $after, our SQL query in ->recent ordered
1158                 if ($newest < $oldest) {
1159                         ($oldest, $newest) = ($newest, $oldest);
1160                         $more = 0 if defined($after) && $after < $oldest;
1161                 }
1162         }
1163         if (defined($oldest) && $more) {
1164                 my $s = ts2str($oldest);
1165                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1166         }
1167         if (defined($newest) && (defined($before) || defined($after))) {
1168                 my $s = ts2str($newest);
1169                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1170         }
1171         $msgs;
1172 }
1173
1174 sub index_topics {
1175         my ($ctx) = @_;
1176         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1177         if (@$msgs) {
1178                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1179         }
1180         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), \&index_nav);
1181 }
1182
1183 sub thread_adj_level {
1184         my ($ctx, $level) = @_;
1185
1186         my $max = $ctx->{cur_level};
1187         if ($level <= 0) {
1188                 return ('', '') if $max == 0; # flat output
1189
1190                 # reset existing lists
1191                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1192                 $ctx->{cur_level} = 0;
1193                 ("$beg</ul>", '');
1194         } elsif ($level == $max) { # continue existing list
1195                 qw(<li> </li>);
1196         } elsif ($level < $max) {
1197                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1198                 $ctx->{cur_level} = $level;
1199                 ("$beg<li>", '</li>');
1200         } else { # ($level > $max) # start a new level
1201                 $ctx->{cur_level} = $level;
1202                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1203                 ($beg, '</li>');
1204         }
1205 }
1206
1207 sub ghost_index_entry {
1208         my ($ctx, $level, $node) = @_;
1209         my ($beg, $end) = thread_adj_level($ctx,  $level);
1210         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1211                 . '</pre>' . $end;
1212 }
1213
1214 1;