lib/PublicInbox/View.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  11 use PublicInbox::MsgTime qw(msg_datestamp);
  12 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  13                         ts2str fmt_ts);
  14 use PublicInbox::Linkify;
  15 use PublicInbox::MID qw(id_compress mids mids_for_index references
  16                         $MID_EXTRACT);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::Address;
  19 use PublicInbox::WwwStream qw(html_oneshot);
  20 use PublicInbox::Reply;
  21 use PublicInbox::ViewDiff qw(flush_diff);
  22 use PublicInbox::Eml;
  23 use POSIX qw(strftime);
  24 use Time::Local qw(timegm);
  25 use PublicInbox::Smsg qw(subject_normalized);
  26 use PublicInbox::ContentHash qw(content_hash);
  27 use constant COLS => 72;
  28 use constant INDENT => '  ';
  29 use constant TCHILD => '` ';
  30 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  31
  32 sub msg_page_i {
  33         my ($ctx, $eml) = @_;
  34         if ($eml) { # called by WwwStream::async_eml or getline
  35                 my $smsg = $ctx->{smsg};
  36                 my $over = $ctx->{ibx}->over;
  37                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  38                                 : $ctx->gone('over');
  39                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  40                                 "../${\mid_href($smsg->{mid})}/" : '';
  41                 if (_msg_page_prepare_obuf($eml, $ctx)) {
  42                         $eml->each_part(\&add_text_body, $ctx, 1);
  43                         $ctx->zmore('</pre><hr>');
  44                 }
  45                 html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 delete($ctx->{obuf}) // \'';
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         if (_msg_page_prepare_obuf($eml, $ctx)) { # sets {-title_html}
  60                 $eml->each_part(\&add_text_body, $ctx, 1);
  61                 $ctx->zmore('</pre><hr>');
  62         }
  63         html_footer($ctx, $eml);
  64         $ctx->html_done;
  65 }
  66
  67 # public functions: (unstable)
  68
  69 sub msg_page {
  70         my ($ctx) = @_;
  71         my $ibx = $ctx->{ibx};
  72         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  73         my $over = $ibx->over or return no_over_html($ctx);
  74         my ($id, $prev);
  75         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  76
  77         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  78                 return; # undef == 404
  79
  80         # allow user to easily browse the range around this message if
  81         # they have ->over
  82         $ctx->{-t_max} = $smsg->{ts};
  83         PublicInbox::WwwStream::aresponse($ctx, \&msg_page_i);
  84 }
  85
  86 # /$INBOX/$MESSAGE_ID/#R
  87 sub msg_reply ($$) {
  88         my ($ctx, $hdr) = @_;
  89         my $se_url =
  90          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  91         my $p_url =
  92          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  93
  94         my $info = '';
  95         my $ibx = $ctx->{ibx};
  96         if (my $url = $ibx->{infourl}) {
  97                 $url = prurl($ctx->{env}, $url);
  98                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
  99         }
 100
 101         my ($arg, $link, $reply_to_all) =
 102                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 103         if (ref($arg) eq 'SCALAR') {
 104                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 105         }
 106
 107         # mailto: link only works if address obfuscation is disabled
 108         if ($link) {
 109                 $link = <<EOF;
 110
 111 * If your mail client supports setting the <b>In-Reply-To</b> header
 112   via mailto: links, try the <a
 113 href="$link">mailto: link</a>
 114 EOF
 115         }
 116
 117         push @$arg, '/path/to/YOUR_REPLY';
 118         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 119         <<EOF
 120 <hr><pre
 121 id=R><b>Reply instructions:</b>
 122
 123 You may reply publicly to <a
 124 href=#t>this message</a> via plain-text email
 125 using any one of the following methods:
 126
 127 * Save the following mbox file, import it into your mail client,
 128   and $reply_to_all from there: <a
 129 href=raw>mbox</a>
 130
 131   Avoid top-posting and favor interleaved quoting:
 132   <a
 133 href="$p_url">$p_url</a>
 134 $info
 135 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 136   switches of git-send-email(1):
 137
 138   git send-email$arg
 139
 140   <a
 141 href="$se_url">$se_url</a>
 142 $link</pre>
 143
 144   Be sure your reply has a <b>Subject:</b> header at the top and a blank line
 145   before the message body.
 146 EOF
 147 }
 148
 149 sub in_reply_to {
 150         my ($hdr) = @_;
 151         my $refs = references($hdr);
 152         $refs->[-1];
 153 }
 154
 155 sub fold_addresses ($) {
 156         return $_[0] if length($_[0]) <= COLS;
 157         # try to fold on commas after non-word chars before $lim chars,
 158         # Try to get the "," preceded by ">" or ")", but avoid folding
 159         # on the comma where somebody uses "Lastname, Firstname".
 160         # We also try to keep the last and penultimate addresses in
 161         # the list on the same line if possible, hence the extra \z
 162         # Fall back to folding on spaces at $lim + 1 chars
 163         my $lim = COLS - 8; # 8 = "\t" display width
 164         my $too_long = $lim + 1;
 165         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 166         $_[0] = join("\n\t",
 167                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 168                                 .{1,$lim}(?:,|\z)|
 169                                 .{1,$lim}|
 170                                 .{$too_long,}?)(?:\s|\z)/xgo));
 171 }
 172
 173 sub _hdr_names_html ($$) {
 174         my ($hdr, $field) = @_;
 175         my @vals = $hdr->header($field) or return '';
 176         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 177 }
 178
 179 sub nr_to_s ($$$) {
 180         my ($nr, $singular, $plural) = @_;
 181         return "0 $plural" if $nr == 0;
 182         $nr == 1 ? "$nr $singular" : "$nr $plural";
 183 }
 184
 185 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 186 # this is already inside a <pre>
 187 sub eml_entry {
 188         my ($ctx, $eml) = @_;
 189         my $smsg = delete $ctx->{smsg};
 190         my $subj = delete $smsg->{subject};
 191         my $mid_raw = $smsg->{mid};
 192         my $id = id_compress($mid_raw, 1);
 193         my $id_m = 'm'.$id;
 194         my $root_anchor = $ctx->{root_anchor} || '';
 195         my $irt;
 196         my $obfs_ibx = $ctx->{-obfs_ibx};
 197
 198         $subj = '(no subject)' if $subj eq '';
 199         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 200         $subj = '<b>'.ascii_html($subj).'</b>';
 201         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 202         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 203         $rv .= $subj . "\n";
 204         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 205         my @tocc;
 206         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 207
 208         # Deleting these fields saves about 400K as we iterate across 1K msgs
 209         delete @$smsg{qw(ts blob)};
 210
 211         my $from = _hdr_names_html($eml, 'From');
 212         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 213         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 214         my $upfx = $ctx->{-upfx};
 215         my $mhref = $upfx . mid_href($mid_raw) . '/';
 216         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 217         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 218         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 219         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 220         my ($tlen, $clen) = (length($to), length($cc));
 221         my $to_cc = '';
 222         if (($tlen + $clen) > COLS) {
 223                 $to_cc .= '  To: '.$to."\n" if $tlen;
 224                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 225         } else {
 226                 if ($tlen) {
 227                         $to_cc .= '  To: '.$to;
 228                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 229                 } else {
 230                         $to_cc .= '  Cc: '.$cc if $clen;
 231                 }
 232                 $to_cc .= "\n";
 233         }
 234         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 235         $rv .= $to_cc;
 236
 237         my $mapping = $ctx->{mapping};
 238         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 239                 my $href = $upfx . mid_href($irt) . '/';
 240                 my $html = ascii_html($irt);
 241                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 242         }
 243         $rv .= "\n";
 244
 245         # scan through all parts, looking for displayable text
 246         $ctx->{mhref} = $mhref;
 247         $ctx->{changed_href} = "#e$id"; # for diffstat "files? changed,"
 248         $ctx->{obuf} = \$rv;
 249         $eml->each_part(\&add_text_body, $ctx, 1); # expensive
 250         $ctx->zmore; # TODO: remove once add_text_body is updated
 251
 252         # add the footer
 253         $rv = "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 254                 "<a\nhref=\"$mhref\">permalink</a>" .
 255                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 256                 " <a\nhref=\"${mhref}#R\">reply</a>";
 257
 258         delete($ctx->{-qry}) and
 259                 $rv .= qq[ <a\nhref="${mhref}#related">related</a>];
 260
 261         my $hr;
 262         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 263                 $rv .= "\t[relevance $pct%]";
 264                 $hr = 1;
 265         } elsif ($mapping) {
 266                 my $nested = 'nested';
 267                 my $flat = 'flat';
 268                 if ($ctx->{flat}) {
 269                         $hr = 1;
 270                         $flat = "<b>$flat</b>";
 271                 } else {
 272                         $nested = "<b>$nested</b>";
 273                 }
 274                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 275                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 276                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 277         } else {
 278                 $hr = $ctx->{-hr};
 279         }
 280
 281         # do we have more messages? start a new <pre> if so
 282         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 283         $rv;
 284 }
 285
 286 sub pad_link ($$;$) {
 287         my ($mid, $level, $s) = @_;
 288         $s ||= '...';
 289         my $href = defined($mid) ?
 290                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 291                 "($s)\n";
 292         (' 'x19).indent_for($level).th_pfx($level).$href;
 293 }
 294
 295 sub _skel_hdr {
 296         # my ($mapping, $mid) = @_;
 297         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 298 }
 299
 300 sub _th_index_lite {
 301         my ($mid_raw, $irt, $id, $ctx) = @_;
 302         my $rv = '';
 303         my $mapping = $ctx->{mapping} or return $rv;
 304         my $pad = '  ';
 305         my $mid_map = $mapping->{$mid_raw};
 306         defined $mid_map or
 307                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 308         my ($attr, $node, $idx, $level) = @$mid_map;
 309         my $children = $node->{children};
 310         my $nr_c = scalar @$children;
 311         my $nr_s = 0;
 312         my $siblings;
 313         # delete saves about 200KB on a 1K message thread
 314         if (my $refs = delete $node->{references}) {
 315                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 316         }
 317         my $irt_map = $mapping->{$$irt} if defined $$irt;
 318         if (defined $irt_map) {
 319                 $siblings = $irt_map->[1]->{children};
 320                 $nr_s = scalar(@$siblings) - 1;
 321                 $rv .= $pad . $irt_map->[0];
 322                 if ($idx > 0) {
 323                         my $prev = $siblings->[$idx - 1];
 324                         my $pmid = $prev->{mid};
 325                         if ($idx > 2) {
 326                                 my $s = ($idx - 1). ' preceding siblings ...';
 327                                 $rv .= pad_link($pmid, $level, $s);
 328                         } elsif ($idx == 2) {
 329                                 $rv .= $pad . _skel_hdr($mapping,
 330                                                 $siblings->[0] ?
 331                                                 $siblings->[0]->{mid} : undef);
 332                         }
 333                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 334                 }
 335         }
 336         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 337         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 338         $attr =~ s!\n\z!</b>\n!s;
 339         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 340         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 341         $rv .= "<b>@ $attr";
 342         if ($nr_c) {
 343                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 344                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 345                 if ($nr_c > 2) {
 346                         my $s = ($nr_c - 1). ' more replies';
 347                         $rv .= pad_link($cmid, $level + 1, $s);
 348                 } elsif (my $cn = $children->[1]) {
 349                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 350                 }
 351         }
 352
 353         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 354         if ($next) {
 355                 my $nmid = $next->{mid};
 356                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 357                 my $nnext = $nr_s - $idx;
 358                 if ($nnext > 2) {
 359                         my $s = ($nnext - 1).' subsequent siblings';
 360                         $rv .= pad_link($nmid, $level, $s);
 361                 } elsif (my $nn = $siblings->[$idx + 2]) {
 362                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 363                 }
 364         }
 365         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 366 }
 367
 368 # non-recursive thread walker
 369 sub walk_thread ($$$) {
 370         my ($rootset, $ctx, $cb) = @_;
 371         my @q = map { (0, $_, -1) } @$rootset;
 372         while (@q) {
 373                 my ($level, $node, $i) = splice(@q, 0, 3);
 374                 defined $node or next;
 375                 $cb->($ctx, $level, $node, $i) or return;
 376                 ++$level;
 377                 $i = 0;
 378                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 379         }
 380 }
 381
 382 sub pre_thread  { # walk_thread callback
 383         my ($ctx, $level, $node, $idx) = @_;
 384         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 385         skel_dump($ctx, $level, $node);
 386 }
 387
 388 sub thread_eml_entry {
 389         my ($ctx, $eml) = @_;
 390         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 391         $ctx->zmore($beg.'<pre>');
 392         eml_entry($ctx, $eml) . '</pre>' . $end;
 393 }
 394
 395 sub next_in_queue ($$) {
 396         my ($q, $ghost_ok) = @_;
 397         while (@$q) {
 398                 my ($level, $smsg) = splice(@$q, 0, 2);
 399                 my $cl = $level + 1;
 400                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 401                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 402         }
 403         undef;
 404 }
 405
 406 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 407         my ($ctx, $eml) = @_;
 408         return thread_eml_entry($ctx, $eml) if $eml;
 409         return unless exists($ctx->{skel});
 410         my $ghost_ok = $ctx->{nr}++;
 411         while (1) {
 412                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 413                 if ($smsg) {
 414                         if (exists $smsg->{blob}) { # next message for cat-file
 415                                 $ctx->{level} = $lvl;
 416                                 if (!$ghost_ok) { # first non-ghost
 417                                         $ctx->{-title_html} =
 418                                                 ascii_html($smsg->{subject});
 419                                         $ctx->zmore($ctx->html_top);
 420                                 }
 421                                 return $smsg;
 422                         }
 423                         # buffer the ghost entry and loop
 424                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 425                 } else { # all done
 426                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 427                         $ctx->zmore(${delete($ctx->{skel})});
 428                         return;
 429                 }
 430         }
 431 }
 432
 433 sub stream_thread ($$) {
 434         my ($rootset, $ctx) = @_;
 435         @{$ctx->{-queue}} = map { (0, $_) } @$rootset;
 436         PublicInbox::WwwStream::aresponse($ctx, \&stream_thread_i);
 437 }
 438
 439 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 440 sub thread_html {
 441         my ($ctx) = @_;
 442         $ctx->{-upfx} = '../../';
 443         my $mid = $ctx->{mid};
 444         my $ibx = $ctx->{ibx};
 445         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 446         return missing_thread($ctx) if $nr == 0;
 447
 448         # link $INBOX_DIR/description text to "index_topics" view around
 449         # the newest message in this thread
 450         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 451         my $t_fmt = fmt_ts($ctx->{-t_max});
 452
 453         my $skel = '<hr><pre>';
 454         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 455         $skel .= <<EOF;
 456 , other threads:[<a
 457 href="../../?t=$t">~$t_fmt UTC</a> | <a
 458 href="../../">newest</a>]
 459
 460 EOF
 461         $skel .= "<b\nid=t>Thread overview:</b> ";
 462         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 463         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 464         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 465         $skel .= "-- links below jump to the message on this page --\n";
 466         $ctx->{cur_level} = 0;
 467         $ctx->{skel} = \$skel;
 468         $ctx->{prev_attr} = '';
 469         $ctx->{prev_level} = 0;
 470         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 471         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 472         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 473                        .' in thread';
 474
 475         my $rootset = thread_results($ctx, $msgs);
 476
 477         # reduce hash lookups in pre_thread->skel_dump
 478         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 479         walk_thread($rootset, $ctx, \&pre_thread);
 480
 481         $skel .= '</pre>';
 482         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 483
 484         # flat display: lazy load the full message from smsg
 485         $ctx->{msgs} = $msgs;
 486         $ctx->{-html_tip} = '<pre>';
 487         PublicInbox::WwwStream::aresponse($ctx, \&thread_html_i);
 488 }
 489
 490 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 491         my ($ctx, $eml) = @_;
 492         if ($eml) {
 493                 my $smsg = $ctx->{smsg};
 494                 if (exists $ctx->{-html_tip}) {
 495                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 496                         $ctx->zmore($ctx->html_top);
 497                 }
 498                 return eml_entry($ctx, $eml);
 499         } else {
 500                 while (my $smsg = shift @{$ctx->{msgs}}) {
 501                         return $smsg if exists($smsg->{blob});
 502                 }
 503                 my $skel = delete($ctx->{skel}) or return; # all done
 504                 $ctx->zmore($$skel);
 505                 undef;
 506         }
 507 }
 508
 509 sub submsg_hdr ($$) {
 510         my ($ctx, $eml) = @_;
 511         my $s = "\n";
 512         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 513                 $s .= "$h: $_\n" for $eml->header($h);
 514         }
 515         obfuscate_addrs($ctx->{-obfs_ibx}, $s) if $ctx->{-obfs_ibx};
 516         ascii_html($s);
 517 }
 518
 519 sub attach_link ($$$$;$) {
 520         my ($ctx, $ct, $p, $fn, $err) = @_;
 521         my ($part, $depth, $idx) = @$p;
 522
 523         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 524         # downloads for 0-byte multipart attachments
 525         return unless $part->{bdy};
 526
 527         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 528         my $size = length($part->body);
 529         delete $part->{bdy}; # save memory
 530
 531         # hide attributes normally, unless we want to aid users in
 532         # spotting MUA problems:
 533         $ct =~ s/;.*// unless $err;
 534         $ct = ascii_html($ct);
 535         my $sfn;
 536         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 537                 $sfn = $fn;
 538         } elsif ($ct eq 'text/plain') {
 539                 $sfn = 'a.txt';
 540         } else {
 541                 $sfn = 'a.bin';
 542         }
 543         my $rv = $ctx->{obuf};
 544         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 545         if ($err) {
 546                 $$rv .= <<EOF;
 547 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 548 EOF
 549         }
 550         $$rv .= "[-- Attachment #$idx: ";
 551         my $ts = "Type: $ct, Size: $size bytes";
 552         my $desc = $part->header('Content-Description') // $fn // '';
 553         $desc = ascii_html($desc);
 554         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 555         $$rv .= "</a>\n";
 556
 557         $$rv .= submsg_hdr($ctx, $part) if $part->{is_submsg};
 558
 559         undef;
 560 }
 561
 562 sub add_text_body { # callback for each_part
 563         my ($p, $ctx) = @_;
 564         my $upfx = $ctx->{mhref};
 565         my $ibx = $ctx->{ibx};
 566         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 567         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 568         my ($part, $depth, $idx) = @$p;
 569         my $ct = $part->content_type || 'text/plain';
 570         my $fn = $part->filename;
 571         my ($s, $err) = msg_part_text($part, $ct);
 572         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 573
 574         my $rv = $ctx->{obuf};
 575         if ($part->{is_submsg}) {
 576                 $$rv .= submsg_hdr($ctx, $part);
 577                 $$rv .= "\n";
 578         }
 579
 580         # makes no difference to browsers, and don't screw up filename
 581         # link generation in diffs with the extra '%0D'
 582         $s =~ s/\r+\n/\n/sg;
 583
 584         # will be escaped to `&#8226;' in HTML
 585         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 586
 587         # always support diff-highlighting, but we can't linkify hunk
 588         # headers for solver unless some coderepo are configured:
 589         my $diff;
 590         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 591                 # diffstat anchors do not link across attachments or messages,
 592                 # -apfx is just a stable prefix for making diffstat anchors
 593                 # linkable to the first diff hunk w/o crossing attachments
 594                 $idx =~ tr!.!/!; # compatibility with previous versions
 595                 $ctx->{-apfx} = $upfx . $idx;
 596
 597                 # do attr => filename mappings for diffstats in git diffs:
 598                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 599                 $diff = 1;
 600                 delete $ctx->{-long_path};
 601                 my $spfx;
 602                 # absolute URL (Atom feeds)
 603                 if ($ibx->{coderepo}) {
 604                         if (index($upfx, '//') >= 0) {
 605                                 $spfx = $upfx;
 606                                 $spfx =~ s!/([^/]*)/\z!/!;
 607                         } else {
 608                                 my $n_slash = $upfx =~ tr!/!/!;
 609                                 if ($n_slash == 0) {
 610                                         $spfx = '../';
 611                                 } elsif ($n_slash == 1) {
 612                                         $spfx = '';
 613                                 } else { # nslash == 2
 614                                         $spfx = '../../';
 615                                 }
 616                         }
 617                 }
 618                 $ctx->{-spfx} = $spfx;
 619         };
 620
 621         # split off quoted and unquoted blocks:
 622         my @sections = PublicInbox::MsgIter::split_quotes($s);
 623         undef $s; # free memory
 624         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 625                 # badly-encoded message with $err? tell the world about it!
 626                 attach_link($ctx, $ct, $p, $fn, $err);
 627                 $$rv .= "\n";
 628         }
 629         delete $part->{bdy}; # save memory
 630         foreach my $cur (@sections) {
 631                 if ($cur =~ /\A>/) {
 632                         # we use a <span> here to allow users to specify
 633                         # their own color for quoted text
 634                         $$rv .= qq(<span\nclass="q">);
 635                         $$rv .= $l->to_html($cur);
 636                         $$rv .= '</span>';
 637                 } elsif ($diff) {
 638                         flush_diff($ctx, \$cur);
 639                 } else {
 640                         # regular lines, OK
 641                         $$rv .= $l->to_html($cur);
 642                 }
 643                 undef $cur; # free memory
 644         }
 645 }
 646
 647 sub _msg_page_prepare_obuf {
 648         my ($eml, $ctx) = @_;
 649         my $have_over = !!$ctx->{ibx}->over;
 650         my $obfs_ibx = $ctx->{-obfs_ibx};
 651         $ctx->{obuf} = \(my $rv = '');
 652         my $mids = mids_for_index($eml);
 653         my $nr = $ctx->{nr}++;
 654         if ($nr) { # unlikely
 655                 if ($ctx->{chash} eq content_hash($eml)) {
 656                         warn "W: BUG? @$mids not deduplicated properly\n";
 657                         return;
 658                 }
 659                 $rv .=
 660 "<pre>WARNING: multiple messages have this Message-ID\n</pre><pre>";
 661         } else {
 662                 $ctx->{first_hdr} = $eml->header_obj;
 663                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 664                 $rv .= "<pre\nid=b>"; # anchor for body start
 665         }
 666         $ctx->{-upfx} = '../';
 667         my @title; # (Subject[0], From[0])
 668         for my $v ($eml->header('From')) {
 669                 my @n = PublicInbox::Address::names($v);
 670                 $v = ascii_html($v);
 671                 $title[1] //= ascii_html(join(', ', @n));
 672                 if ($obfs_ibx) {
 673                         obfuscate_addrs($obfs_ibx, $v);
 674                         obfuscate_addrs($obfs_ibx, $title[1]);
 675                 }
 676                 $rv .= "From: $v\n" if $v ne '';
 677         }
 678         foreach my $h (qw(To Cc)) {
 679                 for my $v ($eml->header($h)) {
 680                         fold_addresses($v);
 681                         $v = ascii_html($v);
 682                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 683                         $rv .= "$h: $v\n" if $v ne '';
 684                 }
 685         }
 686         my @subj = $eml->header('Subject');
 687         if (@subj) {
 688                 my $v = ascii_html(shift @subj);
 689                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 690                 $rv .= 'Subject: ';
 691                 $rv .= $have_over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 692                 $title[0] = $v;
 693                 for $v (@subj) { # multi-Subject message :<
 694                         $v = ascii_html($v);
 695                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 696                         $rv .= "Subject: $v\n";
 697                 }
 698         } else { # dummy anchor for thread skeleton at bottom of page
 699                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $have_over;
 700                 $title[0] = '(no subject)';
 701         }
 702         for my $v ($eml->header('Date')) {
 703                 $v = ascii_html($v);
 704                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 705                 $rv .= qq{Date: $v\n};
 706         }
 707         # [thread overview] link is typically added after Date,
 708         # but added after Subject, or even nothing.
 709         if ($have_over) {
 710                 chop $rv; # drop "\n", or noop if $rv eq ''
 711                 $rv .= qq{\t<a\nhref="#r">[thread overview]</a>\n};
 712         }
 713         if (!$nr) { # first (and only) message, common case
 714                 $ctx->{-title_html} = join(' - ', @title);
 715                 $rv = $ctx->html_top . $rv;
 716         }
 717
 718         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 719         if (scalar(@$mids) == 1) { # common case
 720                 my $mhtml = ascii_html($mids->[0]);
 721                 $rv .= qq[Message-ID: &lt;$mhtml&gt; (<a href="raw">raw</a>)\n];
 722         } else {
 723                 # X-Alt-Message-ID can happen if a message is injected from
 724                 # public-inbox-nntpd because of multiple Message-ID headers.
 725                 my $s = '';
 726                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 727                         $s .= "$h: $_\n" for ($eml->header_raw($h));
 728                 }
 729                 $ctx->{-linkify}->linkify_mids('..', \$s, 1);
 730                 $rv .= $s;
 731         }
 732         $rv .= _parent_headers($ctx, $eml);
 733         1;
 734 }
 735
 736 sub SKEL_EXPAND () {
 737         qq(expand[<a\nhref="T/#u">flat</a>) .
 738                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 739                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 740                 qq(<a\nhref="t.atom">Atom feed</a>);
 741 }
 742
 743 sub thread_skel ($$$) {
 744         my ($skel, $ctx, $hdr) = @_;
 745         my $mid = mids($hdr)->[0];
 746         my $ibx = $ctx->{ibx};
 747         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 748         my $parent = in_reply_to($hdr);
 749         $$skel .= "\n<b>Thread overview: </b>";
 750         if ($nr <= 1) {
 751                 if (defined $parent) {
 752                         $$skel .= SKEL_EXPAND."\n ";
 753                         $$skel .= ghost_parent('../', $parent) . "\n";
 754                 } else {
 755                         $$skel .= "<a\nid=r>[no followups]</a> ".
 756                                         SKEL_EXPAND."\n";
 757                 }
 758                 $ctx->{next_msg} = undef;
 759                 $ctx->{parent_msg} = $parent;
 760                 return;
 761         }
 762
 763         $$skel .= $nr;
 764         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 765
 766         # nb: mutt only shows the first Subject in the index pane
 767         # when multiple Subject: headers are present, so we follow suit:
 768         my $subj = $hdr->header('Subject') // '';
 769         $subj = '(no subject)' if $subj eq '';
 770         $ctx->{cur} = $mid;
 771         $ctx->{prev_attr} = '';
 772         $ctx->{prev_level} = 0;
 773         $ctx->{skel} = $skel;
 774
 775         # reduce hash lookups in skel_dump
 776         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 777         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 778
 779         $ctx->{parent_msg} = $parent;
 780 }
 781
 782 sub _parent_headers {
 783         my ($ctx, $hdr) = @_;
 784         my @irt = $hdr->header_raw('In-Reply-To');
 785         my $refs;
 786         my $s = '';
 787         if (!@irt) {
 788                 $refs = references($hdr);
 789                 $irt[0] = pop(@$refs) if scalar @$refs;
 790         }
 791         $s .= "In-Reply-To: $_\n" for @irt;
 792
 793         # do not display References: if search is present,
 794         # we show the thread skeleton at the bottom, instead.
 795         if (!$ctx->{ibx}->over) {
 796                 $refs //= references($hdr);
 797                 $s .= 'References: <'.join(">\n\t<", @$refs).">\n" if @$refs;
 798         }
 799         $ctx->{-linkify}->linkify_mids('..', \$s); # escapes HTML
 800         $s .= "\n";
 801 }
 802
 803 # appends to obuf
 804 sub html_footer {
 805         my ($ctx, $hdr) = @_;
 806         my $upfx = '../';
 807         my ($related, $skel);
 808         my $qry = delete $ctx->{-qry};
 809         if ($qry && $ctx->{ibx}->isrch) {
 810                 my $q = ''; # search for either ancestor or descendent patches
 811                 for (@{$qry->{dfpre}}, @{$qry->{dfpost}}) {
 812                         chop if length > 7; # include 1 abbrev "older" patches
 813                         $q .= "dfblob:$_ ";
 814                 }
 815                 chop $q; # omit trailing SP
 816                 local $Text::Wrap::columns = COLS;
 817                 local $Text::Wrap::huge = 'overflow';
 818                 $q = wrap('', '', $q);
 819                 my $rows = ($q =~ tr/\n/\n/) + 1;
 820                 $q = ascii_html($q);
 821                 $related = <<EOM;
 822 <form id=related
 823 action=$upfx
 824 ><pre>find likely ancestor, descendant, or conflicting patches for <a
 825 href=#t>this message</a>:
 826 <textarea name=q cols=${\COLS} rows=$rows>$q</textarea>
 827 <input type=submit value=search
 828 />\t(<a href=${upfx}_/text/help/#search>help</a>)</pre></form>
 829 EOM
 830         }
 831         if ($ctx->{ibx}->over) {
 832                 my $t = ts2str($ctx->{-t_max});
 833                 my $t_fmt = fmt_ts($ctx->{-t_max});
 834                 my $fallback = $related ? "\t" : "<a id=related>\t</a>";
 835                 $skel = <<EOF;
 836 ${fallback}other threads:[<a
 837 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 838 href="$upfx">newest</a>]
 839 EOF
 840
 841                 thread_skel(\$skel, $ctx, $hdr);
 842                 my ($next, $prev);
 843                 my $parent = '       ';
 844                 $next = $prev = '    ';
 845
 846                 if (my $n = $ctx->{next_msg}) {
 847                         $n = mid_href($n);
 848                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 849                 }
 850                 my $u;
 851                 my $par = $ctx->{parent_msg};
 852                 if ($par) {
 853                         $u = mid_href($par);
 854                         $u = "$upfx$u/";
 855                 }
 856                 if (my $p = $ctx->{prev_msg}) {
 857                         $prev = mid_href($p);
 858                         if ($p && $par && $p eq $par) {
 859                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 860                                         'rel=prev>prev parent</a>';
 861                                 $parent = '';
 862                         } else {
 863                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 864                                         'rel=prev>prev</a>';
 865                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 866                         }
 867                 } elsif ($u) { # unlikely
 868                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 869                 }
 870                 ${$ctx->{obuf}} .= "<pre>$next $prev$parent ";
 871         } else { # unindexed inboxes w/o over
 872                 ${$ctx->{obuf}} .= '<pre>';
 873                 $skel = qq( <a\nhref="$upfx">latest</a>);
 874         }
 875         ${$ctx->{obuf}} .= qq(<a\nhref="#R">reply</a>);
 876         # $skel may be big for big threads, don't append it to obuf
 877         $skel .= '</pre>' . ($related // '');
 878         $ctx->zmore($skel .= msg_reply($ctx, $hdr)); # flushes obuf
 879 }
 880
 881 sub ghost_parent {
 882         my ($upfx, $mid) = @_;
 883
 884         my $href = mid_href($mid);
 885         my $html = ascii_html($mid);
 886         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 887 }
 888
 889 sub indent_for {
 890         my ($level) = @_;
 891         $level ? INDENT x ($level - 1) : '';
 892 }
 893
 894 sub find_mid_root {
 895         my ($ctx, $level, $node, $idx) = @_;
 896         ++$ctx->{root_idx} if $level == 0;
 897         if ($node->{mid} eq $ctx->{mid}) {
 898                 $ctx->{found_mid_at} = $ctx->{root_idx};
 899                 return 0; # stop iterating
 900         }
 901         1;
 902 }
 903
 904 sub strict_loose_note ($) {
 905         my ($nr) = @_;
 906         my $msg =
 907 "  -- strict thread matches above, loose matches on Subject: below --\n";
 908
 909         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 910                 $msg .=
 911 "  -- use mbox.gz link to download all $nr messages --\n";
 912         }
 913         $msg;
 914 }
 915
 916 sub thread_results {
 917         my ($ctx, $msgs) = @_;
 918         require PublicInbox::SearchThread;
 919         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 920
 921         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 922         # and preserved in the future.  This bug is hidden by `sid' matches
 923         # in get_thread, so we never noticed it until now.  And even when
 924         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 925         # bump since reindexing is expensive and users may not do it
 926
 927         # loose threading could've returned too many results,
 928         # put the root the message we care about at the top:
 929         my $mid = $ctx->{mid};
 930         if (defined($mid) && scalar(@$rootset) > 1) {
 931                 $ctx->{root_idx} = -1;
 932                 my $nr = scalar @$msgs;
 933                 walk_thread($rootset, $ctx, \&find_mid_root);
 934                 my $idx = $ctx->{found_mid_at};
 935                 if (defined($idx) && $idx != 0) {
 936                         my $tip = splice(@$rootset, $idx, 1);
 937                         @$rootset = reverse @$rootset;
 938                         unshift @$rootset, $tip;
 939                         $ctx->{sl_note} = strict_loose_note($nr);
 940                 }
 941         }
 942         $rootset
 943 }
 944
 945 sub missing_thread {
 946         my ($ctx) = @_;
 947         require PublicInbox::ExtMsg;
 948         PublicInbox::ExtMsg::ext_msg($ctx);
 949 }
 950
 951 sub dedupe_subject {
 952         my ($prev_subj, $subj, $val) = @_;
 953
 954         my $omit; # '"' denotes identical text omitted
 955         my (@prev_pop, @curr_pop);
 956         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 957                 push(@prev_pop, pop(@$prev_subj));
 958                 push(@curr_pop, pop(@$subj));
 959                 $omit //= $val;
 960         }
 961         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 962         if (scalar(@curr_pop) == 1) {
 963                 $omit = undef;
 964                 push @$prev_subj, @prev_pop;
 965                 push @$subj, @curr_pop;
 966         }
 967         $omit // '';
 968 }
 969
 970 sub skel_dump { # walk_thread callback
 971         my ($ctx, $level, $smsg) = @_;
 972         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 973
 974         my $skel = $ctx->{skel};
 975         my $cur = $ctx->{cur};
 976         my $mid = $smsg->{mid};
 977
 978         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 979                 $$skel .= delete($ctx->{sl_note}) || '';
 980         }
 981
 982         my $f = ascii_html(delete $smsg->{from_name});
 983         my $obfs_ibx = $ctx->{-obfs_ibx};
 984         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 985
 986         my $d = fmt_ts($smsg->{ds});
 987         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 988         if (exists $ctx->{searchview}) {
 989                 if (defined(my $pct = $smsg->{pct})) {
 990                         $d .= (sprintf(' % 2u', $pct) . '%');
 991                 } else {
 992                         $unmatched = 1;
 993                         $d .= '    ';
 994                 }
 995         }
 996         $d .= ' ' . indent_for($level) . th_pfx($level);
 997         my $attr = $f;
 998         $ctx->{first_level} ||= $level;
 999
1000         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
1001                 $ctx->{prev_attr} = $attr;
1002         }
1003         $ctx->{prev_level} = $level;
1004
1005         if ($cur) {
1006                 if ($cur eq $mid) {
1007                         delete $ctx->{cur};
1008                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
1009                                  "$attr [this message]</a></b>\n";
1010                         return 1;
1011                 } else {
1012                         $ctx->{prev_msg} = $mid;
1013                 }
1014         } else {
1015                 $ctx->{next_msg} ||= $mid;
1016         }
1017
1018         # Subject is never undef, this mail was loaded from
1019         # our Xapian which would've resulted in '' if it were
1020         # really missing (and Filter rejects empty subjects)
1021         my @subj = split(/ /, subject_normalized($smsg->{subject}));
1022         # remove common suffixes from the subject if it matches the previous,
1023         # so we do not show redundant text at the end.
1024         my $prev_subj = $ctx->{prev_subj} || [];
1025         $ctx->{prev_subj} = [ @subj ];
1026         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1027         my $end;
1028         if (@subj) {
1029                 my $subj = join(' ', @subj);
1030                 $subj = ascii_html($subj);
1031                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1032                 $end = "$subj</a> $omit$f\n"
1033         } else {
1034                 $end = "$f</a>\n";
1035         }
1036         my $m;
1037         my $id = '';
1038         my $mapping = $unmatched ? undef : $ctx->{mapping};
1039         if ($mapping) {
1040                 my $map = $mapping->{$mid};
1041                 $id = id_compress($mid, 1);
1042                 $m = '#m'.$id;
1043                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1044                 $id = "\nid=r".$id;
1045         } else {
1046                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1047         }
1048         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1049         1;
1050 }
1051
1052 sub _skel_ghost {
1053         my ($ctx, $level, $node) = @_;
1054
1055         my $mid = $node->{mid};
1056         my $d = '     [not found] ';
1057         $d .= '    '  if exists $ctx->{searchview};
1058         $d .= indent_for($level) . th_pfx($level);
1059         my $upfx = $ctx->{-upfx};
1060         my $href = $upfx . mid_href($mid) . '/';
1061         my $html = ascii_html($mid);
1062
1063         my $mapping = $ctx->{mapping};
1064         my $map = $mapping->{$mid} if $mapping;
1065         if ($map) {
1066                 my $id = id_compress($mid, 1);
1067                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1068                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1069         } else {
1070                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1071         }
1072         ${$ctx->{skel}} .= $d;
1073         1;
1074 }
1075
1076 sub sort_ds {
1077         @{$_[0]} = sort {
1078                 (eval { $a->topmost->{ds} } || 0) <=>
1079                 (eval { $b->topmost->{ds} } || 0)
1080         } @{$_[0]};
1081 }
1082
1083 # accumulate recent topics if search is supported
1084 # returns 200 if done, 404 if not
1085 sub acc_topic { # walk_thread callback
1086         my ($ctx, $level, $smsg) = @_;
1087         my $mid = $smsg->{mid};
1088         my $has_blob = $smsg->{blob} // do {
1089                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1090                         %$smsg = (%$smsg, %$by_mid);
1091                         1;
1092                 }
1093         };
1094         if ($has_blob) {
1095                 my $subj = subject_normalized($smsg->{subject});
1096                 $subj = '(no subject)' if $subj eq '';
1097                 my $ds = $smsg->{ds};
1098                 if ($level == 0) { # new, top-level topic
1099                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1100                         $ctx->{-cur_topic} = $topic;
1101                         push @{$ctx->{order}}, $topic;
1102                         return 1;
1103                 }
1104
1105                 # continue existing topic
1106                 my $topic = $ctx->{-cur_topic}; # should never be undef
1107                 $topic->[0] = $ds if $ds > $topic->[0];
1108                 $topic->[1]++; # bump N+ message counter
1109                 my $seen = $topic->[2];
1110                 if (scalar(@$topic) == 3) { # parent was a ghost
1111                         push @$topic, $subj;
1112                 } elsif (!defined($seen->{$subj})) {
1113                         push @$topic, $level, $subj; # @extra messages
1114                 }
1115                 $seen->{$subj} = $mid; # latest for subject
1116         } else { # ghost message
1117                 return 1 if $level != 0; # ignore child ghosts
1118                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1119                 push @{$ctx->{order}}, $topic;
1120         }
1121         1;
1122 }
1123
1124 sub dump_topics {
1125         my ($ctx) = @_;
1126         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1127         unless ($order) {
1128                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1129                 return 404;
1130         }
1131
1132         my @out;
1133         my $obfs_ibx = $ctx->{ibx}->{obfuscate} ? $ctx->{ibx} : undef;
1134         if (my $note = delete $ctx->{t_note}) {
1135                 push @out, $note; # "messages from ... to ..."
1136         }
1137         # sort by recency, this allows new posts to "bump" old topics...
1138         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1139                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1140                 @$topic = ();
1141                 next unless defined $top_subj;  # ghost topic
1142                 my $mid = delete $seen->{$top_subj};
1143                 my $href = mid_href($mid);
1144                 my $prev_subj = [ split(/ /, $top_subj) ];
1145                 $top_subj = ascii_html($top_subj);
1146                 $ds = fmt_ts($ds);
1147
1148                 # $n isn't the total number of posts on the topic,
1149                 # just the number of posts in the current results window
1150                 my $anchor;
1151                 if ($n == 1) {
1152                         $n = '';
1153                         $anchor = '#u'; # top of only message
1154                 } else {
1155                         $n = " ($n+ messages)";
1156                         $anchor = '#t'; # thread skeleton
1157                 }
1158
1159                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1160                         " $ds UTC $n\n";
1161                 while (@extra) {
1162                         my $level = shift @extra;
1163                         my $subj = shift @extra; # already normalized
1164                         $mid = delete $seen->{$subj};
1165                         my @subj = split(/ /, $subj);
1166                         my @next_prev = @subj; # full copy
1167                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1168                         $prev_subj = \@next_prev;
1169                         $subj = join(' ', @subj);
1170                         $subj = ascii_html($subj);
1171                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1172                         $href = mid_href($mid);
1173                         $s .= indent_for($level) . TCHILD;
1174                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1175                 }
1176                 push @out, $s;
1177         }
1178         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1179         200;
1180 }
1181
1182 sub str2ts ($) {
1183         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1184         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1185 }
1186
1187 sub pagination_footer ($$) {
1188         my ($ctx, $latest) = @_;
1189         my $next = $ctx->{next_page} || '';
1190         my $prev = $ctx->{prev_page} || '';
1191         if ($prev) {  # aligned padding for: 'next (older) | '
1192                 $next = $next ? "$next | " : '             | ';
1193                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1194         }
1195         ($next || $prev) ? "<hr><pre id=nav>page: $next$prev</pre>" : '';
1196 }
1197
1198 sub paginate_recent ($$) {
1199         my ($ctx, $lim) = @_;
1200         my $t = $ctx->{qp}->{t} || '';
1201         my $opts = { limit => $lim };
1202         my ($after, $before);
1203
1204         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1205         # if only $after exists "YYYYMMDD.." because "." could be skipped
1206         # if interpreted as an end-of-sentence
1207         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1208         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1209
1210         my $msgs = $ctx->{ibx}->over->recent($opts, $after, $before);
1211         if (defined($after) && scalar(@$msgs) < $lim) {
1212                 $after = $before = undef;
1213                 $msgs = $ctx->{ibx}->over->recent($opts);
1214         }
1215         my $more = scalar(@$msgs) == $lim;
1216         my ($newest, $oldest);
1217         if (@$msgs) {
1218                 $newest = $msgs->[0]->{ts};
1219                 $oldest = $msgs->[-1]->{ts};
1220                 # if we only had $after, our SQL query in ->recent ordered
1221                 if ($newest < $oldest) {
1222                         ($oldest, $newest) = ($newest, $oldest);
1223                         $more = undef if defined($after) && $after < $oldest;
1224                 }
1225                 if (defined($after // $before)) {
1226                         my $n = strftime('%Y-%m-%d %H:%M:%S', gmtime($newest));
1227                         my $o = strftime('%Y-%m-%d %H:%M:%S', gmtime($oldest));
1228                         $ctx->{t_note} = <<EOM;
1229  messages from $o to $n UTC [<a href="#nav">more...</a>]
1230 EOM
1231                         my $s = ts2str($newest);
1232                         $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1233                                                 'prev (newer)</a>';
1234                 }
1235         }
1236         if (defined($oldest) && $more) {
1237                 my $s = ts2str($oldest);
1238                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1239                                         'next (older)</a>';
1240         }
1241         $msgs;
1242 }
1243
1244 # GET /$INBOX - top-level inbox view for indexed inboxes
1245 sub index_topics {
1246         my ($ctx) = @_;
1247         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1248         walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic) if @$msgs;
1249         html_oneshot($ctx, dump_topics($ctx), pagination_footer($ctx, '.'));
1250 }
1251
1252 sub thread_adj_level {
1253         my ($ctx, $level) = @_;
1254
1255         my $max = $ctx->{cur_level};
1256         if ($level <= 0) {
1257                 return ('', '') if $max == 0; # flat output
1258
1259                 # reset existing lists
1260                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1261                 $ctx->{cur_level} = 0;
1262                 ("$beg</ul>", '');
1263         } elsif ($level == $max) { # continue existing list
1264                 qw(<li> </li>);
1265         } elsif ($level < $max) {
1266                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1267                 $ctx->{cur_level} = $level;
1268                 ("$beg<li>", '</li>');
1269         } else { # ($level > $max) # start a new level
1270                 $ctx->{cur_level} = $level;
1271                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1272                 ($beg, '</li>');
1273         }
1274 }
1275
1276 sub ghost_index_entry {
1277         my ($ctx, $level, $node) = @_;
1278         my ($beg, $end) = thread_adj_level($ctx,  $level);
1279         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1280                 . '</pre>' . $end;
1281 }
1282
1283 1;