lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Hval;
   7 use URI::Escape qw/uri_escape/;
   8 use CGI qw/escapeHTML/;
   9 use Encode qw/find_encoding/;
  10 use Encode::MIME::Header;
  11 use Email::MIME::ContentType qw/parse_content_type/;
  12 use constant MAX_INLINE_QUOTED => 5;
  13 use constant MAX_TRUNC_LEN => 72;
  14
  15 my $enc_utf8 = find_encoding('utf8');
  16 my $enc_ascii = find_encoding('us-ascii');
  17 my $enc_mime = find_encoding('MIME-Header');
  18
  19 # public functions:
  20 sub as_html {
  21         my ($class, $mime, $full_pfx) = @_;
  22
  23         headers_to_html_header($mime, $full_pfx) .
  24                 multipart_text_as_html($mime, $full_pfx) .
  25                 '</pre></body></html>';
  26 }
  27
  28 sub as_feed_entry {
  29         my ($class, $mime, $full_pfx) = @_;
  30
  31         "<pre>" . multipart_text_as_html($mime, $full_pfx) . "</pre>";
  32 }
  33
  34
  35 # only private functions below.
  36
  37 sub enc_for {
  38         my ($ct) = @_;
  39         defined $ct or return $enc_utf8;
  40         my $ct_parsed = parse_content_type($ct);
  41         if ($ct_parsed) {
  42                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
  43                         my $enc = find_encoding($charset);
  44                         return $enc if $enc;
  45                 }
  46         }
  47         $enc_utf8;
  48 }
  49
  50 sub multipart_text_as_html {
  51         my ($mime, $full_pfx) = @_;
  52         my $rv = "";
  53         my $part_nr = 0;
  54         my $enc_msg = enc_for($mime->header("Content-Type"));
  55
  56         # scan through all parts, looking for displayable text
  57         $mime->walk_parts(sub {
  58                 my ($part) = @_;
  59                 return if $part->subparts; # walk_parts already recurses
  60                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  61
  62                 if ($part_nr > 0) {
  63                         my $fn = $part->filename;
  64                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  65                         $rv .= add_filename_line($enc->decode($fn));
  66                 }
  67
  68                 if (defined $full_pfx) {
  69                         $rv .= add_text_body_short($enc, $part, $part_nr,
  70                                                 $full_pfx);
  71                 } else {
  72                         $rv .= add_text_body_full($enc, $part, $part_nr);
  73                 }
  74                 $rv .= "\n" unless $rv =~ /\n\z/s;
  75                 ++$part_nr;
  76         });
  77         $rv;
  78 }
  79
  80 sub add_filename_line {
  81         my ($fn) = @_;
  82         my $len = 72;
  83         my $pad = "-";
  84
  85         $len -= length($fn);
  86         $pad x= ($len/2) if ($len > 0);
  87         "$pad " . ascii_html($fn) . " $pad\n";
  88 }
  89
  90 sub add_text_body_short {
  91         my ($enc, $part, $part_nr, $full_pfx) = @_;
  92         my $n = 0;
  93         my $s = ascii_html($enc->decode($part->body));
  94         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
  95                 my $cur = $1;
  96                 my @lines = split(/\n/, $cur);
  97                 if (@lines > MAX_INLINE_QUOTED) {
  98                         # show a short snippet of quoted text
  99                         $cur = join(' ', @lines);
 100                         $cur =~ s/^&gt;\s*//;
 101
 102                         my @sum = split(/\s+/, $cur);
 103                         $cur = '';
 104                         do {
 105                                 my $tmp = shift(@sum);
 106                                 my $len = length($tmp) + length($cur);
 107                                 if ($len > MAX_TRUNC_LEN) {
 108                                         @sum = ();
 109                                 } else {
 110                                         $cur .= $tmp . ' ';
 111                                 }
 112                         } while (@sum && length($cur) < MAX_TRUNC_LEN);
 113                         $cur =~ s/ \z/ .../;
 114                         "&gt; &lt;<a href=\"${full_pfx}#q${part_nr}_" . $n++ .
 115                                 "\">$cur<\/a>&gt;\n";
 116                 } else {
 117                         $cur;
 118                 }
 119         !emg;
 120         $s;
 121 }
 122
 123 sub add_text_body_full {
 124         my ($enc, $part, $part_nr) = @_;
 125         my $n = 0;
 126         my $s = ascii_html($enc->decode($part->body));
 127         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 128                 my $cur = $1;
 129                 my @lines = split(/\n/, $cur);
 130                 if (@lines > MAX_INLINE_QUOTED) {
 131                         "<a name=q${part_nr}_" . $n++ . ">$cur</a>";
 132                 } else {
 133                         $cur;
 134                 }
 135         !emg;
 136         $s;
 137 }
 138
 139 sub ascii_html {
 140         $enc_ascii->encode(escapeHTML($_[0]), Encode::HTMLCREF);
 141 }
 142
 143 sub headers_to_html_header {
 144         my ($simple, $full_pfx) = @_;
 145
 146         my $rv = "";
 147         my @title;
 148         foreach my $h (qw(From To Cc Subject Date)) {
 149                 my $v = $simple->header($h);
 150                 defined $v or next;
 151                 $v =~ tr/\n/ /s;
 152                 $v =~ tr/\r//d;
 153                 my $raw = $enc_mime->decode($v);
 154                 $v = ascii_html($raw);
 155                 $rv .= "$h: $v\n";
 156
 157                 if ($h eq 'From') {
 158                         my @from = Email::Address->parse($raw);
 159                         $raw = $from[0]->name;
 160                         unless (defined($raw) && length($raw)) {
 161                                 $raw = '<' . $from[0]->address . '>';
 162                         }
 163                         $title[1] = ascii_html($raw);
 164
 165                 } elsif ($h eq 'Subject') {
 166                         $title[0] = $v;
 167                 }
 168         }
 169
 170         my $mid = $simple->header('Message-ID');
 171         if (defined $mid) {
 172                 $mid = PublicInbox::Hval->new_msgid($mid);
 173                 $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 174                 my $href = $mid->as_href;
 175                 $href = "../m/$href" unless $full_pfx;
 176                 $rv .= "(<a href=\"$href.txt\">original</a>)\n";
 177         }
 178
 179         my $irp = $simple->header('In-Reply-To');
 180         if (defined $irp) {
 181                 $irp = PublicInbox::Hval->new_msgid($irp);
 182                 my $html = $irp->as_html;
 183                 my $href = $irp->as_href;
 184                 $rv .= "In-Reply-To: &lt;";
 185                 $rv .= "<a href=\"$href.html\">$html</a>&gt;\n";
 186         }
 187         $rv .= "\n";
 188
 189         ("<html><head><title>".  join(' - ', @title) .
 190          '</title></head><body><pre style="white-space:pre-wrap">' .  $rv);
 191 }
 192
 193 1;