lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  12                         ts2str fmt_ts);
  13 use PublicInbox::Linkify;
  14 use PublicInbox::MID qw(id_compress mids mids_for_index references
  15                         $MID_EXTRACT);
  16 use PublicInbox::MsgIter;
  17 use PublicInbox::Address;
  18 use PublicInbox::WwwStream qw(html_oneshot);
  19 use PublicInbox::Reply;
  20 use PublicInbox::ViewDiff qw(flush_diff);
  21 use PublicInbox::Eml;
  22 use Time::Local qw(timegm);
  23 use PublicInbox::Smsg qw(subject_normalized);
  24 use PublicInbox::ContentHash qw(content_hash);
  25 use constant COLS => 72;
  26 use constant INDENT => '  ';
  27 use constant TCHILD => '` ';
  28 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  29
  30 sub msg_page_i {
  31         my ($ctx, $eml) = @_;
  32         if ($eml) { # called by WwwStream::async_eml or getline
  33                 my $smsg = $ctx->{smsg};
  34                 my $over = $ctx->{ibx}->over;
  35                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  36                                 : $ctx->gone('over');
  37                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  38                                 "../${\mid_href($smsg->{mid})}/" : '';
  39                 my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($eml, $ctx);
  40                 if (length($$obuf)) {
  41                         multipart_text_as_html($eml, $ctx);
  42                         $$obuf .= '</pre><hr>';
  43                 }
  44                 delete $ctx->{obuf};
  45                 $$obuf .= html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 $$obuf;
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         my $obuf = $ctx->{obuf} = _msg_page_prepare_obuf($eml, $ctx);
  60         if (length($$obuf)) {
  61                 multipart_text_as_html($eml, $ctx);
  62                 $$obuf .= '</pre><hr>';
  63         }
  64         delete $ctx->{obuf};
  65         eval { $$obuf .= html_footer($ctx, $eml) };
  66         html_oneshot($ctx, 200, $obuf);
  67 }
  68
  69 # public functions: (unstable)
  70
  71 sub msg_page {
  72         my ($ctx) = @_;
  73         my $ibx = $ctx->{ibx};
  74         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  75         my $over = $ibx->over or return no_over_html($ctx);
  76         my ($id, $prev);
  77         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  78
  79         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  80                 return; # undef == 404
  81
  82         # allow user to easily browse the range around this message if
  83         # they have ->over
  84         $ctx->{-t_max} = $smsg->{ts};
  85         PublicInbox::WwwStream::aresponse($ctx, 200, \&msg_page_i);
  86 }
  87
  88 # /$INBOX/$MESSAGE_ID/#R
  89 sub msg_reply ($$) {
  90         my ($ctx, $hdr) = @_;
  91         my $se_url =
  92          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  93         my $p_url =
  94          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  95
  96         my $info = '';
  97         my $ibx = $ctx->{ibx};
  98         if (my $url = $ibx->{infourl}) {
  99                 $url = prurl($ctx->{env}, $url);
 100                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 101         }
 102
 103         my ($arg, $link, $reply_to_all) =
 104                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 105         if (ref($arg) eq 'SCALAR') {
 106                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 107         }
 108
 109         # mailto: link only works if address obfuscation is disabled
 110         if ($link) {
 111                 $link = <<EOF;
 112
 113 * If your mail client supports setting the <b>In-Reply-To</b> header
 114   via mailto: links, try the <a
 115 href="$link">mailto: link</a>
 116 EOF
 117         }
 118
 119         push @$arg, '/path/to/YOUR_REPLY';
 120         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 121         <<EOF
 122 <hr><pre
 123 id=R><b>Reply instructions:</b>
 124
 125 You may reply publicly to <a
 126 href=#t>this message</a> via plain-text email
 127 using any one of the following methods:
 128
 129 * Save the following mbox file, import it into your mail client,
 130   and $reply_to_all from there: <a
 131 href=raw>mbox</a>
 132
 133   Avoid top-posting and favor interleaved quoting:
 134   <a
 135 href="$p_url">$p_url</a>
 136 $info
 137 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 138   switches of git-send-email(1):
 139
 140   git send-email$arg
 141
 142   <a
 143 href="$se_url">$se_url</a>
 144 $link</pre>
 145 EOF
 146 }
 147
 148 sub in_reply_to {
 149         my ($hdr) = @_;
 150         my $refs = references($hdr);
 151         $refs->[-1];
 152 }
 153
 154 sub fold_addresses ($) {
 155         return $_[0] if length($_[0]) <= COLS;
 156         # try to fold on commas after non-word chars before $lim chars,
 157         # Try to get the "," preceded by ">" or ")", but avoid folding
 158         # on the comma where somebody uses "Lastname, Firstname".
 159         # We also try to keep the last and penultimate addresses in
 160         # the list on the same line if possible, hence the extra \z
 161         # Fall back to folding on spaces at $lim + 1 chars
 162         my $lim = COLS - 8; # 8 = "\t" display width
 163         my $too_long = $lim + 1;
 164         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 165         $_[0] = join("\n\t",
 166                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 167                                 .{1,$lim}(?:,|\z)|
 168                                 .{1,$lim}|
 169                                 .{$too_long,}?)(?:\s|\z)/xgo));
 170 }
 171
 172 sub _hdr_names_html ($$) {
 173         my ($hdr, $field) = @_;
 174         my @vals = $hdr->header($field) or return '';
 175         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 176 }
 177
 178 sub nr_to_s ($$$) {
 179         my ($nr, $singular, $plural) = @_;
 180         return "0 $plural" if $nr == 0;
 181         $nr == 1 ? "$nr $singular" : "$nr $plural";
 182 }
 183
 184 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 185 # this is already inside a <pre>
 186 sub eml_entry {
 187         my ($ctx, $eml) = @_;
 188         my $smsg = delete $ctx->{smsg};
 189         my $subj = delete $smsg->{subject};
 190         my $mid_raw = $smsg->{mid};
 191         my $id = id_compress($mid_raw, 1);
 192         my $id_m = 'm'.$id;
 193         my $root_anchor = $ctx->{root_anchor} || '';
 194         my $irt;
 195         my $obfs_ibx = $ctx->{-obfs_ibx};
 196
 197         $subj = '(no subject)' if $subj eq '';
 198         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 199         $subj = '<b>'.ascii_html($subj).'</b>';
 200         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 201         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 202         $rv .= $subj . "\n";
 203         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 204         my @tocc;
 205         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 206
 207         # Deleting these fields saves about 400K as we iterate across 1K msgs
 208         delete @$smsg{qw(ts blob)};
 209
 210         my $from = _hdr_names_html($eml, 'From');
 211         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 212         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 213         my $upfx = $ctx->{-upfx};
 214         my $mhref = $upfx . mid_href($mid_raw) . '/';
 215         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 216         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 217         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 218         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 219         my ($tlen, $clen) = (length($to), length($cc));
 220         my $to_cc = '';
 221         if (($tlen + $clen) > COLS) {
 222                 $to_cc .= '  To: '.$to."\n" if $tlen;
 223                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 224         } else {
 225                 if ($tlen) {
 226                         $to_cc .= '  To: '.$to;
 227                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 228                 } else {
 229                         $to_cc .= '  Cc: '.$cc if $clen;
 230                 }
 231                 $to_cc .= "\n";
 232         }
 233         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 234         $rv .= $to_cc;
 235
 236         my $mapping = $ctx->{mapping};
 237         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 238                 my $href = $upfx . mid_href($irt) . '/';
 239                 my $html = ascii_html($irt);
 240                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 241         }
 242         $rv .= "\n";
 243
 244         # scan through all parts, looking for displayable text
 245         $ctx->{mhref} = $mhref;
 246         $ctx->{obuf} = \$rv;
 247         $eml->each_part(\&add_text_body, $ctx, 1);
 248         delete $ctx->{obuf};
 249
 250         # add the footer
 251         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 252                 "<a\nhref=\"$mhref\">permalink</a>" .
 253                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 254                 " <a\nhref=\"${mhref}#R\">reply</a>";
 255
 256         my $hr;
 257         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 258                 $rv .= "\t[relevance $pct%]";
 259                 $hr = 1;
 260         } elsif ($mapping) {
 261                 my $nested = 'nested';
 262                 my $flat = 'flat';
 263                 my $end = '';
 264                 if ($ctx->{flat}) {
 265                         $hr = 1;
 266                         $flat = "<b>$flat</b>";
 267                 } else {
 268                         $nested = "<b>$nested</b>";
 269                 }
 270                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 271                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 272                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 273         } else {
 274                 $hr = $ctx->{-hr};
 275         }
 276
 277         # do we have more messages? start a new <pre> if so
 278         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 279         $rv;
 280 }
 281
 282 sub pad_link ($$;$) {
 283         my ($mid, $level, $s) = @_;
 284         $s ||= '...';
 285         my $href = defined($mid) ?
 286                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 287                 "($s)\n";
 288         (' 'x19).indent_for($level).th_pfx($level).$href;
 289 }
 290
 291 sub _skel_hdr {
 292         # my ($mapping, $mid) = @_;
 293         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 294 }
 295
 296 sub _th_index_lite {
 297         my ($mid_raw, $irt, $id, $ctx) = @_;
 298         my $rv = '';
 299         my $mapping = $ctx->{mapping} or return $rv;
 300         my $pad = '  ';
 301         my $mid_map = $mapping->{$mid_raw};
 302         defined $mid_map or
 303                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 304         my ($attr, $node, $idx, $level) = @$mid_map;
 305         my $children = $node->{children};
 306         my $nr_c = scalar @$children;
 307         my $nr_s = 0;
 308         my $siblings;
 309         # delete saves about 200KB on a 1K message thread
 310         if (my $refs = delete $node->{references}) {
 311                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 312         }
 313         my $irt_map = $mapping->{$$irt} if defined $$irt;
 314         if (defined $irt_map) {
 315                 $siblings = $irt_map->[1]->{children};
 316                 $nr_s = scalar(@$siblings) - 1;
 317                 $rv .= $pad . $irt_map->[0];
 318                 if ($idx > 0) {
 319                         my $prev = $siblings->[$idx - 1];
 320                         my $pmid = $prev->{mid};
 321                         if ($idx > 2) {
 322                                 my $s = ($idx - 1). ' preceding siblings ...';
 323                                 $rv .= pad_link($pmid, $level, $s);
 324                         } elsif ($idx == 2) {
 325                                 $rv .= $pad . _skel_hdr($mapping,
 326                                                 $siblings->[0] ?
 327                                                 $siblings->[0]->{mid} : undef);
 328                         }
 329                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 330                 }
 331         }
 332         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 333         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 334         $attr =~ s!\n\z!</b>\n!s;
 335         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 336         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 337         $rv .= "<b>@ $attr";
 338         if ($nr_c) {
 339                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 340                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 341                 if ($nr_c > 2) {
 342                         my $s = ($nr_c - 1). ' more replies';
 343                         $rv .= pad_link($cmid, $level + 1, $s);
 344                 } elsif (my $cn = $children->[1]) {
 345                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 346                 }
 347         }
 348
 349         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 350         if ($next) {
 351                 my $nmid = $next->{mid};
 352                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 353                 my $nnext = $nr_s - $idx;
 354                 if ($nnext > 2) {
 355                         my $s = ($nnext - 1).' subsequent siblings';
 356                         $rv .= pad_link($nmid, $level, $s);
 357                 } elsif (my $nn = $siblings->[$idx + 2]) {
 358                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 359                 }
 360         }
 361         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 362 }
 363
 364 # non-recursive thread walker
 365 sub walk_thread ($$$) {
 366         my ($rootset, $ctx, $cb) = @_;
 367         my @q = map { (0, $_, -1) } @$rootset;
 368         while (@q) {
 369                 my ($level, $node, $i) = splice(@q, 0, 3);
 370                 defined $node or next;
 371                 $cb->($ctx, $level, $node, $i) or return;
 372                 ++$level;
 373                 $i = 0;
 374                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 375         }
 376 }
 377
 378 sub pre_thread  { # walk_thread callback
 379         my ($ctx, $level, $node, $idx) = @_;
 380         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 381         skel_dump($ctx, $level, $node);
 382 }
 383
 384 sub thread_eml_entry {
 385         my ($ctx, $eml) = @_;
 386         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 387         $beg . '<pre>' . eml_entry($ctx, $eml) . '</pre>' . $end;
 388 }
 389
 390 sub next_in_queue ($$) {
 391         my ($q, $ghost_ok) = @_;
 392         while (@$q) {
 393                 my ($level, $smsg) = splice(@$q, 0, 2);
 394                 my $cl = $level + 1;
 395                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 396                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 397         }
 398         undef;
 399 }
 400
 401 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 402         my ($ctx, $eml) = @_;
 403         return thread_eml_entry($ctx, $eml) if $eml;
 404         return unless exists($ctx->{skel});
 405         my $ghost_ok = $ctx->{nr}++;
 406         while (1) {
 407                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 408                 if ($smsg) {
 409                         if (exists $smsg->{blob}) { # next message for cat-file
 410                                 $ctx->{level} = $lvl;
 411                                 if (!$ghost_ok) { # first non-ghost
 412                                         $ctx->{-title_html} =
 413                                                 ascii_html($smsg->{subject});
 414                                         $ctx->zmore($ctx->html_top);
 415                                 }
 416                                 return $smsg;
 417                         }
 418                         # buffer the ghost entry and loop
 419                         $ctx->zmore(ghost_index_entry($ctx, $lvl, $smsg));
 420                 } else { # all done
 421                         $ctx->zmore(join('', thread_adj_level($ctx, 0)));
 422                         $ctx->zmore(${delete($ctx->{skel})});
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 sub stream_thread ($$) {
 429         my ($rootset, $ctx) = @_;
 430         $ctx->{-queue} = [ map { (0, $_) } @$rootset ];
 431         PublicInbox::WwwStream::aresponse($ctx, 200, \&stream_thread_i);
 432 }
 433
 434 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 435 sub thread_html {
 436         my ($ctx) = @_;
 437         $ctx->{-upfx} = '../../';
 438         my $mid = $ctx->{mid};
 439         my $ibx = $ctx->{ibx};
 440         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 441         return missing_thread($ctx) if $nr == 0;
 442
 443         # link $INBOX_DIR/description text to "index_topics" view around
 444         # the newest message in this thread
 445         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 446         my $t_fmt = fmt_ts($ctx->{-t_max});
 447
 448         my $skel = '<hr><pre>';
 449         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 450         $skel .= <<EOF;
 451 , other threads:[<a
 452 href="../../?t=$t">~$t_fmt UTC</a> | <a
 453 href="../../">newest</a>]
 454
 455 EOF
 456         $skel .= "<b\nid=t>Thread overview:</b> ";
 457         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 458         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 459         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 460         $skel .= "-- links below jump to the message on this page --\n";
 461         $ctx->{cur_level} = 0;
 462         $ctx->{skel} = \$skel;
 463         $ctx->{prev_attr} = '';
 464         $ctx->{prev_level} = 0;
 465         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 466         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 467         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 468                        .' in thread';
 469
 470         my $rootset = thread_results($ctx, $msgs);
 471
 472         # reduce hash lookups in pre_thread->skel_dump
 473         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 474         walk_thread($rootset, $ctx, \&pre_thread);
 475
 476         $skel .= '</pre>';
 477         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 478
 479         # flat display: lazy load the full message from smsg
 480         $ctx->{msgs} = $msgs;
 481         $ctx->{-html_tip} = '<pre>';
 482         PublicInbox::WwwStream::aresponse($ctx, 200, \&thread_html_i);
 483 }
 484
 485 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 486         my ($ctx, $eml) = @_;
 487         if ($eml) {
 488                 my $smsg = $ctx->{smsg};
 489                 if (exists $ctx->{-html_tip}) {
 490                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 491                         $ctx->zmore($ctx->html_top);
 492                 }
 493                 return eml_entry($ctx, $eml);
 494         } else {
 495                 while (my $smsg = shift @{$ctx->{msgs}}) {
 496                         return $smsg if exists($smsg->{blob});
 497                 }
 498                 my $skel = delete($ctx->{skel}) or return; # all done
 499                 $ctx->zmore($$skel);
 500                 undef;
 501         }
 502 }
 503
 504 sub multipart_text_as_html {
 505         # ($mime, $ctx) = @_; # each_part may do "$_[0] = undef"
 506
 507         # scan through all parts, looking for displayable text
 508         $_[0]->each_part(\&add_text_body, $_[1], 1);
 509 }
 510
 511 sub submsg_hdr ($$) {
 512         my ($ctx, $eml) = @_;
 513         my $obfs_ibx = $ctx->{-obfs_ibx};
 514         my $rv = $ctx->{obuf};
 515         $$rv .= "\n";
 516         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 517                 my @v = $eml->header($h);
 518                 for my $v (@v) {
 519                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 520                         $v = ascii_html($v);
 521                         $$rv .= "$h: $v\n";
 522                 }
 523         }
 524 }
 525
 526 sub attach_link ($$$$;$) {
 527         my ($ctx, $ct, $p, $fn, $err) = @_;
 528         my ($part, $depth, $idx) = @$p;
 529
 530         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 531         # downloads for 0-byte multipart attachments
 532         return unless $part->{bdy};
 533
 534         my $nl = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 535         my $size = length($part->body);
 536
 537         # hide attributes normally, unless we want to aid users in
 538         # spotting MUA problems:
 539         $ct =~ s/;.*// unless $err;
 540         $ct = ascii_html($ct);
 541         my $sfn;
 542         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 543                 $sfn = $fn;
 544         } elsif ($ct eq 'text/plain') {
 545                 $sfn = 'a.txt';
 546         } else {
 547                 $sfn = 'a.bin';
 548         }
 549         my $rv = $ctx->{obuf};
 550         $$rv .= qq($nl<a\nhref="$ctx->{mhref}$idx-$sfn">);
 551         if ($err) {
 552                 $$rv .= <<EOF;
 553 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 554 EOF
 555         }
 556         $$rv .= "[-- Attachment #$idx: ";
 557         my $ts = "Type: $ct, Size: $size bytes";
 558         my $desc = $part->header('Content-Description') // $fn // '';
 559         $desc = ascii_html($desc);
 560         $$rv .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 561         $$rv .= "</a>\n";
 562
 563         submsg_hdr($ctx, $part) if $part->{is_submsg};
 564
 565         undef;
 566 }
 567
 568 sub add_text_body { # callback for each_part
 569         my ($p, $ctx) = @_;
 570         my $upfx = $ctx->{mhref};
 571         my $ibx = $ctx->{ibx};
 572         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 573         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 574         my ($part, $depth, $idx) = @$p;
 575         my $ct = $part->content_type || 'text/plain';
 576         my $fn = $part->filename;
 577         my ($s, $err) = msg_part_text($part, $ct);
 578         return attach_link($ctx, $ct, $p, $fn) unless defined $s;
 579
 580         my $rv = $ctx->{obuf};
 581         if ($part->{is_submsg}) {
 582                 submsg_hdr($ctx, $part);
 583                 $$rv .= "\n";
 584         }
 585
 586         # makes no difference to browsers, and don't screw up filename
 587         # link generation in diffs with the extra '%0D'
 588         $s =~ s/\r\n/\n/sg;
 589
 590         # will be escaped to `&#8226;' in HTML
 591         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 592
 593         # always support diff-highlighting, but we can't linkify hunk
 594         # headers for solver unless some coderepo are configured:
 595         my $diff;
 596         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 597                 # diffstat anchors do not link across attachments or messages,
 598                 # -apfx is just a stable prefix for making diffstat anchors
 599                 # linkable to the first diff hunk w/o crossing attachments
 600                 $idx =~ tr!.!/!; # compatibility with previous versions
 601                 $ctx->{-apfx} = $upfx . $idx;
 602
 603                 # do attr => filename mappings for diffstats in git diffs:
 604                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 605                 $diff = 1;
 606                 delete $ctx->{-long_path};
 607                 my $spfx;
 608                 # absolute URL (Atom feeds)
 609                 if ($ibx->{coderepo}) {
 610                         if (index($upfx, '//') >= 0) {
 611                                 $spfx = $upfx;
 612                                 $spfx =~ s!/([^/]*)/\z!/!;
 613                         } else {
 614                                 my $n_slash = $upfx =~ tr!/!/!;
 615                                 if ($n_slash == 0) {
 616                                         $spfx = '../';
 617                                 } elsif ($n_slash == 1) {
 618                                         $spfx = '';
 619                                 } else { # nslash == 2
 620                                         $spfx = '../../';
 621                                 }
 622                         }
 623                 }
 624                 $ctx->{-spfx} = $spfx;
 625         };
 626
 627         # split off quoted and unquoted blocks:
 628         my @sections = PublicInbox::MsgIter::split_quotes($s);
 629         undef $s; # free memory
 630         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 631                 # badly-encoded message with $err? tell the world about it!
 632                 attach_link($ctx, $ct, $p, $fn, $err);
 633                 $$rv .= "\n";
 634         }
 635         foreach my $cur (@sections) {
 636                 if ($cur =~ /\A>/) {
 637                         # we use a <span> here to allow users to specify
 638                         # their own color for quoted text
 639                         $$rv .= qq(<span\nclass="q">);
 640                         $$rv .= $l->to_html($cur);
 641                         $$rv .= '</span>';
 642                 } elsif ($diff) {
 643                         flush_diff($ctx, \$cur);
 644                 } else {
 645                         # regular lines, OK
 646                         $$rv .= $l->to_html($cur);
 647                 }
 648                 undef $cur; # free memory
 649         }
 650 }
 651
 652 sub _msg_page_prepare_obuf {
 653         my ($eml, $ctx) = @_;
 654         my $over = $ctx->{ibx}->over;
 655         my $obfs_ibx = $ctx->{-obfs_ibx};
 656         my $rv = '';
 657         my $mids = mids_for_index($eml);
 658         my $nr = $ctx->{nr}++;
 659         if ($nr) { # unlikely
 660                 if ($ctx->{chash} eq content_hash($eml)) {
 661                         warn "W: BUG? @$mids not deduplicated properly\n";
 662                         return \$rv;
 663                 }
 664                 $rv .=
 665 "<pre>WARNING: multiple messages have this Message-ID\n</pre>";
 666                 $rv .= '<pre>';
 667         } else {
 668                 $ctx->{first_hdr} = $eml->header_obj;
 669                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 670                 $rv .= "<pre\nid=b>"; # anchor for body start
 671         }
 672         $ctx->{-upfx} = '../' if $over;
 673         my @title; # (Subject[0], From[0])
 674         for my $v ($eml->header('From')) {
 675                 my @n = PublicInbox::Address::names($v);
 676                 $v = ascii_html($v);
 677                 $title[1] //= ascii_html(join(', ', @n));
 678                 if ($obfs_ibx) {
 679                         obfuscate_addrs($obfs_ibx, $v);
 680                         obfuscate_addrs($obfs_ibx, $title[1]);
 681                 }
 682                 $rv .= "From: $v\n" if $v ne '';
 683         }
 684         foreach my $h (qw(To Cc)) {
 685                 for my $v ($eml->header($h)) {
 686                         fold_addresses($v);
 687                         $v = ascii_html($v);
 688                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 689                         $rv .= "$h: $v\n" if $v ne '';
 690                 }
 691         }
 692         my @subj = $eml->header('Subject');
 693         if (@subj) {
 694                 my $v = ascii_html(shift @subj);
 695                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 696                 $rv .= 'Subject: ';
 697                 $rv .= $over ? qq(<a\nhref="#r"\nid=t>$v</a>\n) : "$v\n";
 698                 $title[0] = $v;
 699                 for $v (@subj) { # multi-Subject message :<
 700                         $v = ascii_html($v);
 701                         obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 702                         $rv .= "Subject: $v\n";
 703                 }
 704         } else { # dummy anchor for thread skeleton at bottom of page
 705                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $over;
 706                 $title[0] = '(no subject)';
 707         }
 708         for my $v ($eml->header('Date')) {
 709                 $v = ascii_html($v);
 710                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 711                 $rv .= qq{Date: $v\t<a\nhref="#r">[thread overview]</a>\n};
 712         }
 713         if (!$nr) { # first (and only) message, common case
 714                 $ctx->{-title_html} = join(' - ', @title);
 715                 $rv = $ctx->html_top . $rv;
 716         }
 717         if (scalar(@$mids) == 1) { # common case
 718                 my $mhtml = ascii_html($mids->[0]);
 719                 $rv .= "Message-ID: &lt;$mhtml&gt; ";
 720                 $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 721         } else {
 722                 # X-Alt-Message-ID can happen if a message is injected from
 723                 # public-inbox-nntpd because of multiple Message-ID headers.
 724                 my $lnk = PublicInbox::Linkify->new;
 725                 my $s = '';
 726                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 727                         $s .= "$h: $_\n" for ($eml->header_raw($h));
 728                 }
 729                 $lnk->linkify_mids('..', \$s, 1);
 730                 $rv .= $s;
 731         }
 732         $rv .= _parent_headers($eml, $over);
 733         $rv .= "\n";
 734         \$rv;
 735 }
 736
 737 sub SKEL_EXPAND () {
 738         qq(expand[<a\nhref="T/#u">flat</a>) .
 739                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 740                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 741                 qq(<a\nhref="t.atom">Atom feed</a>);
 742 }
 743
 744 sub thread_skel ($$$) {
 745         my ($skel, $ctx, $hdr) = @_;
 746         my $mid = mids($hdr)->[0];
 747         my $ibx = $ctx->{ibx};
 748         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 749         my $parent = in_reply_to($hdr);
 750         $$skel .= "\n<b>Thread overview: </b>";
 751         if ($nr <= 1) {
 752                 if (defined $parent) {
 753                         $$skel .= SKEL_EXPAND."\n ";
 754                         $$skel .= ghost_parent('../', $parent) . "\n";
 755                 } else {
 756                         $$skel .= "<a\nid=r>[no followups]</a> ".
 757                                         SKEL_EXPAND."\n";
 758                 }
 759                 $ctx->{next_msg} = undef;
 760                 $ctx->{parent_msg} = $parent;
 761                 return;
 762         }
 763
 764         $$skel .= $nr;
 765         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 766
 767         # nb: mutt only shows the first Subject in the index pane
 768         # when multiple Subject: headers are present, so we follow suit:
 769         my $subj = $hdr->header('Subject') // '';
 770         $subj = '(no subject)' if $subj eq '';
 771         $ctx->{prev_subj} = [ split(/ /, subject_normalized($subj)) ];
 772         $ctx->{cur} = $mid;
 773         $ctx->{prev_attr} = '';
 774         $ctx->{prev_level} = 0;
 775         $ctx->{skel} = $skel;
 776
 777         # reduce hash lookups in skel_dump
 778         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 779         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 780
 781         $ctx->{parent_msg} = $parent;
 782 }
 783
 784 sub _parent_headers {
 785         my ($hdr, $over) = @_;
 786         my $rv = '';
 787         my @irt = $hdr->header_raw('In-Reply-To');
 788         my $refs;
 789         if (@irt) {
 790                 my $lnk = PublicInbox::Linkify->new;
 791                 $rv .= "In-Reply-To: $_\n" for @irt;
 792                 $lnk->linkify_mids('..', \$rv);
 793         } else {
 794                 $refs = references($hdr);
 795                 my $irt = pop @$refs;
 796                 if (defined $irt) {
 797                         my $html = ascii_html($irt);
 798                         my $href = mid_href($irt);
 799                         $rv .= "In-Reply-To: &lt;";
 800                         $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 801                 }
 802         }
 803
 804         # do not display References: if search is present,
 805         # we show the thread skeleton at the bottom, instead.
 806         return $rv if $over;
 807
 808         $refs //= references($hdr);
 809         if (@$refs) {
 810                 @$refs = map { linkify_ref_no_over($_) } @$refs;
 811                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 812         }
 813         $rv;
 814 }
 815
 816 # returns a string buffer
 817 sub html_footer {
 818         my ($ctx, $hdr) = @_;
 819         my $ibx = $ctx->{ibx};
 820         my $upfx = '../';
 821         my $skel;
 822         my $rv = '<pre>';
 823         if ($ibx->over) {
 824                 my $t = ts2str($ctx->{-t_max});
 825                 my $t_fmt = fmt_ts($ctx->{-t_max});
 826                 $skel .= <<EOF;
 827         other threads:[<a
 828 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 829 href="$upfx">newest</a>]
 830 EOF
 831
 832                 thread_skel(\$skel, $ctx, $hdr);
 833                 my ($next, $prev);
 834                 my $parent = '       ';
 835                 $next = $prev = '    ';
 836
 837                 if (my $n = $ctx->{next_msg}) {
 838                         $n = mid_href($n);
 839                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 840                 }
 841                 my $u;
 842                 my $par = $ctx->{parent_msg};
 843                 if ($par) {
 844                         $u = mid_href($par);
 845                         $u = "$upfx$u/";
 846                 }
 847                 if (my $p = $ctx->{prev_msg}) {
 848                         $prev = mid_href($p);
 849                         if ($p && $par && $p eq $par) {
 850                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 851                                         'rel=prev>prev parent</a>';
 852                                 $parent = '';
 853                         } else {
 854                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 855                                         'rel=prev>prev</a>';
 856                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 857                         }
 858                 } elsif ($u) { # unlikely
 859                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 860                 }
 861                 $rv .= "$next $prev$parent ";
 862         } else { # unindexed inboxes w/o over
 863                 $skel = qq( <a\nhref="$upfx">latest</a>);
 864         }
 865         $rv .= qq(<a\nhref="#R">reply</a>);
 866         $rv .= $skel;
 867         $rv .= '</pre>';
 868         $rv .= msg_reply($ctx, $hdr);
 869 }
 870
 871 sub linkify_ref_no_over {
 872         my ($mid) = @_;
 873         my $href = mid_href($mid);
 874         my $html = ascii_html($mid);
 875         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 876 }
 877
 878 sub ghost_parent {
 879         my ($upfx, $mid) = @_;
 880
 881         my $href = mid_href($mid);
 882         my $html = ascii_html($mid);
 883         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 884 }
 885
 886 sub indent_for {
 887         my ($level) = @_;
 888         $level ? INDENT x ($level - 1) : '';
 889 }
 890
 891 sub find_mid_root {
 892         my ($ctx, $level, $node, $idx) = @_;
 893         ++$ctx->{root_idx} if $level == 0;
 894         if ($node->{mid} eq $ctx->{mid}) {
 895                 $ctx->{found_mid_at} = $ctx->{root_idx};
 896                 return 0; # stop iterating
 897         }
 898         1;
 899 }
 900
 901 sub strict_loose_note ($) {
 902         my ($nr) = @_;
 903         my $msg =
 904 "  -- strict thread matches above, loose matches on Subject: below --\n";
 905
 906         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 907                 $msg .=
 908 "  -- use mbox.gz link to download all $nr messages --\n";
 909         }
 910         $msg;
 911 }
 912
 913 sub thread_results {
 914         my ($ctx, $msgs) = @_;
 915         require PublicInbox::SearchThread;
 916         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 917
 918         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 919         # and preserved in the future.  This bug is hidden by `sid' matches
 920         # in get_thread, so we never noticed it until now.  And even when
 921         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 922         # bump since reindexing is expensive and users may not do it
 923
 924         # loose threading could've returned too many results,
 925         # put the root the message we care about at the top:
 926         my $mid = $ctx->{mid};
 927         if (defined($mid) && scalar(@$rootset) > 1) {
 928                 $ctx->{root_idx} = -1;
 929                 my $nr = scalar @$msgs;
 930                 walk_thread($rootset, $ctx, \&find_mid_root);
 931                 my $idx = $ctx->{found_mid_at};
 932                 if (defined($idx) && $idx != 0) {
 933                         my $tip = splice(@$rootset, $idx, 1);
 934                         @$rootset = reverse @$rootset;
 935                         unshift @$rootset, $tip;
 936                         $ctx->{sl_note} = strict_loose_note($nr);
 937                 }
 938         }
 939         $rootset
 940 }
 941
 942 sub missing_thread {
 943         my ($ctx) = @_;
 944         require PublicInbox::ExtMsg;
 945         PublicInbox::ExtMsg::ext_msg($ctx);
 946 }
 947
 948 sub dedupe_subject {
 949         my ($prev_subj, $subj, $val) = @_;
 950
 951         my $omit; # '"' denotes identical text omitted
 952         my (@prev_pop, @curr_pop);
 953         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 954                 push(@prev_pop, pop(@$prev_subj));
 955                 push(@curr_pop, pop(@$subj));
 956                 $omit //= $val;
 957         }
 958         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 959         if (scalar(@curr_pop) == 1) {
 960                 $omit = undef;
 961                 push @$prev_subj, @prev_pop;
 962                 push @$subj, @curr_pop;
 963         }
 964         $omit // '';
 965 }
 966
 967 sub skel_dump { # walk_thread callback
 968         my ($ctx, $level, $smsg) = @_;
 969         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 970
 971         my $skel = $ctx->{skel};
 972         my $cur = $ctx->{cur};
 973         my $mid = $smsg->{mid};
 974
 975         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 976                 $$skel .= delete($ctx->{sl_note}) || '';
 977         }
 978
 979         my $f = ascii_html($smsg->{from_name});
 980         my $obfs_ibx = $ctx->{-obfs_ibx};
 981         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 982
 983         my $d = fmt_ts($smsg->{ds});
 984         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 985         if (exists $ctx->{searchview}) {
 986                 if (defined(my $pct = $smsg->{pct})) {
 987                         $d .= (sprintf(' % 2u', $pct) . '%');
 988                 } else {
 989                         $unmatched = 1;
 990                         $d .= '    ';
 991                 }
 992         }
 993         $d .= ' ' . indent_for($level) . th_pfx($level);
 994         my $attr = $f;
 995         $ctx->{first_level} ||= $level;
 996
 997         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 998                 $ctx->{prev_attr} = $attr;
 999         }
