lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Hval;
   7 use URI::Escape qw/uri_escape_utf8/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 require POSIX;
  12
  13 # TODO: make these constants tunable
  14 use constant MAX_INLINE_QUOTED => 12; # half an 80x24 terminal
  15 use constant MAX_TRUNC_LEN => 72;
  16 use constant PRE_WRAP => '<pre style="white-space:pre-wrap">';
  17
  18 *ascii_html = *PublicInbox::Hval::ascii_html;
  19
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 my $enc_mime = find_encoding('MIME-Header');
  22
  23 # public functions:
  24 sub msg_html {
  25         my ($class, $mime, $full_pfx, $footer) = @_;
  26         if (defined $footer) {
  27                 $footer = "\n" . $footer;
  28         } else {
  29                 $footer = '';
  30         }
  31         headers_to_html_header($mime, $full_pfx) .
  32                 multipart_text_as_html($mime, $full_pfx) .
  33                 '</pre><hr />' . PRE_WRAP .
  34                 html_footer($mime, 1) . $footer .
  35                 '</pre></body></html>';
  36 }
  37
  38 sub feed_entry {
  39         my ($class, $mime, $full_pfx) = @_;
  40
  41         PRE_WRAP . multipart_text_as_html($mime, $full_pfx) . '</pre>';
  42 }
  43
  44 # this is already inside a <pre>
  45 sub index_entry {
  46         my ($class, $mime, $now, $level, $seen) = @_;
  47         my $rv = "";
  48         my $part_nr = 0;
  49         my $enc_msg = enc_for($mime->header("Content-Type"));
  50         my $subj = $mime->header('Subject');
  51         my $header_obj = $mime->header_obj;
  52
  53         my $mid_raw = $header_obj->header_raw('Message-ID');
  54         my $name = anchor_for($mid_raw);
  55         $seen->{$name} = "#$name"; # save the anchor for later
  56
  57         my $mid = PublicInbox::Hval->new_msgid($mid_raw);
  58         my $from = PublicInbox::Hval->new_oneline($mime->header('From'))->raw;
  59         my @from = Email::Address->parse($from);
  60         $from = $from[0]->name;
  61         (defined($from) && length($from)) or $from = $from[0]->address;
  62
  63         $from = PublicInbox::Hval->new_oneline($from)->as_html;
  64         $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
  65         my $pfx = ('  ' x $level);
  66
  67         my $ts = $mime->header('X-PI-Date');
  68         my $fmt = '%H:%M';
  69         if ($now > ($ts + (365 * 24 * 60 * 60))) {
  70                 # doesn't have to be exactly 1 year
  71                 $fmt = '%Y/%m/%d';
  72         } elsif ($now > ($ts + (24 * 60 * 60))) {
  73                 $fmt = '%m/%d';
  74         }
  75         $ts = POSIX::strftime($fmt, gmtime($ts));
  76
  77         $rv .= "$pfx<a name=\"$name\"><b>$subj</b> $from - $ts</a>\n\n";
  78
  79         my $irp = $header_obj->header_raw('In-Reply-To');
  80         my ($anchor_idx, $anchor);
  81         if (defined $irp) {
  82                 $anchor_idx = anchor_for($irp);
  83                 $anchor = $seen->{$anchor_idx};
  84         }
  85         my $href = $mid->as_href;
  86         my $mhref = "m/$href.html";
  87         my $fhref = "f/$href.html";
  88         my $more = 'link';
  89         # scan through all parts, looking for displayable text
  90         $mime->walk_parts(sub {
  91                 my ($part) = @_;
  92                 return if $part->subparts; # walk_parts already recurses
  93                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  94
  95                 if ($part_nr > 0) {
  96                         my $fn = $part->filename;
  97                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  98                         $rv .= $pfx . add_filename_line($enc->decode($fn));
  99                 }
 100
 101                 my $s = add_text_body_short($enc, $part, $part_nr, $fhref);
 102
 103                 # keep signatures for now?  They shold usually be short,
 104                 # and sometimes footnotes/"P.S." appear there.
 105
 106                 # drop the remainder of git patches, they're usually better
 107                 # to review when the full message is viewed
 108                 $s =~ s!^---\n.*\z!!ms and $more = 'more...';
 109
 110                 # kill any leading or trailing whitespace
 111                 $s =~ s/\A\s+//s;
 112                 $s =~ s/\s+\z//s;
 113
 114                 if (length $s) {
 115                         # add prefix:
 116                         $s =~ s/^/$pfx/sgm;
 117
 118                         $rv .= $s . "\n";
 119                 }
 120                 ++$part_nr;
 121         });
 122
 123         $rv .= "$pfx<a\nhref=\"$mhref\">$more</a> ";
 124         my $txt = "m/$href.txt";
 125         $rv .= "<a\nhref=\"$txt\">raw</a> ";
 126         $rv .= html_footer($mime, 0);
 127
 128         if (defined $irp) {
 129                 unless (defined $anchor) {
 130                         my $v = PublicInbox::Hval->new_msgid($irp);
 131                         my $html = $v->as_html;
 132                         $anchor = 'm/' . $v->as_href . '.html';
 133                         $seen->{$anchor_idx} = $anchor;
 134                 }
 135                 $rv .= " <a\nhref=\"$anchor\">parent</a>";
 136         }
 137
 138         $rv . "\n\n";
 139 }
 140
 141 # only private functions below.
 142
 143 sub enc_for {
 144         my ($ct) = @_;
 145         defined $ct or return $enc_utf8;
 146         my $ct_parsed = parse_content_type($ct);
 147         if ($ct_parsed) {
 148                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
 149                         my $enc = find_encoding($charset);
 150                         return $enc if $enc;
 151                 }
 152         }
 153         $enc_utf8;
 154 }
 155
 156 sub multipart_text_as_html {
 157         my ($mime, $full_pfx) = @_;
 158         my $rv = "";
 159         my $part_nr = 0;
 160         my $enc_msg = enc_for($mime->header("Content-Type"));
 161
 162         # scan through all parts, looking for displayable text
 163         $mime->walk_parts(sub {
 164                 my ($part) = @_;
 165                 return if $part->subparts; # walk_parts already recurses
 166                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
 167
 168                 if ($part_nr > 0) {
 169                         my $fn = $part->filename;
 170                         defined($fn) or $fn = "part #" . ($part_nr + 1);
 171                         $rv .= add_filename_line($enc->decode($fn));
 172                 }
 173
 174                 if (defined $full_pfx) {
 175                         $rv .= add_text_body_short($enc, $part, $part_nr,
 176                                                 $full_pfx);
 177                 } else {
 178                         $rv .= add_text_body_full($enc, $part, $part_nr);
 179                 }
 180                 $rv .= "\n" unless $rv =~ /\n\z/s;
 181                 ++$part_nr;
 182         });
 183         $rv;
 184 }
 185
 186 sub add_filename_line {
 187         my ($fn) = @_;
 188         my $len = 72;
 189         my $pad = "-";
 190
 191         $len -= length($fn);
 192         $pad x= ($len/2) if ($len > 0);
 193         "$pad " . ascii_html($fn) . " $pad\n";
 194 }
 195
 196 sub add_text_body_short {
 197         my ($enc, $part, $part_nr, $full_pfx) = @_;
 198         my $n = 0;
 199         my $s = ascii_html($enc->decode($part->body));
 200         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 201                 my $cur = $1;
 202                 my @lines = split(/\n/, $cur);
 203                 if (@lines > MAX_INLINE_QUOTED) {
 204                         # show a short snippet of quoted text
 205                         $cur = join(' ', @lines);
 206                         $cur =~ s/^&gt;\s*//;
 207
 208                         my @sum = split(/\s+/, $cur);
 209                         $cur = '';
 210                         do {
 211                                 my $tmp = shift(@sum);
 212                                 my $len = length($tmp) + length($cur);
 213                                 if ($len > MAX_TRUNC_LEN) {
 214                                         @sum = ();
 215                                 } else {
 216                                         $cur .= $tmp . ' ';
 217                                 }
 218                         } while (@sum && length($cur) < MAX_TRUNC_LEN);
 219                         $cur =~ s/ \z/ .../;
 220                         "&gt; &lt;<a href=\"${full_pfx}#q${part_nr}_" . $n++ .
 221                                 "\">$cur<\/a>&gt;\n";
 222                 } else {
 223                         $cur;
 224                 }
 225         !emg;
 226         $s;
 227 }
 228
 229 sub add_text_body_full {
 230         my ($enc, $part, $part_nr) = @_;
 231         my $n = 0;
 232         my $s = ascii_html($enc->decode($part->body));
 233         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 234                 my $cur = $1;
 235                 my @lines = split(/\n/, $cur);
 236                 if (@lines > MAX_INLINE_QUOTED) {
 237                         "<a name=q${part_nr}_" . $n++ . ">$cur</a>";
 238                 } else {
 239                         $cur;
 240                 }
 241         !emg;
 242         $s;
 243 }
 244
 245 sub headers_to_html_header {
 246         my ($mime, $full_pfx) = @_;
 247
 248         my $rv = "";
 249         my @title;
 250         foreach my $h (qw(From To Cc Subject Date)) {
 251                 my $v = $mime->header($h);
 252                 defined($v) && length($v) or next;
 253                 $v = PublicInbox::Hval->new_oneline($v);
 254                 $rv .= "$h: " . $v->as_html . "\n";
 255
 256                 if ($h eq 'From') {
 257                         my @from = Email::Address->parse($v->raw);
 258                         $v = $from[0]->name;
 259                         unless (defined($v) && length($v)) {
 260                                 $v = '<' . $from[0]->address . '>';
 261                         }
 262                         $title[1] = ascii_html($v);
 263                 } elsif ($h eq 'Subject') {
 264                         $title[0] = $v->as_html;
 265                 }
 266         }
 267
 268         my $header_obj = $mime->header_obj;
 269         my $mid = $header_obj->header_raw('Message-ID');
 270         if (defined $mid) {
 271                 $mid = PublicInbox::Hval->new_msgid($mid);
 272                 $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 273                 my $href = $mid->as_href;
 274                 $href = "../m/$href" unless $full_pfx;
 275                 $rv .= "(<a href=\"$href.txt\">original</a>)\n";
 276         }
 277
 278         my $irp = $header_obj->header_raw('In-Reply-To');
 279         if (defined $irp) {
 280                 my $v = PublicInbox::Hval->new_msgid(my $tmp = $irp);
 281                 my $html = $v->as_html;
 282                 my $href = $v->as_href;
 283                 $rv .= "In-Reply-To: &lt;";
 284                 $rv .= "<a href=\"$href.html\">$html</a>&gt;\n";
 285         }
 286
 287         my $refs = $header_obj->header_raw('References');
 288         if ($refs) {
 289                 $refs =~ s/\s*\Q$irp\E\s*// if (defined $irp);
 290                 my @refs = ($refs =~ /<([^>]+)>/g);
 291                 if (@refs) {
 292                         $rv .= 'References: '. linkify_refs(@refs) . "\n";
 293                 }
 294         }
 295
 296         $rv .= "\n";
 297
 298         ("<html><head><title>".  join(' - ', @title) .
 299          '</title></head><body>' . PRE_WRAP . $rv);
 300 }
 301
 302 sub html_footer {
 303         my ($mime, $purge) = @_;
 304         my %cc; # everyone else
 305         my $to; # this is the From address
 306
 307         foreach my $h (qw(From To Cc)) {
 308                 my $v = $mime->header($h);
 309                 defined($v) && length($v) or next;
 310                 my @addrs = Email::Address->parse($v);
 311                 foreach my $recip (@addrs) {
 312                         my $address = $recip->address;
 313                         my $dst = lc($address);
 314                         $cc{$dst} ||= $address;
 315                         $to ||= $dst;
 316                 }
 317         }
 318         Email::Address->purge_cache if $purge;
 319
 320         my $subj = $mime->header('Subject') || '';
 321         $subj = "Re: $subj" unless $subj =~ /\bRe:/;
 322         my $irp = uri_escape_utf8(
 323                         $mime->header_obj->header_raw('Message-ID') || '');
 324         delete $cc{$to};
 325         $to = uri_escape_utf8($to);
 326         $subj = uri_escape_utf8($subj);
 327
 328         my $cc = uri_escape_utf8(join(',', values %cc));
 329         my $href = "mailto:$to?In-Reply-To=$irp&Cc=${cc}&Subject=$subj";
 330
 331         "<a\nhref=\"" . ascii_html($href) . '">reply</a>';
 332 }
 333
 334 sub linkify_refs {
 335         join(' ', map {
 336                 my $v = PublicInbox::Hval->new_msgid($_);
 337                 my $html = $v->as_html;
 338                 my $href = $v->as_href;
 339                 "&lt;<a href=\"$href.html\">$html</a>&gt;";
 340         } @_);
 341 }
 342
 343 require Digest::SHA;
 344 sub anchor_for {
 345         my ($msgid) = @_;
 346         $msgid =~ s/\A\s*<?//;
 347         $msgid =~ s/>?\s*\z//;
 348         Digest::SHA::sha1_hex($msgid);
 349 }
 350
 351 1;