lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use URI::Escape qw/uri_escape/;
   7 use CGI qw/escapeHTML/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11
  12 my $enc_utf8 = find_encoding('utf8');
  13 my $enc_ascii = find_encoding('us-ascii');
  14 my $enc_mime = find_encoding('MIME-Header');
  15
  16 # public functions:
  17 sub as_html {
  18         my ($class, $mime, $full_pfx) = @_;
  19
  20         headers_to_html_header($mime) .
  21                 multipart_text_as_html($mime, $full_pfx) .
  22                 '</pre></body></html>';
  23 }
  24
  25 sub as_feed_entry {
  26         my ($class, $mime, $full_pfx) = @_;
  27
  28         "<pre>" . multipart_text_as_html($mime, $full_pfx) . "</pre>";
  29 }
  30
  31
  32 # only private functions below.
  33
  34 sub enc_for {
  35         my ($ct) = @_;
  36         defined $ct or return $enc_utf8;
  37         my $ct_parsed = parse_content_type($ct);
  38         if ($ct_parsed) {
  39                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
  40                         my $enc = find_encoding($charset);
  41                         return $enc if $enc;
  42                 }
  43         }
  44         $enc_utf8;
  45 }
  46
  47 sub multipart_text_as_html {
  48         my ($mime, $full_pfx) = @_;
  49         my $rv = "";
  50         my $part_nr = 0;
  51         my $enc_msg = enc_for($mime->header("Content-Type"));
  52
  53         # scan through all parts, looking for displayable text
  54         $mime->walk_parts(sub {
  55                 my ($part) = @_;
  56                 return if $part->subparts; # walk_parts already recurses
  57                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  58
  59                 if ($part_nr > 0) {
  60                         my $fn = $part->filename;
  61                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  62                         $rv .= add_filename_line($enc->decode($fn));
  63                 }
  64
  65                 if (defined $full_pfx) {
  66                         $rv .= add_text_body_short($enc, $part, $part_nr,
  67                                                 $full_pfx);
  68                 } else {
  69                         $rv .= add_text_body_full($enc, $part, $part_nr);
  70                 }
  71                 $rv .= "\n" unless $rv =~ /\n\z/s;
  72                 ++$part_nr;
  73         });
  74         $rv;
  75 }
  76
  77 sub add_filename_line {
  78         my ($fn) = @_;
  79         my $len = 72;
  80         my $pad = "-";
  81
  82         $len -= length($fn);
  83         $pad x= ($len/2) if ($len > 0);
  84         "$pad " . ascii_html($fn) . " $pad\n";
  85 }
  86
  87 sub add_text_body_short {
  88         my ($enc, $part, $part_nr, $full_pfx) = @_;
  89         my $n = 0;
  90         my $s = ascii_html($enc->decode($part->body));
  91         $s =~ s!^((?:(?:&gt;[^\n]+)\n)+)!
  92                 my $cur = $1;
  93                 my @lines = split(/\n/, $cur);
  94                 if (@lines > 1) {
  95                         # show a short snippet of quoted text
  96                         $cur = join(' ', @lines);
  97                         $cur =~ s/&gt; ?//g;
  98
  99                         my @sum = split(/\s+/, $cur);
 100                         $cur = '';
 101                         do {
 102                                 $cur .= shift(@sum) . ' ';
 103                         } while (@sum && length($cur) < 68);
 104                         $cur=~ s/ \z/ .../;
 105                         "&gt; &lt;<a href=\"${full_pfx}#q${part_nr}_" . $n++ .
 106                                 "\">$cur<\/a>&gt;";
 107                 } else {
 108                         $cur;
 109                 }
 110         !emg;
 111         $s;
 112 }
 113
 114 sub add_text_body_full {
 115         my ($enc, $part, $part_nr) = @_;
 116         my $n = 0;
 117         my $s = ascii_html($enc->decode($part->body));
 118         $s =~ s!^((?:(?:&gt;[^\n]+)\n)+)!
 119                 my $cur = $1;
 120                 my @lines = split(/\n/, $cur);
 121                 if (@lines > 1) {
 122                         "<a name=q${part_nr}_" . $n++ . ">$cur</a>";
 123                 } else {
 124                         $cur;
 125                 }
 126         !emg;
 127         $s;
 128 }
 129
 130 sub trim_message_id {
 131         my ($mid) = @_;
 132         $mid = $enc_mime->decode($mid);
 133         $mid =~ s/\A\s*<//;
 134         $mid =~ s/>\s*\z//;
 135         my $html = ascii_html($mid);
 136         my $href = ascii_html(uri_escape($mid));
 137
 138         ($html, $href);
 139 }
 140
 141 sub ascii_html {
 142         $enc_ascii->encode(escapeHTML($_[0]), Encode::HTMLCREF);
 143 }
 144
 145 sub headers_to_html_header {
 146         my ($simple) = @_;
 147
 148         my $rv = "";
 149         my @title;
 150         foreach my $h (qw(From To Cc Subject Date)) {
 151                 my $v = $simple->header($h);
 152                 defined $v or next;
 153                 $v =~ tr/\n/ /s;
 154                 $v =~ tr/\r//d;
 155                 $v = ascii_html($enc_mime->decode($v));
 156                 $rv .= "$h: $v\n";
 157
 158                 if ($h eq "From" || $h eq "Subject") {
 159                         push @title, $v;
 160                 }
 161         }
 162
 163         my $mid = $simple->header('Message-ID');
 164         if (defined $mid) {
 165                 my ($html, $href) = trim_message_id($mid);
 166                 $rv .= "Message-ID: &lt;<a href=\"$href.html\">$html</a>&gt; ";
 167                 $rv .= "(<a href=\"$href.txt\">original</a>)\n";
 168         }
 169
 170         my $irp = $simple->header('In-Reply-To');
 171         if (defined $irp) {
 172                 my ($html, $href) = trim_message_id($irp);
 173                 $rv .= "In-Reply-To: &lt;";
 174                 $rv .= "<a href=\"$href.html\">$html</a>&gt;\n";
 175         }
 176         $rv .= "\n";
 177
 178         ("<html><head><title>".  join(' - ', @title) .
 179          '</title></head><body><pre style="white-space:pre-wrap">' .  $rv);
 180 }
 181
 182 1;