lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MsgTime qw(msg_datestamp);
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::Linkify;
  12 use PublicInbox::MID qw/id_compress mid_escape mids references/;
  13 use PublicInbox::MsgIter;
  14 use PublicInbox::Address;
  15 use PublicInbox::WwwStream;
  16 use PublicInbox::Reply;
  17 use PublicInbox::ViewDiff qw(flush_diff);
  18 require POSIX;
  19 use Time::Local qw(timegm);
  20
  21 use constant COLS => 72;
  22 use constant INDENT => '  ';
  23 use constant TCHILD => '` ';
  24 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  25
  26 # public functions: (unstable)
  27
  28 sub msg_html {
  29         my ($ctx, $mime, $more, $smsg) = @_;
  30         my $hdr = $mime->header_obj;
  31         my $ibx = $ctx->{-inbox};
  32         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  33         my $tip = _msg_html_prepare($hdr, $ctx, $more, 0);
  34         my $end = 2;
  35         PublicInbox::WwwStream->response($ctx, 200, sub {
  36                 my ($nr, undef) = @_;
  37                 if ($nr == 1) {
  38                         # $more cannot be true w/o $smsg being defined:
  39                         my $upfx = $more ? '../'.mid_escape($smsg->mid).'/' : '';
  40                         $tip . multipart_text_as_html($mime, $upfx, $ctx) .
  41                                 '</pre><hr>'
  42                 } elsif ($more && @$more) {
  43                         ++$end;
  44                         msg_html_more($ctx, $more, $nr);
  45                 } elsif ($nr == $end) {
  46                         # fake an EOF if generating the footer fails;
  47                         # we want to at least show the message if something
  48                         # here crashes:
  49                         eval {
  50                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  51                                 '</pre>' . msg_reply($ctx, $hdr)
  52                         };
  53                 } else {
  54                         undef
  55                 }
  56         });
  57 }
  58
  59 sub msg_page {
  60         my ($ctx) = @_;
  61         my $mid = $ctx->{mid};
  62         my $ibx = $ctx->{-inbox};
  63         my ($first, $more);
  64         my $smsg;
  65         if (my $srch = $ibx->search) {
  66                 my ($id, $prev);
  67                 $smsg = $srch->next_by_mid($mid, \$id, \$prev);
  68                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  69                 if ($first) {
  70                         my $next = $srch->next_by_mid($mid, \$id, \$prev);
  71                         $more = [ $id, $prev, $next ] if $next;
  72                 }
  73                 return unless $first;
  74         } else {
  75                 $first = $ibx->msg_by_mid($mid) or return;
  76         }
  77         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  78 }
  79
  80 sub msg_html_more {
  81         my ($ctx, $more, $nr) = @_;
  82         my $str = eval {
  83                 my ($id, $prev, $smsg) = @$more;
  84                 my $mid = $ctx->{mid};
  85                 my $ibx = $ctx->{-inbox};
  86                 $smsg = $ibx->smsg_mime($smsg);
  87                 my $next = $ctx->{srch}->next_by_mid($mid, \$id, \$prev);
  88                 @$more = $next ? ($id, $prev, $next) : ();
  89                 if ($smsg) {
  90                         my $mime = $smsg->{mime};
  91                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
  92                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
  93                                 multipart_text_as_html($mime, $upfx, $ctx) .
  94                                 '</pre><hr>'
  95                 } else {
  96                         '';
  97                 }
  98         };
  99         if ($@) {
 100                 warn "Error lookup up additional messages: $@\n";
 101                 $str = '<pre>Error looking up additional messages</pre>';
 102         }
 103         $str;
 104 }
 105
 106 # /$INBOX/$MESSAGE_ID/#R
 107 sub msg_reply {
 108         my ($ctx, $hdr) = @_;
 109         my $se_url =
 110          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 111         my $p_url =
 112          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 113
 114         my $info = '';
 115         my $ibx = $ctx->{-inbox};
 116         if (my $url = $ibx->{infourl}) {
 117                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
 118                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 119         }
 120
 121         my ($arg, $link, $reply_to_all) =
 122                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 123         if (ref($arg) eq 'SCALAR') {
 124                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 125         }
 126
 127         # mailto: link only works if address obfuscation is disabled
 128         if ($link) {
 129                 $link = <<EOF;
 130
 131 * If your mail client supports setting the <b>In-Reply-To</b> header
 132   via mailto: links, try the <a
 133 href="$link">mailto: link</a>
 134 EOF
 135         }
 136
 137         push @$arg, '/path/to/YOUR_REPLY';
 138         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 139         <<EOF
 140 <hr><pre
 141 id=R><b>Reply instructions:</b>
 142
 143 You may reply publically to <a
 144 href=#t>this message</a> via plain-text email
 145 using any one of the following methods:
 146
 147 * Save the following mbox file, import it into your mail client,
 148   and $reply_to_all from there: <a
 149 href=raw>mbox</a>
 150
 151   Avoid top-posting and favor interleaved quoting:
 152   <a
 153 href="$p_url">$p_url</a>
 154 $info
 155 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 156   switches of git-send-email(1):
 157
 158   git send-email$arg
 159
 160   <a
 161 href="$se_url">$se_url</a>
 162 $link</pre>
 163 EOF
 164 }
 165
 166 sub in_reply_to {
 167         my ($hdr) = @_;
 168         my $refs = references($hdr);
 169         $refs->[-1];
 170 }
 171
 172 sub fold_addresses ($) {
 173         return $_[0] if length($_[0]) <= COLS;
 174         # try to fold on commas after non-word chars before $lim chars,
 175         # Try to get the "," preceeded by ">" or ")", but avoid folding
 176         # on the comma where somebody uses "Lastname, Firstname".
 177         # We also try to keep the last and penultimate addresses in
 178         # the list on the same line if possible, hence the extra \z
 179         # Fall back to folding on spaces at $lim + 1 chars
 180         my $lim = COLS - 8; # 8 = "\t" display width
 181         my $too_long = $lim + 1;
 182         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 183         $_[0] = join("\n\t",
 184                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 185                                 .{1,$lim}(?:,|\z)|
 186                                 .{1,$lim}|
 187                                 .{$too_long,}?)(?:\s|\z)/xgo));
 188 }
 189
 190 sub _hdr_names_html ($$) {
 191         my ($hdr, $field) = @_;
 192         my $val = $hdr->header($field) or return '';
 193         ascii_html(join(', ', PublicInbox::Address::names($val)));
 194 }
 195
 196 sub nr_to_s ($$$) {
 197         my ($nr, $singular, $plural) = @_;
 198         return "0 $plural" if $nr == 0;
 199         $nr == 1 ? "$nr $singular" : "$nr $plural";
 200 }
 201
 202 # this is already inside a <pre>
 203 sub index_entry {
 204         my ($smsg, $ctx, $more) = @_;
 205         my $srch = $ctx->{srch};
 206         my $subj = $smsg->subject;
 207         my $mid_raw = $smsg->mid;
 208         my $id = id_compress($mid_raw, 1);
 209         my $id_m = 'm'.$id;
 210
 211         my $root_anchor = $ctx->{root_anchor} || '';
 212         my $irt;
 213         my $obfs_ibx = $ctx->{-obfs_ibx};
 214
 215         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 216         $subj = '<b>'.ascii_html($subj).'</b>';
 217         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 218         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 219         $rv .= $subj . "\n";
 220         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 221         my @tocc;
 222         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 223         # deleting {mime} is critical to memory use,
 224         # the rest of the fields saves about 400K as we iterate across 1K msgs
 225         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 226
 227         my $hdr = $mime->header_obj;
 228         my $from = _hdr_names_html($hdr, 'From');
 229         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 230         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 231         my $upfx = $ctx->{-upfx};
 232         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 233         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 234         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 235         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 236         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 237         my ($tlen, $clen) = (length($to), length($cc));
 238         my $to_cc = '';
 239         if (($tlen + $clen) > COLS) {
 240                 $to_cc .= '  To: '.$to."\n" if $tlen;
 241                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 242         } else {
 243                 if ($tlen) {
 244                         $to_cc .= '  To: '.$to;
 245                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 246                 } else {
 247                         $to_cc .= '  Cc: '.$cc if $clen;
 248                 }
 249                 $to_cc .= "\n";
 250         }
 251         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 252         $rv .= $to_cc;
 253
 254         my $mapping = $ctx->{mapping};
 255         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 256                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 257                 my $href = $upfx . $mirt->{href}. '/';
 258                 my $html = $mirt->as_html;
 259                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 260         }
 261         $rv .= "\n";
 262
 263         # scan through all parts, looking for displayable text
 264         my $ibx = $ctx->{-inbox};
 265         msg_iter($mime, sub { $rv .= add_text_body($mhref, $ctx, $_[0]) });
 266
 267         # add the footer
 268         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 269                 "<a\nhref=\"$mhref\">permalink</a>" .
 270                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 271                 " <a\nhref=\"${mhref}#R\">reply</a>";
 272
 273         my $hr;
 274         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 275                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 276                 $hr = 1;
 277         } elsif ($mapping) {
 278                 my $nested = 'nested';
 279                 my $flat = 'flat';
 280                 my $end = '';
 281                 if ($ctx->{flat}) {
 282                         $hr = 1;
 283                         $flat = "<b>$flat</b>";
 284                 } else {
 285                         $nested = "<b>$nested</b>";
 286                 }
 287                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 288                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 289                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 290         } else {
 291                 $hr = $ctx->{-hr};
 292         }
 293
 294         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 295         $rv;
 296 }
 297
 298 sub pad_link ($$;$) {
 299         my ($mid, $level, $s) = @_;
 300         $s ||= '...';
 301         my $id = id_compress($mid, 1);
 302         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 303 }
 304
 305 sub _th_index_lite {
 306         my ($mid_raw, $irt, $id, $ctx) = @_;
 307         my $rv = '';
 308         my $mapping = $ctx->{mapping} or return $rv;
 309         my $pad = '  ';
 310         my $mid_map = $mapping->{$mid_raw};
 311         defined $mid_map or
 312                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 313         my ($attr, $node, $idx, $level) = @$mid_map;
 314         my $children = $node->{children};
 315         my $nr_c = scalar @$children;
 316         my $nr_s = 0;
 317         my $siblings;
 318         if (my $smsg = $node->{smsg}) {
 319                 # delete saves about 200KB on a 1K message thread
 320                 if (my $refs = delete $smsg->{references}) {
 321                         ($$irt) = ($refs =~ m/<([^>]+)>\z/);
 322                 }
 323         }
 324         my $irt_map = $mapping->{$$irt} if defined $$irt;
 325         if (defined $irt_map) {
 326                 $siblings = $irt_map->[1]->{children};
 327                 $nr_s = scalar(@$siblings) - 1;
 328                 $rv .= $pad . $irt_map->[0];
 329                 if ($idx > 0) {
 330                         my $prev = $siblings->[$idx - 1];
 331                         my $pmid = $prev->{id};
 332                         if ($idx > 2) {
 333                                 my $s = ($idx - 1). ' preceding siblings ...';
 334                                 $rv .= pad_link($pmid, $level, $s);
 335                         } elsif ($idx == 2) {
 336                                 my $ppmid = $siblings->[0]->{id};
 337                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 338                         }
 339                         $rv .= $pad . $mapping->{$pmid}->[0];
 340                 }
 341         }
 342         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 343         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 344         $attr =~ s!\n\z!</b>\n!s;
 345         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 346         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 347         $rv .= "<b>@ $attr";
 348         if ($nr_c) {
 349                 my $cmid = $children->[0]->{id};
 350                 $rv .= $pad . $mapping->{$cmid}->[0];
 351                 if ($nr_c > 2) {
 352                         my $s = ($nr_c - 1). ' more replies';
 353                         $rv .= pad_link($cmid, $level + 1, $s);
 354                 } elsif (my $cn = $children->[1]) {
 355                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 356                 }
 357         }
 358
 359         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 360         if ($next) {
 361                 my $nmid = $next->{id};
 362                 $rv .= $pad . $mapping->{$nmid}->[0];
 363                 my $nnext = $nr_s - $idx;
 364                 if ($nnext > 2) {
 365                         my $s = ($nnext - 1).' subsequent siblings';
 366                         $rv .= pad_link($nmid, $level, $s);
 367                 } elsif (my $nn = $siblings->[$idx + 2]) {
 368                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 369                 }
 370         }
 371         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 372 }
 373
 374 sub walk_thread {
 375         my ($rootset, $ctx, $cb) = @_;
 376         my @q = map { (0, $_, -1) } @$rootset;
 377         while (@q) {
 378                 my ($level, $node, $i) = splice(@q, 0, 3);
 379                 defined $node or next;
 380                 $cb->($ctx, $level, $node, $i) or return;
 381                 ++$level;
 382                 $i = 0;
 383                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 384         }
 385 }
 386
 387 sub pre_thread  {
 388         my ($ctx, $level, $node, $idx) = @_;
 389         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 390         skel_dump($ctx, $level, $node);
 391 }
 392
 393 sub thread_index_entry {
 394         my ($ctx, $level, $smsg) = @_;
 395         my ($beg, $end) = thread_adj_level($ctx, $level);
 396         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 397 }
 398
 399 sub stream_thread ($$) {
 400         my ($rootset, $ctx) = @_;
 401         my $inbox = $ctx->{-inbox};
 402         my @q = map { (0, $_) } @$rootset;
 403         my $level;
 404         my $smsg;
 405         while (@q) {
 406                 $level = shift @q;
 407                 my $node = shift @q or next;
 408                 my $cl = $level + 1;
 409                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 410                 $smsg = $inbox->smsg_mime($node->{smsg}) and last;
 411         }
 412         return missing_thread($ctx) unless $smsg;
 413
 414         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 415         $ctx->{-title_html} = ascii_html($smsg->subject);
 416         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 417         $smsg = undef;
 418         PublicInbox::WwwStream->response($ctx, 200, sub {
 419                 return unless $ctx;
 420                 while (@q) {
 421                         $level = shift @q;
 422                         my $node = shift @q or next;
 423                         my $cl = $level + 1;
 424                         unshift @q, map { ($cl, $_) } @{$node->{children}};
 425                         if ($smsg = $inbox->smsg_mime($node->{smsg})) {
 426                                 return thread_index_entry($ctx, $level, $smsg);
 427                         } else {
 428                                 return ghost_index_entry($ctx, $level, $node);
 429                         }
 430                 }
 431                 my $ret = join('', thread_adj_level($ctx, 0));
 432                 $ret .= ${$ctx->{dst}}; # skel
 433                 $ctx = undef;
 434                 $ret;
 435         });
 436 }
 437
 438 sub thread_html {
 439         my ($ctx) = @_;
 440         my $mid = $ctx->{mid};
 441         my $srch = $ctx->{srch};
 442         my ($nr, $msgs) = $srch->get_thread($mid);
 443         return missing_thread($ctx) if $nr == 0;
 444         my $skel = '<hr><pre>';
 445         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 446         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 447         $skel .= "<b\nid=t>Thread overview:</b> ";
 448         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 449         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 450         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 451         $skel .= "-- links below jump to the message on this page --\n";
 452         $ctx->{-upfx} = '../../';
 453         $ctx->{cur_level} = 0;
 454         $ctx->{dst} = \$skel;
 455         $ctx->{prev_attr} = '';
 456         $ctx->{prev_level} = 0;
 457         $ctx->{root_anchor} = anchor_for($mid);
 458         $ctx->{mapping} = {};
 459         $ctx->{s_nr} = "$nr+ messages in thread";
 460
 461         my $rootset = thread_results($ctx, $msgs);
 462
 463         # reduce hash lookups in pre_thread->skel_dump
 464         my $inbox = $ctx->{-inbox};
 465         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 466         walk_thread($rootset, $ctx, *pre_thread);
 467
 468         $skel .= '</pre>';
 469         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 470
 471         # flat display: lazy load the full message from smsg
 472         my $smsg;
 473         while (my $m = shift @$msgs) {
 474                 $smsg = $inbox->smsg_mime($m) and last;
 475         }
 476         return missing_thread($ctx) unless $smsg;
 477         $ctx->{-title_html} = ascii_html($smsg->subject);
 478         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 479         $smsg = undef;
 480         PublicInbox::WwwStream->response($ctx, 200, sub {
 481                 return unless $msgs;
 482                 $smsg = undef;
 483                 while (my $m = shift @$msgs) {
 484                         $smsg = $inbox->smsg_mime($m) and last;
 485                 }
 486                 return index_entry($smsg, $ctx, scalar @$msgs) if $smsg;
 487                 $msgs = undef;
 488                 $skel;
 489         });
 490 }
 491
 492 sub multipart_text_as_html {
 493         my ($mime, $upfx, $ctx) = @_;
 494         my $rv = "";
 495
 496         # scan through all parts, looking for displayable text
 497         msg_iter($mime, sub { $rv .= add_text_body($upfx, $ctx, $_[0]) });
 498         $rv;
 499 }
 500
 501 sub flush_quote {
 502         my ($s, $l, $quot) = @_;
 503
 504         # show everything in the full version with anchor from
 505         # short version (see above)
 506         my $rv = $l->linkify_1($$quot);
 507
 508         # we use a <span> here to allow users to specify their own
 509         # color for quoted text
 510         $rv = $l->linkify_2(ascii_html($rv));
 511         $$quot = undef;
 512         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 513 }
 514
 515 sub attach_link ($$$$;$) {
 516         my ($upfx, $ct, $p, $fn, $err) = @_;
 517         my ($part, $depth, @idx) = @$p;
 518         my $nl = $idx[-1] > 1 ? "\n" : '';
 519         my $idx = join('.', @idx);
 520         my $size = bytes::length($part->body);
 521
 522         # hide attributes normally, unless we want to aid users in
 523         # spotting MUA problems:
 524         $ct =~ s/;.*// unless $err;
 525         $ct = ascii_html($ct);
 526         my $desc = $part->header('Content-Description');
 527         $desc = $fn unless defined $desc;
 528         $desc = '' unless defined $desc;
 529         my $sfn;
 530         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 531                 $sfn = $fn;
 532         } elsif ($ct eq 'text/plain') {
 533                 $sfn = 'a.txt';
 534         } else {
 535                 $sfn = 'a.bin';
 536         }
 537         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 538         if ($err) {
 539                 $ret .=
 540 "[-- Warning: decoded text below may be mangled --]\n";
 541         }
 542         $ret .= "[-- Attachment #$idx: ";
 543         my $ts = "Type: $ct, Size: $size bytes";
 544         $desc = ascii_html($desc);
 545         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 546         $ret .= "</a>\n";
 547 }
 548
 549 sub add_text_body {
 550         my ($upfx, $ctx, $p) = @_;
 551         my $ibx = $ctx->{-inbox};
 552         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 553         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 554         my ($part, $depth, @idx) = @$p;
 555         my $ct = $part->content_type || 'text/plain';
 556         my $fn = $part->filename;
 557         my ($s, $err) = msg_part_text($part, $ct);
 558
 559         return attach_link($upfx, $ct, $p, $fn) unless defined $s;
 560
 561         # makes no difference to browsers, and don't screw up filename
 562         # link generation in diffs with the extra '%0D'
 563         $s =~ s/\r\n/\n/sg;
 564
 565         # always support diff-highlighting, but we can't linkify hunk
 566         # headers for solver unless some coderepo are configured:
 567         my $diff;
 568         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 569                 # diffstat anchors do not link across attachments or messages:
 570                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 571                 $ctx->{-apfx} = join('/', @idx);
 572                 $ctx->{-anchors} = {}; # attr => filename
 573                 $ctx->{-diff} = $diff = [];
 574                 my $spfx;
 575                 if ($ibx->{-repo_objs}) {
 576                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 577                                 $spfx = $upfx;
 578                                 $spfx =~ s!/([^/]*)/\z!/!;
 579                         } else {
 580                                 my $n_slash = $upfx =~ tr!/!/!;
 581                                 if ($n_slash == 0) {
 582                                         $spfx = '../';
 583                                 } elsif ($n_slash == 1) {
 584                                         $spfx = '';
 585                                 } else { # nslash == 2
 586                                         $spfx = '../../';
 587                                 }
 588                         }
 589                 }
 590                 $ctx->{-spfx} = $spfx;
 591         };
 592
 593         # some editors don't put trailing newlines at the end:
 594         $s .= "\n" unless $s =~ /\n\z/s;
 595
 596         # split off quoted and unquoted blocks:
 597         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 598         $s = '';
 599         if (defined($fn) || $depth > 0 || $err) {
 600                 # badly-encoded message with $err? tell the world about it!
 601                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 602                 $s .= "\n";
 603         }
 604         my $l = PublicInbox::Linkify->new;
 605         foreach my $cur (@sections) {
 606                 if ($cur =~ /\A>/) {
 607                         flush_quote(\$s, $l, \$cur);
 608                 } elsif ($diff) {
 609                         @$diff = split(/^/m, $cur);
 610                         $cur = undef;
 611                         flush_diff(\$s, $ctx, $l);
 612                 } else {
 613                         # regular lines, OK
 614                         $l->linkify_1($cur);
 615                         $s .= $l->linkify_2(ascii_html($cur));
 616                         $cur = undef;
 617                 }
 618         }
 619
 620         obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 621         $s;
 622 }
 623
 624 sub _msg_html_prepare {
 625         my ($hdr, $ctx, $more, $nr) = @_;
 626         my $srch = $ctx->{srch} if $ctx;
 627         my $atom = '';
 628         my $obfs_ibx = $ctx->{-obfs_ibx};
 629         my $rv = '';
 630         my $mids = mids($hdr);
 631         my $multiple = scalar(@$mids) > 1; # zero, one, infinity
 632         if ($nr == 0) {
 633                 if ($more) {
 634                         $rv .=
 635 "<pre>WARNING: multiple messages refer to this Message-ID\n</pre>";
 636                 }
 637                 $rv .= "<pre\nid=b>"; # anchor for body start
 638         } else {
 639                 $rv .= '<pre>';
 640         }
 641         if ($srch) {
 642                 $ctx->{-upfx} = '../';
 643         }
 644         my @title;
 645         my $v;
 646         if (defined($v = $hdr->header('From'))) {
 647                 $v = PublicInbox::Hval->new($v);
 648                 my @n = PublicInbox::Address::names($v->raw);
 649                 $title[1] = ascii_html(join(', ', @n));
 650                 $v = $v->as_html;
 651                 if ($obfs_ibx) {
 652                         obfuscate_addrs($obfs_ibx, $v);
 653                         obfuscate_addrs($obfs_ibx, $title[1]);
 654                 }
 655                 $rv .= "From: $v\n" if $v ne '';
 656         }
 657         foreach my $h (qw(To Cc)) {
 658                 defined($v = $hdr->header($h)) or next;
 659                 fold_addresses($v);
 660                 $v = ascii_html($v);
 661                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 662                 $rv .= "$h: $v\n" if $v ne '';
 663         }
 664         if (defined($v = $hdr->header('Subject')) && ($v ne '')) {
 665                 $v = ascii_html($v);
 666                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 667                 if ($srch) {
 668                         $rv .= qq(Subject: <a\nhref="#r"\nid=t>$v</a>\n);
 669                 } else {
 670                         $rv .= "Subject: $v\n";
 671                 }
 672                 $title[0] = $v;
 673         } else { # dummy anchor for thread skeleton at bottom of page
 674                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $srch;
 675                 $title[0] = '(no subject)';
 676         }
 677         if (defined($v = $hdr->header('Date'))) {
 678                 $v = ascii_html($v);
 679                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 680                 $rv .= "Date: $v\n";
 681         }
 682         $ctx->{-title_html} = join(' - ', @title);
 683         foreach (@$mids) {
 684                 my $mid = PublicInbox::Hval->new_msgid($_) ;
 685                 my $mhtml = $mid->as_html;
 686                 if ($multiple) {
 687                         my $href = $mid->{href};
 688                         $rv .= "Message-ID: ";
 689                         $rv .= "<a\nhref=\"../$href/\">";
 690                         $rv .= "&lt;$mhtml&gt;</a> ";
 691                         $rv .= "(<a\nhref=\"../$href/raw\">raw</a>)\n";
 692                 } else {
 693                         $rv .= "Message-ID: &lt;$mhtml&gt; ";
 694                         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 695                 }
 696         }
 697         $rv .= _parent_headers($hdr, $srch);
 698         $rv .= "\n";
 699 }
 700
 701 sub thread_skel {
 702         my ($dst, $ctx, $hdr, $tpfx) = @_;
 703         my $srch = $ctx->{srch};
 704         my $mid = mids($hdr)->[0];
 705         my ($nr, $msgs) = $srch->get_thread($mid);
 706         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 707                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 708                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 709                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 710
 711         my $parent = in_reply_to($hdr);
 712         $$dst .= "\n<b>Thread overview: </b>";
 713         if ($nr <= 1) {
 714                 if (defined $parent) {
 715                         $$dst .= "$expand\n ";
 716                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 717                 } else {
 718                         $$dst .= "[no followups] $expand\n";
 719                 }
 720                 $ctx->{next_msg} = undef;
 721                 $ctx->{parent_msg} = $parent;
 722                 return;
 723         }
 724
 725         $$dst .= "$nr+ messages / $expand";
 726         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 727
 728         my $subj = $hdr->header('Subject');
 729         defined $subj or $subj = '';
 730         $ctx->{prev_subj} = [ split(/ /, $srch->subject_normalized($subj)) ];
 731         $ctx->{cur} = $mid;
 732         $ctx->{prev_attr} = '';
 733         $ctx->{prev_level} = 0;
 734         $ctx->{dst} = $dst;
 735
 736         # reduce hash lookups in skel_dump
 737         my $ibx = $ctx->{-inbox};
 738         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 739         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 740
 741         $ctx->{parent_msg} = $parent;
 742 }
 743
 744 sub _parent_headers {
 745         my ($hdr, $srch) = @_;
 746         my $rv = '';
 747
 748         my $refs = references($hdr);
 749         my $irt = pop @$refs;
 750         if (defined $irt) {
 751                 my $v = PublicInbox::Hval->new_msgid($irt);
 752                 my $html = $v->as_html;
 753                 my $href = $v->{href};
 754                 $rv .= "In-Reply-To: &lt;";
 755                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 756         }
 757
 758         # do not display References: if search is present,
 759         # we show the thread skeleton at the bottom, instead.
 760         return $rv if $srch;
 761
 762         if (@$refs) {
 763                 @$refs = map { linkify_ref_nosrch($_) } @$refs;
 764                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 765         }
 766         $rv;
 767 }
 768
 769 sub html_footer {
 770         my ($hdr, $standalone, $ctx, $rhref) = @_;
 771
 772         my $srch = $ctx->{srch} if $ctx;
 773         my $upfx = '../';
 774         my $tpfx = '';
 775         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 776         my $irt = '';
 777         if ($idx && $srch) {
 778                 $idx .= "\n";
 779                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 780                 my ($next, $prev);
 781                 my $parent = '       ';
 782                 $next = $prev = '    ';
 783
 784                 if (my $n = $ctx->{next_msg}) {
 785                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 786                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 787                 }
 788                 my $u;
 789                 my $par = $ctx->{parent_msg};
 790                 if ($par) {
 791                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 792                         $u = "$upfx$u/";
 793                 }
 794                 if (my $p = $ctx->{prev_msg}) {
 795                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 796                         if ($p && $par && $p eq $par) {
 797                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 798                                         'rel=prev>prev parent</a>';
 799                                 $parent = '';
 800                         } else {
 801                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 802                                         'rel=prev>prev</a>';
 803                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 804                         }
 805                 } elsif ($u) { # unlikely
 806                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 807                 }
 808                 $irt = "$next $prev$parent ";
 809         } else {
 810                 $irt = '';
 811         }
 812         $rhref ||= '#R';
 813         $irt .= qq(<a\nhref="$rhref">reply</a>);
 814         $irt .= $idx;
 815 }
 816
 817 sub linkify_ref_nosrch {
 818         my $v = PublicInbox::Hval->new_msgid($_[0]);
 819         my $html = $v->as_html;
 820         my $href = $v->{href};
 821         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 822 }
 823
 824 sub anchor_for {
 825         my ($msgid) = @_;
 826         'm' . id_compress($msgid, 1);
 827 }
 828
 829 sub ghost_parent {
 830         my ($upfx, $mid) = @_;
 831
 832         $mid = PublicInbox::Hval->new_msgid($mid);
 833         my $href = $mid->{href};
 834         my $html = $mid->as_html;
 835         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 836 }
 837
 838 sub indent_for {
 839         my ($level) = @_;
 840         $level ? INDENT x ($level - 1) : '';
 841 }
 842
 843 sub find_mid_root {
 844         my ($ctx, $level, $node, $idx) = @_;
 845         ++$ctx->{root_idx} if $level == 0;
 846         if ($node->{id} eq $ctx->{mid}) {
 847                 $ctx->{found_mid_at} = $ctx->{root_idx};
 848                 return 0;
 849         }
 850         1;
 851 }
 852
 853 sub strict_loose_note ($) {
 854         my ($nr) = @_;
 855         my $msg =
 856 "  -- strict thread matches above, loose matches on Subject: below --\n";
 857
 858         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 859                 $msg .=
 860 "  -- use mbox.gz link to download all $nr messages --\n";
 861         }
 862         $msg;
 863 }
 864
 865 sub thread_results {
 866         my ($ctx, $msgs) = @_;
 867         require PublicInbox::SearchThread;
 868         my $ibx = $ctx->{-inbox};
 869         my $rootset = PublicInbox::SearchThread::thread($msgs, *sort_ds, $ibx);
 870
 871         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 872         # and preserved in the future.  This bug is hidden by `sid' matches
 873         # in get_thread, so we never noticed it until now.  And even when
 874         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 875         # bump since reindexing is expensive and users may not do it
 876
 877         # loose threading could've returned too many results,
 878         # put the root the message we care about at the top:
 879         my $mid = $ctx->{mid};
 880         if (defined($mid) && scalar(@$rootset) > 1) {
 881                 $ctx->{root_idx} = -1;
 882                 my $nr = scalar @$msgs;
 883                 walk_thread($rootset, $ctx, *find_mid_root);
 884                 my $idx = $ctx->{found_mid_at};
 885                 if (defined($idx) && $idx != 0) {
 886                         my $tip = splice(@$rootset, $idx, 1);
 887                         @$rootset = reverse @$rootset;
 888                         unshift @$rootset, $tip;
 889                         $ctx->{sl_note} = strict_loose_note($nr);
 890                 }
 891         }
 892         $rootset
 893 }
 894
 895 sub missing_thread {
 896         my ($ctx) = @_;
 897         require PublicInbox::ExtMsg;
 898         PublicInbox::ExtMsg::ext_msg($ctx);
 899 }
 900
 901 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 902
 903 sub dedupe_subject {
 904         my ($prev_subj, $subj, $val) = @_;
 905
 906         my $omit = ''; # '"' denotes identical text omitted
 907         my (@prev_pop, @curr_pop);
 908         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 909                 push(@prev_pop, pop(@$prev_subj));
 910                 push(@curr_pop, pop(@$subj));
 911                 $omit ||= $val;
 912         }
 913         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 914         if (scalar(@curr_pop) == 1) {
 915                 $omit = '';
 916                 push @$prev_subj, @prev_pop;
 917                 push @$subj, @curr_pop;
 918         }
 919         $omit;
 920 }
 921
 922 sub skel_dump {
 923         my ($ctx, $level, $node) = @_;
 924         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 925
 926         my $dst = $ctx->{dst};
 927         my $cur = $ctx->{cur};
 928         my $mid = $smsg->{mid};
 929
 930         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 931                 $$dst .= delete $ctx->{sl_note} || '';
 932         }
 933
 934         my $f = ascii_html($smsg->from_name);
 935         my $obfs_ibx = $ctx->{-obfs_ibx};
 936         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 937
 938         my $d = fmt_ts($smsg->{ds}) . ' ' . indent_for($level) . th_pfx($level);
 939         my $attr = $f;
 940         $ctx->{first_level} ||= $level;
 941
 942         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 943                 $ctx->{prev_attr} = $attr;
 944         }
 945         $ctx->{prev_level} = $level;
 946
 947         if ($cur) {
 948                 if ($cur eq $mid) {
 949                         delete $ctx->{cur};
 950                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 951                                  "$attr [this message]</a></b>\n";
 952                         return 1;
 953                 } else {
 954                         $ctx->{prev_msg} = $mid;
 955                 }
 956         } else {
 957                 $ctx->{next_msg} ||= $mid;
 958         }
 959
 960         # Subject is never undef, this mail was loaded from
 961         # our Xapian which would've resulted in '' if it were
 962         # really missing (and Filter rejects empty subjects)
 963         my @subj = split(/ /, $ctx->{srch}->subject_normalized($smsg->subject));
 964
 965         # remove common suffixes from the subject if it matches the previous,
 966         # so we do not show redundant text at the end.
 967         my $prev_subj = $ctx->{prev_subj} || [];
 968         $ctx->{prev_subj} = [ @subj ];
 969         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 970         my $end;
 971         if (@subj) {
 972                 my $subj = join(' ', @subj);
 973                 $subj = ascii_html($subj);
 974                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 975                 $end = "$subj</a> $omit$f\n"
 976         } else {
 977                 $end = "$f</a>\n";
 978         }
 979         my $m;
 980         my $id = '';
 981         my $mapping = $ctx->{mapping};
 982         if ($mapping) {
 983                 my $map = $mapping->{$mid};
 984                 $id = id_compress($mid, 1);
 985                 $m = '#m'.$id;
 986                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 987                 $id = "\nid=r".$id;
 988         } else {
 989                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 990         }
 991         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 992         1;
 993 }
 994
 995 sub _skel_ghost {
 996         my ($ctx, $level, $node) = @_;
 997
 998         my $mid = $node->{id};
 999         my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
1000                             : '     [not found] ';
1001         $d .= indent_for($level) . th_pfx($level);
1002         my $upfx = $ctx->{-upfx};
1003         my $m = PublicInbox::Hval->new_msgid($mid);
1004         my $href = $upfx . $m->{href} . '/';
1005         my $html = $m->as_html;
1006
1007         my $mapping = $ctx->{mapping};
1008         my $map = $mapping->{$mid} if $mapping;
1009         if ($map) {
1010                 my $id = id_compress($mid, 1);
1011                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1012                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1013         } else {
1014                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1015         }
1016         my $dst = $ctx->{dst};
1017         $$dst .= $d;
1018         1;
1019 }
1020
1021 sub sort_ds {
1022         [ sort {
1023                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
1024                 (eval { $b->topmost->{smsg}->ds } || 0)
1025         } @{$_[0]} ];
1026 }
1027
1028 # accumulate recent topics if search is supported
1029 # returns 200 if done, 404 if not
1030 sub acc_topic {
1031         my ($ctx, $level, $node) = @_;
1032         my $srch = $ctx->{srch};
1033         my $mid = $node->{id};
1034         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
1035         my ($subj, $ds);
1036         my $topic;
1037         if ($x) {
1038                 $subj = $x->subject;
1039                 $subj = $srch->subject_normalized($subj);
1040                 $ds = $x->ds;
1041                 if ($level == 0) {
1042                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1043                         $ctx->{-cur_topic} = $topic;
1044                         push @{$ctx->{order}}, $topic;
1045                         return 1;
1046                 }
1047
1048                 $topic = $ctx->{-cur_topic}; # should never be undef
1049                 $topic->[0] = $ds if $ds > $topic->[0];
1050                 $topic->[1]++;
1051                 my $seen = $topic->[2];
1052                 if (scalar(@$topic) == 3) { # parent was a ghost
1053                         push @$topic, $subj;
1054                 } elsif (!$seen->{$subj}) {
1055                         push @$topic, $level, $subj;
1056                 }
1057                 $seen->{$subj} = $mid; # latest for subject
1058         } else { # ghost message
1059                 return 1 if $level != 0; # ignore child ghosts
1060                 $topic = [ -666, 0, {} ];
1061                 $ctx->{-cur_topic} = $topic;
1062                 push @{$ctx->{order}}, $topic;
1063         }
1064         1;
1065 }
1066
1067 sub dump_topics {
1068         my ($ctx) = @_;
1069         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1070         if (!@$order) {
1071                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1072                 return 404;
1073         }
1074
1075         my @out;
1076         my $ibx = $ctx->{-inbox};
1077         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1078         my $srch = $ctx->{srch};
1079
1080         # sort by recency, this allows new posts to "bump" old topics...
1081         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1082                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1083                 @$topic = ();
1084                 next unless defined $top;  # ghost topic
1085                 my $mid = delete $seen->{$top};
1086                 my $href = mid_escape($mid);
1087                 my $prev_subj = [ split(/ /, $top) ];
1088                 $top = PublicInbox::Hval->new($top)->as_html;
1089                 $ds = fmt_ts($ds);
1090
1091                 # $n isn't the total number of posts on the topic,
1092                 # just the number of posts in the current results window
1093                 my $anchor;
1094                 if ($n == 1) {
1095                         $n = '';
1096                         $anchor = '#u'; # top of only message
1097                 } else {
1098                         $n = " ($n+ messages)";
1099                         $anchor = '#t'; # thread skeleton
1100                 }
1101
1102                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1103                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1104                 my $s = "<a\nhref=\"$href/T/$anchor\">$top</a>\n" .
1105                         " $ds UTC $n - $mbox / $atom\n";
1106                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1107                         my $level = $ex[$i];
1108                         my $subj = $ex[$i + 1];
1109                         $mid = delete $seen->{$subj};
1110                         my @subj = split(/ /, $srch->subject_normalized($subj));
1111                         my @next_prev = @subj; # full copy
1112                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1113                         $prev_subj = \@next_prev;
1114                         $subj = ascii_html(join(' ', @subj));
1115                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1116                         $href = mid_escape($mid);
1117                         $s .= indent_for($level) . TCHILD;
1118                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1119                 }
1120                 push @out, $s;
1121         }
1122         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1123         200;
1124 }
1125
1126 sub ts2str ($) {
1127         my ($ts) = @_;
1128         POSIX::strftime('%Y%m%d%H%M%S', gmtime($ts));
1129 }
1130
1131 sub str2ts ($) {
1132         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1133         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1134 }
1135
1136 sub pagination_footer ($$) {
1137         my ($ctx, $latest) = @_;
1138         delete $ctx->{qp} or return;
1139         my $next = $ctx->{next_page} || '';
1140         my $prev = $ctx->{prev_page} || '';
1141         if ($prev) {
1142                 $next = $next ? "$next " : '     ';
1143                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1144         }
1145         "<hr><pre>page: $next$prev</pre>";
1146 }
1147
1148 sub index_nav { # callback for WwwStream
1149         my (undef, $ctx) = @_;
1150         pagination_footer($ctx, '.')
1151 }
1152
1153 sub paginate_recent ($$) {
1154         my ($ctx, $lim) = @_;
1155         my $t = $ctx->{qp}->{t} || '';
1156         my $opts = { limit => $lim };
1157         my ($after, $before);
1158
1159         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1160         # if only $after exists "YYYYMMDD.." because "." could be skipped
1161         # if interpreted as an end-of-sentence
1162         $t =~ s/\A(\d{8,14})-// and $after = str2ts($1);
1163         $t =~ /\A(\d{8,14})\z/ and $before = str2ts($1);
1164
1165         my $ibx = $ctx->{-inbox};
1166         my $msgs = $ibx->recent($opts, $after, $before);
1167         my $nr = scalar @$msgs;
1168         if ($nr < $lim && defined($after)) {
1169                 $after = $before = undef;
1170                 $msgs = $ibx->recent($opts);
1171                 $nr = scalar @$msgs;
1172         }
1173         my $more = $nr == $lim;
1174         my ($newest, $oldest);
1175         if ($nr) {
1176                 $newest = $msgs->[0]->{ts};
1177                 $oldest = $msgs->[-1]->{ts};
1178                 # if we only had $after, our SQL query in ->recent ordered
1179                 if ($newest < $oldest) {
1180                         ($oldest, $newest) = ($newest, $oldest);
1181                         $more = 0 if defined($after) && $after < $oldest;
1182                 }
1183         }
1184         if (defined($oldest) && $more) {
1185                 my $s = ts2str($oldest);
1186                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1187         }
1188         if (defined($newest) && (defined($before) || defined($after))) {
1189                 my $s = ts2str($newest);
1190                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1191         }
1192         $msgs;
1193 }
1194
1195 sub index_topics {
1196         my ($ctx) = @_;
1197         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1198         if (@$msgs) {
1199                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1200         }
1201         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1202 }
1203
1204 sub thread_adj_level {
1205         my ($ctx, $level) = @_;
1206
1207         my $max = $ctx->{cur_level};
1208         if ($level <= 0) {
1209                 return ('', '') if $max == 0; # flat output
1210
1211                 # reset existing lists
1212                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1213                 $ctx->{cur_level} = 0;
1214                 ("$beg</ul>", '');
1215         } elsif ($level == $max) { # continue existing list
1216                 qw(<li> </li>);
1217         } elsif ($level < $max) {
1218                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1219                 $ctx->{cur_level} = $level;
1220                 ("$beg<li>", '</li>');
1221         } else { # ($level > $max) # start a new level
1222                 $ctx->{cur_level} = $level;
1223                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1224                 ($beg, '</li>');
1225         }
1226 }
1227
1228 sub ghost_index_entry {
1229         my ($ctx, $level, $node) = @_;
1230         my ($beg, $end) = thread_adj_level($ctx,  $level);
1231         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1232                 . '</pre>' . $end;
1233 }
1234
1235 1;