1000         $ctx->{prev_level} = $level;
1001
1002         if ($cur) {
1003                 if ($cur eq $mid) {
1004                         delete $ctx->{cur};
1005                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
1006                                  "$attr [this message]</a></b>\n";
1007                         return 1;
1008                 } else {
1009                         $ctx->{prev_msg} = $mid;
1010                 }
1011         } else {
1012                 $ctx->{next_msg} ||= $mid;
1013         }
1014
1015         # Subject is never undef, this mail was loaded from
1016         # our Xapian which would've resulted in '' if it were
1017         # really missing (and Filter rejects empty subjects)
1018         my @subj = split(/ /, subject_normalized($smsg->{subject}));
1019         # remove common suffixes from the subject if it matches the previous,
1020         # so we do not show redundant text at the end.
1021         my $prev_subj = $ctx->{prev_subj} || [];
1022         $ctx->{prev_subj} = [ @subj ];
1023         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
1024         my $end;
1025         if (@subj) {
1026                 my $subj = join(' ', @subj);
1027                 $subj = ascii_html($subj);
1028                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1029                 $end = "$subj</a> $omit$f\n"
1030         } else {
1031                 $end = "$f</a>\n";
1032         }
1033         my $m;
1034         my $id = '';
1035         my $mapping = $unmatched ? undef : $ctx->{mapping};
1036         if ($mapping) {
1037                 my $map = $mapping->{$mid};
1038                 $id = id_compress($mid, 1);
1039                 $m = '#m'.$id;
1040                 $map->[0] = "$d<a\nhref=\"$m\">$end";
1041                 $id = "\nid=r".$id;
1042         } else {
1043                 $m = $ctx->{-upfx}.mid_href($mid).'/';
1044         }
1045         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
1046         1;
1047 }
1048
1049 sub _skel_ghost {
1050         my ($ctx, $level, $node) = @_;
1051
1052         my $mid = $node->{mid};
1053         my $d = '     [not found] ';
1054         $d .= '    '  if exists $ctx->{searchview};
1055         $d .= indent_for($level) . th_pfx($level);
1056         my $upfx = $ctx->{-upfx};
1057         my $href = $upfx . mid_href($mid) . '/';
1058         my $html = ascii_html($mid);
1059
1060         my $mapping = $ctx->{mapping};
1061         my $map = $mapping->{$mid} if $mapping;
1062         if ($map) {
1063                 my $id = id_compress($mid, 1);
1064                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1065                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1066         } else {
1067                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1068         }
1069         ${$ctx->{skel}} .= $d;
1070         1;
1071 }
1072
1073 sub sort_ds {
1074         [ sort {
1075                 (eval { $a->topmost->{ds} } || 0) <=>
1076                 (eval { $b->topmost->{ds} } || 0)
1077         } @{$_[0]} ];
1078 }
1079
1080 # accumulate recent topics if search is supported
1081 # returns 200 if done, 404 if not
1082 sub acc_topic { # walk_thread callback
1083         my ($ctx, $level, $smsg) = @_;
1084         my $mid = $smsg->{mid};
1085         my $has_blob = $smsg->{blob} // do {
1086                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1087                         %$smsg = (%$smsg, %$by_mid);
1088                         1;
1089                 }
1090         };
1091         if ($has_blob) {
1092                 my $subj = subject_normalized($smsg->{subject});
1093                 $subj = '(no subject)' if $subj eq '';
1094                 my $ds = $smsg->{ds};
1095                 if ($level == 0) { # new, top-level topic
1096                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1097                         $ctx->{-cur_topic} = $topic;
1098                         push @{$ctx->{order}}, $topic;
1099                         return 1;
1100                 }
1101
1102                 # continue existing topic
1103                 my $topic = $ctx->{-cur_topic}; # should never be undef
1104                 $topic->[0] = $ds if $ds > $topic->[0];
1105                 $topic->[1]++; # bump N+ message counter
1106                 my $seen = $topic->[2];
1107                 if (scalar(@$topic) == 3) { # parent was a ghost
1108                         push @$topic, $subj;
1109                 } elsif (!defined($seen->{$subj})) {
1110                         push @$topic, $level, $subj; # @extra messages
1111                 }
1112                 $seen->{$subj} = $mid; # latest for subject
1113         } else { # ghost message
1114                 return 1 if $level != 0; # ignore child ghosts
1115                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1116                 push @{$ctx->{order}}, $topic;
1117         }
1118         1;
1119 }
1120
1121 sub dump_topics {
1122         my ($ctx) = @_;
1123         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1124         unless ($order) {
1125                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1126                 return 404;
1127         }
1128
1129         my @out;
1130         my $ibx = $ctx->{ibx};
1131         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1132
1133         # sort by recency, this allows new posts to "bump" old topics...
1134         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1135                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1136                 @$topic = ();
1137                 next unless defined $top_subj;  # ghost topic
1138                 my $mid = delete $seen->{$top_subj};
1139                 my $href = mid_href($mid);
1140                 my $prev_subj = [ split(/ /, $top_subj) ];
1141                 $top_subj = ascii_html($top_subj);
1142                 $ds = fmt_ts($ds);
1143
1144                 # $n isn't the total number of posts on the topic,
1145                 # just the number of posts in the current results window
1146                 my $anchor;
1147                 if ($n == 1) {
1148                         $n = '';
1149                         $anchor = '#u'; # top of only message
1150                 } else {
1151                         $n = " ($n+ messages)";
1152                         $anchor = '#t'; # thread skeleton
1153                 }
1154
1155                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1156                         " $ds UTC $n\n";
1157                 for (my $i = 0; $i < scalar(@extra); $i += 2) {
1158                         my $level = $extra[$i];
1159                         my $subj = $extra[$i + 1]; # already normalized
1160                         $mid = delete $seen->{$subj};
1161                         my @subj = split(/ /, $subj);
1162                         my @next_prev = @subj; # full copy
1163                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1164                         $prev_subj = \@next_prev;
1165                         $subj = join(' ', @subj);
1166                         $subj = ascii_html($subj);
1167                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1168                         $href = mid_href($mid);
1169                         $s .= indent_for($level) . TCHILD;
1170                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1171                 }
1172                 push @out, $s;
1173         }
1174         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1175         200;
1176 }
1177
1178 sub str2ts ($) {
1179         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1180         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1181 }
1182
1183 sub pagination_footer ($$) {
1184         my ($ctx, $latest) = @_;
1185         my $next = $ctx->{next_page} || '';
1186         my $prev = $ctx->{prev_page} || '';
1187         if ($prev) {  # aligned padding for: 'next (older) | '
1188                 $next = $next ? "$next | " : '             | ';
1189                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1190         }
1191         "<hr><pre>page: $next$prev</pre>";
1192 }
1193
1194 sub paginate_recent ($$) {
1195         my ($ctx, $lim) = @_;
1196         my $t = $ctx->{qp}->{t} || '';
1197         my $opts = { limit => $lim };
1198         my ($after, $before);
1199
1200         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1201         # if only $after exists "YYYYMMDD.." because "." could be skipped
1202         # if interpreted as an end-of-sentence
1203         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1204         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1205
1206         my $ibx = $ctx->{ibx};
1207         my $msgs = $ibx->recent($opts, $after, $before);
1208         my $nr = scalar @$msgs;
1209         if ($nr < $lim && defined($after)) {
1210                 $after = $before = undef;
1211                 $msgs = $ibx->recent($opts);
1212                 $nr = scalar @$msgs;
1213         }
1214         my $more = $nr == $lim;
1215         my ($newest, $oldest);
1216         if ($nr) {
1217                 $newest = $msgs->[0]->{ts};
1218                 $oldest = $msgs->[-1]->{ts};
1219                 # if we only had $after, our SQL query in ->recent ordered
1220                 if ($newest < $oldest) {
1221                         ($oldest, $newest) = ($newest, $oldest);
1222                         $more = 0 if defined($after) && $after < $oldest;
1223                 }
1224         }
1225         if (defined($oldest) && $more) {
1226                 my $s = ts2str($oldest);
1227                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1228                                         'next (older)</a>';
1229         }
1230         if (defined($newest) && (defined($before) || defined($after))) {
1231                 my $s = ts2str($newest);
1232                 $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1233                                         'prev (newer)</a>';
1234         }
1235         $msgs;
1236 }
1237
1238 # GET /$INBOX - top-level inbox view for indexed inboxes
1239 sub index_topics {
1240         my ($ctx) = @_;
1241         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1242         if (@$msgs) {
1243                 walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic);
1244         }
1245         html_oneshot($ctx, dump_topics($ctx), \pagination_footer($ctx, '.'));
1246
1247 }
1248
1249 sub thread_adj_level {
1250         my ($ctx, $level) = @_;
1251
1252         my $max = $ctx->{cur_level};
1253         if ($level <= 0) {
1254                 return ('', '') if $max == 0; # flat output
1255
1256                 # reset existing lists
1257                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1258                 $ctx->{cur_level} = 0;
1259                 ("$beg</ul>", '');
1260         } elsif ($level == $max) { # continue existing list
1261                 qw(<li> </li>);
1262         } elsif ($level < $max) {
1263                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1264                 $ctx->{cur_level} = $level;
1265                 ("$beg<li>", '</li>');
1266         } else { # ($level > $max) # start a new level
1267                 $ctx->{cur_level} = $level;
1268                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1269                 ($beg, '</li>');
1270         }
1271 }
1272
1273 sub ghost_index_entry {
1274         my ($ctx, $level, $node) = @_;
1275         my ($beg, $end) = thread_adj_level($ctx,  $level);
1276         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1277                 . '</pre>' . $end;
1278 }
1279
1280 1;