lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use URI::Escape qw/uri_escape_utf8/;
  10 use Date::Parse qw/str2time/;
  11 use PublicInbox::Hval qw/ascii_html/;
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw/mid_clean id_compress mid_mime mid_escape/;
  14 use PublicInbox::MsgIter;
  15 use PublicInbox::Address;
  16 use PublicInbox::WwwStream;
  17 require POSIX;
  18
  19 use constant INDENT => '  ';
  20 use constant TCHILD => '` ';
  21 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  22
  23 # public functions: (unstable)
  24 sub msg_html {
  25         my ($ctx, $mime) = @_;
  26         my $hdr = $mime->header_obj;
  27         my $tip = _msg_html_prepare($hdr, $ctx);
  28         PublicInbox::WwwStream->response($ctx, 200, sub {
  29                 my ($nr, undef) = @_;
  30                 if ($nr == 1) {
  31                         $tip . multipart_text_as_html($mime, '') . '</pre><hr>'
  32                 } elsif ($nr == 2) {
  33                         # fake an EOF if generating the footer fails;
  34                         # we want to at least show the message if something
  35                         # here crashes:
  36                         eval {
  37                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  38                                 '</pre>' . msg_reply($ctx, $hdr)
  39                         };
  40                 } else {
  41                         undef
  42                 }
  43         });
  44 }
  45
  46 # /$INBOX/$MESSAGE_ID/#R
  47 sub msg_reply {
  48         my ($ctx, $hdr) = @_;
  49         my $se_url =
  50          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  51         my $p_url =
  52          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  53
  54         my $info = '';
  55         if (my $url = $ctx->{-inbox}->{infourl}) {
  56                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
  57                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  58         }
  59
  60         my ($arg, $link) = mailto_arg_link($hdr);
  61         push @$arg, '/path/to/YOUR_REPLY';
  62         $arg = ascii_html(join(" \\\n    ", '', @$arg));
  63         <<EOF
  64 <hr><pre
  65 id=R><b>Reply instructions:</b>
  66
  67 You may reply publically to <a
  68 href=#t>this message</a> via plain-text email
  69 using any one of the following methods:
  70
  71 * Save the following mbox file, import it into your mail client,
  72   and reply-to-all from there: <a
  73 href=raw>mbox</a>
  74
  75   Avoid top-posting and favor interleaved quoting:
  76   <a
  77 href="$p_url">$p_url</a>
  78 $info
  79 * Reply to all the recipients using the <b>--to</b>, <b>--cc</b>,
  80   and <b>--in-reply-to</b> switches of git-send-email(1):
  81
  82   git send-email$arg
  83
  84   <a
  85 href="$se_url">$se_url</a>
  86
  87 * If your mail client supports setting the <b>In-Reply-To</b> header
  88   via mailto: links, try the <a
  89 href="$link">mailto: link</a></pre>
  90 EOF
  91 }
  92
  93 sub in_reply_to {
  94         my ($hdr) = @_;
  95         my $irt = $hdr->header_raw('In-Reply-To');
  96
  97         return mid_clean($irt) if defined $irt && $irt ne '';
  98
  99         my $refs = $hdr->header_raw('References');
 100         if ($refs && $refs =~ /<([^>]+)>\s*\z/s) {
 101                 return $1;
 102         }
 103         undef;
 104 }
 105
 106 sub _hdr_names ($$) {
 107         my ($hdr, $field) = @_;
 108         my $val = $hdr->header($field) or return '';
 109         ascii_html(join(', ', PublicInbox::Address::names($val)));
 110 }
 111
 112 sub nr_to_s ($$$) {
 113         my ($nr, $singular, $plural) = @_;
 114         return "0 $plural" if $nr == 0;
 115         $nr == 1 ? "$nr $singular" : "$nr $plural";
 116 }
 117
 118 # this is already inside a <pre>
 119 sub index_entry {
 120         my ($mime, $ctx, $more) = @_;
 121         my $srch = $ctx->{srch};
 122         my $hdr = $mime->header_obj;
 123         my $subj = $hdr->header('Subject');
 124
 125         my $mid_raw = mid_clean(mid_mime($mime));
 126         my $id = id_compress($mid_raw, 1);
 127         my $id_m = 'm'.$id;
 128
 129         my $root_anchor = $ctx->{root_anchor} || '';
 130         my $irt = in_reply_to($hdr);
 131
 132         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 133         $subj = '<b>'.ascii_html($subj).'</b>';
 134         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 135         $rv .= $subj . "\n";
 136         $rv .= _th_index_lite($mid_raw, $irt, $id, $ctx);
 137         my @tocc;
 138         foreach my $f (qw(To Cc)) {
 139                 my $dst = _hdr_names($hdr, $f);
 140                 push @tocc, "$f: $dst" if $dst ne '';
 141         }
 142         $rv .= "From: "._hdr_names($hdr, 'From').' @ '._msg_date($hdr)." UTC";
 143         my $upfx = $ctx->{-upfx};
 144         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 145         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 146         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 147         $rv .= '  '.join('; +', @tocc) . "\n" if @tocc;
 148
 149         my $mapping = $ctx->{mapping};
 150         if (!$mapping && $irt) {
 151                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 152                 my $href = $upfx . $mirt->{href}. '/';
 153                 my $html = $mirt->as_html;
 154                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 155         }
 156         $rv .= "\n";
 157
 158         # scan through all parts, looking for displayable text
 159         msg_iter($mime, sub { $rv .= add_text_body($mhref, $_[0]) });
 160
 161         # add the footer
 162         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 163                 "<a\nhref=\"$mhref\">permalink</a>" .
 164                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 165                 " <a\nhref=\"${mhref}#R\">reply</a>";
 166
 167         my $hr;
 168         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 169                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 170                 $hr = 1;
 171         } elsif ($mapping) {
 172                 my $threaded = 'threaded';
 173                 my $flat = 'flat';
 174                 my $end = '';
 175                 if ($ctx->{flat}) {
 176                         $hr = 1;
 177                         $flat = "<b>$flat</b>";
 178                 } else {
 179                         $threaded = "<b>$threaded</b>";
 180                 }
 181                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 182                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$threaded</a>]";
 183                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 184         } else {
 185                 $hr = $ctx->{-hr};
 186         }
 187
 188         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 189         $rv;
 190 }
 191
 192 sub pad_link ($$;$) {
 193         my ($mid, $level, $s) = @_;
 194         $s ||= '...';
 195         my $id = id_compress($mid, 1);
 196         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 197 }
 198
 199 sub _th_index_lite {
 200         my ($mid_raw, $irt, $id, $ctx) = @_;
 201         my $rv = '';
 202         my $mapping = $ctx->{mapping} or return $rv;
 203         my $pad = '  ';
 204         # map = [children, attr, node, idx, level]
 205         my $map = $mapping->{$mid_raw};
 206         my $nr_c = scalar @{$map->[0]};
 207         my $nr_s = 0;
 208         my $level = $map->[4];
 209         my $idx = $map->[3];
 210         my $irt_map = $mapping->{$irt} if defined $irt;
 211         if (defined $irt_map) {
 212                 my $siblings = $irt_map->[0];
 213                 $nr_s = scalar(@$siblings) - 1;
 214                 $rv .= $pad . $irt_map->[1];
 215                 if ($idx > 0) {
 216                         my $prev = $siblings->[$idx - 1];
 217                         my $pmid = $prev->messageid;
 218                         if ($idx > 2) {
 219                                 my $s = ($idx - 1). ' preceding siblings ...';
 220                                 $rv .= pad_link($pmid, $level, $s);
 221                         } elsif ($idx == 2) {
 222                                 my $ppmid = $siblings->[0]->messageid;
 223                                 $rv .= $pad . $mapping->{$ppmid}->[1];
 224                         }
 225                         $rv .= $pad . $mapping->{$pmid}->[1];
 226                 }
 227         }
 228         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 229         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 230         my $this = $map->[1];
 231         $this =~ s!\n\z!</b>\n!s;
 232         $this =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 233         $this =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 234         $rv .= "<b>@ $this";
 235         my $node = $map->[2];
 236         if (my $child = $node->child) {
 237                 my $cmid = $child->messageid;
 238                 $rv .= $pad . $mapping->{$cmid}->[1];
 239                 if ($nr_c > 2) {
 240                         my $s = ($nr_c - 1). ' more replies';
 241                         $rv .= pad_link($cmid, $level + 1, $s);
 242                 } elsif (my $cn = $child->next) {
 243                         $rv .= $pad . $mapping->{$cn->messageid}->[1];
 244                 }
 245         }
 246         if (my $next = $node->next) {
 247                 my $nmid = $next->messageid;
 248                 $rv .= $pad . $mapping->{$nmid}->[1];
 249                 my $nnext = $nr_s - $idx;
 250                 if ($nnext > 2) {
 251                         my $s = ($nnext - 1).' subsequent siblings';
 252                         $rv .= pad_link($nmid, $level, $s);
 253                 } elsif (my $nn = $next->next) {
 254                         $rv .= $pad . $mapping->{$nn->messageid}->[1];
 255                 }
 256         }
 257         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 258 }
 259
 260 sub walk_thread {
 261         my ($th, $ctx, $cb) = @_;
 262         my @q = map { (0, $_) } $th->rootset;
 263         while (@q) {
 264                 my $level = shift @q;
 265                 my $node = shift @q or next;
 266                 $cb->($ctx, $level, $node);
 267                 unshift @q, $level+1, $node->child, $level, $node->next;
 268         }
 269 }
 270
 271 sub pre_thread  {
 272         my ($ctx, $level, $node) = @_;
 273         my $mapping = $ctx->{mapping};
 274         my $idx = -1;
 275         if (my $parent = $node->parent) {
 276                 my $m = $mapping->{$parent->messageid}->[0];
 277                 $idx = scalar @$m;
 278                 push @$m, $node;
 279         }
 280         $mapping->{$node->messageid} = [ [], '', $node, $idx, $level ];
 281         skel_dump($ctx, $level, $node);
 282 }
 283
 284 sub thread_index_entry {
 285         my ($ctx, $level, $mime) = @_;
 286         my ($beg, $end) = thread_adj_level($ctx, $level);
 287         $beg . '<pre>' . index_entry($mime, $ctx, 0) . '</pre>' . $end;
 288 }
 289
 290 sub stream_thread ($$) {
 291         my ($th, $ctx) = @_;
 292         my $inbox = $ctx->{-inbox};
 293         my $mime;
 294         my @q = map { (0, $_) } $th->rootset;
 295         my $level;
 296         while (@q) {
 297                 $level = shift @q;
 298                 my $node = shift @q or next;
 299                 unshift @q, $level+1, $node->child, $level, $node->next;
 300                 $mime = $inbox->msg_by_mid($node->messageid) and last;
 301         }
 302         return missing_thread($ctx) unless $mime;
 303
 304         $mime = Email::MIME->new($mime);
 305         $ctx->{-title_html} = ascii_html($mime->header('Subject'));
 306         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $mime);
 307         PublicInbox::WwwStream->response($ctx, 200, sub {
 308                 return unless $ctx;
 309                 while (@q) {
 310                         $level = shift @q;
 311                         my $node = shift @q or next;
 312                         unshift @q, $level+1, $node->child, $level, $node->next;
 313                         my $mid = $node->messageid;
 314                         if ($mime = $inbox->msg_by_mid($mid)) {
 315                                 $mime = Email::MIME->new($mime);
 316                                 return thread_index_entry($ctx, $level, $mime);
 317                         } else {
 318                                 return ghost_index_entry($ctx, $level, $mid);
 319                         }
 320                 }
 321                 my $ret = join('', thread_adj_level($ctx, 0));
 322                 $ret .= ${$ctx->{dst}}; # skel
 323                 $ctx = undef;
 324                 $ret;
 325         });
 326 }
 327
 328 sub thread_html {
 329         my ($ctx) = @_;
 330         my $mid = $ctx->{mid};
 331         my $sres = $ctx->{srch}->get_thread($mid, { asc => 1 });
 332         my $msgs = load_results($sres);
 333         my $nr = $sres->{total};
 334         return missing_thread($ctx) if $nr == 0;
 335         my $skel = '<hr><pre>';
 336         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 337         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 338         $skel .= "<b\nid=t>Thread overview:</b> ";
 339         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 340         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 341         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 342         $skel .= "-- links below jump to the message on this page --\n";
 343         $ctx->{-upfx} = '../../';
 344         $ctx->{cur_level} = 0;
 345         $ctx->{dst} = \$skel;
 346         $ctx->{prev_attr} = '';
 347         $ctx->{prev_level} = 0;
 348         $ctx->{root_anchor} = anchor_for($mid);
 349         $ctx->{seen} = {};
 350         $ctx->{mapping} = {};
 351         $ctx->{s_nr} = "$nr+ messages in thread";
 352
 353         my $th = thread_results($msgs);
 354         walk_thread($th, $ctx, *pre_thread);
 355         $skel .= '</pre>';
 356         return stream_thread($th, $ctx) unless $ctx->{flat};
 357
 358         # flat display: lazy load the full message from mini_mime:
 359         my $inbox = $ctx->{-inbox};
 360         my $mime;
 361         while ($mime = shift @$msgs) {
 362                 $mime = $inbox->msg_by_mid(mid_clean(mid_mime($mime))) and last;
 363         }
 364         return missing_thread($ctx) unless $mime;
 365         $mime = Email::MIME->new($mime);
 366         $ctx->{-title_html} = ascii_html($mime->header('Subject'));
 367         $ctx->{-html_tip} = '<pre>'.index_entry($mime, $ctx, scalar @$msgs);
 368         $mime = undef;
 369         PublicInbox::WwwStream->response($ctx, 200, sub {
 370                 return unless $msgs;
 371                 while ($mime = shift @$msgs) {
 372                         $mid = mid_clean(mid_mime($mime));
 373                         $mime = $inbox->msg_by_mid($mid) and last;
 374                 }
 375                 if ($mime) {
 376                         $mime = Email::MIME->new($mime);
 377                         return index_entry($mime, $ctx, scalar @$msgs);
 378                 }
 379                 $msgs = undef;
 380                 $skel;
 381         });
 382 }
 383
 384 sub multipart_text_as_html {
 385         my ($mime, $upfx) = @_;
 386         my $rv = "";
 387
 388         # scan through all parts, looking for displayable text
 389         msg_iter($mime, sub {
 390                 my ($p) = @_;
 391                 $rv .= add_text_body($upfx, $p);
 392         });
 393         $rv;
 394 }
 395
 396 sub flush_quote {
 397         my ($s, $l, $quot) = @_;
 398
 399         # show everything in the full version with anchor from
 400         # short version (see above)
 401         my $rv = $l->linkify_1(join('', @$quot));
 402         @$quot = ();
 403
 404         # we use a <span> here to allow users to specify their own
 405         # color for quoted text
 406         $rv = $l->linkify_2(ascii_html($rv));
 407         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 408 }
 409
 410 sub attach_link ($$$$) {
 411         my ($upfx, $ct, $p, $fn) = @_;
 412         my ($part, $depth, @idx) = @$p;
 413         my $nl = $idx[-1] > 1 ? "\n" : '';
 414         my $idx = join('.', @idx);
 415         my $size = bytes::length($part->body);
 416         $ct ||= 'text/plain';
 417         $ct =~ s/;.*//; # no attributes
 418         $ct = ascii_html($ct);
 419         my $desc = $part->header('Content-Description');
 420         $desc = $fn unless defined $desc;
 421         $desc = '' unless defined $desc;
 422         my $sfn;
 423         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 424                 $sfn = $fn;
 425         } elsif ($ct eq 'text/plain') {
 426                 $sfn = 'a.txt';
 427         } else {
 428                 $sfn = 'a.bin';
 429         }
 430         my @ret = qq($nl<a\nhref="$upfx$idx-$sfn">[-- Attachment #$idx: );
 431         my $ts = "Type: $ct, Size: $size bytes";
 432         push(@ret, ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]");
 433         join('', @ret, "</a>\n");
 434 }
 435
 436 sub add_text_body {
 437         my ($upfx, $p) = @_; # from msg_iter: [ Email::MIME, depth, @idx ]
 438         my ($part, $depth, @idx) = @$p;
 439         my $ct = $part->content_type;
 440         my $fn = $part->filename;
 441
 442         if (defined $ct && $ct =~ m!\btext/x?html\b!i) {
 443                 return attach_link($upfx, $ct, $p, $fn);
 444         }
 445
 446         my $s = eval { $part->body_str };
 447
 448         # badly-encoded message? tell the world about it!
 449         return attach_link($upfx, $ct, $p, $fn) if $@;
 450
 451         my @lines = split(/^/m, $s);
 452         $s = '';
 453         if (defined($fn) || $depth > 0) {
 454                 $s .= attach_link($upfx, $ct, $p, $fn);
 455                 $s .= "\n";
 456         }
 457         my @quot;
 458         my $l = PublicInbox::Linkify->new;
 459         while (defined(my $cur = shift @lines)) {
 460                 if ($cur !~ /^>/) {
 461                         # show the previously buffered quote inline
 462                         flush_quote(\$s, $l, \@quot) if @quot;
 463
 464                         # regular line, OK
 465                         $cur = $l->linkify_1($cur);
 466                         $cur = ascii_html($cur);
 467                         $s .= $l->linkify_2($cur);
 468                 } else {
 469                         push @quot, $cur;
 470                 }
 471         }
 472
 473         my $end = "\n";
 474         if (@quot) {
 475                 $end = '';
 476                 flush_quote(\$s, $l, \@quot);
 477         }
 478         $s =~ s/[ \t]+$//sgm; # kill per-line trailing whitespace
 479         $s =~ s/\A\n+//s; # kill leading blank lines
 480         $s =~ s/\s+\z//s; # kill all trailing spaces
 481         $s .= $end;
 482 }
 483
 484 sub _msg_html_prepare {
 485         my ($hdr, $ctx) = @_;
 486         my $srch = $ctx->{srch} if $ctx;
 487         my $atom = '';
 488         my $rv = "<pre\nid=b>"; # anchor for body start
 489
 490         if ($srch) {
 491                 $ctx->{-upfx} = '../';
 492         }
 493         my @title;
 494         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 495         $mid = PublicInbox::Hval->new_msgid($mid);
 496         foreach my $h (qw(From To Cc Subject Date)) {
 497                 my $v = $hdr->header($h);
 498                 defined($v) && ($v ne '') or next;
 499                 $v = PublicInbox::Hval->new($v);
 500
 501                 if ($h eq 'From') {
 502                         my @n = PublicInbox::Address::names($v->raw);
 503                         $title[1] = ascii_html(join(', ', @n));
 504                 } elsif ($h eq 'Subject') {
 505                         $title[0] = $v->as_html;
 506                         if ($srch) {
 507                                 $rv .= qq($h: <a\nhref="#r"\nid=t>);
 508                                 $rv .= $v->as_html . "</a>\n";
 509                                 next;
 510                         }
 511                 }
 512                 $v = $v->as_html;
 513                 $v =~ s/(\@[^,]+,) /$1\n\t/g if ($h eq 'Cc' || $h eq 'To');
 514                 $rv .= "$h: $v\n";
 515
 516         }
 517         $title[0] ||= '(no subject)';
 518         $ctx->{-title_html} = join(' - ', @title);
 519         $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 520         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 521         $rv .= _parent_headers($hdr, $srch);
 522         $rv .= "\n";
 523 }
 524
 525 sub thread_skel {
 526         my ($dst, $ctx, $hdr, $tpfx) = @_;
 527         my $srch = $ctx->{srch};
 528         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 529         my $sres = $srch->get_thread($mid);
 530         my $nr = $sres->{total};
 531         my $expand = qq(<a\nhref="${tpfx}T/#u">expand</a> ) .
 532                         qq(/ <a\nhref="${tpfx}t.mbox.gz">mbox.gz</a> ) .
 533                         qq(/ <a\nhref="${tpfx}t.atom">Atom feed</a>);
 534
 535         my $parent = in_reply_to($hdr);
 536         $$dst .= "\n<b>Thread overview: </b>";
 537         if ($nr <= 1) {
 538                 if (defined $parent) {
 539                         $$dst .= "($expand)\n ";
 540                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 541                 } else {
 542                         $$dst .= "[no followups, yet] ($expand)\n";
 543                 }
 544                 $ctx->{next_msg} = undef;
 545                 $ctx->{parent_msg} = $parent;
 546                 return;
 547         }
 548
 549         $$dst .= "$nr+ messages in thread ($expand";
 550         $$dst .= qq! / <a\nhref="#b">[top]</a>)\n!;
 551
 552         my $subj = $srch->subject_path($hdr->header('Subject'));
 553         $ctx->{seen} = { $subj => 1 };
 554         $ctx->{cur} = $mid;
 555         $ctx->{prev_attr} = '';
 556         $ctx->{prev_level} = 0;
 557         $ctx->{dst} = $dst;
 558         walk_thread(thread_results(load_results($sres)), $ctx, *skel_dump);
 559         $ctx->{parent_msg} = $parent;
 560 }
 561
 562 sub _parent_headers {
 563         my ($hdr, $srch) = @_;
 564         my $rv = '';
 565
 566         my $irt = in_reply_to($hdr);
 567         if (defined $irt) {
 568                 my $v = PublicInbox::Hval->new_msgid($irt);
 569                 my $html = $v->as_html;
 570                 my $href = $v->{href};
 571                 $rv .= "In-Reply-To: &lt;";
 572                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 573         }
 574
 575         # do not display References: if search is present,
 576         # we show the thread skeleton at the bottom, instead.
 577         return $rv if $srch;
 578
 579         my $refs = $hdr->header_raw('References');
 580         if ($refs) {
 581                 # avoid redundant URLs wasting bandwidth
 582                 my %seen;
 583                 $seen{$irt} = 1 if defined $irt;
 584                 my @refs;
 585                 my @raw_refs = ($refs =~ /<([^>]+)>/g);
 586                 foreach my $ref (@raw_refs) {
 587                         next if $seen{$ref};
 588                         $seen{$ref} = 1;
 589                         push @refs, linkify_ref_nosrch($ref);
 590                 }
 591
 592                 if (@refs) {
 593                         $rv .= 'References: '. join("\n\t", @refs) . "\n";
 594                 }
 595         }
 596         $rv;
 597 }
 598
 599 sub squote_maybe ($) {
 600         my ($val) = @_;
 601         if ($val =~ m{([^\w@\./,\%\+\-])}) {
 602                 $val =~ s/(['!])/'\\$1'/g; # '!' for csh
 603                 return "'$val'";
 604         }
 605         $val;
 606 }
 607
 608 sub mailto_arg_link {
 609         my ($hdr) = @_;
 610         my %cc; # everyone else
 611         my $to; # this is the From address
 612
 613         foreach my $h (qw(From To Cc)) {
 614                 my $v = $hdr->header($h);
 615                 defined($v) && ($v ne '') or next;
 616                 my @addrs = PublicInbox::Address::emails($v);
 617                 foreach my $address (@addrs) {
 618                         my $dst = lc($address);
 619                         $cc{$dst} ||= $address;
 620                         $to ||= $dst;
 621                 }
 622         }
 623         my @arg;
 624
 625         my $subj = $hdr->header('Subject') || '';
 626         $subj = "Re: $subj" unless $subj =~ /\bRe:/i;
 627         my $mid = $hdr->header_raw('Message-ID');
 628         push @arg, '--in-reply-to='.squote_maybe(mid_clean($mid));
 629         my $irt = mid_escape($mid);
 630         delete $cc{$to};
 631         push @arg, "--to=$to";
 632         $to = uri_escape_utf8($to);
 633         $subj = uri_escape_utf8($subj);
 634         my @cc = sort values %cc;
 635         push(@arg, map { "--cc=$_" } @cc);
 636         my $cc = uri_escape_utf8(join(',', @cc));
 637         my $href = "mailto:$to?In-Reply-To=$irt&Cc=${cc}&Subject=$subj";
 638         $href =~ s/%20/+/g;
 639
 640         (\@arg, ascii_html($href));
 641 }
 642
 643 sub html_footer {
 644         my ($hdr, $standalone, $ctx, $rhref) = @_;
 645
 646         my $srch = $ctx->{srch} if $ctx;
 647         my $upfx = '../';
 648         my $tpfx = '';
 649         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 650         my $irt = '';
 651         if ($idx && $srch) {
 652                 $idx .= "\n";
 653                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 654                 my ($next, $prev);
 655                 my $parent = '       ';
 656                 $next = $prev = '    ';
 657
 658                 if (my $n = $ctx->{next_msg}) {
 659                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 660                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 661                 }
 662                 my $u;
 663                 my $par = $ctx->{parent_msg};
 664                 if ($par) {
 665                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 666                         $u = "$upfx$u/";
 667                 }
 668                 if (my $p = $ctx->{prev_msg}) {
 669                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 670                         if ($p && $par && $p eq $par) {
 671                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 672                                         'rel=prev>prev parent</a>';
 673                                 $parent = '';
 674                         } else {
 675                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 676                                         'rel=prev>prev</a>';
 677                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 678                         }
 679                 } elsif ($u) { # unlikely
 680                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 681                 }
 682                 $irt = "$next $prev$parent ";
 683         } else {
 684                 $irt = '';
 685         }
 686         $rhref ||= '#R';
 687         $irt .= qq(<a\nhref="$rhref">reply</a>);
 688         $irt .= $idx;
 689 }
 690
 691 sub linkify_ref_nosrch {
 692         my $v = PublicInbox::Hval->new_msgid($_[0]);
 693         my $html = $v->as_html;
 694         my $href = $v->{href};
 695         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 696 }
 697
 698 sub anchor_for {
 699         my ($msgid) = @_;
 700         'm' . id_compress($msgid, 1);
 701 }
 702
 703 sub ghost_parent {
 704         my ($upfx, $mid) = @_;
 705         # 'subject dummy' is used internally by Mail::Thread
 706         return '[no common parent]' if ($mid eq 'subject dummy');
 707
 708         $mid = PublicInbox::Hval->new_msgid($mid);
 709         my $href = $mid->{href};
 710         my $html = $mid->as_html;
 711         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 712 }
 713
 714 sub indent_for {
 715         my ($level) = @_;
 716         INDENT x ($level - 1);
 717 }
 718
 719 sub load_results {
 720         my ($sres) = @_;
 721
 722         [ map { $_->mini_mime } @{delete $sres->{msgs}} ];
 723 }
 724
 725 sub msg_timestamp {
 726         my ($hdr) = @_;
 727         my $ts = eval { str2time($hdr->header('Date')) };
 728         defined($ts) ? $ts : 0;
 729 }
 730
 731 sub thread_results {
 732         my ($msgs) = @_;
 733         require PublicInbox::Thread;
 734         my $th = PublicInbox::Thread->new(@$msgs);
 735         $th->thread;
 736         $th->order(*sort_ts);
 737         $th
 738 }
 739
 740 sub missing_thread {
 741         my ($ctx) = @_;
 742         require PublicInbox::ExtMsg;
 743         PublicInbox::ExtMsg::ext_msg($ctx);
 744 }
 745
 746 sub _msg_date {
 747         my ($hdr) = @_;
 748         my $ts = $hdr->header('X-PI-TS') || msg_timestamp($hdr);
 749         fmt_ts($ts);
 750 }
 751
 752 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 753
 754 sub _skel_header {
 755         my ($ctx, $hdr, $level) = @_;
 756
 757         my $dst = $ctx->{dst};
 758         my $cur = $ctx->{cur};
 759         my $mid = mid_clean($hdr->header_raw('Message-ID'));
 760         my $f = ascii_html($hdr->header('X-PI-From'));
 761         my $d = _msg_date($hdr) . ' ' . indent_for($level) . th_pfx($level);
 762         my $attr = $f;
 763         $ctx->{first_level} ||= $level;
 764
 765         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 766                 $ctx->{prev_attr} = $attr;
 767         }
 768         $ctx->{prev_level} = $level;
 769
 770         if ($cur) {
 771                 if ($cur eq $mid) {
 772                         delete $ctx->{cur};
 773                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 774                                  "$attr [this message]</a></b>\n";
 775                         return;
 776                 } else {
 777                         $ctx->{prev_msg} = $mid;
 778                 }
 779         } else {
 780                 $ctx->{next_msg} ||= $mid;
 781         }
 782
 783         # Subject is never undef, this mail was loaded from
 784         # our Xapian which would've resulted in '' if it were
 785         # really missing (and Filter rejects empty subjects)
 786         my $s = $hdr->header('Subject');
 787         my $h = $ctx->{srch}->subject_path($s);
 788         if ($ctx->{seen}->{$h}) {
 789                 $s = undef;
 790         } else {
 791                 $ctx->{seen}->{$h} = 1;
 792                 $s = PublicInbox::Hval->new($s);
 793                 $s = $s->as_html;
 794         }
 795         my $m;
 796         my $id = '';
 797         my $mapping = $ctx->{mapping};
 798         my $end = defined($s) ? "$s</a> $f\n" : "$f</a>\n";
 799         if ($mapping) {
 800                 my $map = $mapping->{$mid};
 801                 $id = id_compress($mid, 1);
 802                 $m = '#m'.$id;
 803                 $map->[1] = "$d<a\nhref=\"$m\">$end";
 804                 $id = "\nid=r".$id;
 805         } else {
 806                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 807         }
 808         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 809 }
 810
 811 sub skel_dump {
 812         my ($ctx, $level, $node) = @_;
 813         if (my $mime = $node->message) {
 814                 _skel_header($ctx, $mime->header_obj, $level);
 815         } else {
 816                 my $mid = $node->messageid;
 817                 my $dst = $ctx->{dst};
 818                 my $mapping = $ctx->{mapping};
 819                 my $map = $mapping->{$mid} if $mapping;
 820                 if ($mid eq 'subject dummy') {
 821                         my $ncp = "\t[no common parent]\n";
 822                         $map->[1] = $ncp if $map;
 823                         $$dst .= $ncp;
 824                         return;
 825                 }
 826                 my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
 827                                     : '     [not found] ';
 828                 $d .= indent_for($level) . th_pfx($level);
 829                 my $upfx = $ctx->{-upfx};
 830                 my $m = PublicInbox::Hval->new_msgid($mid);
 831                 my $href = $upfx . $m->{href} . '/';
 832                 my $html = $m->as_html;
 833
 834                 if ($map) {
 835                         my $id = id_compress($mid, 1);
 836                         $map->[1] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
 837                         $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
 838                 } else {
 839                         $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
 840                 }
 841                 $$dst .= $d;
 842         }
 843 }
 844
 845 sub sort_ts {
 846         sort {
 847                 (eval { $a->topmost->message->header('X-PI-TS') } || 0) <=>
 848                 (eval { $b->topmost->message->header('X-PI-TS') } || 0)
 849         } @_;
 850 }
 851
 852 sub _tryload_ghost ($$) {
 853         my ($srch, $mid) = @_;
 854         my $smsg = $srch->lookup_mail($mid) or return;
 855         $smsg->mini_mime;
 856 }
 857
 858 # accumulate recent topics if search is supported
 859 # returns 200 if done, 404 if not
 860 sub acc_topic {
 861         my ($ctx, $level, $node) = @_;
 862         my $srch = $ctx->{srch};
 863         my $mid = $node->messageid;
 864         my $x = $node->message || _tryload_ghost($srch, $mid);
 865         my ($subj, $ts);
 866         my $topic;
 867         if ($x) {
 868                 $x = $x->header_obj;
 869                 $subj = $x->header('Subject') || '';
 870                 $subj = $srch->subject_normalized($subj);
 871                 $ts = $x->header('X-PI-TS');
 872                 if ($level == 0) {
 873                         $topic = [ $ts, 1, { $subj => $mid }, $subj ];
 874                         $ctx->{-cur_topic} = $topic;
 875                         push @{$ctx->{order}}, $topic;
 876                         return;
 877                 }
 878
 879                 $topic = $ctx->{-cur_topic}; # should never be undef
 880                 $topic->[0] = $ts if $ts > $topic->[0];
 881                 $topic->[1]++;
 882                 my $seen = $topic->[2];
 883                 if (scalar(@$topic) == 3) { # parent was a ghost
 884                         push @$topic, $subj;
 885                 } elsif (!$seen->{$subj}) {
 886                         push @$topic, $level, $subj;
 887                 }
 888                 $seen->{$subj} = $mid; # latest for subject
 889         } else { # ghost message
 890                 return if $level != 0; # ignore child ghosts
 891                 $topic = [ -666, 0, {} ];
 892                 $ctx->{-cur_topic} = $topic;
 893                 push @{$ctx->{order}}, $topic;
 894         }
 895 }
 896
 897 sub dump_topics {
 898         my ($ctx) = @_;
 899         my $order = delete $ctx->{order}; # [ ts, subj1, subj2, subj3, ... ]
 900         if (!@$order) {
 901                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
 902                 return 404;
 903         }
 904
 905         my @out;
 906
 907         # sort by recency, this allows new posts to "bump" old topics...
 908         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
 909                 my ($ts, $n, $seen, $top, @ex) = @$topic;
 910                 @$topic = ();
 911                 next unless defined $top;  # ghost topic
 912                 my $mid = delete $seen->{$top};
 913                 my $href = mid_escape($mid);
 914                 $top = PublicInbox::Hval->new($top)->as_html;
 915                 $ts = fmt_ts($ts);
 916
 917                 # $n isn't the total number of posts on the topic,
 918                 # just the number of posts in the current results window
 919                 my $anchor;
 920                 if ($n == 1) {
 921                         $n = '';
 922                         $anchor = '#u'; # top of only message
 923                 } else {
 924                         $n = " ($n+ messages)";
 925                         $anchor = '#t'; # thread skeleton
 926                 }
 927
 928                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
 929                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
 930                 my $s = "<a\nhref=\"$href/T/$anchor\"><b>$top</b></a>\n" .
 931                         " $ts UTC $n - $mbox / $atom\n";
 932                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
 933                         my $level = $ex[$i];
 934                         my $sub = $ex[$i + 1];
 935                         $mid = delete $seen->{$sub};
 936                         $sub = PublicInbox::Hval->new($sub)->as_html;
 937                         $href = mid_escape($mid);
 938                         $s .= indent_for($level) . TCHILD;
 939                         $s .= "<a\nhref=\"$href/T/#u\">$sub</a>\n";
 940                 }
 941                 push @out, $s;
 942         }
 943         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
 944         200;
 945 }
 946
 947 sub index_nav { # callback for WwwStream
 948         my (undef, $ctx) = @_;
 949         delete $ctx->{qp} or return;
 950         my ($next, $prev);
 951         $next = $prev = '    ';
 952         my $latest = '';
 953
 954         my $next_o = $ctx->{-next_o};
 955         if ($next_o) {
 956                 $next = qq!<a\nhref="?o=$next_o"\nrel=next>next</a>!;
 957         }
 958         if (my $cur_o = $ctx->{-cur_o}) {
 959                 $latest = qq! <a\nhref=.>latest</a>!;
 960
 961                 my $o = $cur_o - ($next_o - $cur_o);
 962                 if ($o > 0) {
 963                         $prev = qq!<a\nhref="?o=$o"\nrel=prev>prev</a>!;
 964                 } elsif ($o == 0) {
 965                         $prev = qq!<a\nhref=.\nrel=prev>prev</a>!;
 966                 }
 967         }
 968         "<hr><pre>page: $next $prev$latest</pre>";
 969 }
 970
 971 sub index_topics {
 972         my ($ctx) = @_;
 973         my ($off) = (($ctx->{qp}->{o} || '0') =~ /(\d+)/);
 974         my $opts = { offset => $off, limit => 200 };
 975
 976         $ctx->{order} = [];
 977         my $sres = $ctx->{srch}->query('', $opts);
 978         my $nr = scalar @{$sres->{msgs}};
 979         if ($nr) {
 980                 $sres = load_results($sres);
 981                 walk_thread(thread_results($sres), $ctx, *acc_topic);
 982         }
 983         $ctx->{-next_o} = $off+ $nr;
 984         $ctx->{-cur_o} = $off;
 985         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
 986 }
 987
 988 sub thread_adj_level {
 989         my ($ctx, $level) = @_;
 990
 991         my $max = $ctx->{cur_level};
 992         if ($level <= 0) {
 993                 return ('', '') if $max == 0; # flat output
 994
 995                 # reset existing lists
 996                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
 997                 $ctx->{cur_level} = 0;
 998                 ("$beg</ul>", '');
 999         } elsif ($level == $max) { # continue existing list
1000                 qw(<li> </li>);
1001         } elsif ($level < $max) {
1002                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1003                 $ctx->{cur_level} = $level;
1004                 ("$beg<li>", '</li>');
1005         } else { # ($level > $max) # start a new level
1006                 $ctx->{cur_level} = $level;
1007                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1008                 ($beg, '</li>');
1009         }
1010 }
1011
1012 sub ghost_index_entry {
1013         my ($ctx, $level, $mid) = @_;
1014         my ($beg, $end) = thread_adj_level($ctx,  $level);
1015         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $mid) . '</pre>' . $end;
1016 }
1017
1018 1;