lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use URI::Escape qw/uri_escape/;
   7 use CGI qw/escapeHTML/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 use constant MAX_INLINE_QUOTED => 5;
  12
  13 my $enc_utf8 = find_encoding('utf8');
  14 my $enc_ascii = find_encoding('us-ascii');
  15 my $enc_mime = find_encoding('MIME-Header');
  16
  17 # public functions:
  18 sub as_html {
  19         my ($class, $mime, $full_pfx) = @_;
  20
  21         headers_to_html_header($mime) .
  22                 multipart_text_as_html($mime, $full_pfx) .
  23                 '</pre></body></html>';
  24 }
  25
  26 sub as_feed_entry {
  27         my ($class, $mime, $full_pfx) = @_;
  28
  29         "<pre>" . multipart_text_as_html($mime, $full_pfx) . "</pre>";
  30 }
  31
  32
  33 # only private functions below.
  34
  35 sub enc_for {
  36         my ($ct) = @_;
  37         defined $ct or return $enc_utf8;
  38         my $ct_parsed = parse_content_type($ct);
  39         if ($ct_parsed) {
  40                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
  41                         my $enc = find_encoding($charset);
  42                         return $enc if $enc;
  43                 }
  44         }
  45         $enc_utf8;
  46 }
  47
  48 sub multipart_text_as_html {
  49         my ($mime, $full_pfx) = @_;
  50         my $rv = "";
  51         my $part_nr = 0;
  52         my $enc_msg = enc_for($mime->header("Content-Type"));
  53
  54         # scan through all parts, looking for displayable text
  55         $mime->walk_parts(sub {
  56                 my ($part) = @_;
  57                 return if $part->subparts; # walk_parts already recurses
  58                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  59
  60                 if ($part_nr > 0) {
  61                         my $fn = $part->filename;
  62                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  63                         $rv .= add_filename_line($enc->decode($fn));
  64                 }
  65
  66                 if (defined $full_pfx) {
  67                         $rv .= add_text_body_short($enc, $part, $part_nr,
  68                                                 $full_pfx);
  69                 } else {
  70                         $rv .= add_text_body_full($enc, $part, $part_nr);
  71                 }
  72                 $rv .= "\n" unless $rv =~ /\n\z/s;
  73                 ++$part_nr;
  74         });
  75         $rv;
  76 }
  77
  78 sub add_filename_line {
  79         my ($fn) = @_;
  80         my $len = 72;
  81         my $pad = "-";
  82
  83         $len -= length($fn);
  84         $pad x= ($len/2) if ($len > 0);
  85         "$pad " . ascii_html($fn) . " $pad\n";
  86 }
  87
  88 sub add_text_body_short {
  89         my ($enc, $part, $part_nr, $full_pfx) = @_;
  90         my $n = 0;
  91         my $s = ascii_html($enc->decode($part->body));
  92         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
  93                 my $cur = $1;
  94                 my @lines = split(/\n/, $cur);
  95                 if (@lines > MAX_INLINE_QUOTED) {
  96                         # show a short snippet of quoted text
  97                         $cur = join(' ', @lines);
  98                         $cur =~ s/&gt; ?//g;
  99
 100                         my @sum = split(/\s+/, $cur);
 101                         $cur = '';
 102                         do {
 103                                 $cur .= shift(@sum) . ' ';
 104                         } while (@sum && length($cur) < 64);
 105                         $cur=~ s/ \z/ .../;
 106                         "&gt; &lt;<a href=\"${full_pfx}#q${part_nr}_" . $n++ .
 107                                 "\">$cur<\/a>&gt;\n";
 108                 } else {
 109                         $cur;
 110                 }
 111         !emg;
 112         $s;
 113 }
 114
 115 sub add_text_body_full {
 116         my ($enc, $part, $part_nr) = @_;
 117         my $n = 0;
 118         my $s = ascii_html($enc->decode($part->body));
 119         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 120                 my $cur = $1;
 121                 my @lines = split(/\n/, $cur);
 122                 if (@lines > MAX_INLINE_QUOTED) {
 123                         "<a name=q${part_nr}_" . $n++ . ">$cur</a>";
 124                 } else {
 125                         $cur;
 126                 }
 127         !emg;
 128         $s;
 129 }
 130
 131 sub trim_message_id {
 132         my ($mid) = @_;
 133         $mid = $enc_mime->decode($mid);
 134         $mid =~ s/\A\s*<//;
 135         $mid =~ s/>\s*\z//;
 136         my $html = ascii_html($mid);
 137         my $href = ascii_html(uri_escape($mid));
 138
 139         ($html, $href);
 140 }
 141
 142 sub ascii_html {
 143         $enc_ascii->encode(escapeHTML($_[0]), Encode::HTMLCREF);
 144 }
 145
 146 sub headers_to_html_header {
 147         my ($simple) = @_;
 148
 149         my $rv = "";
 150         my @title;
 151         foreach my $h (qw(From To Cc Subject Date)) {
 152                 my $v = $simple->header($h);
 153                 defined $v or next;
 154                 $v =~ tr/\n/ /s;
 155                 $v =~ tr/\r//d;
 156                 my $raw = $enc_mime->decode($v);
 157                 $v = ascii_html($raw);
 158                 $rv .= "$h: $v\n";
 159
 160                 if ($h eq 'From') {
 161                         my @from = Email::Address->parse($raw);
 162                         $raw = $from[0]->name;
 163                         unless (defined($raw) && length($raw)) {
 164                                 $raw = '<' . $from[0]->address . '>';
 165                         }
 166                         $title[1] = ascii_html($raw);
 167
 168                 } elsif ($h eq 'Subject') {
 169                         $title[0] = $v;
 170                 }
 171         }
 172
 173         my $mid = $simple->header('Message-ID');
 174         if (defined $mid) {
 175                 my ($html, $href) = trim_message_id($mid);
 176                 $rv .= "Message-ID: &lt;<a href=\"$href.html\">$html</a>&gt; ";
 177                 $rv .= "(<a href=\"$href.txt\">original</a>)\n";
 178         }
 179
 180         my $irp = $simple->header('In-Reply-To');
 181         if (defined $irp) {
 182                 my ($html, $href) = trim_message_id($irp);
 183                 $rv .= "In-Reply-To: &lt;";
 184                 $rv .= "<a href=\"$href.html\">$html</a>&gt;\n";
 185         }
 186         $rv .= "\n";
 187
 188         ("<html><head><title>".  join(' - ', @title) .
 189          '</title></head><body><pre style="white-space:pre-wrap">' .  $rv);
 190 }
 191
 192 1;