lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use URI::Escape qw/uri_escape_utf8/;
   7 use Date::Parse qw/str2time/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 use PublicInbox::Hval;
  12 use PublicInbox::MID qw/mid_clean mid_compressed mid2path/;
  13 use Digest::SHA;
  14 require POSIX;
  15
  16 # TODO: make these constants tunable
  17 use constant MAX_INLINE_QUOTED => 12; # half an 80x24 terminal
  18 use constant MAX_TRUNC_LEN => 72;
  19 use constant PRE_WRAP => "<pre\nstyle=\"white-space:pre-wrap\">";
  20 use constant T_ANCHOR => '#u';
  21
  22 *ascii_html = *PublicInbox::Hval::ascii_html;
  23
  24 my $enc_utf8 = find_encoding('UTF-8');
  25
  26 # public functions:
  27 sub msg_html {
  28         my ($class, $mime, $full_pfx, $footer, $srch) = @_;
  29         if (defined $footer) {
  30                 $footer = "\n" . $footer;
  31         } else {
  32                 $footer = '';
  33         }
  34         headers_to_html_header($mime, $full_pfx, $srch) .
  35                 multipart_text_as_html($mime, $full_pfx) .
  36                 '</pre><hr /><pre>' .
  37                 html_footer($mime, 1, $full_pfx, $srch) .
  38                 $footer .
  39                 '</pre></body></html>';
  40 }
  41
  42 sub feed_entry {
  43         my ($class, $mime, $full_pfx) = @_;
  44
  45         PRE_WRAP . multipart_text_as_html($mime, $full_pfx) . '</pre>';
  46 }
  47
  48 # this is already inside a <pre>
  49 # state = [ time, seen = {}, first_commit, page_nr = 0 ]
  50 sub index_entry {
  51         my ($fh, $mime, $level, $state) = @_;
  52         my ($srch, $seen, $first_commit) = @$state;
  53         my $midx = $state->[3]++;
  54         my ($prev, $next) = ($midx - 1, $midx + 1);
  55         my $part_nr = 0;
  56         my $enc = enc_for($mime->header("Content-Type"));
  57         my $subj = $mime->header('Subject');
  58         my $header_obj = $mime->header_obj;
  59
  60         my $mid_raw = $header_obj->header('Message-ID');
  61         my $id = anchor_for($mid_raw);
  62         $seen->{$id} = "#$id"; # save the anchor for later
  63
  64         my $mid = PublicInbox::Hval->new_msgid($mid_raw);
  65         my $from = PublicInbox::Hval->new_oneline($mime->header('From'))->raw;
  66         my @from = Email::Address->parse($from);
  67         $from = $from[0]->name;
  68         (defined($from) && length($from)) or $from = $from[0]->address;
  69
  70         $from = PublicInbox::Hval->new_oneline($from)->as_html;
  71         $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
  72         my $root_anchor = $seen->{root_anchor};
  73         my $more = 'permalink';
  74         my $path = $root_anchor ? '../' : '';
  75         my $href = $mid->as_href;
  76         my $irt = $header_obj->header('In-Reply-To');
  77         my ($anchor_idx, $anchor, $t_anchor);
  78         if (defined $irt) {
  79                 $anchor_idx = anchor_for($irt);
  80                 $anchor = $seen->{$anchor_idx};
  81                 $t_anchor = T_ANCHOR;
  82         } else {
  83                 $t_anchor = '';
  84         }
  85         if (defined $srch) {
  86                 $subj = "<a\nhref=\"${path}t/$href.html#u\">$subj</a>";
  87         }
  88         if ($root_anchor && $root_anchor eq $id) {
  89                 $subj = "<u\nid=\"u\">$subj</u>";
  90         }
  91
  92         my $ts = $mime->header('X-PI-TS');
  93         unless (defined $ts) {
  94                 $ts = msg_timestamp($mime);
  95         }
  96         my $fmt = '%Y-%m-%d %H:%M';
  97         $ts = POSIX::strftime($fmt, gmtime($ts));
  98
  99         my $rv = "<table\nsummary=l$level><tr>";
 100         if ($level) {
 101                 $rv .= '<td><pre>' . ('  ' x $level) . '</pre></td>';
 102         }
 103         $rv .= "<td\nid=s$midx>" . PRE_WRAP;
 104         $rv .= "<b\nid=\"$id\">$subj</b>\n";
 105         $rv .= "- by $from @ $ts UTC - ";
 106         $rv .= "<a\nhref=\"#s$next\">next</a>";
 107         if ($prev >= 0) {
 108                 $rv .= "/<a\nhref=\"#s$prev\">prev</a>";
 109         }
 110         $fh->write($rv .= "\n\n");
 111
 112         my ($fhref, $more_ref);
 113         my $mhref = "${path}m/$href.html";
 114         if ($level > 0) {
 115                 $fhref = "${path}f/$href.html";
 116                 $more_ref = \$more;
 117         }
 118         # scan through all parts, looking for displayable text
 119         $mime->walk_parts(sub {
 120                 index_walk($fh, $_[0], $enc, \$part_nr, $fhref, $more_ref);
 121         });
 122         $mime->body_set('');
 123
 124         my $txt = "${path}m/$href.txt";
 125         $rv = "\n<a\nhref=\"$mhref\">$more</a> <a\nhref=\"$txt\">raw</a> ";
 126         $rv .= html_footer($mime, 0);
 127
 128         if (defined $irt) {
 129                 unless (defined $anchor) {
 130                         my $v = PublicInbox::Hval->new_msgid($irt);
 131                         $v = $v->as_href;
 132                         $anchor = "${path}m/$v.html";
 133                         $seen->{$anchor_idx} = $anchor;
 134                 }
 135                 $rv .= " <a\nhref=\"$anchor\">parent</a>";
 136         }
 137
 138         if ($srch) {
 139                 $rv .= " <a\nhref=\"${path}t/$href.html$t_anchor\">" .
 140                        "threadlink</a>";
 141         }
 142
 143         $fh->write($rv .= '</pre></td></tr></table>');
 144 }
 145
 146 sub thread_html {
 147         my ($ctx, $foot, $srch) = @_;
 148         sub { emit_thread_html($_[0], $ctx, $foot, $srch) }
 149 }
 150
 151 # only private functions below.
 152
 153 sub emit_thread_html {
 154         my ($cb, $ctx, $foot, $srch) = @_;
 155         my $mid = mid_compressed($ctx->{mid});
 156         my $res = $srch->get_thread($mid);
 157         my $msgs = load_results($res);
 158         my $nr = scalar @$msgs;
 159         return missing_thread($cb) if $nr == 0;
 160         my $fh = $cb->([200,['Content-Type'=>'text/html; charset=UTF-8']]);
 161         my $th = thread_results($msgs);
 162         my $state = [ $srch, { root_anchor => anchor_for($mid) }, undef, 0 ];
 163         {
 164                 require PublicInbox::GitCatFile;
 165                 my $git = PublicInbox::GitCatFile->new($ctx->{git_dir});
 166                 thread_entry($fh, $git, $state, $_, 0) for $th->rootset;
 167         }
 168         my $final_anchor = $state->[3];
 169         my $next = "<a\nid=\"s$final_anchor\">";
 170
 171         if ($final_anchor == 1) {
 172                 $next .= 'only message in thread';
 173         } else {
 174                 $next .= 'end of thread';
 175         }
 176         $next .= "</a>, back to <a\nhref=\"../\">index</a>\n";
 177
 178         $fh->write("<hr />" . PRE_WRAP . $next . $foot .
 179                    "</pre></body></html>");
 180         $fh->close;
 181 }
 182
 183 sub index_walk {
 184         my ($fh, $part, $enc, $part_nr, $fhref, $more) = @_;
 185         my $s = add_text_body($enc, $part, $part_nr, $fhref);
 186
 187         if ($more) {
 188                 # drop the remainder of git patches, they're usually better
 189                 # to review when the full message is viewed
 190                 $s =~ s!^---+\n.*\z!!ms and $$more = 'more...';
 191
 192                 # Drop signatures
 193                 $s =~ s/^-- \n.*\z//ms and $$more = 'more...';
 194         }
 195
 196         # kill any leading or trailing whitespace lines
 197         $s =~ s/^\s*$//sgm;
 198         $s =~ s/\s+\z//s;
 199
 200         if (length $s) {
 201                 # kill per-line trailing whitespace
 202                 $s =~ s/[ \t]+$//sgm;
 203                 $s .= "\n" unless $s =~ /\n\z/s;
 204         }
 205         $fh->write($s);
 206 }
 207
 208 sub enc_for {
 209         my ($ct, $default) = @_;
 210         $default ||= $enc_utf8;
 211         defined $ct or return $default;
 212         my $ct_parsed = parse_content_type($ct);
 213         if ($ct_parsed) {
 214                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
 215                         my $enc = find_encoding($charset);
 216                         return $enc if $enc;
 217                 }
 218         }
 219         $default;
 220 }
 221
 222 sub multipart_text_as_html {
 223         my ($mime, $full_pfx, $srch) = @_;
 224         my $rv = "";
 225         my $part_nr = 0;
 226         my $enc = enc_for($mime->header("Content-Type"));
 227
 228         # scan through all parts, looking for displayable text
 229         $mime->walk_parts(sub {
 230                 my ($part) = @_;
 231                 $rv .= add_text_body($enc, $part, \$part_nr, $full_pfx);
 232         });
 233         $mime->body_set('');
 234         $rv;
 235 }
 236
 237 sub add_filename_line {
 238         my ($enc, $fn) = @_;
 239         my $len = 72;
 240         my $pad = "-";
 241         $fn = $enc->decode($fn);
 242         $len -= length($fn);
 243         $pad x= ($len/2) if ($len > 0);
 244         "$pad " . ascii_html($fn) . " $pad\n";
 245 }
 246
 247 my $LINK_RE = qr!\b((?:ftp|https?|nntp)://[@\w\+\&\?\.\%\;/#=-]+)!;
 248
 249 sub linkify {
 250         # no newlines added here since it'd break the splitting we do
 251         # to fold quotes
 252         $_[0] =~ s!$LINK_RE!<a\nhref="$1">$1</a>!g;
 253 }
 254
 255 sub flush_quote {
 256         my ($quot, $n, $part_nr, $full_pfx, $final) = @_;
 257
 258         if ($full_pfx) {
 259                 if (!$final && scalar(@$quot) <= MAX_INLINE_QUOTED) {
 260                         # show quote inline
 261                         my $rv = join("\n", map { linkify($_); $_ } @$quot);
 262                         @$quot = ();
 263                         return $rv . "\n";
 264                 }
 265
 266                 # show a short snippet of quoted text and link to full version:
 267                 @$quot = map { s/^(?:&gt;\s*)+//gm; $_ } @$quot;
 268                 my $cur = join(' ', @$quot);
 269                 @$quot = split(/\s+/, $cur);
 270                 $cur = '';
 271                 do {
 272                         my $tmp = shift(@$quot);
 273                         my $len = length($tmp) + length($cur);
 274                         if ($len > MAX_TRUNC_LEN) {
 275                                 @$quot = ();
 276                         } else {
 277                                 $cur .= $tmp . ' ';
 278                         }
 279                 } while (@$quot && length($cur) < MAX_TRUNC_LEN);
 280                 @$quot = ();
 281                 $cur =~ s/ \z/ .../s;
 282                 my $nr = ++$$n;
 283                 "&gt; [<a\nhref=\"$full_pfx#q${part_nr}_$nr\">$cur</a>]\n";
 284         } else {
 285                 # show everything in the full version with anchor from
 286                 # short version (see above)
 287                 my $nr = ++$$n;
 288                 my $rv = "<a\nid=q${part_nr}_$nr></a>";
 289                 $rv .= join("\n", map { linkify($_); $_ } @$quot) . "\n";
 290                 @$quot = ();
 291                 $rv;
 292         }
 293 }
 294
 295 sub add_text_body {
 296         my ($enc_msg, $part, $part_nr, $full_pfx) = @_;
 297         return '' if $part->subparts;
 298
 299         my $ct = $part->content_type;
 300         # account for filter bugs...
 301         if (defined $ct && $ct =~ m!\btext/[xh]+tml\b!i) {
 302                 $part->body_set('');
 303                 return '';
 304         }
 305         my $enc = enc_for($ct, $enc_msg);
 306         my $n = 0;
 307         my $nr = 0;
 308         my $s = $part->body;
 309         $part->body_set('');
 310         $s = $enc->decode($s);
 311         $s = ascii_html($s);
 312         my @lines = split(/\n/, $s);
 313         $s = '';
 314
 315         if ($$part_nr > 0) {
 316                 my $fn = $part->filename;
 317                 defined($fn) or $fn = "part #" . ($$part_nr + 1);
 318                 $s .= add_filename_line($enc, $fn);
 319         }
 320
 321         my @quot;
 322         while (defined(my $cur = shift @lines)) {
 323                 if ($cur !~ /^&gt;/) {
 324                         # show the previously buffered quote inline
 325                         if (scalar @quot) {
 326                                 $s .= flush_quote(\@quot, \$n, $$part_nr,
 327                                                   $full_pfx, 0);
 328                         }
 329
 330                         # regular line, OK
 331                         linkify($cur);
 332                         $s .= $cur;
 333                         $s .= "\n";
 334                 } else {
 335                         push @quot, $cur;
 336                 }
 337         }
 338         $s .= flush_quote(\@quot, \$n, $$part_nr, $full_pfx, 1) if scalar @quot;
 339         $s .= "\n" unless $s =~ /\n\z/s;
 340         ++$$part_nr;
 341         $s;
 342 }
 343
 344 sub headers_to_html_header {
 345         my ($mime, $full_pfx, $srch) = @_;
 346
 347         my $rv = "";
 348         my @title;
 349         my $header_obj = $mime->header_obj;
 350         my $mid = $header_obj->header('Message-ID');
 351         $mid = PublicInbox::Hval->new_msgid($mid);
 352         my $mid_href = $mid->as_href;
 353         foreach my $h (qw(From To Cc Subject Date)) {
 354                 my $v = $mime->header($h);
 355                 defined($v) && length($v) or next;
 356                 $v = PublicInbox::Hval->new_oneline($v);
 357
 358                 if ($h eq 'From') {
 359                         my @from = Email::Address->parse($v->raw);
 360                         $title[1] = ascii_html($from[0]->name);
 361                 } elsif ($h eq 'Subject') {
 362                         $title[0] = $v->as_html;
 363                         if ($srch) {
 364                                 $rv .= "$h: <a\nhref=\"../t/$mid_href.html\">";
 365                                 $rv .= $v->as_html . "</a>\n";
 366                                 next;
 367                         }
 368                 }
 369                 $rv .= "$h: " . $v->as_html . "\n";
 370
 371         }
 372
 373         $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 374         $mid_href = "../m/$mid_href" unless $full_pfx;
 375         $rv .= "(<a\nhref=\"$mid_href.txt\">raw</a>)\n";
 376
 377         my $irt = $header_obj->header('In-Reply-To');
 378         if (defined $irt) {
 379                 my $v = PublicInbox::Hval->new_msgid($irt);
 380                 my $html = $v->as_html;
 381                 my $href = $v->as_href;
 382                 $rv .= "In-Reply-To: &lt;";
 383                 $rv .= "<a\nhref=\"$href.html\">$html</a>&gt;\n";
 384         }
 385
 386         my $refs = $header_obj->header('References');
 387         if ($refs) {
 388                 # avoid redundant URLs wasting bandwidth
 389                 my %seen;
 390                 $seen{mid_clean($irt)} = 1 if defined $irt;
 391                 my @refs;
 392                 my @raw_refs = ($refs =~ /<([^>]+)>/g);
 393                 foreach my $ref (@raw_refs) {
 394                         next if $seen{$ref};
 395                         $seen{$ref} = 1;
 396                         push @refs, linkify_ref($ref);
 397                 }
 398
 399                 if (@refs) {
 400                         $rv .= 'References: '. join(' ', @refs) . "\n";
 401                 }
 402         }
 403
 404         $rv .= "\n";
 405
 406         ("<html><head><title>".  join(' - ', @title) .
 407          '</title></head><body>' . PRE_WRAP . $rv);
 408 }
 409
 410 sub html_footer {
 411         my ($mime, $standalone, $full_pfx, $srch) = @_;
 412         my %cc; # everyone else
 413         my $to; # this is the From address
 414
 415         foreach my $h (qw(From To Cc)) {
 416                 my $v = $mime->header($h);
 417                 defined($v) && length($v) or next;
 418                 my @addrs = Email::Address->parse($v);
 419                 foreach my $recip (@addrs) {
 420                         my $address = $recip->address;
 421                         my $dst = lc($address);
 422                         $cc{$dst} ||= $address;
 423                         $to ||= $dst;
 424                 }
 425         }
 426         Email::Address->purge_cache if $standalone;
 427
 428         my $subj = $mime->header('Subject') || '';
 429         $subj = "Re: $subj" unless $subj =~ /\bRe:/;
 430         my $mid = $mime->header_obj->header('Message-ID');
 431         my $irt = uri_escape_utf8($mid);
 432         delete $cc{$to};
 433         $to = uri_escape_utf8($to);
 434         $subj = uri_escape_utf8($subj);
 435
 436         my $cc = uri_escape_utf8(join(',', sort values %cc));
 437         my $href = "mailto:$to?In-Reply-To=$irt&Cc=${cc}&Subject=$subj";
 438
 439         my $idx = $standalone ? " <a\nhref=\"../\">index</a>" : '';
 440         if ($idx && $srch) {
 441                 $irt = $mime->header_obj->header('In-Reply-To') || '';
 442                 $mid = mid_compressed(mid_clean($mid));
 443                 my $t_anchor = length $irt ? T_ANCHOR : '';
 444                 $idx = " <a\nhref=\"../t/$mid.html$t_anchor\">".
 445                        "threadlink</a>$idx";
 446                 my $res = $srch->get_followups($mid);
 447                 if (my $c = $res->{total}) {
 448                         $c = $c == 1 ? '1 followup' : "$c followups";
 449                         $idx .= "\n$c:\n";
 450                         $res->{srch} = $srch;
 451                         thread_followups(\$idx, $mime, $res);
 452                 } else {
 453                         $idx .= "\n(no followups, yet)\n";
 454                 }
 455                 if ($irt) {
 456                         $irt = PublicInbox::Hval->new_msgid($irt);
 457                         $irt = $irt->as_href;
 458                         $irt = "<a\nhref=\"$irt\">parent</a> ";
 459                 } else {
 460                         $irt = ' ' x length('parent ');
 461                 }
 462         } else {
 463                 $irt = '';
 464         }
 465
 466         "$irt<a\nhref=\"" . ascii_html($href) . '">reply</a>' . $idx;
 467 }
 468
 469 sub linkify_ref {
 470         my $v = PublicInbox::Hval->new_msgid($_[0]);
 471         my $html = $v->as_html;
 472         my $href = $v->as_href;
 473         "&lt;<a\nhref=\"$href.html\">$html</a>&gt;";
 474 }
 475
 476 sub anchor_for {
 477         my ($msgid) = @_;
 478         my $id = $msgid;
 479         if ($id !~ /\A[a-f0-9]{40}\z/) {
 480                 $id = mid_compressed(mid_clean($id), 1);
 481         }
 482         'm' . $id;
 483 }
 484
 485 sub simple_dump {
 486         my ($dst, $root, $node, $level) = @_;
 487         return unless $node;
 488         # $root = [ Root Message-ID, \%seen, $srch ];
 489         if (my $x = $node->message) {
 490                 my $mid = $x->header('Message-ID');
 491                 if ($root->[0] ne $mid) {
 492                         my $pfx = '  ' x $level;
 493                         $$dst .= $pfx;
 494                         my $s = $x->header('Subject');
 495                         my $h = $root->[2]->subject_path($s);
 496                         if ($root->[1]->{$h}) {
 497                                 $s = '';
 498                         } else {
 499                                 $root->[1]->{$h} = 1;
 500                                 $s = PublicInbox::Hval->new($s);
 501                                 $s = $s->as_html;
 502                         }
 503                         my $m = PublicInbox::Hval->new_msgid($mid);
 504                         my $f = PublicInbox::Hval->new($x->header('X-PI-From'));
 505                         my $d = PublicInbox::Hval->new($x->header('X-PI-Date'));
 506                         $m = $m->as_href . '.html';
 507                         $f = $f->as_html;
 508                         $d = $d->as_html . ' UTC';
 509                         if (length($s) == 0) {
 510                                 $$dst .= "` <a\nhref=\"$m\">$f @ $d</a>\n";
 511                         } else {
 512                                 $$dst .= "` <a\nhref=\"$m\">$s</a>\n" .
 513                                      "$pfx  by $f @ $d\n";
 514                         }
 515                 }
 516         }
 517         simple_dump($dst, $root, $node->child, $level+1);
 518         simple_dump($dst, $root, $node->next, $level);
 519 }
 520
 521 sub thread_followups {
 522         my ($dst, $root, $res) = @_;
 523         $root->header_set('X-PI-TS', '0');
 524         my $msgs = load_results($res);
 525         push @$msgs, $root;
 526         my $th = thread_results($msgs);
 527         my $srch = $res->{srch};
 528         my $subj = $srch->subject_path($root->header('Subject'));
 529         my %seen = ($subj => 1);
 530         $root = [ $root->header('Message-ID'), \%seen, $srch ];
 531         simple_dump($dst, $root, $_, 0) for $th->rootset;
 532 }
 533
 534 sub thread_html_head {
 535         my ($mime) = @_;
 536         my $s = PublicInbox::Hval->new_oneline($mime->header('Subject'));
 537         $s = $s->as_html;
 538         "<html><head><title>$s</title></head><body>";
 539 }
 540
 541 sub thread_entry {
 542         my ($fh, $git, $state, $node, $level) = @_;
 543         return unless $node;
 544         # $state = [ $search_res, $seen, undef, 0 (msg_nr) ];
 545         # $seen is overloaded with 3 types of fields:
 546         #       1) "root_anchor" => anchor_for(Message-ID),
 547         #       2) seen subject hashes: sha1(subject) => 1
 548         #       3) anchors hashes: "#$sha1_hex" (same as $seen in index_entry)
 549         if (my $mime = $node->message) {
 550
 551                 # lazy load the full message from mini_mime:
 552                 my $path = mid2path(mid_clean($mime->header('Message-ID')));
 553                 $mime = eval { Email::MIME->new($git->cat_file("HEAD:$path")) };
 554                 if ($mime) {
 555                         if ($state->[3] == 0) {
 556                                 $fh->write(thread_html_head($mime));
 557                         }
 558                         index_entry($fh, $mime, $level, $state);
 559                 }
 560         }
 561         thread_entry($fh, $git, $state, $node->child, $level + 1);
 562         thread_entry($fh, $git, $state, $node->next, $level);
 563 }
 564
 565 sub load_results {
 566         my ($res) = @_;
 567
 568         [ map { $_->mini_mime } @{delete $res->{msgs}} ];
 569 }
 570
 571 sub msg_timestamp {
 572         my ($mime) = @_;
 573         my $ts = eval { str2time($mime->header('Date')) };
 574         defined($ts) ? $ts : 0;
 575 }
 576
 577 sub thread_results {
 578         my ($msgs) = @_;
 579         require PublicInbox::Thread;
 580         my $th = PublicInbox::Thread->new(@$msgs);
 581         $th->thread;
 582         $th->order(*PublicInbox::Thread::sort_ts);
 583         $th
 584 }
 585
 586 sub missing_thread {
 587         my ($cb) = @_;
 588         my $title = 'Thread does not exist';
 589         $cb->([404, ['Content-Type' => 'text/html']])->write(<<EOF);
 590 <html><head><title>$title</title></head><body><pre>$title
 591 <a href="../">Return to index</a></pre></body></html>
 592 EOF
 593 }
 594
 595 1;