lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Hval;
   7 use URI::Escape qw/uri_escape_utf8/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 require POSIX;
  12
  13 # TODO: make these constants tunable
  14 use constant MAX_INLINE_QUOTED => 12; # half an 80x24 terminal
  15 use constant MAX_TRUNC_LEN => 72;
  16 use constant PRE_WRAP => "<pre\nstyle=\"white-space:pre-wrap\">";
  17
  18 *ascii_html = *PublicInbox::Hval::ascii_html;
  19
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 my $enc_mime = find_encoding('MIME-Header');
  22
  23 # public functions:
  24 sub msg_html {
  25         my ($class, $mime, $full_pfx, $footer) = @_;
  26         if (defined $footer) {
  27                 $footer = "\n" . $footer;
  28         } else {
  29                 $footer = '';
  30         }
  31         headers_to_html_header($mime, $full_pfx) .
  32                 multipart_text_as_html($mime, $full_pfx) .
  33                 '</pre><hr />' . PRE_WRAP .
  34                 html_footer($mime, 1) . $footer .
  35                 '</pre></body></html>';
  36 }
  37
  38 sub feed_entry {
  39         my ($class, $mime, $full_pfx) = @_;
  40
  41         PRE_WRAP . multipart_text_as_html($mime, $full_pfx) . '</pre>';
  42 }
  43
  44 # this is already inside a <pre>
  45 sub index_entry {
  46         my ($class, $mime, $now, $level, $seen, $first) = @_;
  47         my $rv = "";
  48         my $part_nr = 0;
  49         my $enc_msg = enc_for($mime->header("Content-Type"));
  50         my $subj = $mime->header('Subject');
  51         my $header_obj = $mime->header_obj;
  52
  53         my $mid_raw = $header_obj->header_raw('Message-ID');
  54         my $name = anchor_for($mid_raw);
  55         $seen->{$name} = "#$name"; # save the anchor for later
  56
  57         my $mid = PublicInbox::Hval->new_msgid($mid_raw);
  58         my $from = PublicInbox::Hval->new_oneline($mime->header('From'))->raw;
  59         my @from = Email::Address->parse($from);
  60         $from = $from[0]->name;
  61         (defined($from) && length($from)) or $from = $from[0]->address;
  62
  63         $from = PublicInbox::Hval->new_oneline($from)->as_html;
  64         $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
  65         my $pfx = ('  ' x $level);
  66
  67         my $ts = $mime->header('X-PI-Date');
  68         my $fmt = '%H:%M';
  69         if ($now > ($ts + (365 * 24 * 60 * 60))) {
  70                 # doesn't have to be exactly 1 year
  71                 $fmt = '%Y/%m/%d';
  72         } elsif ($now > ($ts + (24 * 60 * 60))) {
  73                 $fmt = '%m/%d';
  74         }
  75         $ts = POSIX::strftime($fmt, gmtime($ts));
  76
  77         $rv .= "$pfx<a\nname=\"$name\"><b>$subj</b> $from - $ts</a>\n\n";
  78
  79         my $irp = $header_obj->header_raw('In-Reply-To');
  80         my ($anchor_idx, $anchor);
  81         if (defined $irp) {
  82                 $anchor_idx = anchor_for($irp);
  83                 $anchor = $seen->{$anchor_idx};
  84         }
  85         my $href = $mid->as_href;
  86         my $mhref = "m/$href.html";
  87         my $fhref = "f/$href.html";
  88         my $more = 'message';
  89         # scan through all parts, looking for displayable text
  90         $mime->walk_parts(sub {
  91                 my ($part) = @_;
  92                 return if $part->subparts; # walk_parts already recurses
  93                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
  94
  95                 if ($part_nr > 0) {
  96                         my $fn = $part->filename;
  97                         defined($fn) or $fn = "part #" . ($part_nr + 1);
  98                         $rv .= $pfx . add_filename_line($enc->decode($fn));
  99                 }
 100
 101                 my $s = add_text_body_short($enc, $part, $part_nr, $fhref);
 102
 103                 # keep signatures for now?  They shold usually be short,
 104                 # and sometimes footnotes/"P.S." appear there.
 105
 106                 # drop the remainder of git patches, they're usually better
 107                 # to review when the full message is viewed
 108                 $s =~ s!^---\n.*\z!!ms and $more = 'more...';
 109
 110                 # kill any leading or trailing whitespace
 111                 $s =~ s/\A\s+//s;
 112                 $s =~ s/\s+\z//s;
 113
 114                 if (length $s) {
 115                         # add prefix:
 116                         $s =~ s/^/$pfx/sgm;
 117
 118                         $rv .= $s . "\n";
 119                 }
 120                 ++$part_nr;
 121         });
 122
 123         $rv .= "$pfx<a\nhref=\"$mhref\">$more</a> ";
 124         my $txt = "m/$href.txt";
 125         $rv .= "<a\nhref=\"$txt\">raw</a> ";
 126         $rv .= html_footer($mime, 0);
 127
 128         if (defined $irp) {
 129                 unless (defined $anchor) {
 130                         my $v = PublicInbox::Hval->new_msgid($irp);
 131                         my $html = $v->as_html;
 132                         $anchor = 'm/' . $v->as_href . '.html';
 133                         $seen->{$anchor_idx} = $anchor;
 134                 }
 135                 $rv .= " <a\nhref=\"$anchor\">parent</a>";
 136         }
 137         $rv .= " <a\nhref=\"?r=$first#$name\">permalink</a>";
 138
 139         $rv . "\n\n";
 140 }
 141
 142 # only private functions below.
 143
 144 sub enc_for {
 145         my ($ct) = @_;
 146         defined $ct or return $enc_utf8;
 147         my $ct_parsed = parse_content_type($ct);
 148         if ($ct_parsed) {
 149                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
 150                         my $enc = find_encoding($charset);
 151                         return $enc if $enc;
 152                 }
 153         }
 154         $enc_utf8;
 155 }
 156
 157 sub multipart_text_as_html {
 158         my ($mime, $full_pfx) = @_;
 159         my $rv = "";
 160         my $part_nr = 0;
 161         my $enc_msg = enc_for($mime->header("Content-Type"));
 162
 163         # scan through all parts, looking for displayable text
 164         $mime->walk_parts(sub {
 165                 my ($part) = @_;
 166                 return if $part->subparts; # walk_parts already recurses
 167                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
 168
 169                 if ($part_nr > 0) {
 170                         my $fn = $part->filename;
 171                         defined($fn) or $fn = "part #" . ($part_nr + 1);
 172                         $rv .= add_filename_line($enc->decode($fn));
 173                 }
 174
 175                 if (defined $full_pfx) {
 176                         $rv .= add_text_body_short($enc, $part, $part_nr,
 177                                                 $full_pfx);
 178                 } else {
 179                         $rv .= add_text_body_full($enc, $part, $part_nr);
 180                 }
 181                 $rv .= "\n" unless $rv =~ /\n\z/s;
 182                 ++$part_nr;
 183         });
 184         $rv;
 185 }
 186
 187 sub add_filename_line {
 188         my ($fn) = @_;
 189         my $len = 72;
 190         my $pad = "-";
 191
 192         $len -= length($fn);
 193         $pad x= ($len/2) if ($len > 0);
 194         "$pad " . ascii_html($fn) . " $pad\n";
 195 }
 196
 197 sub add_text_body_short {
 198         my ($enc, $part, $part_nr, $full_pfx) = @_;
 199         my $n = 0;
 200         my $s = ascii_html($enc->decode($part->body));
 201         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 202                 my $cur = $1;
 203                 my @lines = split(/\n/, $cur);
 204                 if (@lines > MAX_INLINE_QUOTED) {
 205                         # show a short snippet of quoted text
 206                         $cur = join(' ', @lines);
 207                         $cur =~ s/^&gt;\s*//;
 208
 209                         my @sum = split(/\s+/, $cur);
 210                         $cur = '';
 211                         do {
 212                                 my $tmp = shift(@sum);
 213                                 my $len = length($tmp) + length($cur);
 214                                 if ($len > MAX_TRUNC_LEN) {
 215                                         @sum = ();
 216                                 } else {
 217                                         $cur .= $tmp . ' ';
 218                                 }
 219                         } while (@sum && length($cur) < MAX_TRUNC_LEN);
 220                         $cur =~ s/ \z/ .../;
 221                         "&gt; &lt;<a\nhref=\"${full_pfx}#q${part_nr}_" . $n++ .
 222                                 "\">$cur<\/a>&gt;\n";
 223                 } else {
 224                         $cur;
 225                 }
 226         !emg;
 227         $s;
 228 }
 229
 230 sub add_text_body_full {
 231         my ($enc, $part, $part_nr) = @_;
 232         my $n = 0;
 233         my $s = ascii_html($enc->decode($part->body));
 234         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 235                 my $cur = $1;
 236                 my @lines = split(/\n/, $cur);
 237                 if (@lines > MAX_INLINE_QUOTED) {
 238                         "<a\nname=q${part_nr}_" . $n++ . ">$cur</a>";
 239                 } else {
 240                         $cur;
 241                 }
 242         !emg;
 243         $s;
 244 }
 245
 246 sub headers_to_html_header {
 247         my ($mime, $full_pfx) = @_;
 248
 249         my $rv = "";
 250         my @title;
 251         foreach my $h (qw(From To Cc Subject Date)) {
 252                 my $v = $mime->header($h);
 253                 defined($v) && length($v) or next;
 254                 $v = PublicInbox::Hval->new_oneline($v);
 255                 $rv .= "$h: " . $v->as_html . "\n";
 256
 257                 if ($h eq 'From') {
 258                         my @from = Email::Address->parse($v->raw);
 259                         $v = $from[0]->name;
 260                         unless (defined($v) && length($v)) {
 261                                 $v = '<' . $from[0]->address . '>';
 262                         }
 263                         $title[1] = ascii_html($v);
 264                 } elsif ($h eq 'Subject') {
 265                         $title[0] = $v->as_html;
 266                 }
 267         }
 268
 269         my $header_obj = $mime->header_obj;
 270         my $mid = $header_obj->header_raw('Message-ID');
 271         if (defined $mid) {
 272                 $mid = PublicInbox::Hval->new_msgid($mid);
 273                 $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 274                 my $href = $mid->as_href;
 275                 $href = "../m/$href" unless $full_pfx;
 276                 $rv .= "(<a\nhref=\"$href.txt\">original</a>)\n";
 277         }
 278
 279         my $irp = $header_obj->header_raw('In-Reply-To');
 280         if (defined $irp) {
 281                 my $v = PublicInbox::Hval->new_msgid(my $tmp = $irp);
 282                 my $html = $v->as_html;
 283                 my $href = $v->as_href;
 284                 $rv .= "In-Reply-To: &lt;";
 285                 $rv .= "<a\nhref=\"$href.html\">$html</a>&gt;\n";
 286         }
 287
 288         my $refs = $header_obj->header_raw('References');
 289         if ($refs) {
 290                 $refs =~ s/\s*\Q$irp\E\s*// if (defined $irp);
 291                 my @refs = ($refs =~ /<([^>]+)>/g);
 292                 if (@refs) {
 293                         $rv .= 'References: '. linkify_refs(@refs) . "\n";
 294                 }
 295         }
 296
 297         $rv .= "\n";
 298
 299         ("<html><head><title>".  join(' - ', @title) .
 300          '</title></head><body>' . PRE_WRAP . $rv);
 301 }
 302
 303 sub html_footer {
 304         my ($mime, $purge) = @_;
 305         my %cc; # everyone else
 306         my $to; # this is the From address
 307
 308         foreach my $h (qw(From To Cc)) {
 309                 my $v = $mime->header($h);
 310                 defined($v) && length($v) or next;
 311                 my @addrs = Email::Address->parse($v);
 312                 foreach my $recip (@addrs) {
 313                         my $address = $recip->address;
 314                         my $dst = lc($address);
 315                         $cc{$dst} ||= $address;
 316                         $to ||= $dst;
 317                 }
 318         }
 319         Email::Address->purge_cache if $purge;
 320
 321         my $subj = $mime->header('Subject') || '';
 322         $subj = "Re: $subj" unless $subj =~ /\bRe:/;
 323         my $irp = uri_escape_utf8(
 324                         $mime->header_obj->header_raw('Message-ID') || '');
 325         delete $cc{$to};
 326         $to = uri_escape_utf8($to);
 327         $subj = uri_escape_utf8($subj);
 328
 329         my $cc = uri_escape_utf8(join(',', values %cc));
 330         my $href = "mailto:$to?In-Reply-To=$irp&Cc=${cc}&Subject=$subj";
 331
 332         "<a\nhref=\"" . ascii_html($href) . '">reply</a>';
 333 }
 334
 335 sub linkify_refs {
 336         join(' ', map {
 337                 my $v = PublicInbox::Hval->new_msgid($_);
 338                 my $html = $v->as_html;
 339                 my $href = $v->as_href;
 340                 "&lt;<a\nhref=\"$href.html\">$html</a>&gt;";
 341         } @_);
 342 }
 343
 344 require Digest::SHA;
 345 sub anchor_for {
 346         my ($msgid) = @_;
 347         $msgid =~ s/\A\s*<?//;
 348         $msgid =~ s/>?\s*\z//;
 349         Digest::SHA::sha1_hex($msgid);
 350 }
 351
 352 1;