lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use PublicInbox::MsgTime qw(msg_datestamp);
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::Linkify;
  12 use PublicInbox::MID qw/id_compress mid_escape mids references/;
  13 use PublicInbox::MsgIter;
  14 use PublicInbox::Address;
  15 use PublicInbox::WwwStream;
  16 use PublicInbox::Reply;
  17 use PublicInbox::ViewDiff qw(flush_diff);
  18 require POSIX;
  19 use Time::Local qw(timegm);
  20
  21 use constant COLS => 72;
  22 use constant INDENT => '  ';
  23 use constant TCHILD => '` ';
  24 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  25
  26 # public functions: (unstable)
  27
  28 sub msg_html {
  29         my ($ctx, $mime, $more, $smsg) = @_;
  30         my $hdr = $mime->header_obj;
  31         my $ibx = $ctx->{-inbox};
  32         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  33         my $tip = _msg_html_prepare($hdr, $ctx, $more, 0);
  34         my $end = 2;
  35         PublicInbox::WwwStream->response($ctx, 200, sub {
  36                 my ($nr, undef) = @_;
  37                 if ($nr == 1) {
  38                         # $more cannot be true w/o $smsg being defined:
  39                         my $upfx = $more ? '../'.mid_escape($smsg->mid).'/' : '';
  40                         $tip . multipart_text_as_html($mime, $upfx, $ibx) .
  41                                 '</pre><hr>'
  42                 } elsif ($more && @$more) {
  43                         ++$end;
  44                         msg_html_more($ctx, $more, $nr);
  45                 } elsif ($nr == $end) {
  46                         # fake an EOF if generating the footer fails;
  47                         # we want to at least show the message if something
  48                         # here crashes:
  49                         eval {
  50                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  51                                 '</pre>' . msg_reply($ctx, $hdr)
  52                         };
  53                 } else {
  54                         undef
  55                 }
  56         });
  57 }
  58
  59 sub msg_page {
  60         my ($ctx) = @_;
  61         my $mid = $ctx->{mid};
  62         my $ibx = $ctx->{-inbox};
  63         my ($first, $more);
  64         my $smsg;
  65         if (my $srch = $ibx->search) {
  66                 my ($id, $prev);
  67                 $smsg = $srch->next_by_mid($mid, \$id, \$prev);
  68                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  69                 if ($first) {
  70                         my $next = $srch->next_by_mid($mid, \$id, \$prev);
  71                         $more = [ $id, $prev, $next ] if $next;
  72                 }
  73                 return unless $first;
  74         } else {
  75                 $first = $ibx->msg_by_mid($mid) or return;
  76         }
  77         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  78 }
  79
  80 sub msg_html_more {
  81         my ($ctx, $more, $nr) = @_;
  82         my $str = eval {
  83                 my ($id, $prev, $smsg) = @$more;
  84                 my $mid = $ctx->{mid};
  85                 my $ibx = $ctx->{-inbox};
  86                 $smsg = $ibx->smsg_mime($smsg);
  87                 my $next = $ctx->{srch}->next_by_mid($mid, \$id, \$prev);
  88                 @$more = $next ? ($id, $prev, $next) : ();
  89                 if ($smsg) {
  90                         my $mime = $smsg->{mime};
  91                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
  92                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
  93                                 multipart_text_as_html($mime, $upfx, $ibx) .
  94                                 '</pre><hr>'
  95                 } else {
  96                         '';
  97                 }
  98         };
  99         if ($@) {
 100                 warn "Error lookup up additional messages: $@\n";
 101                 $str = '<pre>Error looking up additional messages</pre>';
 102         }
 103         $str;
 104 }
 105
 106 # /$INBOX/$MESSAGE_ID/#R
 107 sub msg_reply {
 108         my ($ctx, $hdr) = @_;
 109         my $se_url =
 110          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 111         my $p_url =
 112          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 113
 114         my $info = '';
 115         my $ibx = $ctx->{-inbox};
 116         if (my $url = $ibx->{infourl}) {
 117                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
 118                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 119         }
 120
 121         my ($arg, $link, $reply_to_all) =
 122                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 123         if (ref($arg) eq 'SCALAR') {
 124                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 125         }
 126
 127         # mailto: link only works if address obfuscation is disabled
 128         if ($link) {
 129                 $link = <<EOF;
 130
 131 * If your mail client supports setting the <b>In-Reply-To</b> header
 132   via mailto: links, try the <a
 133 href="$link">mailto: link</a>
 134 EOF
 135         }
 136
 137         push @$arg, '/path/to/YOUR_REPLY';
 138         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 139         <<EOF
 140 <hr><pre
 141 id=R><b>Reply instructions:</b>
 142
 143 You may reply publically to <a
 144 href=#t>this message</a> via plain-text email
 145 using any one of the following methods:
 146
 147 * Save the following mbox file, import it into your mail client,
 148   and $reply_to_all from there: <a
 149 href=raw>mbox</a>
 150
 151   Avoid top-posting and favor interleaved quoting:
 152   <a
 153 href="$p_url">$p_url</a>
 154 $info
 155 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 156   switches of git-send-email(1):
 157
 158   git send-email$arg
 159
 160   <a
 161 href="$se_url">$se_url</a>
 162 $link</pre>
 163 EOF
 164 }
 165
 166 sub in_reply_to {
 167         my ($hdr) = @_;
 168         my $refs = references($hdr);
 169         $refs->[-1];
 170 }
 171
 172 sub fold_addresses ($) {
 173         return $_[0] if length($_[0]) <= COLS;
 174         # try to fold on commas after non-word chars before $lim chars,
 175         # Try to get the "," preceeded by ">" or ")", but avoid folding
 176         # on the comma where somebody uses "Lastname, Firstname".
 177         # We also try to keep the last and penultimate addresses in
 178         # the list on the same line if possible, hence the extra \z
 179         # Fall back to folding on spaces at $lim + 1 chars
 180         my $lim = COLS - 8; # 8 = "\t" display width
 181         my $too_long = $lim + 1;
 182         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 183         $_[0] = join("\n\t",
 184                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 185                                 .{1,$lim}(?:,|\z)|
 186                                 .{1,$lim}|
 187                                 .{$too_long,}?)(?:\s|\z)/xgo));
 188 }
 189
 190 sub _hdr_names_html ($$) {
 191         my ($hdr, $field) = @_;
 192         my $val = $hdr->header($field) or return '';
 193         ascii_html(join(', ', PublicInbox::Address::names($val)));
 194 }
 195
 196 sub nr_to_s ($$$) {
 197         my ($nr, $singular, $plural) = @_;
 198         return "0 $plural" if $nr == 0;
 199         $nr == 1 ? "$nr $singular" : "$nr $plural";
 200 }
 201
 202 # this is already inside a <pre>
 203 sub index_entry {
 204         my ($smsg, $ctx, $more) = @_;
 205         my $srch = $ctx->{srch};
 206         my $subj = $smsg->subject;
 207         my $mid_raw = $smsg->mid;
 208         my $id = id_compress($mid_raw, 1);
 209         my $id_m = 'm'.$id;
 210
 211         my $root_anchor = $ctx->{root_anchor} || '';
 212         my $irt;
 213         my $obfs_ibx = $ctx->{-obfs_ibx};
 214
 215         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 216         $subj = '<b>'.ascii_html($subj).'</b>';
 217         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 218         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 219         $rv .= $subj . "\n";
 220         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 221         my @tocc;
 222         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 223         # deleting {mime} is critical to memory use,
 224         # the rest of the fields saves about 400K as we iterate across 1K msgs
 225         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 226
 227         my $hdr = $mime->header_obj;
 228         my $from = _hdr_names_html($hdr, 'From');
 229         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 230         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 231         my $upfx = $ctx->{-upfx};
 232         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 233         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 234         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 235         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 236         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 237         my ($tlen, $clen) = (length($to), length($cc));
 238         my $to_cc = '';
 239         if (($tlen + $clen) > COLS) {
 240                 $to_cc .= '  To: '.$to."\n" if $tlen;
 241                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 242         } else {
 243                 if ($tlen) {
 244                         $to_cc .= '  To: '.$to;
 245                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 246                 } else {
 247                         $to_cc .= '  Cc: '.$cc if $clen;
 248                 }
 249                 $to_cc .= "\n";
 250         }
 251         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 252         $rv .= $to_cc;
 253
 254         my $mapping = $ctx->{mapping};
 255         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 256                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 257                 my $href = $upfx . $mirt->{href}. '/';
 258                 my $html = $mirt->as_html;
 259                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 260         }
 261         $rv .= "\n";
 262
 263         # scan through all parts, looking for displayable text
 264         my $ibx = $ctx->{-inbox};
 265         msg_iter($mime, sub { $rv .= add_text_body($mhref, $ibx, $_[0]) });
 266
 267         # add the footer
 268         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 269                 "<a\nhref=\"$mhref\">permalink</a>" .
 270                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 271                 " <a\nhref=\"${mhref}#R\">reply</a>";
 272
 273         my $hr;
 274         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 275                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 276                 $hr = 1;
 277         } elsif ($mapping) {
 278                 my $nested = 'nested';
 279                 my $flat = 'flat';
 280                 my $end = '';
 281                 if ($ctx->{flat}) {
 282                         $hr = 1;
 283                         $flat = "<b>$flat</b>";
 284                 } else {
 285                         $nested = "<b>$nested</b>";
 286                 }
 287                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 288                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 289                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 290         } else {
 291                 $hr = $ctx->{-hr};
 292         }
 293
 294         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 295         $rv;
 296 }
 297
 298 sub pad_link ($$;$) {
 299         my ($mid, $level, $s) = @_;
 300         $s ||= '...';
 301         my $id = id_compress($mid, 1);
 302         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 303 }
 304
 305 sub _th_index_lite {
 306         my ($mid_raw, $irt, $id, $ctx) = @_;
 307         my $rv = '';
 308         my $mapping = $ctx->{mapping} or return $rv;
 309         my $pad = '  ';
 310         my $mid_map = $mapping->{$mid_raw};
 311         defined $mid_map or
 312                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 313         my ($attr, $node, $idx, $level) = @$mid_map;
 314         my $children = $node->{children};
 315         my $nr_c = scalar @$children;
 316         my $nr_s = 0;
 317         my $siblings;
 318         if (my $smsg = $node->{smsg}) {
 319                 # delete saves about 200KB on a 1K message thread
 320                 if (my $refs = delete $smsg->{references}) {
 321                         ($$irt) = ($refs =~ m/<([^>]+)>\z/);
 322                 }
 323         }
 324         my $irt_map = $mapping->{$$irt} if defined $$irt;
 325         if (defined $irt_map) {
 326                 $siblings = $irt_map->[1]->{children};
 327                 $nr_s = scalar(@$siblings) - 1;
 328                 $rv .= $pad . $irt_map->[0];
 329                 if ($idx > 0) {
 330                         my $prev = $siblings->[$idx - 1];
 331                         my $pmid = $prev->{id};
 332                         if ($idx > 2) {
 333                                 my $s = ($idx - 1). ' preceding siblings ...';
 334                                 $rv .= pad_link($pmid, $level, $s);
 335                         } elsif ($idx == 2) {
 336                                 my $ppmid = $siblings->[0]->{id};
 337                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 338                         }
 339                         $rv .= $pad . $mapping->{$pmid}->[0];
 340                 }
 341         }
 342         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 343         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 344         $attr =~ s!\n\z!</b>\n!s;
 345         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 346         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 347         $rv .= "<b>@ $attr";
 348         if ($nr_c) {
 349                 my $cmid = $children->[0]->{id};
 350                 $rv .= $pad . $mapping->{$cmid}->[0];
 351                 if ($nr_c > 2) {
 352                         my $s = ($nr_c - 1). ' more replies';
 353                         $rv .= pad_link($cmid, $level + 1, $s);
 354                 } elsif (my $cn = $children->[1]) {
 355                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 356                 }
 357         }
 358
 359         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 360         if ($next) {
 361                 my $nmid = $next->{id};
 362                 $rv .= $pad . $mapping->{$nmid}->[0];
 363                 my $nnext = $nr_s - $idx;
 364                 if ($nnext > 2) {
 365                         my $s = ($nnext - 1).' subsequent siblings';
 366                         $rv .= pad_link($nmid, $level, $s);
 367                 } elsif (my $nn = $siblings->[$idx + 2]) {
 368                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 369                 }
 370         }
 371         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 372 }
 373
 374 sub walk_thread {
 375         my ($rootset, $ctx, $cb) = @_;
 376         my @q = map { (0, $_, -1) } @$rootset;
 377         while (@q) {
 378                 my ($level, $node, $i) = splice(@q, 0, 3);
 379                 defined $node or next;
 380                 $cb->($ctx, $level, $node, $i) or return;
 381                 ++$level;
 382                 $i = 0;
 383                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 384         }
 385 }
 386
 387 sub pre_thread  {
 388         my ($ctx, $level, $node, $idx) = @_;
 389         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 390         skel_dump($ctx, $level, $node);
 391 }
 392
 393 sub thread_index_entry {
 394         my ($ctx, $level, $smsg) = @_;
 395         my ($beg, $end) = thread_adj_level($ctx, $level);
 396         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 397 }
 398
 399 sub stream_thread ($$) {
 400         my ($rootset, $ctx) = @_;
 401         my $inbox = $ctx->{-inbox};
 402         my @q = map { (0, $_) } @$rootset;
 403         my $level;
 404         my $smsg;
 405         while (@q) {
 406                 $level = shift @q;
 407                 my $node = shift @q or next;
 408                 my $cl = $level + 1;
 409                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 410                 $smsg = $inbox->smsg_mime($node->{smsg}) and last;
 411         }
 412         return missing_thread($ctx) unless $smsg;
 413
 414         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 415         $ctx->{-title_html} = ascii_html($smsg->subject);
 416         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 417         $smsg = undef;
 418         PublicInbox::WwwStream->response($ctx, 200, sub {
 419                 return unless $ctx;
 420                 while (@q) {
 421                         $level = shift @q;
 422                         my $node = shift @q or next;
 423                         my $cl = $level + 1;
 424                         unshift @q, map { ($cl, $_) } @{$node->{children}};
 425                         if ($smsg = $inbox->smsg_mime($node->{smsg})) {
 426                                 return thread_index_entry($ctx, $level, $smsg);
 427                         } else {
 428                                 return ghost_index_entry($ctx, $level, $node);
 429                         }
 430                 }
 431                 my $ret = join('', thread_adj_level($ctx, 0));
 432                 $ret .= ${$ctx->{dst}}; # skel
 433                 $ctx = undef;
 434                 $ret;
 435         });
 436 }
 437
 438 sub thread_html {
 439         my ($ctx) = @_;
 440         my $mid = $ctx->{mid};
 441         my $srch = $ctx->{srch};
 442         my ($nr, $msgs) = $srch->get_thread($mid);
 443         return missing_thread($ctx) if $nr == 0;
 444         my $skel = '<hr><pre>';
 445         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 446         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 447         $skel .= "<b\nid=t>Thread overview:</b> ";
 448         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 449         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 450         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 451         $skel .= "-- links below jump to the message on this page --\n";
 452         $ctx->{-upfx} = '../../';
 453         $ctx->{cur_level} = 0;
 454         $ctx->{dst} = \$skel;
 455         $ctx->{prev_attr} = '';
 456         $ctx->{prev_level} = 0;
 457         $ctx->{root_anchor} = anchor_for($mid);
 458         $ctx->{mapping} = {};
 459         $ctx->{s_nr} = "$nr+ messages in thread";
 460
 461         my $rootset = thread_results($ctx, $msgs);
 462
 463         # reduce hash lookups in pre_thread->skel_dump
 464         my $inbox = $ctx->{-inbox};
 465         $ctx->{-obfs_ibx} = $inbox->{obfuscate} ? $inbox : undef;
 466         walk_thread($rootset, $ctx, *pre_thread);
 467
 468         $skel .= '</pre>';
 469         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 470
 471         # flat display: lazy load the full message from smsg
 472         my $smsg;
 473         while (my $m = shift @$msgs) {
 474                 $smsg = $inbox->smsg_mime($m) and last;
 475         }
 476         return missing_thread($ctx) unless $smsg;
 477         $ctx->{-title_html} = ascii_html($smsg->subject);
 478         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 479         $smsg = undef;
 480         PublicInbox::WwwStream->response($ctx, 200, sub {
 481                 return unless $msgs;
 482                 $smsg = undef;
 483                 while (my $m = shift @$msgs) {
 484                         $smsg = $inbox->smsg_mime($m) and last;
 485                 }
 486                 return index_entry($smsg, $ctx, scalar @$msgs) if $smsg;
 487                 $msgs = undef;
 488                 $skel;
 489         });
 490 }
 491
 492 sub multipart_text_as_html {
 493         my ($mime, $upfx, $ibx) = @_;
 494         my $rv = "";
 495
 496         # scan through all parts, looking for displayable text
 497         msg_iter($mime, sub { $rv .= add_text_body($upfx, $ibx, $_[0]) });
 498         $rv;
 499 }
 500
 501 sub flush_quote {
 502         my ($s, $l, $quot) = @_;
 503
 504         # show everything in the full version with anchor from
 505         # short version (see above)
 506         my $rv = $l->linkify_1(join('', @$quot));
 507         @$quot = ();
 508
 509         # we use a <span> here to allow users to specify their own
 510         # color for quoted text
 511         $rv = $l->linkify_2(ascii_html($rv));
 512         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 513 }
 514
 515 sub attach_link ($$$$;$) {
 516         my ($upfx, $ct, $p, $fn, $err) = @_;
 517         my ($part, $depth, @idx) = @$p;
 518         my $nl = $idx[-1] > 1 ? "\n" : '';
 519         my $idx = join('.', @idx);
 520         my $size = bytes::length($part->body);
 521
 522         # hide attributes normally, unless we want to aid users in
 523         # spotting MUA problems:
 524         $ct =~ s/;.*// unless $err;
 525         $ct = ascii_html($ct);
 526         my $desc = $part->header('Content-Description');
 527         $desc = $fn unless defined $desc;
 528         $desc = '' unless defined $desc;
 529         my $sfn;
 530         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 531                 $sfn = $fn;
 532         } elsif ($ct eq 'text/plain') {
 533                 $sfn = 'a.txt';
 534         } else {
 535                 $sfn = 'a.bin';
 536         }
 537         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 538         if ($err) {
 539                 $ret .=
 540 "[-- Warning: decoded text below may be mangled --]\n";
 541         }
 542         $ret .= "[-- Attachment #$idx: ";
 543         my $ts = "Type: $ct, Size: $size bytes";
 544         $desc = ascii_html($desc);
 545         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 546         $ret .= "</a>\n";
 547 }
 548
 549 sub add_text_body {
 550         my ($upfx, $ibx, $p) = @_;
 551         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 552         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 553         my ($part, $depth) = @$p; # attachment @idx is unused
 554         my $ct = $part->content_type || 'text/plain';
 555         my $fn = $part->filename;
 556         my ($s, $err) = msg_part_text($part, $ct);
 557
 558         return attach_link($upfx, $ct, $p, $fn) unless defined $s;
 559
 560         my ($diff, $spfx);
 561         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 562                 $diff = [];
 563                 if ($ibx->{-repo_objs}) {
 564                         my $n_slash = $upfx =~ tr!/!/!;
 565                         if ($n_slash == 0) {
 566                                 $spfx = '../';
 567                         } elsif ($n_slash == 1) {
 568                                 $spfx = '';
 569                         } else { # nslash == 2
 570                                 $spfx = '../../';
 571                         }
 572                 }
 573         };
 574
 575         my @lines = split(/^/m, $s);
 576         $s = '';
 577         if (defined($fn) || $depth > 0 || $err) {
 578                 # badly-encoded message with $err? tell the world about it!
 579                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 580                 $s .= "\n";
 581         }
 582         my @quot;
 583         my $l = PublicInbox::Linkify->new;
 584         foreach my $cur (@lines) {
 585                 if ($cur !~ /^>/) {
 586                         # show the previously buffered quote inline
 587                         flush_quote(\$s, $l, \@quot) if @quot;
 588
 589                         if ($diff) {
 590                                 push @$diff, $cur;
 591                         } else {
 592                                 # regular line, OK
 593                                 $l->linkify_1($cur);
 594                                 $s .= $l->linkify_2(ascii_html($cur));
 595                         }
 596                 } else {
 597                         flush_diff(\$s, $spfx, $l, $diff) if $diff && @$diff;
 598                         push @quot, $cur;
 599                 }
 600         }
 601
 602         if (@quot) { # ugh, top posted
 603                 flush_quote(\$s, $l, \@quot);
 604                 flush_diff(\$s, $spfx, $l, $diff) if $diff && @$diff;
 605                 obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 606                 $s;
 607         } else {
 608                 flush_diff(\$s, $spfx, $l, $diff) if $diff && @$diff;
 609                 obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 610                 if ($s =~ /\n\z/s) { # common, last line ends with a newline
 611                         $s;
 612                 } else { # some editors don't do newlines...
 613                         $s .= "\n";
 614                 }
 615         }
 616 }
 617
 618 sub _msg_html_prepare {
 619         my ($hdr, $ctx, $more, $nr) = @_;
 620         my $srch = $ctx->{srch} if $ctx;
 621         my $atom = '';
 622         my $obfs_ibx = $ctx->{-obfs_ibx};
 623         my $rv = '';
 624         my $mids = mids($hdr);
 625         my $multiple = scalar(@$mids) > 1; # zero, one, infinity
 626         if ($nr == 0) {
 627                 if ($more) {
 628                         $rv .=
 629 "<pre>WARNING: multiple messages refer to this Message-ID\n</pre>";
 630                 }
 631                 $rv .= "<pre\nid=b>"; # anchor for body start
 632         } else {
 633                 $rv .= '<pre>';
 634         }
 635         if ($srch) {
 636                 $ctx->{-upfx} = '../';
 637         }
 638         my @title;
 639         my $v;
 640         if (defined($v = $hdr->header('From'))) {
 641                 $v = PublicInbox::Hval->new($v);
 642                 my @n = PublicInbox::Address::names($v->raw);
 643                 $title[1] = ascii_html(join(', ', @n));
 644                 $v = $v->as_html;
 645                 if ($obfs_ibx) {
 646                         obfuscate_addrs($obfs_ibx, $v);
 647                         obfuscate_addrs($obfs_ibx, $title[1]);
 648                 }
 649                 $rv .= "From: $v\n" if $v ne '';
 650         }
 651         foreach my $h (qw(To Cc)) {
 652                 defined($v = $hdr->header($h)) or next;
 653                 fold_addresses($v);
 654                 $v = ascii_html($v);
 655                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 656                 $rv .= "$h: $v\n" if $v ne '';
 657         }
 658         if (defined($v = $hdr->header('Subject')) && ($v ne '')) {
 659                 $v = ascii_html($v);
 660                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 661                 if ($srch) {
 662                         $rv .= qq(Subject: <a\nhref="#r"\nid=t>$v</a>\n);
 663                 } else {
 664                         $rv .= "Subject: $v\n";
 665                 }
 666                 $title[0] = $v;
 667         } else { # dummy anchor for thread skeleton at bottom of page
 668                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $srch;
 669                 $title[0] = '(no subject)';
 670         }
 671         if (defined($v = $hdr->header('Date'))) {
 672                 $v = ascii_html($v);
 673                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 674                 $rv .= "Date: $v\n";
 675         }
 676         $ctx->{-title_html} = join(' - ', @title);
 677         foreach (@$mids) {
 678                 my $mid = PublicInbox::Hval->new_msgid($_) ;
 679                 my $mhtml = $mid->as_html;
 680                 if ($multiple) {
 681                         my $href = $mid->{href};
 682                         $rv .= "Message-ID: ";
 683                         $rv .= "<a\nhref=\"../$href/\">";
 684                         $rv .= "&lt;$mhtml&gt;</a> ";
 685                         $rv .= "(<a\nhref=\"../$href/raw\">raw</a>)\n";
 686                 } else {
 687                         $rv .= "Message-ID: &lt;$mhtml&gt; ";
 688                         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 689                 }
 690         }
 691         $rv .= _parent_headers($hdr, $srch);
 692         $rv .= "\n";
 693 }
 694
 695 sub thread_skel {
 696         my ($dst, $ctx, $hdr, $tpfx) = @_;
 697         my $srch = $ctx->{srch};
 698         my $mid = mids($hdr)->[0];
 699         my ($nr, $msgs) = $srch->get_thread($mid);
 700         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 701                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 702                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 703                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 704
 705         my $parent = in_reply_to($hdr);
 706         $$dst .= "\n<b>Thread overview: </b>";
 707         if ($nr <= 1) {
 708                 if (defined $parent) {
 709                         $$dst .= "$expand\n ";
 710                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 711                 } else {
 712                         $$dst .= "[no followups] $expand\n";
 713                 }
 714                 $ctx->{next_msg} = undef;
 715                 $ctx->{parent_msg} = $parent;
 716                 return;
 717         }
 718
 719         $$dst .= "$nr+ messages / $expand";
 720         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 721
 722         my $subj = $hdr->header('Subject');
 723         defined $subj or $subj = '';
 724         $ctx->{prev_subj} = [ split(/ /, $srch->subject_normalized($subj)) ];
 725         $ctx->{cur} = $mid;
 726         $ctx->{prev_attr} = '';
 727         $ctx->{prev_level} = 0;
 728         $ctx->{dst} = $dst;
 729
 730         # reduce hash lookups in skel_dump
 731         my $ibx = $ctx->{-inbox};
 732         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 733         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 734
 735         $ctx->{parent_msg} = $parent;
 736 }
 737
 738 sub _parent_headers {
 739         my ($hdr, $srch) = @_;
 740         my $rv = '';
 741
 742         my $refs = references($hdr);
 743         my $irt = pop @$refs;
 744         if (defined $irt) {
 745                 my $v = PublicInbox::Hval->new_msgid($irt);
 746                 my $html = $v->as_html;
 747                 my $href = $v->{href};
 748                 $rv .= "In-Reply-To: &lt;";
 749                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 750         }
 751
 752         # do not display References: if search is present,
 753         # we show the thread skeleton at the bottom, instead.
 754         return $rv if $srch;
 755
 756         if (@$refs) {
 757                 @$refs = map { linkify_ref_nosrch($_) } @$refs;
 758                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 759         }
 760         $rv;
 761 }
 762
 763 sub html_footer {
 764         my ($hdr, $standalone, $ctx, $rhref) = @_;
 765
 766         my $srch = $ctx->{srch} if $ctx;
 767         my $upfx = '../';
 768         my $tpfx = '';
 769         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 770         my $irt = '';
 771         if ($idx && $srch) {
 772                 $idx .= "\n";
 773                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 774                 my ($next, $prev);
 775                 my $parent = '       ';
 776                 $next = $prev = '    ';
 777
 778                 if (my $n = $ctx->{next_msg}) {
 779                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 780                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 781                 }
 782                 my $u;
 783                 my $par = $ctx->{parent_msg};
 784                 if ($par) {
 785                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 786                         $u = "$upfx$u/";
 787                 }
 788                 if (my $p = $ctx->{prev_msg}) {
 789                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 790                         if ($p && $par && $p eq $par) {
 791                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 792                                         'rel=prev>prev parent</a>';
 793                                 $parent = '';
 794                         } else {
 795                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 796                                         'rel=prev>prev</a>';
 797                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 798                         }
 799                 } elsif ($u) { # unlikely
 800                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 801                 }
 802                 $irt = "$next $prev$parent ";
 803         } else {
 804                 $irt = '';
 805         }
 806         $rhref ||= '#R';
 807         $irt .= qq(<a\nhref="$rhref">reply</a>);
 808         $irt .= $idx;
 809 }
 810
 811 sub linkify_ref_nosrch {
 812         my $v = PublicInbox::Hval->new_msgid($_[0]);
 813         my $html = $v->as_html;
 814         my $href = $v->{href};
 815         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 816 }
 817
 818 sub anchor_for {
 819         my ($msgid) = @_;
 820         'm' . id_compress($msgid, 1);
 821 }
 822
 823 sub ghost_parent {
 824         my ($upfx, $mid) = @_;
 825
 826         $mid = PublicInbox::Hval->new_msgid($mid);
 827         my $href = $mid->{href};
 828         my $html = $mid->as_html;
 829         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 830 }
 831
 832 sub indent_for {
 833         my ($level) = @_;
 834         $level ? INDENT x ($level - 1) : '';
 835 }
 836
 837 sub find_mid_root {
 838         my ($ctx, $level, $node, $idx) = @_;
 839         ++$ctx->{root_idx} if $level == 0;
 840         if ($node->{id} eq $ctx->{mid}) {
 841                 $ctx->{found_mid_at} = $ctx->{root_idx};
 842                 return 0;
 843         }
 844         1;
 845 }
 846
 847 sub strict_loose_note ($) {
 848         my ($nr) = @_;
 849         my $msg =
 850 "  -- strict thread matches above, loose matches on Subject: below --\n";
 851
 852         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 853                 $msg .=
 854 "  -- use mbox.gz link to download all $nr messages --\n";
 855         }
 856         $msg;
 857 }
 858
 859 sub thread_results {
 860         my ($ctx, $msgs) = @_;
 861         require PublicInbox::SearchThread;
 862         my $ibx = $ctx->{-inbox};
 863         my $rootset = PublicInbox::SearchThread::thread($msgs, *sort_ds, $ibx);
 864
 865         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 866         # and preserved in the future.  This bug is hidden by `sid' matches
 867         # in get_thread, so we never noticed it until now.  And even when
 868         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 869         # bump since reindexing is expensive and users may not do it
 870
 871         # loose threading could've returned too many results,
 872         # put the root the message we care about at the top:
 873         my $mid = $ctx->{mid};
 874         if (defined($mid) && scalar(@$rootset) > 1) {
 875                 $ctx->{root_idx} = -1;
 876                 my $nr = scalar @$msgs;
 877                 walk_thread($rootset, $ctx, *find_mid_root);
 878                 my $idx = $ctx->{found_mid_at};
 879                 if (defined($idx) && $idx != 0) {
 880                         my $tip = splice(@$rootset, $idx, 1);
 881                         @$rootset = reverse @$rootset;
 882                         unshift @$rootset, $tip;
 883                         $ctx->{sl_note} = strict_loose_note($nr);
 884                 }
 885         }
 886         $rootset
 887 }
 888
 889 sub missing_thread {
 890         my ($ctx) = @_;
 891         require PublicInbox::ExtMsg;
 892         PublicInbox::ExtMsg::ext_msg($ctx);
 893 }
 894
 895 sub _msg_date {
 896         my ($hdr) = @_;
 897         fmt_ts(msg_datestamp($hdr));
 898 }
 899
 900 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 901
 902 sub dedupe_subject {
 903         my ($prev_subj, $subj, $val) = @_;
 904
 905         my $omit = ''; # '"' denotes identical text omitted
 906         my (@prev_pop, @curr_pop);
 907         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 908                 push(@prev_pop, pop(@$prev_subj));
 909                 push(@curr_pop, pop(@$subj));
 910                 $omit ||= $val;
 911         }
 912         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 913         if (scalar(@curr_pop) == 1) {
 914                 $omit = '';
 915                 push @$prev_subj, @prev_pop;
 916                 push @$subj, @curr_pop;
 917         }
 918         $omit;
 919 }
 920
 921 sub skel_dump {
 922         my ($ctx, $level, $node) = @_;
 923         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 924
 925         my $dst = $ctx->{dst};
 926         my $cur = $ctx->{cur};
 927         my $mid = $smsg->{mid};
 928
 929         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 930                 $$dst .= delete $ctx->{sl_note} || '';
 931         }
 932
 933         my $f = ascii_html($smsg->from_name);
 934         my $obfs_ibx = $ctx->{-obfs_ibx};
 935         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 936
 937         my $d = fmt_ts($smsg->{ds}) . ' ' . indent_for($level) . th_pfx($level);
 938         my $attr = $f;
 939         $ctx->{first_level} ||= $level;
 940
 941         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 942                 $ctx->{prev_attr} = $attr;
 943         }
 944         $ctx->{prev_level} = $level;
 945
 946         if ($cur) {
 947                 if ($cur eq $mid) {
 948                         delete $ctx->{cur};
 949                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 950                                  "$attr [this message]</a></b>\n";
 951                         return 1;
 952                 } else {
 953                         $ctx->{prev_msg} = $mid;
 954                 }
 955         } else {
 956                 $ctx->{next_msg} ||= $mid;
 957         }
 958
 959         # Subject is never undef, this mail was loaded from
 960         # our Xapian which would've resulted in '' if it were
 961         # really missing (and Filter rejects empty subjects)
 962         my @subj = split(/ /, $ctx->{srch}->subject_normalized($smsg->subject));
 963
 964         # remove common suffixes from the subject if it matches the previous,
 965         # so we do not show redundant text at the end.
 966         my $prev_subj = $ctx->{prev_subj} || [];
 967         $ctx->{prev_subj} = [ @subj ];
 968         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 969         my $end;
 970         if (@subj) {
 971                 my $subj = join(' ', @subj);
 972                 $subj = ascii_html($subj);
 973                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 974                 $end = "$subj</a> $omit$f\n"
 975         } else {
 976                 $end = "$f</a>\n";
 977         }
 978         my $m;
 979         my $id = '';
 980         my $mapping = $ctx->{mapping};
 981         if ($mapping) {
 982                 my $map = $mapping->{$mid};
 983                 $id = id_compress($mid, 1);
 984                 $m = '#m'.$id;
 985                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 986                 $id = "\nid=r".$id;
 987         } else {
 988                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 989         }
 990         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 991         1;
 992 }
 993
 994 sub _skel_ghost {
 995         my ($ctx, $level, $node) = @_;
 996
 997         my $mid = $node->{id};
 998         my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
 999                             : '     [not found] ';
1000         $d .= indent_for($level) . th_pfx($level);
1001         my $upfx = $ctx->{-upfx};
1002         my $m = PublicInbox::Hval->new_msgid($mid);
1003         my $href = $upfx . $m->{href} . '/';
1004         my $html = $m->as_html;
1005
1006         my $mapping = $ctx->{mapping};
1007         my $map = $mapping->{$mid} if $mapping;
1008         if ($map) {
1009                 my $id = id_compress($mid, 1);
1010                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1011                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1012         } else {
1013                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1014         }
1015         my $dst = $ctx->{dst};
1016         $$dst .= $d;
1017         1;
1018 }
1019
1020 sub sort_ds {
1021         [ sort {
1022                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
1023                 (eval { $b->topmost->{smsg}->ds } || 0)
1024         } @{$_[0]} ];
1025 }
1026
1027 # accumulate recent topics if search is supported
1028 # returns 200 if done, 404 if not
1029 sub acc_topic {
1030         my ($ctx, $level, $node) = @_;
1031         my $srch = $ctx->{srch};
1032         my $mid = $node->{id};
1033         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
1034         my ($subj, $ds);
1035         my $topic;
1036         if ($x) {
1037                 $subj = $x->subject;
1038                 $subj = $srch->subject_normalized($subj);
1039                 $ds = $x->ds;
1040                 if ($level == 0) {
1041                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1042                         $ctx->{-cur_topic} = $topic;
1043                         push @{$ctx->{order}}, $topic;
1044                         return 1;
1045                 }
1046
1047                 $topic = $ctx->{-cur_topic}; # should never be undef
1048                 $topic->[0] = $ds if $ds > $topic->[0];
1049                 $topic->[1]++;
1050                 my $seen = $topic->[2];
1051                 if (scalar(@$topic) == 3) { # parent was a ghost
1052                         push @$topic, $subj;
1053                 } elsif (!$seen->{$subj}) {
1054                         push @$topic, $level, $subj;
1055                 }
1056                 $seen->{$subj} = $mid; # latest for subject
1057         } else { # ghost message
1058                 return 1 if $level != 0; # ignore child ghosts
1059                 $topic = [ -666, 0, {} ];
1060                 $ctx->{-cur_topic} = $topic;
1061                 push @{$ctx->{order}}, $topic;
1062         }
1063         1;
1064 }
1065
1066 sub dump_topics {
1067         my ($ctx) = @_;
1068         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1069         if (!@$order) {
1070                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1071                 return 404;
1072         }
1073
1074         my @out;
1075         my $ibx = $ctx->{-inbox};
1076         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1077         my $srch = $ctx->{srch};
1078
1079         # sort by recency, this allows new posts to "bump" old topics...
1080         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1081                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1082                 @$topic = ();
1083                 next unless defined $top;  # ghost topic
1084                 my $mid = delete $seen->{$top};
1085                 my $href = mid_escape($mid);
1086                 my $prev_subj = [ split(/ /, $top) ];
1087                 $top = PublicInbox::Hval->new($top)->as_html;
1088                 $ds = fmt_ts($ds);
1089
1090                 # $n isn't the total number of posts on the topic,
1091                 # just the number of posts in the current results window
1092                 my $anchor;
1093                 if ($n == 1) {
1094                         $n = '';
1095                         $anchor = '#u'; # top of only message
1096                 } else {
1097                         $n = " ($n+ messages)";
1098                         $anchor = '#t'; # thread skeleton
1099                 }
1100
1101                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1102                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1103                 my $s = "<a\nhref=\"$href/T/$anchor\">$top</a>\n" .
1104                         " $ds UTC $n - $mbox / $atom\n";
1105                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1106                         my $level = $ex[$i];
1107                         my $subj = $ex[$i + 1];
1108                         $mid = delete $seen->{$subj};
1109                         my @subj = split(/ /, $srch->subject_normalized($subj));
1110                         my @next_prev = @subj; # full copy
1111                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1112                         $prev_subj = \@next_prev;
1113                         $subj = ascii_html(join(' ', @subj));
1114                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1115                         $href = mid_escape($mid);
1116                         $s .= indent_for($level) . TCHILD;
1117                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1118                 }
1119                 push @out, $s;
1120         }
1121         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1122         200;
1123 }
1124
1125 sub ts2str ($) {
1126         my ($ts) = @_;
1127         POSIX::strftime('%Y%m%d%H%M%S', gmtime($ts));
1128 }
1129
1130 sub str2ts ($) {
1131         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1132         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1133 }
1134
1135 sub pagination_footer ($$) {
1136         my ($ctx, $latest) = @_;
1137         delete $ctx->{qp} or return;
1138         my $next = $ctx->{next_page} || '';
1139         my $prev = $ctx->{prev_page} || '';
1140         if ($prev) {
1141                 $next = $next ? "$next " : '     ';
1142                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1143         }
1144         "<hr><pre>page: $next$prev</pre>";
1145 }
1146
1147 sub index_nav { # callback for WwwStream
1148         my (undef, $ctx) = @_;
1149         pagination_footer($ctx, '.')
1150 }
1151
1152 sub paginate_recent ($$) {
1153         my ($ctx, $lim) = @_;
1154         my $t = $ctx->{qp}->{t} || '';
1155         my $opts = { limit => $lim };
1156         my ($after, $before);
1157
1158         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1159         # if only $after exists "YYYYMMDD.." because "." could be skipped
1160         # if interpreted as an end-of-sentence
1161         $t =~ s/\A(\d{8,14})-// and $after = str2ts($1);
1162         $t =~ /\A(\d{8,14})\z/ and $before = str2ts($1);
1163
1164         my $ibx = $ctx->{-inbox};
1165         my $msgs = $ibx->recent($opts, $after, $before);
1166         my $nr = scalar @$msgs;
1167         if ($nr < $lim && defined($after)) {
1168                 $after = $before = undef;
1169                 $msgs = $ibx->recent($opts);
1170                 $nr = scalar @$msgs;
1171         }
1172         my $more = $nr == $lim;
1173         my ($newest, $oldest);
1174         if ($nr) {
1175                 $newest = $msgs->[0]->{ts};
1176                 $oldest = $msgs->[-1]->{ts};
1177                 # if we only had $after, our SQL query in ->recent ordered
1178                 if ($newest < $oldest) {
1179                         ($oldest, $newest) = ($newest, $oldest);
1180                         $more = 0 if defined($after) && $after < $oldest;
1181                 }
1182         }
1183         if (defined($oldest) && $more) {
1184                 my $s = ts2str($oldest);
1185                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1186         }
1187         if (defined($newest) && (defined($before) || defined($after))) {
1188                 my $s = ts2str($newest);
1189                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1190         }
1191         $msgs;
1192 }
1193
1194 sub index_topics {
1195         my ($ctx) = @_;
1196         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1197         if (@$msgs) {
1198                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1199         }
1200         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1201 }
1202
1203 sub thread_adj_level {
1204         my ($ctx, $level) = @_;
1205
1206         my $max = $ctx->{cur_level};
1207         if ($level <= 0) {
1208                 return ('', '') if $max == 0; # flat output
1209
1210                 # reset existing lists
1211                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1212                 $ctx->{cur_level} = 0;
1213                 ("$beg</ul>", '');
1214         } elsif ($level == $max) { # continue existing list
1215                 qw(<li> </li>);
1216         } elsif ($level < $max) {
1217                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1218                 $ctx->{cur_level} = $level;
1219                 ("$beg<li>", '</li>');
1220         } else { # ($level > $max) # start a new level
1221                 $ctx->{cur_level} = $level;
1222                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1223                 ($beg, '</li>');
1224         }
1225 }
1226
1227 sub ghost_index_entry {
1228         my ($ctx, $level, $node) = @_;
1229         my ($beg, $end) = thread_adj_level($ctx,  $level);
1230         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1231                 . '</pre>' . $end;
1232 }
1233
1234 1;