lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href);
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw(id_compress mids mids_for_index references
  14                         $MID_EXTRACT);
  15 use PublicInbox::MsgIter;
  16 use PublicInbox::Address;
  17 use PublicInbox::WwwStream;
  18 use PublicInbox::Reply;
  19 use PublicInbox::ViewDiff qw(flush_diff);
  20 use PublicInbox::Eml;
  21 use POSIX qw(strftime);
  22 use Time::Local qw(timegm);
  23 use PublicInbox::Smsg qw(subject_normalized);
  24 use constant COLS => 72;
  25 use constant INDENT => '  ';
  26 use constant TCHILD => '` ';
  27 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  28
  29 sub msg_page_i {
  30         my ($ctx, $eml) = @_;
  31         if ($eml) { # called by WwwStream::async_eml or getline
  32                 my $smsg = $ctx->{smsg};
  33                 $ctx->{smsg} = $ctx->{over}->next_by_mid(@{$ctx->{next_arg}});
  34                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  35                                 "../${\mid_href($smsg->{mid})}/" : '';
  36                 my $hdr = $eml->header_obj;
  37                 my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx);
  38                 multipart_text_as_html($eml, $ctx);
  39                 delete $ctx->{obuf};
  40                 $$obuf .= '</pre><hr>';
  41                 $$obuf .= html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  42                 $$obuf;
  43         } else { # called by WwwStream::async_next or getline
  44                 $ctx->{smsg}; # may be undef
  45         }
  46 }
  47
  48 # /$INBOX/$MESSAGE_ID/ for unindexed v1 inboxes
  49 sub no_over_i {
  50         my ($ctx) = @_;
  51         my $eml = delete $ctx->{eml} or return;
  52         my $hdr = $eml->header_obj;
  53         $ctx->{mhref} = '';
  54         my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($hdr, $ctx);
  55         multipart_text_as_html($eml, $ctx);
  56         delete $ctx->{obuf};
  57         $$obuf .= '</pre><hr>';
  58         eval { $$obuf .= html_footer($ctx, $hdr) };
  59         $$obuf
  60 }
  61
  62 sub no_over_html ($) {
  63         my ($ctx) = @_;
  64         my $bref = $ctx->{-inbox}->msg_by_mid($ctx->{mid}) or return; # 404
  65         $ctx->{eml} = PublicInbox::Eml->new($bref);
  66         PublicInbox::WwwStream::response($ctx, 200, \&no_over_i);
  67 }
  68
  69 # public functions: (unstable)
  70
  71 sub msg_page {
  72         my ($ctx) = @_;
  73         my $ibx = $ctx->{-inbox};
  74         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  75         my $over = $ctx->{over} = $ibx->over or return no_over_html($ctx);
  76         my ($id, $prev);
  77         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  78         $ctx->{smsg} = $over->next_by_mid(@$next_arg) or return; # undef == 404
  79         PublicInbox::WwwStream::aresponse($ctx, 200, \&msg_page_i);
  80 }
  81
  82 # /$INBOX/$MESSAGE_ID/#R
  83 sub msg_reply ($$) {
  84         my ($ctx, $hdr) = @_;
  85         my $se_url =
  86          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  87         my $p_url =
  88          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  89
  90         my $info = '';
  91         my $ibx = $ctx->{-inbox};
  92         if (my $url = $ibx->{infourl}) {
  93                 $url = prurl($ctx->{env}, $url);
  94                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  95         }
  96
  97         my ($arg, $link, $reply_to_all) =
  98                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
  99         if (ref($arg) eq 'SCALAR') {
 100                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 101         }
 102
 103         # mailto: link only works if address obfuscation is disabled
 104         if ($link) {
 105                 $link = <<EOF;
 106
 107 * If your mail client supports setting the <b>In-Reply-To</b> header
 108   via mailto: links, try the <a
 109 href="$link">mailto: link</a>
 110 EOF
 111         }
 112
 113         push @$arg, '/path/to/YOUR_REPLY';
 114         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 115         <<EOF
 116 <hr><pre
 117 id=R><b>Reply instructions:</b>
 118
 119 You may reply publicly to <a
 120 href=#t>this message</a> via plain-text email
 121 using any one of the following methods:
 122
 123 * Save the following mbox file, import it into your mail client,
 124   and $reply_to_all from there: <a
 125 href=raw>mbox</a>
 126
 127   Avoid top-posting and favor interleaved quoting:
 128   <a
 129 href="$p_url">$p_url</a>
 130 $info
 131 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 132   switches of git-send-email(1):
 133
 134   git send-email$arg
 135
 136   <a
 137 href="$se_url">$se_url</a>
 138 $link</pre>
 139 EOF
 140 }
 141
 142 sub in_reply_to {
 143         my ($hdr) = @_;
 144         my $refs = references($hdr);
 145         $refs->[-1];
 146 }
 147
 148 sub fold_addresses ($) {
 149         return $_[0] if length($_[0]) <= COLS;
 150         # try to fold on commas after non-word chars before $lim chars,
 151         # Try to get the "," preceded by ">" or ")", but avoid folding
 152         # on the comma where somebody uses "Lastname, Firstname".
 153         # We also try to keep the last and penultimate addresses in
 154         # the list on the same line if possible, hence the extra \z
 155         # Fall back to folding on spaces at $lim + 1 chars
 156         my $lim = COLS - 8; # 8 = "\t" display width
 157         my $too_long = $lim + 1;
 158         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 159         $_[0] = join("\n\t",
 160                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 161                                 .{1,$lim}(?:,|\z)|
 162                                 .{1,$lim}|
 163                                 .{$too_long,}?)(?:\s|\z)/xgo));
 164 }
 165
 166 sub _hdr_names_html ($$) {
 167         my ($hdr, $field) = @_;
 168         my @vals = $hdr->header($field) or return '';
 169         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 170 }
 171
 172 sub nr_to_s ($$$) {
 173         my ($nr, $singular, $plural) = @_;
 174         return "0 $plural" if $nr == 0;
 175         $nr == 1 ? "$nr $singular" : "$nr $plural";
 176 }
 177
 178 # human-friendly format
 179 sub fmt_ts ($) { strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 180
 181 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 182 # this is already inside a <pre>
 183 sub eml_entry {
 184         my ($ctx, $smsg, $eml, $more) = @_;
 185         my $subj = delete $smsg->{subject};
 186         my $mid_raw = $smsg->{mid};
 187         my $id = id_compress($mid_raw, 1);
 188         my $id_m = 'm'.$id;
 189         my $root_anchor = $ctx->{root_anchor} || '';
 190         my $irt;
 191         my $obfs_ibx = $ctx->{-obfs_ibx};
 192
 193         $subj = '(no subject)' if $subj eq '';
 194         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 195         $subj = '<b>'.ascii_html($subj).'</b>';
 196         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 197         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 198         $rv .= $subj . "\n";
 199         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 200         my @tocc;
 201         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 202
 203         # Deleting these fields saves about 400K as we iterate across 1K msgs
 204         delete @$smsg{qw(ts blob)};
 205
 206         my $hdr = $eml->header_obj;
 207         my $from = _hdr_names_html($hdr, 'From');
 208         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 209         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 210         my $upfx = $ctx->{-upfx};
 211         my $mhref = $upfx . mid_href($mid_raw) . '/';
 212         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 213         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 214         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 215         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 216         my ($tlen, $clen) = (length($to), length($cc));
 217         my $to_cc = '';
 218         if (($tlen + $clen) > COLS) {
 219                 $to_cc .= '  To: '.$to."\n" if $tlen;
 220                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 221         } else {
 222                 if ($tlen) {
 223                         $to_cc .= '  To: '.$to;
 224                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 225                 } else {
 226                         $to_cc .= '  Cc: '.$cc if $clen;
 227                 }
 228                 $to_cc .= "\n";
 229         }
 230         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 231         $rv .= $to_cc;
 232
 233         my $mapping = $ctx->{mapping};
 234         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 235                 my $href = $upfx . mid_href($irt) . '/';
 236                 my $html = ascii_html($irt);
 237                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 238         }
 239         $rv .= "\n";
 240
 241         # scan through all parts, looking for displayable text
 242         $ctx->{mhref} = $mhref;
 243         $ctx->{obuf} = \$rv;
 244         $eml->each_part(\&add_text_body, $ctx, 1);
 245         delete $ctx->{obuf};
 246
 247         # add the footer
 248         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 249                 "<a\nhref=\"$mhref\">permalink</a>" .
 250                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 251                 " <a\nhref=\"${mhref}#R\">reply</a>";
 252
 253         my $hr;
 254         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 255                 $rv .= "\t[relevance $pct%]";
 256                 $hr = 1;
 257         } elsif ($mapping) {
 258                 my $nested = 'nested';
 259                 my $flat = 'flat';
 260                 my $end = '';
 261                 if ($ctx->{flat}) {
 262                         $hr = 1;
 263                         $flat = "<b>$flat</b>";
 264                 } else {
 265                         $nested = "<b>$nested</b>";
 266                 }
 267                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 268                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 269                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 270         } else {
 271                 $hr = $ctx->{-hr};
 272         }
 273
 274         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 275         $rv;
 276 }
 277
 278 sub pad_link ($$;$) {
 279         my ($mid, $level, $s) = @_;
 280         $s ||= '...';
 281         my $id = id_compress($mid, 1);
 282         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 283 }
 284
 285 sub _th_index_lite {
 286         my ($mid_raw, $irt, $id, $ctx) = @_;
 287         my $rv = '';
 288         my $mapping = $ctx->{mapping} or return $rv;
 289         my $pad = '  ';
 290         my $mid_map = $mapping->{$mid_raw};
 291         defined $mid_map or
 292                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 293         my ($attr, $node, $idx, $level) = @$mid_map;
 294         my $children = $node->{children};
 295         my $nr_c = scalar @$children;
 296         my $nr_s = 0;
 297         my $siblings;
 298         # delete saves about 200KB on a 1K message thread
 299         if (my $refs = delete $node->{references}) {
 300                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 301         }
 302         my $irt_map = $mapping->{$$irt} if defined $$irt;
 303         if (defined $irt_map) {
 304                 $siblings = $irt_map->[1]->{children};
 305                 $nr_s = scalar(@$siblings) - 1;
 306                 $rv .= $pad . $irt_map->[0];
 307                 if ($idx > 0) {
 308                         my $prev = $siblings->[$idx - 1];
 309                         my $pmid = $prev->{mid};
 310                         if ($idx > 2) {
 311                                 my $s = ($idx - 1). ' preceding siblings ...';
 312                                 $rv .= pad_link($pmid, $level, $s);
 313                         } elsif ($idx == 2) {
 314                                 my $ppmid = $siblings->[0]->{mid};
 315                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 316                         }
 317                         $rv .= $pad . $mapping->{$pmid}->[0];
 318                 }
 319         }
 320         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 321         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 322         $attr =~ s!\n\z!</b>\n!s;
 323         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 324         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 325         $rv .= "<b>@ $attr";
 326         if ($nr_c) {
 327                 my $cmid = $children->[0]->{mid};
 328                 $rv .= $pad . $mapping->{$cmid}->[0];
 329                 if ($nr_c > 2) {
 330                         my $s = ($nr_c - 1). ' more replies';
 331                         $rv .= pad_link($cmid, $level + 1, $s);
 332                 } elsif (my $cn = $children->[1]) {
 333                         $rv .= $pad . $mapping->{$cn->{mid}}->[0];
 334                 }
 335         }
 336
 337         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 338         if ($next) {
 339                 my $nmid = $next->{mid};
 340                 $rv .= $pad . $mapping->{$nmid}->[0];
 341                 my $nnext = $nr_s - $idx;
 342                 if ($nnext > 2) {
 343                         my $s = ($nnext - 1).' subsequent siblings';
 344                         $rv .= pad_link($nmid, $level, $s);
 345                 } elsif (my $nn = $siblings->[$idx + 2]) {
 346                         $rv .= $pad . $mapping->{$nn->{mid}}->[0];
 347                 }
 348         }
 349         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 350 }
 351
 352 # non-recursive thread walker
 353 sub walk_thread ($$$) {
 354         my ($rootset, $ctx, $cb) = @_;
 355         my @q = map { (0, $_, -1) } @$rootset;
 356         while (@q) {
 357                 my ($level, $node, $i) = splice(@q, 0, 3);
 358                 defined $node or next;
 359                 $cb->($ctx, $level, $node, $i) or return;
 360                 ++$level;
 361                 $i = 0;
 362                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 363         }
 364 }
 365
 366 sub pre_thread  { # walk_thread callback
 367         my ($ctx, $level, $node, $idx) = @_;
 368         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 369         skel_dump($ctx, $level, $node);
 370 }
 371
 372 sub thread_eml_entry {
 373         my ($ctx, $level, $smsg, $eml) = @_;
 374         my ($beg, $end) = thread_adj_level($ctx, $level);
 375         $beg . '<pre>' . eml_entry($ctx, $smsg, $eml, 0) . '</pre>' . $end;
 376 }
 377
 378 sub next_in_queue ($$) {
 379         my ($q, $ghost_ok) = @_;
 380         while (@$q) {
 381                 my ($level, $smsg) = splice(@$q, 0, 2);
 382                 my $cl = $level + 1;
 383                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 384                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 385         }
 386         undef;
 387 }
 388
 389 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 390         my ($ctx, $eml) = @_;
 391
 392         if ($eml) {
 393                 my ($level, $smsg) = delete @$ctx{qw(level smsg)};
 394                 if ($ctx->{nr} == 1) {
 395                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 396                         $ctx->zmore($ctx->html_top);
 397                 }
 398                 return thread_eml_entry($ctx, $level, $smsg, $eml);
 399         }
 400         return unless exists($ctx->{skel});
 401         my $ghost_ok = $ctx->{nr}++;
 402         while (1) {
 403                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 404                 if ($smsg) {
 405                         if (exists $smsg->{blob}) { # next message for cat-file
 406                                 $ctx->{level} = $lvl;
 407                                 return $smsg;
 408                         }
 409                         # buffer the ghost entry and loop
 410                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 411                 } else { # all done
 412                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 413                         $ctx->zmore(${delete($ctx->{skel})});
 414                         return;
 415                 }
 416         }
 417 }
 418
 419 sub stream_thread ($$) {
 420         my ($rootset, $ctx) = @_;
 421         $ctx->{-queue} = [ map { (0, $_) } @$rootset ];
 422         PublicInbox::WwwStream::aresponse($ctx, 200, \&stream_thread_i);
 423 }
 424
 425 # /$INBOX/$MESSAGE_ID/t/
 426 sub thread_html {
 427         my ($ctx) = @_;
 428         my $mid = $ctx->{mid};
 429         my $ibx = $ctx->{-inbox};
 430         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 431         return missing_thread($ctx) if $nr == 0;
 432         my $skel = '<hr><pre>';
 433         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 434         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 435         $skel .= "<b\nid=t>Thread overview:</b> ";
 436         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 437         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 438         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 439         $skel .= "-- links below jump to the message on this page --\n";
 440         $ctx->{-upfx} = '../../';
 441         $ctx->{cur_level} = 0;
 442         $ctx->{skel} = \$skel;
 443         $ctx->{prev_attr} = '';
 444         $ctx->{prev_level} = 0;
 445         $ctx->{root_anchor} = anchor_for($mid);
 446         $ctx->{mapping} = {};
 447         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 448                        .' in thread';
 449
 450         my $rootset = thread_results($ctx, $msgs);
 451
 452         # reduce hash lookups in pre_thread->skel_dump
 453         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 454         walk_thread($rootset, $ctx, \&pre_thread);
 455
 456         $skel .= '</pre>';
 457         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 458
 459         # flat display: lazy load the full message from smsg
 460         $ctx->{msgs} = $msgs;
 461         $ctx->{-html_tip} = '<pre>';
 462         PublicInbox::WwwStream::aresponse($ctx, 200, \&thread_html_i);
 463 }
 464
 465 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 466         my ($ctx, $eml) = @_;
 467         if ($eml) {
 468                 my $smsg = $ctx->{smsg};
 469                 if (exists $ctx->{-html_tip}) {
 470                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 471                         $ctx->zmore($ctx->html_top);
 472                 }
 473                 return eml_entry($ctx, $smsg, $eml, scalar @{$ctx->{msgs}});
 474         } else {
 475                 while (my $smsg = shift @{$ctx->{msgs}}) {
 476                         return $smsg if exists($smsg->{blob});
 477                 }
 478                 my $skel = delete($ctx->{skel}) or return; # all done
 479                 $ctx->zmore($$skel);
 480                 undef;
 481         }
 482 }
 483
 484 sub multipart_text_as_html {
 485         # ($mime, $ctx) = @_; # each_part may do "$_[0] = undef"
 486
 487         # scan through all parts, looking for displayable text
 488         $_[0]->each_part(\&add_text_body, $_[1], 1);
 489 }
 490
 491 sub submsg_hdr ($$) {
 492         my ($ctx, $eml) = @_;
 493         my $obfs_ibx = $ctx->{-obfs_ibx};
 494         my $rv = $ctx->{obuf};
 495         $$rv .= "\n";
 496         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 497                 my @v = $eml->header($h);
 498                 for my $v (@v) {
 499                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 500                         $v = ascii_html($v);
 501                         $$rv .= "$h: $v\n";
 502                 }
 503         }
 504 }
 505
 506 sub attach_link ($$$$;$) {
 507         my ($ctx, $ct, $p, $fn, $err) = @_;
 508         my ($part, $depth, $idx) = @$p;
 509
 510         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 511         # downloads for 0-byte multipart attachments
 512         return unless $part->{bdy};
 513
 514         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 515         my $size = bytes::length($part->body);
 516
 517         # hide attributes normally, unless we want to aid users in
 518         # spotting MUA problems:
 519         $ct =~ s/;.*// unless $err;
 520         $ct = ascii_html($ct);
 521         my $sfn;
 522         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 523                 $sfn = $fn;
 524         } elsif ($ct eq 'text/plain') {
 525                 $sfn = 'a.txt';
 526         } else {
 527                 $sfn = 'a.bin';
 528         }
 529         my $rv = $ctx->{obuf};
 530         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 531         if ($err) {
 532                 $$rv .= <<EOF;
 533 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 534 EOF
 535         }
 536         $$rv .= "[-- Attachment #$idx: ";
 537         my $ts = "Type: $ct, Size: $size bytes";
 538         my $desc = $part->header('Content-Description') // $fn // '';
 539         $desc = ascii_html($desc);
 540         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 541         $$rv .= "</a>\n";
 542
 543         submsg_hdr($ctx, $part) if $part->{is_submsg};
 544
 545         undef;
 546 }
 547
 548 sub add_text_body { # callback for each_part
 549         my ($p, $ctx) = @_;
 550         my $upfx = $ctx->{mhref};
 551         my $ibx = $ctx->{-inbox};
 552         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 553         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 554         my ($part, $depth, $idx) = @$p;
 555         my $ct = $part->content_type || 'text/plain';
 556         my $fn = $part->filename;
 557         my ($s, $err) = msg_part_text($part, $ct);
 558         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 559
 560         my $rv = $ctx->{obuf};
 561         if ($part->{is_submsg}) {
 562                 submsg_hdr($ctx, $part);
 563                 $$rv .= "\n";
 564         }
 565
 566         # makes no difference to browsers, and don't screw up filename
 567         # link generation in diffs with the extra '%0D'
 568         $s =~ s/\r\n/\n/sg;
 569
 570         # will be escaped to `&#8226;' in HTML
 571         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 572
 573         # always support diff-highlighting, but we can't linkify hunk
 574         # headers for solver unless some coderepo are configured:
 575         my $diff;
 576         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 577                 # diffstat anchors do not link across attachments or messages,
 578                 # -apfx is just a stable prefix for making diffstat anchors
 579                 # linkable to the first diff hunk w/o crossing attachments
 580                 $idx =~ tr!.!/!; # compatibility with previous versions
 581                 $ctx->{-apfx} = $upfx . $idx;
 582
 583                 # do attr => filename mappings for diffstats in git diffs:
 584                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 585                 $diff = 1;
 586                 delete $ctx->{-long_path};
 587                 my $spfx;
 588                 if ($ibx->{-repo_objs}) {
 589                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 590                                 $spfx = $upfx;
 591                                 $spfx =~ s!/([^/]*)/\z!/!;
 592                         } else {
 593                                 my $n_slash = $upfx =~ tr!/!/!;
 594                                 if ($n_slash == 0) {
 595                                         $spfx = '../';
 596                                 } elsif ($n_slash == 1) {
 597                                         $spfx = '';
 598                                 } else { # nslash == 2
 599                                         $spfx = '../../';
 600                                 }
 601                         }
 602                 }
 603                 $ctx->{-spfx} = $spfx;
 604         };
 605
 606         # some editors don't put trailing newlines at the end:
 607         $s .= "\n" unless $s =~ /\n\z/s;
 608
 609         # split off quoted and unquoted blocks:
 610         my @sections = PublicInbox::MsgIter::split_quotes($s);
 611         undef $s; # free memory
 612         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 613                 # badly-encoded message with $err? tell the world about it!
 614                 attach_link($ctx, $ct, $p, $fn, $err);
 615                 $$rv .= "\n";
 616         }
 617         foreach my $cur (@sections) {
 618                 if ($cur =~ /\A>/) {
 619                         # we use a <span> here to allow users to specify
 620                         # their own color for quoted text
 621                         $$rv .= qq(<span\nclass="q">);
 622                         $$rv .= $l->to_html($cur);
 623                         $$rv .= '</span>';
 624                 } elsif ($diff) {
 625                         flush_diff($ctx, \$cur);
 626                 } else {
 627                         # regular lines, OK
 628                         $$rv .= $l->to_html($cur);
 629                 }
 630                 undef $cur; # free memory
 631         }
 632 }
 633
 634 sub _msg_page_prepare_obuf {
 635         my ($hdr, $ctx) = @_;
 636         my $over = $ctx->{-inbox}->over;
 637         my $obfs_ibx = $ctx->{-obfs_ibx};
 638         my $rv = '';
 639         my $mids = mids_for_index($hdr);
 640         my $nr = $ctx->{nr}++;
 641         if ($nr) { # unlikely
 642                 $rv .= '<pre>';
 643         } else {
 644                 $ctx->{first_hdr} = $hdr;
 645                 if ($ctx->{smsg}) {
 646                         $rv .=
 647 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 648                 }
 649                 $rv .= "<pre\nid=b>"; # anchor for body start
 650         }
 651         $ctx->{-upfx} = '../' if $over;
 652         my @title; # (Subject[0], From[0])
 653         for my $v ($hdr->header('From')) {
 654                 my @n = PublicInbox::Address::names($v);
 655                 $v = ascii_html($v);
 656                 $title[1] //= ascii_html(join(', ', @n));
 657                 if ($obfs_ibx) {
 658                         obfuscate_addrs($obfs_ibx, $v);
 659                         obfuscate_addrs($obfs_ibx, $title[1]);
 660                 }
 661                 $rv .= "From: $v\n" if $v ne '';
 662         }
 663         foreach my $h (qw(To Cc)) {
 664                 for my $v ($hdr->header($h)) {
 665                         fold_addresses($v);
 666                         $v = ascii_html($v);
 667                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 668                         $rv .= "$h: $v\n" if $v ne '';
 669                 }
 670         }
 671         my @subj = $hdr->header('Subject');
 672         if (@subj) {
 673                 my $v = ascii_html(shift @subj);
 674                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 675                 $rv .= 'Subject: ';
 676                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 677                 $title[0] = $v;
 678                 for $v (@subj) { # multi-Subject message :<
 679                         $v = ascii_html($v);
 680                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 681                         $rv .= "Subject: $v\n";
 682                 }
 683         } else { # dummy anchor for thread skeleton at bottom of page
 684                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 685                 $title[0] = '(no subject)';
 686         }
 687         for my $v ($hdr->header('Date')) {
 688                 $v = ascii_html($v);
 689                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 690                 $rv .= "Date: $v\n";
 691         }
 692         if (!$nr) { # first (and only) message, common case
 693                 $ctx->{-title_html} = join(' - ', @title);
 694                 $rv = $ctx->html_top . $rv;
 695         }
 696         if (scalar(@$mids) == 1) { # common case
 697                 my $mhtml = ascii_html($mids->[0]);
 698                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 699                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 700         } else {
 701                 # X-Alt-Message-ID can happen if a message is injected from
 702                 # public-inbox-nntpd because of multiple Message-ID headers.
 703                 my $lnk = PublicInbox::Linkify->new;
 704                 my $s = '';
 705                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 706                         $s .= "$h: $_\n" for ($hdr->header_raw($h));
 707                 }
 708                 $lnk->linkify_mids('..', \$s, 1);
 709                 $rv .= $s;
 710         }
 711         $rv .= _parent_headers($hdr, $over);
 712         $rv .= "\n";
 713         \$rv;
 714 }
 715
 716 sub SKEL_EXPAND () {
 717         qq(expand[<a\nhref="T/#u">flat</a>) .
 718                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 719                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 720                 qq(<a\nhref="t.atom">Atom feed</a>);
 721 }
 722
 723 sub thread_skel ($$$) {
 724         my ($skel, $ctx, $hdr) = @_;
 725         my $mid = mids($hdr)->[0];
 726         my $ibx = $ctx->{-inbox};
 727         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 728         my $parent = in_reply_to($hdr);
 729         $$skel .= "\n<b>Thread overview: </b>";
 730         if ($nr <= 1) {
 731                 if (defined $parent) {
 732                         $$skel .= SKEL_EXPAND."\n ";
 733                         $$skel .= ghost_parent('../', $parent) . "\n";
 734                 } else {
 735                         $$skel .= '[no followups] '.SKEL_EXPAND."\n";
 736                 }
 737                 $ctx->{next_msg} = undef;
 738                 $ctx->{parent_msg} = $parent;
 739                 return;
 740         }
 741
 742         $$skel .= $nr;
 743         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 744
 745         # nb: mutt only shows the first Subject in the index pane
 746         # when multiple Subject: headers are present, so we follow suit:
 747         my $subj = $hdr->header('Subject') // '';
 748         $subj = '(no subject)' if $subj eq '';
 749         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 750         $ctx->{cur} = $mid;
 751         $ctx->{prev_attr} = '';
 752         $ctx->{prev_level} = 0;
 753         $ctx->{skel} = $skel;
 754
 755         # reduce hash lookups in skel_dump
 756         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 757         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 758
 759         $ctx->{parent_msg} = $parent;
 760 }
 761
 762 sub _parent_headers {
 763         my ($hdr, $over) = @_;
 764         my $rv = '';
 765         my @irt = $hdr->header_raw('In-Reply-To');
 766         my $refs;
 767         if (@irt) {
 768                 my $lnk = PublicInbox::Linkify->new;
 769                 $rv .= "In-Reply-To: $_\n" for @irt;
 770                 $lnk->linkify_mids('..', \$rv);
 771         } else {
 772                 $refs = references($hdr);
 773                 my $irt = pop @$refs;
 774                 if (defined $irt) {
 775                         my $html = ascii_html($irt);
 776                         my $href = mid_href($irt);
 777                         $rv .= "In-Reply-To: &lt;";
 778                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 779                 }
 780         }
 781
 782         # do not display References: if search is present,
 783         # we show the thread skeleton at the bottom, instead.
 784         return $rv if $over;
 785
 786         $refs //= references($hdr);
 787         if (@$refs) {
 788                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 789                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 790         }
 791         $rv;
 792 }
 793
 794 # returns a string buffer via ->getline
 795 sub html_footer {
 796         my ($ctx, $hdr) = @_;
 797         my $ibx = $ctx->{-inbox};
 798         my $upfx = '../';
 799         my $skel = " <a\nhref=\"$upfx\">index</a>";
 800         my $rv = '<pre>';
 801         if ($ibx->over) {
 802                 $skel .= "\n";
 803                 thread_skel(\$skel, $ctx, $hdr);
 804                 my ($next, $prev);
 805                 my $parent = '       ';
 806                 $next = $prev = '    ';
 807
 808                 if (my $n = $ctx->{next_msg}) {
 809                         $n = mid_href($n);
 810                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 811                 }
 812                 my $u;
 813                 my $par = $ctx->{parent_msg};
 814                 if ($par) {
 815                         $u = mid_href($par);
 816                         $u = "$upfx$u/";
 817                 }
 818                 if (my $p = $ctx->{prev_msg}) {
 819                         $prev = mid_href($p);
 820                         if ($p && $par && $p eq $par) {
 821                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 822                                         'rel=prev>prev parent</a>';
 823                                 $parent = '';
 824                         } else {
 825                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 826                                         'rel=prev>prev</a>';
 827                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 828                         }
 829                 } elsif ($u) { # unlikely
 830                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 831                 }
 832                 $rv .= "$next $prev$parent ";
 833         }
 834         $rv .= qq(<a\nhref="#R">reply</a>);
 835         $rv .= $skel;
 836         $rv .= '</pre>';
 837         $rv .= msg_reply($ctx, $hdr);
 838 }
 839
 840 sub linkify_ref_no_over {
 841         my ($mid) = @_;
 842         my $href = mid_href($mid);
 843         my $html = ascii_html($mid);
 844         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 845 }
 846
 847 sub anchor_for {
 848         my ($msgid) = @_;
 849         'm' . id_compress($msgid, 1);
 850 }
 851
 852 sub ghost_parent {
 853         my ($upfx, $mid) = @_;
 854
 855         my $href = mid_href($mid);
 856         my $html = ascii_html($mid);
 857         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 858 }
 859
 860 sub indent_for {
 861         my ($level) = @_;
 862         $level ? INDENT x ($level - 1) : '';
 863 }
 864
 865 sub find_mid_root {
 866         my ($ctx, $level, $node, $idx) = @_;
 867         ++$ctx->{root_idx} if $level == 0;
 868         if ($node->{mid} eq $ctx->{mid}) {
 869                 $ctx->{found_mid_at} = $ctx->{root_idx};
 870                 return 0;
 871         }
 872         1;
 873 }
 874
 875 sub strict_loose_note ($) {
 876         my ($nr) = @_;
 877         my $msg =
 878 "  -- strict thread matches above, loose matches on Subject: below --\n";
 879
 880         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 881                 $msg .=
 882 "  -- use mbox.gz link to download all $nr messages --\n";
 883         }
 884         $msg;
 885 }
 886
 887 sub thread_results {
 888         my ($ctx, $msgs) = @_;
 889         require PublicInbox::SearchThread;
 890         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 891
 892         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 893         # and preserved in the future.  This bug is hidden by `sid' matches
 894         # in get_thread, so we never noticed it until now.  And even when
 895         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 896         # bump since reindexing is expensive and users may not do it
 897
 898         # loose threading could've returned too many results,
 899         # put the root the message we care about at the top:
 900         my $mid = $ctx->{mid};
 901         if (defined($mid) && scalar(@$rootset) > 1) {
 902                 $ctx->{root_idx} = -1;
 903                 my $nr = scalar @$msgs;
 904                 walk_thread($rootset, $ctx, \&find_mid_root);
 905                 my $idx = $ctx->{found_mid_at};
 906                 if (defined($idx) && $idx != 0) {
 907                         my $tip = splice(@$rootset, $idx, 1);
 908                         @$rootset = reverse @$rootset;
 909                         unshift @$rootset, $tip;
 910                         $ctx->{sl_note} = strict_loose_note($nr);
 911                 }
 912         }
 913         $rootset
 914 }
 915
 916 sub missing_thread {
 917         my ($ctx) = @_;
 918         require PublicInbox::ExtMsg;
 919         PublicInbox::ExtMsg::ext_msg($ctx);
 920 }
 921
 922 sub dedupe_subject {
 923         my ($prev_subj, $subj, $val) = @_;
 924
 925         my $omit; # '"' denotes identical text omitted
 926         my (@prev_pop, @curr_pop);
 927         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 928                 push(@prev_pop, pop(@$prev_subj));
 929                 push(@curr_pop, pop(@$subj));
 930                 $omit //= $val;
 931         }
 932         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 933         if (scalar(@curr_pop) == 1) {
 934                 $omit = undef;
 935                 push @$prev_subj, @prev_pop;
 936                 push @$subj, @curr_pop;
 937         }
 938         $omit // '';
 939 }
 940
 941 sub skel_dump { # walk_thread callback
 942         my ($ctx, $level, $smsg) = @_;
 943         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 944
 945         my $skel = $ctx->{skel};
 946         my $cur = $ctx->{cur};
 947         my $mid = $smsg->{mid};
 948
 949         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 950                 $$skel .= delete($ctx->{sl_note}) || '';
 951         }
 952
 953         my $f = ascii_html($smsg->{from_name});
 954         my $obfs_ibx = $ctx->{-obfs_ibx};
 955         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 956
 957         my $d = fmt_ts($smsg->{ds});
 958         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 959         if (exists $ctx->{searchview}) {
 960                 if (defined(my $pct = $smsg->{pct})) {
 961                         $d .= (sprintf(' % 2u', $pct) . '%');
 962                 } else {
 963                         $unmatched = 1;
 964                         $d .= '    ';
 965                 }
 966         }
 967         $d .= ' ' . indent_for($level) . th_pfx($level);
 968         my $attr = $f;
 969         $ctx->{first_level} ||= $level;
 970
 971         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 972                 $ctx->{prev_attr} = $attr;
 973         }
 974         $ctx->{prev_level} = $level;
 975
 976         if ($cur) {
 977                 if ($cur eq $mid) {
 978                         delete $ctx->{cur};
 979                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 980                                  "$attr [this message]</a></b>\n";
 981                         return 1;
 982                 } else {
 983                         $ctx->{prev_msg} = $mid;
 984                 }
 985         } else {
 986                 $ctx->{next_msg} ||= $mid;
 987         }
 988
 989         # Subject is never undef, this mail was loaded from
 990         # our Xapian which would've resulted in '' if it were
 991         # really missing (and Filter rejects empty subjects)
 992         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 993         # remove common suffixes from the subject if it matches the previous,
 994         # so we do not show redundant text at the end.
 995         my $prev_subj = $ctx->{prev_subj} || [];
 996         $ctx->{prev_subj} = [ @subj ];
 997         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 998         my $end;
 999         if (@subj) {
1000                 my $subj = join(' ', @subj);
1001                 $subj = ascii_html($subj);
1002                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1003                 $end = "$subj</a> $omit$f\n"
1004         } else {
1005                 $end = "$f</a>\n";
1006         }
1007         my $m;
1008         my $id = '';
1009         my $mapping = $unmatched ? undef : $ctx->{mapping};
1010         if ($mapping) {
1011                 my $map = $mapping->{$mid};
1012                 $id = id_compress($mid, 1);
1013                 $m = '#m'.$id;
1014                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1015                 $id = "\nid=r".$id;
1016         } else {
1017                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1018         }
1019         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1020         1;
1021 }
1022
1023 sub _skel_ghost {
1024         my ($ctx, $level, $node) = @_;
1025
1026         my $mid = $node->{mid};
1027         my $d = '     [not found] ';
1028         $d .= '    '  if exists $ctx->{searchview};
1029         $d .= indent_for($level) . th_pfx($level);
1030         my $upfx = $ctx->{-upfx};
1031         my $href = $upfx . mid_href($mid) . '/';
1032         my $html = ascii_html($mid);
1033
1034         my $mapping = $ctx->{mapping};
1035         my $map = $mapping->{$mid} if $mapping;
1036         if ($map) {
1037                 my $id = id_compress($mid, 1);
1038                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1039                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1040         } else {
1041                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1042         }
1043         ${$ctx->{skel}} .= $d;
1044         1;
1045 }
1046
1047 sub sort_ds {
1048         [ sort {
1049                 (eval { $a->topmost->{ds} } || 0) <=>
1050                 (eval { $b->topmost->{ds} } || 0)
1051         } @{$_[0]} ];
1052 }
1053
1054 # accumulate recent topics if search is supported
1055 # returns 200 if done, 404 if not
1056 sub acc_topic { # walk_thread callback
1057         my ($ctx, $level, $smsg) = @_;
1058         my $mid = $smsg->{mid};
1059         my $has_blob = $smsg->{blob} // do {
1060                 if (my $by_mid = $ctx->{-inbox}->smsg_by_mid($mid)) {
1061                         %$smsg = (%$smsg, %$by_mid);
1062                         1;
1063                 }
1064         };
1065         if ($has_blob) {
1066                 my $subj = subject_normalized($smsg->{subject});
1067                 $subj = '(no subject)' if $subj eq '';
1068                 my $ds = $smsg->{ds};
1069                 if ($level == 0) { # new, top-level topic
1070                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1071                         $ctx->{-cur_topic} = $topic;
1072                         push @{$ctx->{order}}, $topic;
1073                         return 1;
1074                 }
1075
1076                 # continue existing topic
1077                 my $topic = $ctx->{-cur_topic}; # should never be undef
1078                 $topic->[0] = $ds if $ds > $topic->[0];
1079                 $topic->[1]++; # bump N+ message counter
1080                 my $seen = $topic->[2];
1081                 if (scalar(@$topic) == 3) { # parent was a ghost
1082                         push @$topic, $subj;
1083                 } elsif (!defined($seen->{$subj})) {
1084                         push @$topic, $level, $subj; # @extra messages
1085                 }
1086                 $seen->{$subj} = $mid; # latest for subject
1087         } else { # ghost message
1088                 return 1 if $level != 0; # ignore child ghosts
1089                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1090                 push @{$ctx->{order}}, $topic;
1091         }
1092         1;
1093 }
1094
1095 sub dump_topics {
1096         my ($ctx) = @_;
1097         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1098         unless ($order) {
1099                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1100                 return 404;
1101         }
1102
1103         my @out;
1104         my $ibx = $ctx->{-inbox};
1105         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1106
1107         # sort by recency, this allows new posts to "bump" old topics...
1108         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1109                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1110                 @$topic = ();
1111                 next unless defined $top_subj;  # ghost topic
1112                 my $mid = delete $seen->{$top_subj};
1113                 my $href = mid_href($mid);
1114                 my $prev_subj = [ split(/ /, $top_subj) ];
1115                 $top_subj = ascii_html($top_subj);
1116                 $ds = fmt_ts($ds);
1117
1118                 # $n isn't the total number of posts on the topic,
1119                 # just the number of posts in the current results window
1120                 my $anchor;
1121                 if ($n == 1) {
1122                         $n = '';
1123                         $anchor = '#u'; # top of only message
1124                 } else {
1125                         $n = " ($n+ messages)";
1126                         $anchor = '#t'; # thread skeleton
1127                 }
1128
1129                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1130                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1131                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1132                         " $ds UTC $n - $mbox / $atom\n";
1133                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1134                         my $level = $extra[$i];
1135                         my $subj = $extra[$i + 1]; # already normalized
1136                         $mid = delete $seen->{$subj};
1137                         my @subj = split(/ /, $subj);
1138                         my @next_prev = @subj; # full copy
1139                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1140                         $prev_subj = \@next_prev;
1141                         $subj = join(' ', @subj);
1142                         $subj = ascii_html($subj);
1143                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1144                         $href = mid_href($mid);
1145                         $s .= indent_for($level) . TCHILD;
1146                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1147                 }
1148                 push @out, $s;
1149         }
1150         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1151         200;
1152 }
1153
1154 # only for the t= query parameter passed to overview DB
1155 sub ts2str ($) { strftime('%Y%m%d%H%M%S', gmtime($_[0])) };
1156
1157 sub str2ts ($) {
1158         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1159         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1160 }
1161
1162 sub pagination_footer ($$) {
1163         my ($ctx, $latest) = @_;
1164         delete $ctx->{qp} or return;
1165         my $next = $ctx->{next_page} || '';
1166         my $prev = $ctx->{prev_page} || '';
1167         if ($prev) {
1168                 $next = $next ? "$next " : '     ';
1169                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1170         }
1171         "<hr><pre>page: $next$prev</pre>";
1172 }
1173
1174 sub index_nav { # callback for WwwStream::getline
1175         my ($ctx) = @_;
1176         return $ctx->html_top if exists $ctx->{-html_tip};
1177         pagination_footer($ctx, '.')
1178 }
1179
1180 sub paginate_recent ($$) {
1181         my ($ctx, $lim) = @_;
1182         my $t = $ctx->{qp}->{t} || '';
1183         my $opts = { limit => $lim };
1184         my ($after, $before);
1185
1186         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1187         # if only $after exists "YYYYMMDD.." because "." could be skipped
1188         # if interpreted as an end-of-sentence
1189         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1190         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1191
1192         my $ibx = $ctx->{-inbox};
1193         my $msgs = $ibx->recent($opts, $after, $before);
1194         my $nr = scalar @$msgs;
1195         if ($nr < $lim && defined($after)) {
1196                 $after = $before = undef;
1197                 $msgs = $ibx->recent($opts);
1198                 $nr = scalar @$msgs;
1199         }
1200         my $more = $nr == $lim;
1201         my ($newest, $oldest);
1202         if ($nr) {
1203                 $newest = $msgs->[0]->{ts};
1204                 $oldest = $msgs->[-1]->{ts};
1205                 # if we only had $after, our SQL query in ->recent ordered
1206                 if ($newest < $oldest) {
1207                         ($oldest, $newest) = ($newest, $oldest);
1208                         $more = 0 if defined($after) && $after < $oldest;
1209                 }
1210         }
1211         if (defined($oldest) && $more) {
1212                 my $s = ts2str($oldest);
1213                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1214         }
1215         if (defined($newest) && (defined($before) || defined($after))) {
1216                 my $s = ts2str($newest);
1217                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1218         }
1219         $msgs;
1220 }
1221
1222 sub index_topics {
1223         my ($ctx) = @_;
1224         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1225         if (@$msgs) {
1226                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1227         }
1228         PublicInbox::WwwStream::response($ctx, dump_topics($ctx), \&index_nav);
1229 }
1230
1231 sub thread_adj_level {
1232         my ($ctx, $level) = @_;
1233
1234         my $max = $ctx->{cur_level};
1235         if ($level <= 0) {
1236                 return ('', '') if $max == 0; # flat output
1237
1238                 # reset existing lists
1239                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1240                 $ctx->{cur_level} = 0;
1241                 ("$beg</ul>", '');
1242         } elsif ($level == $max) { # continue existing list
1243                 qw(<li> </li>);
1244         } elsif ($level < $max) {
1245                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1246                 $ctx->{cur_level} = $level;
1247                 ("$beg<li>", '</li>');
1248         } else { # ($level > $max) # start a new level
1249                 $ctx->{cur_level} = $level;
1250                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1251                 ($beg, '</li>');
1252         }
1253 }
1254
1255 sub ghost_index_entry {
1256         my ($ctx, $level, $node) = @_;
1257         my ($beg, $end) = thread_adj_level($ctx,  $level);
1258         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid})
1259                 . '</pre>' . $end;
1260 }
1261
1262 1;