lib/PublicInbox/View.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::View;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Hval;
   7 use URI::Escape qw/uri_escape_utf8/;
   8 use Encode qw/find_encoding/;
   9 use Encode::MIME::Header;
  10 use Email::MIME::ContentType qw/parse_content_type/;
  11 require POSIX;
  12
  13 # TODO: make these constants tunable
  14 use constant MAX_INLINE_QUOTED => 12; # half an 80x24 terminal
  15 use constant MAX_TRUNC_LEN => 72;
  16 use constant PRE_WRAP => "<pre\nstyle=\"white-space:pre-wrap\">";
  17
  18 *ascii_html = *PublicInbox::Hval::ascii_html;
  19
  20 my $enc_utf8 = find_encoding('UTF-8');
  21 my $enc_mime = find_encoding('MIME-Header');
  22
  23 # public functions:
  24 sub msg_html {
  25         my ($class, $mime, $full_pfx, $footer) = @_;
  26         if (defined $footer) {
  27                 $footer = "\n" . $footer;
  28         } else {
  29                 $footer = '';
  30         }
  31         headers_to_html_header($mime, $full_pfx) .
  32                 multipart_text_as_html($mime, $full_pfx) .
  33                 '</pre><hr />' . PRE_WRAP .
  34                 html_footer($mime, 1) . $footer .
  35                 '</pre></body></html>';
  36 }
  37
  38 sub feed_entry {
  39         my ($class, $mime, $full_pfx) = @_;
  40
  41         PRE_WRAP . multipart_text_as_html($mime, $full_pfx) . '</pre>';
  42 }
  43
  44 # this is already inside a <pre>
  45 sub index_entry {
  46         my ($class, $mime, $level, $state) = @_;
  47         my ($now, $seen, $first) = @$state;
  48         my $midx = $state->[3]++;
  49         my ($prev, $next) = ($midx - 1, $midx + 1);
  50         my $rv = '';
  51         my $part_nr = 0;
  52         my $enc_msg = enc_for($mime->header("Content-Type"));
  53         my $subj = $mime->header('Subject');
  54         my $header_obj = $mime->header_obj;
  55
  56         my $mid_raw = $header_obj->header_raw('Message-ID');
  57         my $name = anchor_for($mid_raw);
  58         $seen->{$name} = "#$name"; # save the anchor for later
  59
  60         my $mid = PublicInbox::Hval->new_msgid($mid_raw);
  61         my $from = PublicInbox::Hval->new_oneline($mime->header('From'))->raw;
  62         my @from = Email::Address->parse($from);
  63         $from = $from[0]->name;
  64         (defined($from) && length($from)) or $from = $from[0]->address;
  65
  66         $from = PublicInbox::Hval->new_oneline($from)->as_html;
  67         $subj = PublicInbox::Hval->new_oneline($subj)->as_html;
  68         my $pfx = ('  ' x $level);
  69
  70         my $ts = $mime->header('X-PI-Date');
  71         my $fmt = '%H:%M';
  72         if ($now > ($ts + (365 * 24 * 60 * 60))) {
  73                 # doesn't have to be exactly 1 year
  74                 $fmt = '%Y/%m/%d';
  75         } elsif ($now > ($ts + (24 * 60 * 60))) {
  76                 $fmt = '%m/%d';
  77         }
  78         $ts = POSIX::strftime($fmt, gmtime($ts));
  79
  80         $rv .= "$pfx<a\nname=\"$name\"></a>" .
  81                 "<a\nname=\"s$midx\"></a>" .
  82                 "<b>$subj</b> $from - $ts\n" .
  83                 "$pfx<a\nhref=\"#s$next\">next</a>";
  84
  85         $rv .= " <a\nhref=\"#s$prev\">prev</a>" if $prev >= 0;
  86         $rv .= "\n";
  87
  88         my $irp = $header_obj->header_raw('In-Reply-To');
  89         my ($anchor_idx, $anchor);
  90         if (defined $irp) {
  91                 $anchor_idx = anchor_for($irp);
  92                 $anchor = $seen->{$anchor_idx};
  93         }
  94         my $href = $mid->as_href;
  95         my $mhref = "m/$href.html";
  96         my $fhref = "f/$href.html";
  97         my $more = 'message';
  98         # scan through all parts, looking for displayable text
  99         $mime->walk_parts(sub {
 100                 my ($part) = @_;
 101                 return if $part->subparts; # walk_parts already recurses
 102                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
 103
 104                 if ($part_nr > 0) {
 105                         my $fn = $part->filename;
 106                         defined($fn) or $fn = "part #" . ($part_nr + 1);
 107                         $rv .= $pfx . add_filename_line($enc->decode($fn));
 108                 }
 109
 110                 my $s = add_text_body_short($enc, $part, $part_nr, $fhref);
 111
 112                 # keep signatures for now?  They shold usually be short,
 113                 # and sometimes footnotes/"P.S." appear there.
 114
 115                 # drop the remainder of git patches, they're usually better
 116                 # to review when the full message is viewed
 117                 $s =~ s!^---\n.*\z!!ms and $more = 'more...';
 118
 119                 # kill any leading or trailing whitespace
 120                 $s =~ s/\A\s+//s;
 121                 $s =~ s/\s+\z//s;
 122
 123                 if (length $s) {
 124                         # add prefix:
 125                         $s =~ s/^/$pfx/sgm;
 126
 127                         $rv .= $s . "\n";
 128                 }
 129                 ++$part_nr;
 130         });
 131
 132         $rv .= "$pfx<a\nhref=\"$mhref\">$more</a> ";
 133         my $txt = "m/$href.txt";
 134         $rv .= "<a\nhref=\"$txt\">raw</a> ";
 135         $rv .= html_footer($mime, 0);
 136
 137         if (defined $irp) {
 138                 unless (defined $anchor) {
 139                         my $v = PublicInbox::Hval->new_msgid($irp);
 140                         my $html = $v->as_html;
 141                         $anchor = 'm/' . $v->as_href . '.html';
 142                         $seen->{$anchor_idx} = $anchor;
 143                 }
 144                 $rv .= " <a\nhref=\"$anchor\">parent</a>";
 145         }
 146         $rv .= " <a\nhref=\"?r=$first#$name\">permalink</a>";
 147
 148         $rv . "\n\n";
 149 }
 150
 151 # only private functions below.
 152
 153 sub enc_for {
 154         my ($ct) = @_;
 155         defined $ct or return $enc_utf8;
 156         my $ct_parsed = parse_content_type($ct);
 157         if ($ct_parsed) {
 158                 if (my $charset = $ct_parsed->{attributes}->{charset}) {
 159                         my $enc = find_encoding($charset);
 160                         return $enc if $enc;
 161                 }
 162         }
 163         $enc_utf8;
 164 }
 165
 166 sub multipart_text_as_html {
 167         my ($mime, $full_pfx) = @_;
 168         my $rv = "";
 169         my $part_nr = 0;
 170         my $enc_msg = enc_for($mime->header("Content-Type"));
 171
 172         # scan through all parts, looking for displayable text
 173         $mime->walk_parts(sub {
 174                 my ($part) = @_;
 175                 return if $part->subparts; # walk_parts already recurses
 176                 my $enc = enc_for($part->content_type) || $enc_msg || $enc_utf8;
 177
 178                 if ($part_nr > 0) {
 179                         my $fn = $part->filename;
 180                         defined($fn) or $fn = "part #" . ($part_nr + 1);
 181                         $rv .= add_filename_line($enc->decode($fn));
 182                 }
 183
 184                 if (defined $full_pfx) {
 185                         $rv .= add_text_body_short($enc, $part, $part_nr,
 186                                                 $full_pfx);
 187                 } else {
 188                         $rv .= add_text_body_full($enc, $part, $part_nr);
 189                 }
 190                 $rv .= "\n" unless $rv =~ /\n\z/s;
 191                 ++$part_nr;
 192         });
 193         $rv;
 194 }
 195
 196 sub add_filename_line {
 197         my ($fn) = @_;
 198         my $len = 72;
 199         my $pad = "-";
 200
 201         $len -= length($fn);
 202         $pad x= ($len/2) if ($len > 0);
 203         "$pad " . ascii_html($fn) . " $pad\n";
 204 }
 205
 206 sub add_text_body_short {
 207         my ($enc, $part, $part_nr, $full_pfx) = @_;
 208         my $n = 0;
 209         my $s = ascii_html($enc->decode($part->body));
 210         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 211                 my $cur = $1;
 212                 my @lines = split(/\n/, $cur);
 213                 if (@lines > MAX_INLINE_QUOTED) {
 214                         # show a short snippet of quoted text
 215                         $cur = join(' ', @lines);
 216                         $cur =~ s/^&gt;\s*//;
 217
 218                         my @sum = split(/\s+/, $cur);
 219                         $cur = '';
 220                         do {
 221                                 my $tmp = shift(@sum);
 222                                 my $len = length($tmp) + length($cur);
 223                                 if ($len > MAX_TRUNC_LEN) {
 224                                         @sum = ();
 225                                 } else {
 226                                         $cur .= $tmp . ' ';
 227                                 }
 228                         } while (@sum && length($cur) < MAX_TRUNC_LEN);
 229                         $cur =~ s/ \z/ .../;
 230                         "&gt; &lt;<a\nhref=\"${full_pfx}#q${part_nr}_" . $n++ .
 231                                 "\">$cur<\/a>&gt;\n";
 232                 } else {
 233                         $cur;
 234                 }
 235         !emg;
 236         $s;
 237 }
 238
 239 sub add_text_body_full {
 240         my ($enc, $part, $part_nr) = @_;
 241         my $n = 0;
 242         my $s = ascii_html($enc->decode($part->body));
 243         $s =~ s!^((?:(?:&gt;[^\n]*)\n)+)!
 244                 my $cur = $1;
 245                 my @lines = split(/\n/, $cur);
 246                 if (@lines > MAX_INLINE_QUOTED) {
 247                         "<a\nname=q${part_nr}_" . $n++ . ">$cur</a>";
 248                 } else {
 249                         $cur;
 250                 }
 251         !emg;
 252         $s;
 253 }
 254
 255 sub headers_to_html_header {
 256         my ($mime, $full_pfx) = @_;
 257
 258         my $rv = "";
 259         my @title;
 260         foreach my $h (qw(From To Cc Subject Date)) {
 261                 my $v = $mime->header($h);
 262                 defined($v) && length($v) or next;
 263                 $v = PublicInbox::Hval->new_oneline($v);
 264                 $rv .= "$h: " . $v->as_html . "\n";
 265
 266                 if ($h eq 'From') {
 267                         my @from = Email::Address->parse($v->raw);
 268                         $v = $from[0]->name;
 269                         unless (defined($v) && length($v)) {
 270                                 $v = '<' . $from[0]->address . '>';
 271                         }
 272                         $title[1] = ascii_html($v);
 273                 } elsif ($h eq 'Subject') {
 274                         $title[0] = $v->as_html;
 275                 }
 276         }
 277
 278         my $header_obj = $mime->header_obj;
 279         my $mid = $header_obj->header_raw('Message-ID');
 280         if (defined $mid) {
 281                 $mid = PublicInbox::Hval->new_msgid($mid);
 282                 $rv .= 'Message-ID: &lt;' . $mid->as_html . '&gt; ';
 283                 my $href = $mid->as_href;
 284                 $href = "../m/$href" unless $full_pfx;
 285                 $rv .= "(<a\nhref=\"$href.txt\">original</a>)\n";
 286         }
 287
 288         my $irp = $header_obj->header_raw('In-Reply-To');
 289         if (defined $irp) {
 290                 my $v = PublicInbox::Hval->new_msgid($irp);
 291                 my $html = $v->as_html;
 292                 my $href = $v->as_href;
 293                 $rv .= "In-Reply-To: &lt;";
 294                 $rv .= "<a\nhref=\"$href.html\">$html</a>&gt;\n";
 295         }
 296
 297         my $refs = $header_obj->header_raw('References');
 298         if ($refs) {
 299                 $refs =~ s/\s*\Q$irp\E\s*// if (defined $irp);
 300                 my @refs = ($refs =~ /<([^>]+)>/g);
 301                 if (@refs) {
 302                         $rv .= 'References: '. linkify_refs(@refs) . "\n";
 303                 }
 304         }
 305
 306         $rv .= "\n";
 307
 308         ("<html><head><title>".  join(' - ', @title) .
 309          '</title></head><body>' . PRE_WRAP . $rv);
 310 }
 311
 312 sub html_footer {
 313         my ($mime, $standalone) = @_;
 314         my %cc; # everyone else
 315         my $to; # this is the From address
 316
 317         foreach my $h (qw(From To Cc)) {
 318                 my $v = $mime->header($h);
 319                 defined($v) && length($v) or next;
 320                 my @addrs = Email::Address->parse($v);
 321                 foreach my $recip (@addrs) {
 322                         my $address = $recip->address;
 323                         my $dst = lc($address);
 324                         $cc{$dst} ||= $address;
 325                         $to ||= $dst;
 326                 }
 327         }
 328         Email::Address->purge_cache if $standalone;
 329
 330         my $subj = $mime->header('Subject') || '';
 331         $subj = "Re: $subj" unless $subj =~ /\bRe:/;
 332         my $irp = uri_escape_utf8(
 333                         $mime->header_obj->header_raw('Message-ID') || '');
 334         delete $cc{$to};
 335         $to = uri_escape_utf8($to);
 336         $subj = uri_escape_utf8($subj);
 337
 338         my $cc = uri_escape_utf8(join(',', values %cc));
 339         my $href = "mailto:$to?In-Reply-To=$irp&Cc=${cc}&Subject=$subj";
 340
 341         my $idx = $standalone ? " <a\nhref=\"../\">index</a>" : '';
 342
 343         "<a\nhref=\"" . ascii_html($href) . '">reply</a>' . $idx;
 344 }
 345
 346 sub linkify_refs {
 347         join(' ', map {
 348                 my $v = PublicInbox::Hval->new_msgid($_);
 349                 my $html = $v->as_html;
 350                 my $href = $v->as_href;
 351                 "&lt;<a\nhref=\"$href.html\">$html</a>&gt;";
 352         } @_);
 353 }
 354
 355 require Digest::SHA;
 356 sub anchor_for {
 357         my ($msgid) = @_;
 358         $msgid =~ s/\A\s*<?//;
 359         $msgid =~ s/>?\s*\z//;
 360         Digest::SHA::sha1_hex($msgid);
 361 }
 362
 363 1;