lib/PublicInbox/View.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  11 use PublicInbox::MsgTime qw(msg_datestamp);
  12 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  13                         ts2str fmt_ts);
  14 use PublicInbox::Linkify;
  15 use PublicInbox::MID qw(id_compress mids mids_for_index references
  16                         $MID_EXTRACT);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::Address;
  19 use PublicInbox::WwwStream qw(html_oneshot);
  20 use PublicInbox::Reply;
  21 use PublicInbox::ViewDiff qw(flush_diff);
  22 use PublicInbox::Eml;
  23 use POSIX qw(strftime);
  24 use Time::Local qw(timegm);
  25 use PublicInbox::Smsg qw(subject_normalized);
  26 use PublicInbox::ContentHash qw(content_hash);
  27 use constant COLS => 72;
  28 use constant INDENT => '  ';
  29 use constant TCHILD => '` ';
  30 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  31
  32 sub msg_page_i {
  33         my ($ctx, $eml) = @_;
  34         if ($eml) { # called by WwwStream::async_eml or getline
  35                 my $smsg = $ctx->{smsg};
  36                 my $over = $ctx->{ibx}->over;
  37                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  38                                 : $ctx->gone('over');
  39                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  40                                 "../${\mid_href($smsg->{mid})}/" : '';
  41                 if (_msg_page_prepare_obuf($eml, $ctx)) {
  42                         $eml->each_part(\&add_text_body, $ctx, 1);
  43                         $ctx->zmore('</pre><hr>');
  44                 }
  45                 html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 delete($ctx->{obuf}) // \'';
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         if (_msg_page_prepare_obuf($eml, $ctx)) { # sets {-title_html}
  60                 $eml->each_part(\&add_text_body, $ctx, 1);
  61                 $ctx->zmore('</pre><hr>');
  62         }
  63         html_footer($ctx, $eml);
  64         $ctx->html_done;
  65 }
  66
  67 # public functions: (unstable)
  68
  69 sub msg_page {
  70         my ($ctx) = @_;
  71         my $ibx = $ctx->{ibx};
  72         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  73         my $over = $ibx->over or return no_over_html($ctx);
  74         my ($id, $prev);
  75         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  76
  77         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  78                 return; # undef == 404
  79
  80         # allow user to easily browse the range around this message if
  81         # they have ->over
  82         $ctx->{-t_max} = $smsg->{ts};
  83         PublicInbox::WwwStream::aresponse($ctx, \&msg_page_i);
  84 }
  85
  86 # /$INBOX/$MESSAGE_ID/#R
  87 sub msg_reply ($$) {
  88         my ($ctx, $hdr) = @_;
  89         my $se_url =
  90          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  91         my $p_url =
  92          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  93
  94         my $info = '';
  95         my $ibx = $ctx->{ibx};
  96         if (my $url = $ibx->{infourl}) {
  97                 $url = prurl($ctx->{env}, $url);
  98                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  99         }
 100
 101         my ($arg, $link, $reply_to_all) =
 102                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 103         if (ref($arg) eq 'SCALAR') {
 104                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 105         }
 106
 107         # mailto: link only works if address obfuscation is disabled
 108         if ($link) {
 109                 $link = <<EOF;
 110
 111 * If your mail client supports setting the <b>In-Reply-To</b> header
 112   via mailto: links, try the <a
 113 href="$link">mailto: link</a>
 114 EOF
 115         }
 116
 117         push @$arg, '/path/to/YOUR_REPLY';
 118         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 119         <<EOF
 120 <hr><pre
 121 id=R><b>Reply instructions:</b>
 122
 123 You may reply publicly to <a
 124 href=#t>this message</a> via plain-text email
 125 using any one of the following methods:
 126
 127 * Save the following mbox file, import it into your mail client,
 128   and $reply_to_all from there: <a
 129 href=raw>mbox</a>
 130
 131   Avoid top-posting and favor interleaved quoting:
 132   <a
 133 href="$p_url">$p_url</a>
 134 $info
 135 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 136   switches of git-send-email(1):
 137
 138   git send-email$arg
 139
 140   <a
 141 href="$se_url">$se_url</a>
 142 $link</pre>
 143
 144   Be sure your reply has a <b>Subject:</b> header at the top and a blank line
 145   before the message body.
 146 EOF
 147 }
 148
 149 sub in_reply_to {
 150         my ($hdr) = @_;
 151         my $refs = references($hdr);
 152         $refs->[-1];
 153 }
 154
 155 sub fold_addresses ($) {
 156         return $_[0] if length($_[0]) <= COLS;
 157         # try to fold on commas after non-word chars before $lim chars,
 158         # Try to get the "," preceded by ">" or ")", but avoid folding
 159         # on the comma where somebody uses "Lastname, Firstname".
 160         # We also try to keep the last and penultimate addresses in
 161         # the list on the same line if possible, hence the extra \z
 162         # Fall back to folding on spaces at $lim + 1 chars
 163         my $lim = COLS - 8; # 8 = "\t" display width
 164         my $too_long = $lim + 1;
 165         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 166         $_[0] = join("\n\t",
 167                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 168                                 .{1,$lim}(?:,|\z)|
 169                                 .{1,$lim}|
 170                                 .{$too_long,}?)(?:\s|\z)/xgo));
 171 }
 172
 173 sub _hdr_names_html ($$) {
 174         my ($hdr, $field) = @_;
 175         my @vals = $hdr->header($field) or return '';
 176         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 177 }
 178
 179 sub nr_to_s ($$$) {
 180         my ($nr, $singular, $plural) = @_;
 181         return "0 $plural" if $nr == 0;
 182         $nr == 1 ? "$nr $singular" : "$nr $plural";
 183 }
 184
 185 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 186 # this is already inside a <pre>
 187 sub eml_entry {
 188         my ($ctx, $eml) = @_;
 189         my $smsg = delete $ctx->{smsg};
 190         my $subj = delete $smsg->{subject};
 191         my $mid_raw = $smsg->{mid};
 192         my $id = id_compress($mid_raw, 1);
 193         my $id_m = 'm'.$id;
 194         my $root_anchor = $ctx->{root_anchor} || '';
 195         my $irt;
 196         my $obfs_ibx = $ctx->{-obfs_ibx};
 197
 198         $subj = '(no subject)' if $subj eq '';
 199         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 200         $subj = '<b>'.ascii_html($subj).'</b>';
 201         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 202         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 203         $rv .= $subj . "\n";
 204         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 205         my @tocc;
 206         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 207
 208         # Deleting these fields saves about 400K as we iterate across 1K msgs
 209         delete @$smsg{qw(ts blob)};
 210
 211         my $from = _hdr_names_html($eml, 'From');
 212         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 213         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 214         my $upfx = $ctx->{-upfx};
 215         my $mhref = $upfx . mid_href($mid_raw) . '/';
 216         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 217         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 218         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 219         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 220         my ($tlen, $clen) = (length($to), length($cc));
 221         my $to_cc = '';
 222         if (($tlen + $clen) > COLS) {
 223                 $to_cc .= '  To: '.$to."\n" if $tlen;
 224                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 225         } else {
 226                 if ($tlen) {
 227                         $to_cc .= '  To: '.$to;
 228                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 229                 } else {
 230                         $to_cc .= '  Cc: '.$cc if $clen;
 231                 }
 232                 $to_cc .= "\n";
 233         }
 234         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 235         $rv .= $to_cc;
 236
 237         my $mapping = $ctx->{mapping};
 238         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 239                 my $href = $upfx . mid_href($irt) . '/';
 240                 my $html = ascii_html($irt);
 241                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 242         }
 243         $rv .= "\n";
 244
 245         # scan through all parts, looking for displayable text
 246         $ctx->{mhref} = $mhref;
 247         $ctx->{changed_href} = "#e$id"; # for diffstat "files? changed,"
 248         $ctx->{obuf} = \$rv;
 249         $eml->each_part(\&add_text_body, $ctx, 1); # expensive
 250         $ctx->zmore; # TODO: remove once add_text_body is updated
 251
 252         # add the footer
 253         $rv = "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 254                 "<a\nhref=\"$mhref\">permalink</a>" .
 255                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 256                 " <a\nhref=\"${mhref}#R\">reply</a>";
 257
 258         delete($ctx->{-qry}) and
 259                 $rv .= qq[ <a\nhref="${mhref}#related">related</a>];
 260
 261         my $hr;
 262         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 263                 $rv .= "\t[relevance $pct%]";
 264                 $hr = 1;
 265         } elsif ($mapping) {
 266                 my $nested = 'nested';
 267                 my $flat = 'flat';
 268                 if ($ctx->{flat}) {
 269                         $hr = 1;
 270                         $flat = "<b>$flat</b>";
 271                 } else {
 272                         $nested = "<b>$nested</b>";
 273                 }
 274                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 275                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 276                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 277         } else {
 278                 $hr = $ctx->{-hr};
 279         }
 280
 281         # do we have more messages? start a new <pre> if so
 282         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 283         $rv;
 284 }
 285
 286 sub pad_link ($$;$) {
 287         my ($mid, $level, $s) = @_;
 288         $s ||= '...';
 289         my $href = defined($mid) ?
 290                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 291                 "($s)\n";
 292         (' 'x19).indent_for($level).th_pfx($level).$href;
 293 }
 294
 295 sub _skel_hdr {
 296         # my ($mapping, $mid) = @_;
 297         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 298 }
 299
 300 sub _th_index_lite {
 301         my ($mid_raw, $irt, $id, $ctx) = @_;
 302         my $rv = '';
 303         my $mapping = $ctx->{mapping} or return $rv;
 304         my $pad = '  ';
 305         my $mid_map = $mapping->{$mid_raw};
 306         defined $mid_map or
 307                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 308         my ($attr, $node, $idx, $level) = @$mid_map;
 309         my $children = $node->{children};
 310         my $nr_c = scalar @$children;
 311         my $nr_s = 0;
 312         my $siblings;
 313         # delete saves about 200KB on a 1K message thread
 314         if (my $refs = delete $node->{references}) {
 315                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 316         }
 317         my $irt_map = $mapping->{$$irt} if defined $$irt;
 318         if (defined $irt_map) {
 319                 $siblings = $irt_map->[1]->{children};
 320                 $nr_s = scalar(@$siblings) - 1;
 321                 $rv .= $pad . $irt_map->[0];
 322                 if ($idx > 0) {
 323                         my $prev = $siblings->[$idx - 1];
 324                         my $pmid = $prev->{mid};
 325                         if ($idx > 2) {
 326                                 my $s = ($idx - 1). ' preceding siblings ...';
 327                                 $rv .= pad_link($pmid, $level, $s);
 328                         } elsif ($idx == 2) {
 329                                 $rv .= $pad . _skel_hdr($mapping,
 330                                                 $siblings->[0] ?
 331                                                 $siblings->[0]->{mid} : undef);
 332                         }
 333                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 334                 }
 335         }
 336         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 337         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 338         chop $attr; # remove "\n"
 339         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 340         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 341         $rv .= "<b>@ $attr</b>\n";
 342         if ($nr_c) {
 343                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 344                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 345                 if ($nr_c > 2) {
 346                         my $s = ($nr_c - 1). ' more replies';
 347                         $rv .= pad_link($cmid, $level + 1, $s);
 348                 } elsif (my $cn = $children->[1]) {
 349                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 350                 }
 351         }
 352
 353         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 354         if ($next) {
 355                 my $nmid = $next->{mid};
 356                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 357                 my $nnext = $nr_s - $idx;
 358                 if ($nnext > 2) {
 359                         my $s = ($nnext - 1).' subsequent siblings';
 360                         $rv .= pad_link($nmid, $level, $s);
 361                 } elsif (my $nn = $siblings->[$idx + 2]) {
 362                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 363                 }
 364         }
 365         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 366 }
 367
 368 # non-recursive thread walker
 369 sub walk_thread ($$$) {
 370         my ($rootset, $ctx, $cb) = @_;
 371         my @q = map { (0, $_, -1) } @$rootset;
 372         while (@q) {
 373                 my ($level, $node, $i) = splice(@q, 0, 3);
 374                 defined $node or next;
 375                 $cb->($ctx, $level, $node, $i) or return;
 376                 ++$level;
 377                 $i = 0;
 378                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 379         }
 380 }
 381
 382 sub pre_thread  { # walk_thread callback
 383         my ($ctx, $level, $node, $idx) = @_;
 384         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 385         skel_dump($ctx, $level, $node);
 386 }
 387
 388 sub thread_eml_entry {
 389         my ($ctx, $eml) = @_;
 390         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 391         $ctx->zmore($beg.'<pre>');
 392         eml_entry($ctx, $eml) . '</pre>' . $end;
 393 }
 394
 395 sub next_in_queue ($$) {
 396         my ($q, $ghost_ok) = @_;
 397         while (@$q) {
 398                 my ($level, $smsg) = splice(@$q, 0, 2);
 399                 my $cl = $level + 1;
 400                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 401                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 402         }
 403         undef;
 404 }
 405
 406 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 407         my ($ctx, $eml) = @_;
 408         return thread_eml_entry($ctx, $eml) if $eml;
 409         return unless exists($ctx->{skel});
 410         my $ghost_ok = $ctx->{nr}++;
 411         while (1) {
 412                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 413                 if ($smsg) {
 414                         if (exists $smsg->{blob}) { # next message for cat-file
 415                                 $ctx->{level} = $lvl;
 416                                 if (!$ghost_ok) { # first non-ghost
 417                                         $ctx->{-title_html} =
 418                                                 ascii_html($smsg->{subject});
 419                                         $ctx->zmore($ctx->html_top);
 420                                 }
 421                                 return $smsg;
 422                         }
 423                         # buffer the ghost entry and loop
 424                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 425                 } else { # all done
 426                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 427                         $ctx->zmore(${delete($ctx->{skel})});
 428                         return;
 429                 }
 430         }
 431 }
 432
 433 sub stream_thread ($$) {
 434         my ($rootset, $ctx) = @_;
 435         @{$ctx->{-queue}} = map { (0, $_) } @$rootset;
 436         PublicInbox::WwwStream::aresponse($ctx, \&stream_thread_i);
 437 }
 438
 439 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 440 sub thread_html {
 441         my ($ctx) = @_;
 442         $ctx->{-upfx} = '../../';
 443         my $mid = $ctx->{mid};
 444         my $ibx = $ctx->{ibx};
 445         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 446         return missing_thread($ctx) if $nr == 0;
 447
 448         # link $INBOX_DIR/description text to "index_topics" view around
 449         # the newest message in this thread
 450         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 451         my $t_fmt = fmt_ts($ctx->{-t_max});
 452
 453         my $skel = '<hr><pre>';
 454         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 455         $skel .= <<EOF;
 456 , other threads:[<a
 457 href="../../?t=$t">~$t_fmt UTC</a> | <a
 458 href="../../">newest</a>]
 459
 460 EOF
 461         $skel .= "<b\nid=t>Thread overview:</b> ";
 462         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 463         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 464         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 465         $skel .= "-- links below jump to the message on this page --\n";
 466         $ctx->{cur_level} = 0;
 467         $ctx->{skel} = \$skel;
 468         $ctx->{prev_attr} = '';
 469         $ctx->{prev_level} = 0;
 470         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 471         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 472         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 473                        .' in thread';
 474
 475         my $rootset = thread_results($ctx, $msgs);
 476
 477         # reduce hash lookups in pre_thread->skel_dump
 478         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 479         walk_thread($rootset, $ctx, \&pre_thread);
 480
 481         $skel .= '</pre>';
 482         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 483
 484         # flat display: lazy load the full message from smsg
 485         $ctx->{msgs} = $msgs;
 486         $ctx->{-html_tip} = '<pre>';
 487         PublicInbox::WwwStream::aresponse($ctx, \&thread_html_i);
 488 }
 489
 490 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 491         my ($ctx, $eml) = @_;
 492         if ($eml) {
 493                 my $smsg = $ctx->{smsg};
 494                 if (exists $ctx->{-html_tip}) {
 495                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 496                         $ctx->zmore($ctx->html_top);
 497                 }
 498                 return eml_entry($ctx, $eml);
 499         } else {
 500                 while (my $smsg = shift @{$ctx->{msgs}}) {
 501                         return $smsg if exists($smsg->{blob});
 502                 }
 503                 my $skel = delete($ctx->{skel}) or return; # all done
 504                 $ctx->zmore($$skel);
 505                 undef;
 506         }
 507 }
 508
 509 sub submsg_hdr ($$) {
 510         my ($ctx, $eml) = @_;
 511         my $s = "\n";
 512         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 513                 $s .= "$h: $_\n" for $eml->header($h);
 514         }
 515         obfuscate_addrs($ctx->{-obfs_ibx}, $s) if $ctx->{-obfs_ibx};
 516         ascii_html($s);
 517 }
 518
 519 sub attach_link ($$$$;$) {
 520         my ($ctx, $ct, $p, $fn, $err) = @_;
 521         my ($part, $depth, $idx) = @$p;
 522
 523         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 524         # downloads for 0-byte multipart attachments
 525         return unless $part->{bdy};
 526
 527         my $size = length($part->body);
 528         delete $part->{bdy}; # save memory
 529
 530         # hide attributes normally, unless we want to aid users in
 531         # spotting MUA problems:
 532         $ct =~ s/;.*// unless $err;
 533         $ct = ascii_html($ct);
 534         my $sfn;
 535         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 536                 $sfn = $fn;
 537         } elsif ($ct eq 'text/plain') {
 538                 $sfn = 'a.txt';
 539         } else {
 540                 $sfn = 'a.bin';
 541         }
 542         my $rv = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 543         $rv .= qq(<a\nhref="$ctx->{mhref}$idx-$sfn">);
 544         $rv .= <<EOF if $err;
 545 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 546 EOF
 547         $rv .= "[-- Attachment #$idx: ";
 548         my $desc = $part->header('Content-Description') // $fn // '';
 549         $rv .= ascii_html($desc)." --]\n[-- " if $desc ne '';
 550         $rv .= "Type: $ct, Size: $size bytes --]</a>\n";
 551         $rv .= submsg_hdr($ctx, $part) if $part->{is_submsg};
 552         $rv;
 553 }
 554
 555 sub add_text_body { # callback for each_part
 556         my ($p, $ctx) = @_;
 557         my $upfx = $ctx->{mhref};
 558         my $ibx = $ctx->{ibx};
 559         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 560         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 561         my ($part, $depth, $idx) = @$p;
 562         my $ct = $part->content_type || 'text/plain';
 563         my $fn = $part->filename;
 564         my $rv = $ctx->{obuf};
 565         my ($s, $err) = msg_part_text($part, $ct);
 566         $s // return $$rv .= (attach_link($ctx, $ct, $p, $fn) // '');
 567         if ($part->{is_submsg}) {
 568                 $$rv .= submsg_hdr($ctx, $part);
 569                 $$rv .= "\n";
 570         }
 571
 572         # makes no difference to browsers, and don't screw up filename
 573         # link generation in diffs with the extra '%0D'
 574         $s =~ s/\r+\n/\n/sg;
 575
 576         # will be escaped to `&#8226;' in HTML
 577         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 578
 579         # always support diff-highlighting, but we can't linkify hunk
 580         # headers for solver unless some coderepo are configured:
 581         my $diff;
 582         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 583                 # diffstat anchors do not link across attachments or messages,
 584                 # -apfx is just a stable prefix for making diffstat anchors
 585                 # linkable to the first diff hunk w/o crossing attachments
 586                 $idx =~ tr!.!/!; # compatibility with previous versions
 587                 $ctx->{-apfx} = $upfx . $idx;
 588
 589                 # do attr => filename mappings for diffstats in git diffs:
 590                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 591                 $diff = 1;
 592                 delete $ctx->{-long_path};
 593                 my $spfx;
 594                 # absolute URL (Atom feeds)
 595                 if ($ibx->{coderepo}) {
 596                         if (index($upfx, '//') >= 0) {
 597                                 $spfx = $upfx;
 598                                 $spfx =~ s!/([^/]*)/\z!/!;
 599                         } else {
 600                                 my $n_slash = $upfx =~ tr!/!/!;
 601                                 if ($n_slash == 0) {
 602                                         $spfx = '../';
 603                                 } elsif ($n_slash == 1) {
 604                                         $spfx = '';
 605                                 } else { # nslash == 2
 606                                         $spfx = '../../';
 607                                 }
 608                         }
 609                 }
 610                 $ctx->{-spfx} = $spfx;
 611         };
 612
 613         # split off quoted and unquoted blocks:
 614         my @sections = PublicInbox::MsgIter::split_quotes($s);
 615         undef $s; # free memory
 616         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 617                 # badly-encoded message with $err? tell the world about it!
 618                 $$rv .= attach_link($ctx, $ct, $p, $fn, $err);
 619                 $$rv .= "\n";
 620         }
 621         delete $part->{bdy}; # save memory
 622         foreach my $cur (@sections) {
 623                 if ($cur =~ /\A>/) {
 624                         # we use a <span> here to allow users to specify
 625                         # their own color for quoted text
 626                         $$rv .= qq(<span\nclass="q">);
 627                         $$rv .= $l->to_html($cur);
 628                         $$rv .= '</span>';
 629                 } elsif ($diff) {
 630                         flush_diff($ctx, \$cur);
 631                 } else {
 632                         # regular lines, OK
 633                         $$rv .= $l->to_html($cur);
 634                 }
 635                 undef $cur; # free memory
 636         }
 637 }
 638
 639 sub _msg_page_prepare_obuf {
 640         my ($eml, $ctx) = @_;
 641         my $have_over = !!$ctx->{ibx}->over;
 642         my $obfs_ibx = $ctx->{-obfs_ibx};
 643         $ctx->{obuf} = \(my $rv = '');
 644         my $mids = mids_for_index($eml);
 645         my $nr = $ctx->{nr}++;
 646         if ($nr) { # unlikely
 647                 if ($ctx->{chash} eq content_hash($eml)) {
 648                         warn "W: BUG? @$mids not deduplicated properly\n";
 649                         return;
 650                 }
 651                 $rv .=
 652 "<pre>WARNING: multiple messages have this Message-ID\n</pre><pre>";
 653         } else {
 654                 $ctx->{first_hdr} = $eml->header_obj;
 655                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 656                 $rv .= "<pre\nid=b>"; # anchor for body start
 657         }
 658         $ctx->{-upfx} = '../';
 659         my @title; # (Subject[0], From[0])
 660         for my $v ($eml->header('From')) {
 661                 my @n = PublicInbox::Address::names($v);
 662                 $v = ascii_html($v);
 663                 $title[1] //= ascii_html(join(', ', @n));
 664                 if ($obfs_ibx) {
 665                         obfuscate_addrs($obfs_ibx, $v);
 666                         obfuscate_addrs($obfs_ibx, $title[1]);
 667                 }
 668                 $rv .= "From: $v\n" if $v ne '';
 669         }
 670         foreach my $h (qw(To Cc)) {
 671                 for my $v ($eml->header($h)) {
 672                         fold_addresses($v);
 673                         $v = ascii_html($v);
 674                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 675                         $rv .= "$h: $v\n" if $v ne '';
 676                 }
 677         }
 678         my @subj = $eml->header('Subject');
 679         if (@subj) {
 680                 my $v = ascii_html(shift @subj);
 681                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 682                 $rv .= 'Subject: ';
 683                 $rv .= $have_over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 684                 $title[0] = $v;
 685                 for $v (@subj) { # multi-Subject message :<
 686                         $v = ascii_html($v);
 687                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 688                         $rv .= "Subject: $v\n";
 689                 }
 690         } else { # dummy anchor for thread skeleton at bottom of page
 691                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $have_over;
 692                 $title[0] = '(no subject)';
 693         }
 694         for my $v ($eml->header('Date')) {
 695                 $v = ascii_html($v);
 696                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 697                 $rv .= qq{Date: $v\n};
 698         }
 699         # [thread overview] link is typically added after Date,
 700         # but added after Subject, or even nothing.
 701         if ($have_over) {
 702                 chop $rv; # drop "\n", or noop if $rv eq ''
 703                 $rv .= qq{\t<a\nhref="#r">[thread overview]</a>\n};
 704         }
 705         if (!$nr) { # first (and only) message, common case
 706                 $ctx->{-title_html} = join(' - ', @title);
 707                 $rv = $ctx->html_top . $rv;
 708         }
 709
 710         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 711         if (scalar(@$mids) == 1) { # common case
 712                 my $mhtml = ascii_html($mids->[0]);
 713                 $rv .= qq[Message-ID: &lt;$mhtml&gt; (<a href="raw">raw</a>)\n];
 714         } else {
 715                 # X-Alt-Message-ID can happen if a message is injected from
 716                 # public-inbox-nntpd because of multiple Message-ID headers.
 717                 my $s = '';
 718                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 719                         $s .= "$h: $_\n" for ($eml->header_raw($h));
 720                 }
 721                 $ctx->{-linkify}->linkify_mids('..', \$s, 1);
 722                 $rv .= $s;
 723         }
 724         $rv .= _parent_headers($ctx, $eml);
 725         1;
 726 }
 727
 728 sub SKEL_EXPAND () {
 729         qq(expand[<a\nhref="T/#u">flat</a>) .
 730                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 731                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 732                 qq(<a\nhref="t.atom">Atom feed</a>);
 733 }
 734
 735 sub thread_skel ($$$) {
 736         my ($skel, $ctx, $hdr) = @_;
 737         my $mid = mids($hdr)->[0];
 738         my $ibx = $ctx->{ibx};
 739         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 740         my $parent = in_reply_to($hdr);
 741         $$skel .= "\n<b>Thread overview: </b>";
 742         if ($nr <= 1) {
 743                 if (defined $parent) {
 744                         $$skel .= SKEL_EXPAND."\n ";
 745                         $$skel .= ghost_parent('../', $parent) . "\n";
 746                 } else {
 747                         $$skel .= "<a\nid=r>[no followups]</a> ".
 748                                         SKEL_EXPAND."\n";
 749                 }
 750                 $ctx->{next_msg} = undef;
 751                 $ctx->{parent_msg} = $parent;
 752                 return;
 753         }
 754
 755         $$skel .= $nr;
 756         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 757
 758         # nb: mutt only shows the first Subject in the index pane
 759         # when multiple Subject: headers are present, so we follow suit:
 760         my $subj = $hdr->header('Subject') // '';
 761         $subj = '(no subject)' if $subj eq '';
 762         $ctx->{cur} = $mid;
 763         $ctx->{prev_attr} = '';
 764         $ctx->{prev_level} = 0;
 765         $ctx->{skel} = $skel;
 766
 767         # reduce hash lookups in skel_dump
 768         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 769         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 770
 771         $ctx->{parent_msg} = $parent;
 772 }
 773
 774 sub _parent_headers {
 775         my ($ctx, $hdr) = @_;
 776         my @irt = $hdr->header_raw('In-Reply-To');
 777         my $refs;
 778         my $s = '';
 779         if (!@irt) {
 780                 $refs = references($hdr);
 781                 $irt[0] = pop(@$refs) if scalar @$refs;
 782         }
 783         $s .= "In-Reply-To: $_\n" for @irt;
 784
 785         # do not display References: if search is present,
 786         # we show the thread skeleton at the bottom, instead.
 787         if (!$ctx->{ibx}->over) {
 788                 $refs //= references($hdr);
 789                 $s .= 'References: <'.join(">\n\t<", @$refs).">\n" if @$refs;
 790         }
 791         $ctx->{-linkify}->linkify_mids('..', \$s); # escapes HTML
 792         $s .= "\n";
 793 }
 794
 795 # appends to obuf
 796 sub html_footer {
 797         my ($ctx, $hdr) = @_;
 798         my $upfx = '../';
 799         my ($related, $skel);
 800         my $qry = delete $ctx->{-qry};
 801         if ($qry && $ctx->{ibx}->isrch) {
 802                 my $q = ''; # search for either ancestor or descendent patches
 803                 for (@{$qry->{dfpre}}, @{$qry->{dfpost}}) {
 804                         chop if length > 7; # include 1 abbrev "older" patches
 805                         $q .= "dfblob:$_ ";
 806                 }
 807                 chop $q; # omit trailing SP
 808                 local $Text::Wrap::columns = COLS;
 809                 local $Text::Wrap::huge = 'overflow';
 810                 $q = wrap('', '', $q);
 811                 my $rows = ($q =~ tr/\n/\n/) + 1;
 812                 $q = ascii_html($q);
 813                 $related = <<EOM;
 814 <form id=related
 815 action=$upfx
 816 ><pre>find likely ancestor, descendant, or conflicting patches for <a
 817 href=#t>this message</a>:
 818 <textarea name=q cols=${\COLS} rows=$rows>$q</textarea>
 819 <input type=submit value=search
 820 />\t(<a href=${upfx}_/text/help/#search>help</a>)</pre></form>
 821 EOM
 822         }
 823         if ($ctx->{ibx}->over) {
 824                 my $t = ts2str($ctx->{-t_max});
 825                 my $t_fmt = fmt_ts($ctx->{-t_max});
 826                 my $fallback = $related ? "\t" : "<a id=related>\t</a>";
 827                 $skel = <<EOF;
 828 ${fallback}other threads:[<a
 829 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 830 href="$upfx">newest</a>]
 831 EOF
 832
 833                 thread_skel(\$skel, $ctx, $hdr);
 834                 my ($next, $prev);
 835                 my $parent = '       ';
 836                 $next = $prev = '    ';
 837
 838                 if (my $n = $ctx->{next_msg}) {
 839                         $n = mid_href($n);
 840                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 841                 }
 842                 my $u;
 843                 my $par = $ctx->{parent_msg};
 844                 if ($par) {
 845                         $u = mid_href($par);
 846                         $u = "$upfx$u/";
 847                 }
 848                 if (my $p = $ctx->{prev_msg}) {
 849                         $prev = mid_href($p);
 850                         if ($p && $par && $p eq $par) {
 851                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 852                                         'rel=prev>prev parent</a>';
 853                                 $parent = '';
 854                         } else {
 855                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 856                                         'rel=prev>prev</a>';
 857                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 858                         }
 859                 } elsif ($u) { # unlikely
 860                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 861                 }
 862                 ${$ctx->{obuf}} .= "<pre>$next $prev$parent ";
 863         } else { # unindexed inboxes w/o over
 864                 ${$ctx->{obuf}} .= '<pre>';
 865                 $skel = qq( <a\nhref="$upfx">latest</a>);
 866         }
 867         ${$ctx->{obuf}} .= qq(<a\nhref="#R">reply</a>);
 868         # $skel may be big for big threads, don't append it to obuf
 869         $skel .= '</pre>' . ($related // '');
 870         $ctx->zmore($skel .= msg_reply($ctx, $hdr)); # flushes obuf
 871 }
 872
 873 sub ghost_parent {
 874         my ($upfx, $mid) = @_;
 875
 876         my $href = mid_href($mid);
 877         my $html = ascii_html($mid);
 878         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 879 }
 880
 881 sub indent_for {
 882         my ($level) = @_;
 883         $level ? INDENT x ($level - 1) : '';
 884 }
 885
 886 sub find_mid_root {
 887         my ($ctx, $level, $node, $idx) = @_;
 888         ++$ctx->{root_idx} if $level == 0;
 889         if ($node->{mid} eq $ctx->{mid}) {
 890                 $ctx->{found_mid_at} = $ctx->{root_idx};
 891                 return 0; # stop iterating
 892         }
 893         1;
 894 }
 895
 896 sub strict_loose_note ($) {
 897         my ($nr) = @_;
 898         my $msg =
 899 "  -- strict thread matches above, loose matches on Subject: below --\n";
 900
 901         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 902                 $msg .=
 903 "  -- use mbox.gz link to download all $nr messages --\n";
 904         }
 905         $msg;
 906 }
 907
 908 sub thread_results {
 909         my ($ctx, $msgs) = @_;
 910         require PublicInbox::SearchThread;
 911         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 912
 913         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 914         # and preserved in the future.  This bug is hidden by `sid' matches
 915         # in get_thread, so we never noticed it until now.  And even when
 916         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 917         # bump since reindexing is expensive and users may not do it
 918
 919         # loose threading could've returned too many results,
 920         # put the root the message we care about at the top:
 921         my $mid = $ctx->{mid};
 922         if (defined($mid) && scalar(@$rootset) > 1) {
 923                 $ctx->{root_idx} = -1;
 924                 my $nr = scalar @$msgs;
 925                 walk_thread($rootset, $ctx, \&find_mid_root);
 926                 my $idx = $ctx->{found_mid_at};
 927                 if (defined($idx) && $idx != 0) {
 928                         my $tip = splice(@$rootset, $idx, 1);
 929                         @$rootset = reverse @$rootset;
 930                         unshift @$rootset, $tip;
 931                         $ctx->{sl_note} = strict_loose_note($nr);
 932                 }
 933         }
 934         $rootset
 935 }
 936
 937 sub missing_thread {
 938         my ($ctx) = @_;
 939         require PublicInbox::ExtMsg;
 940         PublicInbox::ExtMsg::ext_msg($ctx);
 941 }
 942
 943 sub dedupe_subject {
 944         my ($prev_subj, $subj, $val) = @_;
 945
 946         my $omit; # '"' denotes identical text omitted
 947         my (@prev_pop, @curr_pop);
 948         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 949                 push(@prev_pop, pop(@$prev_subj));
 950                 push(@curr_pop, pop(@$subj));
 951                 $omit //= $val;
 952         }
 953         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 954         if (scalar(@curr_pop) == 1) {
 955                 $omit = undef;
 956                 push @$prev_subj, @prev_pop;
 957                 push @$subj, @curr_pop;
 958         }
 959         $omit // '';
 960 }
 961
 962 sub skel_dump { # walk_thread callback
 963         my ($ctx, $level, $smsg) = @_;
 964         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 965
 966         my $skel = $ctx->{skel};
 967         my $cur = $ctx->{cur};
 968         my $mid = $smsg->{mid};
 969
 970         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 971                 $$skel .= delete($ctx->{sl_note}) || '';
 972         }
 973
 974         my $f = ascii_html(delete $smsg->{from_name});
 975         my $obfs_ibx = $ctx->{-obfs_ibx};
 976         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 977
 978         my $d = fmt_ts($smsg->{ds});
 979         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 980         if (exists $ctx->{searchview}) {
 981                 if (defined(my $pct = $smsg->{pct})) {
 982                         $d .= (sprintf(' % 2u', $pct) . '%');
 983                 } else {
 984                         $unmatched = 1;
 985                         $d .= '    ';
 986                 }
 987         }
 988         $d .= ' ' . indent_for($level) . th_pfx($level);
 989         my $attr = $f;
 990         $ctx->{first_level} ||= $level;
 991
 992         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 993                 $ctx->{prev_attr} = $attr;
 994         }
 995         $ctx->{prev_level} = $level;
 996
 997         if ($cur) {
 998                 if ($cur eq $mid) {
 999                         delete $ctx->{cur};
1000                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
1001                                  "$attr [this message]</a></b>\n";
1002                         return 1;
1003                 } else {
1004                         $ctx->{prev_msg} = $mid;
1005                 }
1006         } else {
1007                 $ctx->{next_msg} ||= $mid;
1008         }
1009
1010         # Subject is never undef, this mail was loaded from
1011         # our Xapian which would've resulted in '' if it were
1012         # really missing (and Filter rejects empty subjects)
1013         my @subj = split(/ /, subject_normalized($smsg->{subject}));
1014         # remove common suffixes from the subject if it matches the previous,
1015         # so we do not show redundant text at the end.
1016         my $prev_subj = $ctx->{prev_subj} || [];
1017         $ctx->{prev_subj} = [ @subj ];
1018         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1019         my $end;
1020         if (@subj) {
1021                 my $subj = join(' ', @subj);
1022                 $subj = ascii_html($subj);
1023                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1024                 $end = "$subj</a> $omit$f\n"
1025         } else {
1026                 $end = "$f</a>\n";
1027         }
1028         my $m;
1029         my $id = '';
1030         my $mapping = $unmatched ? undef : $ctx->{mapping};
1031         if ($mapping) {
1032                 my $map = $mapping->{$mid};
1033                 $id = id_compress($mid, 1);
1034                 $m = '#m'.$id;
1035                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1036                 $id = "\nid=r".$id;
1037         } else {
1038                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1039         }
1040         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1041         1;
1042 }
1043
1044 sub _skel_ghost {
1045         my ($ctx, $level, $node) = @_;
1046
1047         my $mid = $node->{mid};
1048         my $d = '     [not found] ';
1049         $d .= '    '  if exists $ctx->{searchview};
1050         $d .= indent_for($level) . th_pfx($level);
1051         my $upfx = $ctx->{-upfx};
1052         my $href = $upfx . mid_href($mid) . '/';
1053         my $html = ascii_html($mid);
1054
1055         my $mapping = $ctx->{mapping};
1056         my $map = $mapping->{$mid} if $mapping;
1057         if ($map) {
1058                 my $id = id_compress($mid, 1);
1059                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1060                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1061         } else {
1062                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1063         }
1064         ${$ctx->{skel}} .= $d;
1065         1;
1066 }
1067
1068 sub sort_ds {
1069         @{$_[0]} = sort {
1070                 (eval { $a->topmost->{ds} } || 0) <=>
1071                 (eval { $b->topmost->{ds} } || 0)
1072         } @{$_[0]};
1073 }
1074
1075 # accumulate recent topics if search is supported
1076 # returns 200 if done, 404 if not
1077 sub acc_topic { # walk_thread callback
1078         my ($ctx, $level, $smsg) = @_;
1079         my $mid = $smsg->{mid};
1080         my $has_blob = $smsg->{blob} // do {
1081                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1082                         %$smsg = (%$smsg, %$by_mid);
1083                         1;
1084                 }
1085         };
1086         if ($has_blob) {
1087                 my $subj = subject_normalized($smsg->{subject});
1088                 $subj = '(no subject)' if $subj eq '';
1089                 my $ds = $smsg->{ds};
1090                 if ($level == 0) { # new, top-level topic
1091                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1092                         $ctx->{-cur_topic} = $topic;
1093                         push @{$ctx->{order}}, $topic;
1094                         return 1;
1095                 }
1096
1097                 # continue existing topic
1098                 my $topic = $ctx->{-cur_topic}; # should never be undef
1099                 $topic->[0] = $ds if $ds > $topic->[0];
1100                 $topic->[1]++; # bump N+ message counter
1101                 my $seen = $topic->[2];
1102                 if (scalar(@$topic) == 3) { # parent was a ghost
1103                         push @$topic, $subj;
1104                 } elsif (!defined($seen->{$subj})) {
1105                         push @$topic, $level, $subj; # @extra messages
1106                 }
1107                 $seen->{$subj} = $mid; # latest for subject
1108         } else { # ghost message
1109                 return 1 if $level != 0; # ignore child ghosts
1110                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1111                 push @{$ctx->{order}}, $topic;
1112         }
1113         1;
1114 }
1115
1116 sub dump_topics {
1117         my ($ctx) = @_;
1118         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1119         unless ($order) {
1120                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1121                 return 404;
1122         }
1123
1124         my @out;
1125         my $obfs_ibx = $ctx->{ibx}->{obfuscate} ? $ctx->{ibx} : undef;
1126         if (my $note = delete $ctx->{t_note}) {
1127                 push @out, $note; # "messages from ... to ..."
1128         }
1129         # sort by recency, this allows new posts to "bump" old topics...
1130         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1131                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1132                 @$topic = ();
1133                 next unless defined $top_subj;  # ghost topic
1134                 my $mid = delete $seen->{$top_subj};
1135                 my $href = mid_href($mid);
1136                 my $prev_subj = [ split(/ /, $top_subj) ];
1137                 $top_subj = ascii_html($top_subj);
1138                 $ds = fmt_ts($ds);
1139
1140                 # $n isn't the total number of posts on the topic,
1141                 # just the number of posts in the current results window
1142                 my $anchor;
1143                 if ($n == 1) {
1144                         $n = '';
1145                         $anchor = '#u'; # top of only message
1146                 } else {
1147                         $n = " ($n+ messages)";
1148                         $anchor = '#t'; # thread skeleton
1149                 }
1150
1151                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1152                         " $ds UTC $n\n";
1153                 while (@extra) {
1154                         my $level = shift @extra;
1155                         my $subj = shift @extra; # already normalized
1156                         $mid = delete $seen->{$subj};
1157                         my @subj = split(/ /, $subj);
1158                         my @next_prev = @subj; # full copy
1159                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1160                         $prev_subj = \@next_prev;
1161                         $subj = join(' ', @subj);
1162                         $subj = ascii_html($subj);
1163                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1164                         $href = mid_href($mid);
1165                         $s .= indent_for($level) . TCHILD;
1166                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1167                 }
1168                 push @out, $s;
1169         }
1170         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1171         200;
1172 }
1173
1174 sub str2ts ($) {
1175         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1176         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1177 }
1178
1179 sub pagination_footer ($$) {
1180         my ($ctx, $latest) = @_;
1181         my $next = $ctx->{next_page} || '';
1182         my $prev = $ctx->{prev_page} || '';
1183         if ($prev) {  # aligned padding for: 'next (older) | '
1184                 $next = $next ? "$next | " : '             | ';
1185                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1186         }
1187         ($next || $prev) ? "<hr><pre id=nav>page: $next$prev</pre>" : '';
1188 }
1189
1190 sub paginate_recent ($$) {
1191         my ($ctx, $lim) = @_;
1192         my $t = $ctx->{qp}->{t} || '';
1193         my $opts = { limit => $lim };
1194         my ($after, $before);
1195
1196         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1197         # if only $after exists "YYYYMMDD.." because "." could be skipped
1198         # if interpreted as an end-of-sentence
1199         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1200         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1201
1202         my $msgs = $ctx->{ibx}->over->recent($opts, $after, $before);
1203         if (defined($after) && scalar(@$msgs) < $lim) {
1204                 $after = $before = undef;
1205                 $msgs = $ctx->{ibx}->over->recent($opts);
1206         }
1207         my $more = scalar(@$msgs) == $lim;
1208         my ($newest, $oldest);
1209         if (@$msgs) {
1210                 $newest = $msgs->[0]->{ts};
1211                 $oldest = $msgs->[-1]->{ts};
1212                 # if we only had $after, our SQL query in ->recent ordered
1213                 if ($newest < $oldest) {
1214                         ($oldest, $newest) = ($newest, $oldest);
1215                         $more = undef if defined($after) && $after < $oldest;
1216                 }
1217                 if (defined($after // $before)) {
1218                         my $n = strftime('%Y-%m-%d %H:%M:%S', gmtime($newest));
1219                         my $o = strftime('%Y-%m-%d %H:%M:%S', gmtime($oldest));
1220                         $ctx->{t_note} = <<EOM;
1221  messages from $o to $n UTC [<a href="#nav">more...</a>]
1222 EOM
1223                         my $s = ts2str($newest);
1224                         $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1225                                                 'prev (newer)</a>';
1226                 }
1227         }
1228         if (defined($oldest) && $more) {
1229                 my $s = ts2str($oldest);
1230                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1231                                         'next (older)</a>';
1232         }
1233         $msgs;
1234 }
1235
1236 # GET /$INBOX - top-level inbox view for indexed inboxes
1237 sub index_topics {
1238         my ($ctx) = @_;
1239         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1240         walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic) if @$msgs;
1241         html_oneshot($ctx, dump_topics($ctx), pagination_footer($ctx, '.'));
1242 }
1243
1244 sub thread_adj_level {
1245         my ($ctx, $level) = @_;
1246
1247         my $max = $ctx->{cur_level};
1248         if ($level <= 0) {
1249                 return ('', '') if $max == 0; # flat output
1250
1251                 # reset existing lists
1252                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1253                 $ctx->{cur_level} = 0;
1254                 ("$beg</ul>", '');
1255         } elsif ($level == $max) { # continue existing list
1256                 qw(<li> </li>);
1257         } elsif ($level < $max) {
1258                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1259                 $ctx->{cur_level} = $level;
1260                 ("$beg<li>", '</li>');
1261         } else { # ($level > $max) # start a new level
1262                 $ctx->{cur_level} = $level;
1263                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1264                 ($beg, '</li>');
1265         }
1266 }
1267
1268 sub ghost_index_entry {
1269         my ($ctx, $level, $node) = @_;
1270         my ($beg, $end) = thread_adj_level($ctx,  $level);
1271         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1272                 . '</pre>' . $end;
1273 }
1274
1275 1;