lib/PublicInbox/View.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use v5.10.1;
   9 use List::Util qw(max);
  10 use Text::Wrap qw(wrap); # stdlib, we need Perl 5.6+ for $huge
  11 use PublicInbox::MsgTime qw(msg_datestamp);
  12 use PublicInbox::Hval qw(ascii_html obfuscate_addrs prurl mid_href
  13                         ts2str fmt_ts);
  14 use PublicInbox::Linkify;
  15 use PublicInbox::MID qw(id_compress mids mids_for_index references
  16                         $MID_EXTRACT);
  17 use PublicInbox::MsgIter;
  18 use PublicInbox::Address;
  19 use PublicInbox::WwwStream qw(html_oneshot);
  20 use PublicInbox::Reply;
  21 use PublicInbox::ViewDiff qw(flush_diff);
  22 use PublicInbox::Eml;
  23 use POSIX qw(strftime);
  24 use Time::Local qw(timegm);
  25 use PublicInbox::Smsg qw(subject_normalized);
  26 use PublicInbox::ContentHash qw(content_hash);
  27 use constant COLS => 72;
  28 use constant INDENT => '  ';
  29 use constant TCHILD => '` ';
  30 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  31
  32 sub msg_page_i {
  33         my ($ctx, $eml) = @_;
  34         if ($eml) { # called by WwwStream::async_eml or getline
  35                 my $smsg = $ctx->{smsg};
  36                 my $over = $ctx->{ibx}->over;
  37                 $ctx->{smsg} = $over ? $over->next_by_mid(@{$ctx->{next_arg}})
  38                                 : $ctx->gone('over');
  39                 $ctx->{mhref} = ($ctx->{nr} || $ctx->{smsg}) ?
  40                                 "../${\mid_href($smsg->{mid})}/" : '';
  41                 if (_msg_page_prepare($eml, $ctx)) {
  42                         $eml->each_part(\&add_text_body, $ctx, 1);
  43                         print { $ctx->{zfh} } '</pre><hr>';
  44                 }
  45                 html_footer($ctx, $ctx->{first_hdr}) if !$ctx->{smsg};
  46                 ''; # XXX TODO cleanup
  47         } else { # called by WwwStream::async_next or getline
  48                 $ctx->{smsg}; # may be undef
  49         }
  50 }
  51
  52 # /$INBOX/$MSGID/ for unindexed v1 inboxes
  53 sub no_over_html ($) {
  54         my ($ctx) = @_;
  55         my $bref = $ctx->{ibx}->msg_by_mid($ctx->{mid}) or return; # 404
  56         my $eml = PublicInbox::Eml->new($bref);
  57         $ctx->{mhref} = '';
  58         PublicInbox::WwwStream::init($ctx);
  59         if (_msg_page_prepare($eml, $ctx)) { # sets {-title_html}
  60                 $eml->each_part(\&add_text_body, $ctx, 1);
  61                 print { $ctx->{zfh} } '</pre><hr>';
  62         }
  63         html_footer($ctx, $eml);
  64         $ctx->html_done;
  65 }
  66
  67 # public functions: (unstable)
  68
  69 sub msg_page {
  70         my ($ctx) = @_;
  71         my $ibx = $ctx->{ibx};
  72         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  73         my $over = $ibx->over or return no_over_html($ctx);
  74         my ($id, $prev);
  75         my $next_arg = $ctx->{next_arg} = [ $ctx->{mid}, \$id, \$prev ];
  76
  77         my $smsg = $ctx->{smsg} = $over->next_by_mid(@$next_arg) or
  78                 return; # undef == 404
  79
  80         # allow user to easily browse the range around this message if
  81         # they have ->over
  82         $ctx->{-t_max} = $smsg->{ts};
  83         $ctx->{-spfx} = '../' if $ibx->{coderepo};
  84         PublicInbox::WwwStream::aresponse($ctx, \&msg_page_i);
  85 }
  86
  87 # /$INBOX/$MESSAGE_ID/#R
  88 sub msg_reply ($$) {
  89         my ($ctx, $hdr) = @_;
  90         my $se_url =
  91          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
  92         my $p_url =
  93          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
  94
  95         my $info = '';
  96         my $ibx = $ctx->{ibx};
  97         if (my $url = $ibx->{infourl}) {
  98                 $url = prurl($ctx->{env}, $url);
  99                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 100         }
 101
 102         my ($arg, $link, $reply_to_all) =
 103                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 104         if (ref($arg) eq 'SCALAR') {
 105                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 106         }
 107
 108         # mailto: link only works if address obfuscation is disabled
 109         if ($link) {
 110                 $link = <<EOF;
 111
 112 * If your mail client supports setting the <b>In-Reply-To</b> header
 113   via mailto: links, try the <a
 114 href="$link">mailto: link</a>
 115 EOF
 116         }
 117
 118         push @$arg, '/path/to/YOUR_REPLY';
 119         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 120         <<EOF
 121 <hr><pre
 122 id=R><b>Reply instructions:</b>
 123
 124 You may reply publicly to <a
 125 href=#t>this message</a> via plain-text email
 126 using any one of the following methods:
 127
 128 * Save the following mbox file, import it into your mail client,
 129   and $reply_to_all from there: <a
 130 href=raw>mbox</a>
 131
 132   Avoid top-posting and favor interleaved quoting:
 133   <a
 134 href="$p_url">$p_url</a>
 135 $info
 136 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 137   switches of git-send-email(1):
 138
 139   git send-email$arg
 140
 141   <a
 142 href="$se_url">$se_url</a>
 143 $link</pre>
 144
 145   Be sure your reply has a <b>Subject:</b> header at the top and a blank line
 146   before the message body.
 147 EOF
 148 }
 149
 150 sub in_reply_to {
 151         my ($hdr) = @_;
 152         my $refs = references($hdr);
 153         $refs->[-1];
 154 }
 155
 156 sub fold_addresses ($) {
 157         return $_[0] if length($_[0]) <= COLS;
 158         # try to fold on commas after non-word chars before $lim chars,
 159         # Try to get the "," preceded by ">" or ")", but avoid folding
 160         # on the comma where somebody uses "Lastname, Firstname".
 161         # We also try to keep the last and penultimate addresses in
 162         # the list on the same line if possible, hence the extra \z
 163         # Fall back to folding on spaces at $lim + 1 chars
 164         my $lim = COLS - 8; # 8 = "\t" display width
 165         my $too_long = $lim + 1;
 166         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 167         $_[0] = join("\n\t",
 168                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 169                                 .{1,$lim}(?:,|\z)|
 170                                 .{1,$lim}|
 171                                 .{$too_long,}?)(?:\s|\z)/xgo));
 172 }
 173
 174 sub _hdr_names_html ($$) {
 175         my ($hdr, $field) = @_;
 176         my @vals = $hdr->header($field) or return '';
 177         ascii_html(join(', ', PublicInbox::Address::names(join(',', @vals))));
 178 }
 179
 180 sub nr_to_s ($$$) {
 181         my ($nr, $singular, $plural) = @_;
 182         return "0 $plural" if $nr == 0;
 183         $nr == 1 ? "$nr $singular" : "$nr $plural";
 184 }
 185
 186 # Displays the text of of the message for /$INBOX/$MSGID/[Tt]/ endpoint
 187 # this is already inside a <pre>
 188 sub eml_entry {
 189         my ($ctx, $eml) = @_;
 190         my $smsg = delete $ctx->{smsg};
 191         my $subj = delete $smsg->{subject};
 192         my $mid_raw = $smsg->{mid};
 193         my $id = id_compress($mid_raw, 1);
 194         my $id_m = 'm'.$id;
 195         my $root_anchor = $ctx->{root_anchor} || '';
 196         my $irt;
 197         my $obfs_ibx = $ctx->{-obfs_ibx};
 198
 199         $subj = '(no subject)' if $subj eq '';
 200         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 201         $subj = '<b>'.ascii_html($subj).'</b>';
 202         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 203         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 204         $rv .= $subj . "\n";
 205         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 206         my @tocc;
 207         my $ds = delete $smsg->{ds}; # for v1 non-Xapian/SQLite users
 208
 209         # Deleting these fields saves about 400K as we iterate across 1K msgs
 210         delete @$smsg{qw(ts blob)};
 211
 212         my $from = _hdr_names_html($eml, 'From');
 213         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 214         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 215         my $upfx = $ctx->{-upfx};
 216         my $mhref = $upfx . mid_href($mid_raw) . '/';
 217         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 218         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 219         my $to = fold_addresses(_hdr_names_html($eml, 'To'));
 220         my $cc = fold_addresses(_hdr_names_html($eml, 'Cc'));
 221         my ($tlen, $clen) = (length($to), length($cc));
 222         my $to_cc = '';
 223         if (($tlen + $clen) > COLS) {
 224                 $to_cc .= '  To: '.$to."\n" if $tlen;
 225                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 226         } else {
 227                 if ($tlen) {
 228                         $to_cc .= '  To: '.$to;
 229                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 230                 } else {
 231                         $to_cc .= '  Cc: '.$cc if $clen;
 232                 }
 233                 $to_cc .= "\n";
 234         }
 235         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 236         $rv .= $to_cc;
 237
 238         my $mapping = $ctx->{mapping};
 239         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($eml)))) {
 240                 my $href = $upfx . mid_href($irt) . '/';
 241                 my $html = ascii_html($irt);
 242                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 243         }
 244         say { $ctx->zfh } $rv;
 245
 246         # scan through all parts, looking for displayable text
 247         $ctx->{mhref} = $mhref;
 248         $ctx->{changed_href} = "#e$id"; # for diffstat "files? changed,"
 249         $eml->each_part(\&add_text_body, $ctx, 1); # expensive
 250
 251         # add the footer
 252         $rv = "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 253                 "<a\nhref=\"$mhref\">permalink</a>" .
 254                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 255                 " <a\nhref=\"${mhref}#R\">reply</a>";
 256
 257         delete($ctx->{-qry}) and
 258                 $rv .= qq[ <a\nhref="${mhref}#related">related</a>];
 259
 260         my $hr;
 261         if (defined(my $pct = $smsg->{pct})) { # used by SearchView.pm
 262                 $rv .= "\t[relevance $pct%]";
 263                 $hr = 1;
 264         } elsif ($mapping) {
 265                 my $nested = 'nested';
 266                 my $flat = 'flat';
 267                 if ($ctx->{flat}) {
 268                         $hr = 1;
 269                         $flat = "<b>$flat</b>";
 270                 } else {
 271                         $nested = "<b>$nested</b>";
 272                 }
 273                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 274                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 275                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 276         } else {
 277                 $hr = $ctx->{-hr};
 278         }
 279
 280         # do we have more messages? start a new <pre> if so
 281         $rv .= scalar(@{$ctx->{msgs}}) ? '</pre><hr><pre>' : '</pre>' if $hr;
 282         $rv;
 283 }
 284
 285 sub pad_link ($$;$) {
 286         my ($mid, $level, $s) = @_;
 287         $s ||= '...';
 288         my $href = defined($mid) ?
 289                 ("<a\nhref=#r".id_compress($mid, 1).">($s)</a>\n") :
 290                 "($s)\n";
 291         (' 'x19).indent_for($level).th_pfx($level).$href;
 292 }
 293
 294 sub _skel_hdr {
 295         # my ($mapping, $mid) = @_;
 296         ($_[0]->{$_[1] // \'bogus'} // [ "(?)\n" ])->[0];
 297 }
 298
 299 sub _th_index_lite {
 300         my ($mid_raw, $irt, $id, $ctx) = @_;
 301         my $rv = '';
 302         my $mapping = $ctx->{mapping} or return $rv;
 303         my $pad = '  ';
 304         my $mid_map = $mapping->{$mid_raw} //
 305                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 306         my ($attr, $node, $idx, $level) = @$mid_map;
 307         my $children = $node->{children};
 308         my $nr_c = scalar @$children;
 309         my $nr_s = 0;
 310         my $siblings;
 311         # delete saves about 200KB on a 1K message thread
 312         if (my $refs = delete $node->{references}) {
 313                 ($$irt) = ($refs =~ m/$MID_EXTRACT\z/o);
 314         }
 315         my $irt_map = $mapping->{$$irt} if defined $$irt;
 316         if (defined $irt_map) {
 317                 $siblings = $irt_map->[1]->{children};
 318                 $nr_s = scalar(@$siblings) - 1;
 319                 $rv .= $pad . $irt_map->[0];
 320                 if ($idx > 0) {
 321                         my $prev = $siblings->[$idx - 1];
 322                         my $pmid = $prev->{mid};
 323                         if ($idx > 2) {
 324                                 my $s = ($idx - 1). ' preceding siblings ...';
 325                                 $rv .= pad_link($pmid, $level, $s);
 326                         } elsif ($idx == 2) {
 327                                 $rv .= $pad . _skel_hdr($mapping,
 328                                                 $siblings->[0] ?
 329                                                 $siblings->[0]->{mid} : undef);
 330                         }
 331                         $rv .= $pad . _skel_hdr($mapping, $pmid);
 332                 }
 333         }
 334         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 335         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 336         chop $attr; # remove "\n"
 337         $attr =~ s!<a\nhref.*</a> (?:&#34; )?!!s; # no point in dup subject
 338         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 339         $rv .= "<b>@ $attr</b>\n";
 340         if ($nr_c) {
 341                 my $cmid = $children->[0] ? $children->[0]->{mid} : undef;
 342                 $rv .= $pad . _skel_hdr($mapping, $cmid);
 343                 if ($nr_c > 2) {
 344                         my $s = ($nr_c - 1). ' more replies';
 345                         $rv .= pad_link($cmid, $level + 1, $s);
 346                 } elsif (my $cn = $children->[1]) {
 347                         $rv .= $pad . _skel_hdr($mapping, $cn->{mid});
 348                 }
 349         }
 350
 351         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 352         if ($next) {
 353                 my $nmid = $next->{mid};
 354                 $rv .= $pad . _skel_hdr($mapping, $nmid);
 355                 my $nnext = $nr_s - $idx;
 356                 if ($nnext > 2) {
 357                         my $s = ($nnext - 1).' subsequent siblings';
 358                         $rv .= pad_link($nmid, $level, $s);
 359                 } elsif (my $nn = $siblings->[$idx + 2]) {
 360                         $rv .= $pad . _skel_hdr($mapping, $nn->{mid});
 361                 }
 362         }
 363         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 364 }
 365
 366 # non-recursive thread walker
 367 sub walk_thread ($$$) {
 368         my ($rootset, $ctx, $cb) = @_;
 369         my @q = map { (0, $_, -1) } @$rootset;
 370         while (@q) {
 371                 my ($level, $node, $i) = splice(@q, 0, 3);
 372                 defined $node or next;
 373                 $cb->($ctx, $level, $node, $i) or return;
 374                 ++$level;
 375                 $i = 0;
 376                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 377         }
 378 }
 379
 380 sub pre_thread  { # walk_thread callback
 381         my ($ctx, $level, $node, $idx) = @_;
 382         $ctx->{mapping}->{$node->{mid}} = [ '', $node, $idx, $level ];
 383         skel_dump($ctx, $level, $node);
 384 }
 385
 386 sub thread_eml_entry {
 387         my ($ctx, $eml) = @_;
 388         my ($beg, $end) = thread_adj_level($ctx, $ctx->{level});
 389         print { $ctx->zfh } $beg, '<pre>';
 390         print { $ctx->{zfh} } eml_entry($ctx, $eml), '</pre>', $end;
 391 }
 392
 393 sub next_in_queue ($$) {
 394         my ($q, $ghost_ok) = @_;
 395         while (@$q) {
 396                 my ($level, $smsg) = splice(@$q, 0, 2);
 397                 my $cl = $level + 1;
 398                 unshift @$q, map { ($cl, $_) } @{$smsg->{children}};
 399                 return ($level, $smsg) if $ghost_ok || exists($smsg->{blob});
 400         }
 401         undef;
 402 }
 403
 404 sub stream_thread_i { # PublicInbox::WwwStream::getline callback
 405         my ($ctx, $eml) = @_;
 406         return thread_eml_entry($ctx, $eml) if $eml;
 407         return unless exists($ctx->{skel});
 408         my $ghost_ok = $ctx->{nr}++;
 409         while (1) {
 410                 my ($lvl, $smsg) = next_in_queue($ctx->{-queue}, $ghost_ok);
 411                 if ($smsg) {
 412                         if (exists $smsg->{blob}) { # next message for cat-file
 413                                 $ctx->{level} = $lvl;
 414                                 if (!$ghost_ok) { # first non-ghost
 415                                         $ctx->{-title_html} =
 416                                                 ascii_html($smsg->{subject});
 417                                         print { $ctx->zfh } $ctx->html_top;
 418                                 }
 419                                 return $smsg;
 420                         }
 421                         # buffer the ghost entry and loop
 422                         print { $ctx->zfh } ghost_index_entry($ctx, $lvl, $smsg)
 423                 } else { # all done
 424                         print { $ctx->zfh } thread_adj_level($ctx, 0),
 425                                                 ${delete($ctx->{skel})};
 426                         return;
 427                 }
 428         }
 429 }
 430
 431 sub stream_thread ($$) {
 432         my ($rootset, $ctx) = @_;
 433         @{$ctx->{-queue}} = map { (0, $_) } @$rootset;
 434         PublicInbox::WwwStream::aresponse($ctx, \&stream_thread_i);
 435 }
 436
 437 # /$INBOX/$MSGID/t/ and /$INBOX/$MSGID/T/
 438 sub thread_html {
 439         my ($ctx) = @_;
 440         $ctx->{-upfx} = '../../';
 441         my $mid = $ctx->{mid};
 442         my $ibx = $ctx->{ibx};
 443         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 444         return missing_thread($ctx) if $nr == 0;
 445         $ctx->{-spfx} = '../../' if $ibx->{coderepo};
 446
 447         # link $INBOX_DIR/description text to "index_topics" view around
 448         # the newest message in this thread
 449         my $t = ts2str($ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs));
 450         my $t_fmt = fmt_ts($ctx->{-t_max});
 451
 452         my $skel = '<hr><pre>';
 453         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 454         $skel .= <<EOF;
 455 , other threads:[<a
 456 href="../../?t=$t">~$t_fmt UTC</a> | <a
 457 href="../../">newest</a>]
 458
 459 EOF
 460         $skel .= "<b\nid=t>Thread overview:</b> ";
 461         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 462         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 463         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 464         $skel .= "-- links below jump to the message on this page --\n";
 465         $ctx->{cur_level} = 0;
 466         $ctx->{skel} = \$skel;
 467         $ctx->{prev_attr} = '';
 468         $ctx->{prev_level} = 0;
 469         $ctx->{root_anchor} = 'm' . id_compress($mid, 1);
 470         $ctx->{mapping} = {}; # mid -> [ header_summary, node, idx, level ]
 471         $ctx->{s_nr} = ($nr > 1 ? "$nr+ messages" : 'only message')
 472                        .' in thread';
 473
 474         my $rootset = thread_results($ctx, $msgs);
 475
 476         # reduce hash lookups in pre_thread->skel_dump
 477         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 478         walk_thread($rootset, $ctx, \&pre_thread);
 479
 480         $skel .= '</pre>';
 481         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 482
 483         # flat display: lazy load the full message from smsg
 484         $ctx->{msgs} = $msgs;
 485         $ctx->{-html_tip} = '<pre>';
 486         PublicInbox::WwwStream::aresponse($ctx, \&thread_html_i);
 487 }
 488
 489 sub thread_html_i { # PublicInbox::WwwStream::getline callback
 490         my ($ctx, $eml) = @_;
 491         if ($eml) {
 492                 my $smsg = $ctx->{smsg};
 493                 if (exists $ctx->{-html_tip}) {
 494                         $ctx->{-title_html} = ascii_html($smsg->{subject});
 495                         print { $ctx->zfh } $ctx->html_top;
 496                 }
 497                 return eml_entry($ctx, $eml);
 498         } else {
 499                 while (my $smsg = shift @{$ctx->{msgs}}) {
 500                         return $smsg if exists($smsg->{blob});
 501                 }
 502                 my $skel = delete($ctx->{skel}) or return; # all done
 503                 print { $ctx->zfh } $$skel;
 504                 undef;
 505         }
 506 }
 507
 508 sub submsg_hdr ($$) {
 509         my ($ctx, $eml) = @_;
 510         my $s = "\n";
 511         for my $h (qw(From To Cc Subject Date Message-ID X-Alt-Message-ID)) {
 512                 $s .= "$h: $_\n" for $eml->header($h);
 513         }
 514         obfuscate_addrs($ctx->{-obfs_ibx}, $s) if $ctx->{-obfs_ibx};
 515         ascii_html($s);
 516 }
 517
 518 sub attach_link ($$$$;$) {
 519         my ($ctx, $ct, $p, $fn, $err) = @_;
 520         my ($part, $depth, $idx) = @$p;
 521
 522         # Eml iteration clobbers multipart ->{bdy}, so do not offer
 523         # downloads for 0-byte multipart attachments
 524         return unless $part->{bdy};
 525
 526         my $size = length($part->body);
 527         delete $part->{bdy}; # save memory
 528
 529         # hide attributes normally, unless we want to aid users in
 530         # spotting MUA problems:
 531         $ct =~ s/;.*// unless $err;
 532         $ct = ascii_html($ct);
 533         my $sfn;
 534         if (defined $fn && $fn =~ /\A$PublicInbox::Hval::FN\z/o) {
 535                 $sfn = $fn;
 536         } elsif ($ct eq 'text/plain') {
 537                 $sfn = 'a.txt';
 538         } else {
 539                 $sfn = 'a.bin';
 540         }
 541         my $rv = $idx eq '1' ? '' : "\n"; # like join("\n", ...)
 542         $rv .= qq(<a\nhref="$ctx->{mhref}$idx-$sfn">);
 543         $rv .= <<EOF if $err;
 544 [-- Warning: decoded text below may be mangled, UTF-8 assumed --]
 545 EOF
 546         $rv .= "[-- Attachment #$idx: ";
 547         my $desc = $part->header('Content-Description') // $fn // '';
 548         $rv .= ascii_html($desc)." --]\n[-- " if $desc ne '';
 549         $rv .= "Type: $ct, Size: $size bytes --]</a>\n";
 550         $rv .= submsg_hdr($ctx, $part) if $part->{is_submsg};
 551         $rv;
 552 }
 553
 554 sub add_text_body { # callback for each_part
 555         my ($p, $ctx) = @_;
 556         my $upfx = $ctx->{mhref};
 557         my $ibx = $ctx->{ibx};
 558         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 559         # $p - from each_part: [ Email::MIME-like, depth, $idx ]
 560         my ($part, $depth, $idx) = @$p;
 561         my $ct = $part->content_type || 'text/plain';
 562         my $fn = $part->filename;
 563         my ($s, $err) = msg_part_text($part, $ct);
 564         my $zfh = $ctx->zfh;
 565         $s // return print $zfh (attach_link($ctx, $ct, $p, $fn) // '');
 566         say $zfh submsg_hdr($ctx, $part) if $part->{is_submsg};
 567
 568         # makes no difference to browsers, and don't screw up filename
 569         # link generation in diffs with the extra '%0D'
 570         $s =~ s/\r+\n/\n/sg;
 571
 572         # will be escaped to `&#8226;' in HTML
 573         obfuscate_addrs($ibx, $s, "\x{2022}") if $ibx->{obfuscate};
 574
 575         # always support diff-highlighting, but we can't linkify hunk
 576         # headers for solver unless some coderepo are configured:
 577         my $diff;
 578         if ($s =~ /^--- [^\n]+\n\+{3} [^\n]+\n@@ /ms) {
 579                 # diffstat anchors do not link across attachments or messages,
 580                 # -apfx is just a stable prefix for making diffstat anchors
 581                 # linkable to the first diff hunk w/o crossing attachments
 582                 $idx =~ tr!.!/!; # compatibility with previous versions
 583                 $ctx->{-apfx} = $upfx . $idx;
 584
 585                 # do attr => filename mappings for diffstats in git diffs:
 586                 $ctx->{-anchors} = {} if $s =~ /^diff --git /sm;
 587                 $diff = 1;
 588                 delete $ctx->{-long_path};
 589         };
 590
 591         # split off quoted and unquoted blocks:
 592         my @sections = PublicInbox::MsgIter::split_quotes($s);
 593         undef $s; # free memory
 594         if (defined($fn) || ($depth > 0 && !$part->{is_submsg}) || $err) {
 595                 # badly-encoded message with $err? tell the world about it!
 596                 say $zfh attach_link($ctx, $ct, $p, $fn, $err);
 597         }
 598         delete $part->{bdy}; # save memory
 599         for my $cur (@sections) { # $cur may be huge
 600                 if ($cur =~ /\A>/) {
 601                         # we use a <span> here to allow users to specify
 602                         # their own color for quoted text
 603                         print $zfh qq(<span\nclass="q">),
 604                                         $l->to_html($cur), '</span>';
 605                 } elsif ($diff) {
 606                         flush_diff($ctx, \$cur);
 607                 } else { # regular lines, OK
 608                         print $zfh $l->to_html($cur);
 609                 }
 610                 undef $cur; # free memory
 611         }
 612 }
 613
 614 sub _msg_page_prepare {
 615         my ($eml, $ctx) = @_;
 616         my $have_over = !!$ctx->{ibx}->over;
 617         my $mids = mids_for_index($eml);
 618         my $nr = $ctx->{nr}++;
 619         if ($nr) { # unlikely
 620                 if ($ctx->{chash} eq content_hash($eml)) {
 621                         warn "W: BUG? @$mids not deduplicated properly\n";
 622                         return;
 623                 }
 624                 $ctx->{-html_tip} =
 625 "<pre>WARNING: multiple messages have this Message-ID\n</pre><pre>";
 626         } else {
 627                 $ctx->{first_hdr} = $eml->header_obj;
 628                 $ctx->{chash} = content_hash($eml) if $ctx->{smsg}; # reused MID
 629                 $ctx->{-html_tip} = "<pre\nid=b>"; # anchor for body start
 630         }
 631         $ctx->{-upfx} = '../';
 632         my @title; # (Subject[0], From[0])
 633         my $hbuf = '';
 634         for my $v ($eml->header('From')) {
 635                 my @n = PublicInbox::Address::names($v);
 636                 $title[1] //= join(', ', @n);
 637                 $hbuf .= "From: $v\n" if $v ne '';
 638         }
 639         for my $h (qw(To Cc)) {
 640                 for my $v ($eml->header($h)) {
 641                         fold_addresses($v);
 642                         $hbuf .= "$h: $v\n" if $v ne '';
 643                 }
 644         }
 645         my @subj = $eml->header('Subject');
 646         $hbuf .= "Subject: $_\n" for @subj;
 647         $title[0] = $subj[0] // '(no subject)';
 648         $hbuf .= "Date: $_\n" for $eml->header('Date');
 649         $hbuf = ascii_html($hbuf);
 650         $ctx->{-title_html} = ascii_html(join(' - ', @title));
 651         if (my $obfs_ibx = $ctx->{-obfs_ibx}) {
 652                 obfuscate_addrs($obfs_ibx, $hbuf);
 653                 obfuscate_addrs($obfs_ibx, $ctx->{-title_html});
 654         }
 655
 656         # [thread overview] link is typically added after Date,
 657         # but added after Subject, or even nothing.
 658         if ($have_over) {
 659                 chop $hbuf; # drop "\n", or noop if $rv eq ''
 660                 $hbuf .= qq{\t<a\nhref="#r">[thread overview]</a>\n};
 661                 $hbuf =~ s!^Subject:\x20(.*?)(\n[A-Z]|\z)
 662                                 !Subject: <a\nhref="#r"\nid=t>$1</a>$2!msx or
 663                         $hbuf .= qq(<a\nhref="#r\nid=t></a>);
 664         }
 665         if (scalar(@$mids) == 1) { # common case
 666                 my $x = ascii_html($mids->[0]);
 667                 $hbuf .= qq[Message-ID: &lt;$x&gt; (<a href="raw">raw</a>)\n];
 668         }
 669         if (!$nr) { # first (and only) message, common case
 670                 print { $ctx->zfh } $ctx->html_top, $hbuf;
 671         } else {
 672                 delete $ctx->{-title_html};
 673                 print { $ctx->zfh } $ctx->{-html_tip}, $hbuf;
 674         }
 675         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 676         $hbuf = '';
 677         if (scalar(@$mids) != 1) { # unlikely, but it happens :<
 678                 # X-Alt-Message-ID can happen if a message is injected from
 679                 # public-inbox-nntpd because of multiple Message-ID headers.
 680                 for my $h (qw(Message-ID X-Alt-Message-ID)) {
 681                         $hbuf .= "$h: $_\n" for ($eml->header_raw($h));
 682                 }
 683                 $ctx->{-linkify}->linkify_mids('..', \$hbuf, 1); # escapes HTML
 684                 print { $ctx->{zfh} } $hbuf;
 685                 $hbuf = '';
 686         }
 687         my @irt = $eml->header_raw('In-Reply-To');
 688         my $refs;
 689         if (!@irt) {
 690                 $refs = references($eml);
 691                 $irt[0] = pop(@$refs) if scalar @$refs;
 692         }
 693         $hbuf .= "In-Reply-To: $_\n" for @irt;
 694
 695         # do not display References: if search is present,
 696         # we show the thread skeleton at the bottom, instead.
 697         if (!$have_over) {
 698                 $refs //= references($eml);
 699                 $hbuf .= 'References: <'.join(">\n\t<", @$refs).">\n" if @$refs;
 700         }
 701         $ctx->{-linkify}->linkify_mids('..', \$hbuf); # escapes HTML
 702         say { $ctx->{zfh} } $hbuf;
 703         1;
 704 }
 705
 706 sub SKEL_EXPAND () {
 707         qq(expand[<a\nhref="T/#u">flat</a>) .
 708                 qq(|<a\nhref="t/#u">nested</a>]  ) .
 709                 qq(<a\nhref="t.mbox.gz">mbox.gz</a>  ) .
 710                 qq(<a\nhref="t.atom">Atom feed</a>);
 711 }
 712
 713 sub thread_skel ($$$) {
 714         my ($skel, $ctx, $hdr) = @_;
 715         my $mid = mids($hdr)->[0];
 716         my $ibx = $ctx->{ibx};
 717         my ($nr, $msgs) = $ibx->over->get_thread($mid);
 718         my $parent = in_reply_to($hdr);
 719         $$skel .= "\n<b>Thread overview: </b>";
 720         if ($nr <= 1) {
 721                 if (defined $parent) {
 722                         $$skel .= SKEL_EXPAND."\n ";
 723                         $$skel .= ghost_parent('../', $parent) . "\n";
 724                 } else {
 725                         $$skel .= "<a\nid=r>[no followups]</a> ".
 726                                         SKEL_EXPAND."\n";
 727                 }
 728                 $ctx->{next_msg} = undef;
 729                 $ctx->{parent_msg} = $parent;
 730                 return;
 731         }
 732
 733         $$skel .= $nr;
 734         $$skel .= '+ messages / '.SKEL_EXPAND.qq!  <a\nhref="#b">top</a>\n!;
 735
 736         # nb: mutt only shows the first Subject in the index pane
 737         # when multiple Subject: headers are present, so we follow suit:
 738         my $subj = $hdr->header('Subject') // '';
 739         $subj = '(no subject)' if $subj eq '';
 740         $ctx->{cur} = $mid;
 741         $ctx->{prev_attr} = '';
 742         $ctx->{prev_level} = 0;
 743         $ctx->{skel} = $skel;
 744
 745         # reduce hash lookups in skel_dump
 746         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 747         walk_thread(thread_results($ctx, $msgs), $ctx, \&skel_dump);
 748
 749         $ctx->{parent_msg} = $parent;
 750 }
 751
 752 # writes to zbuf
 753 sub html_footer {
 754         my ($ctx, $hdr) = @_;
 755         my $upfx = '../';
 756         my (@related, $skel);
 757         my $foot = '<pre>';
 758         my $qry = delete $ctx->{-qry};
 759         if ($qry && $ctx->{ibx}->isrch) {
 760                 my $q = ''; # search for either ancestor or descendent patches
 761                 for (@{$qry->{dfpre}}, @{$qry->{dfpost}}) {
 762                         chop if length > 7; # include 1 abbrev "older" patches
 763                         $q .= "dfblob:$_ ";
 764                 }
 765                 chop $q; # omit trailing SP
 766                 local $Text::Wrap::columns = COLS;
 767                 local $Text::Wrap::huge = 'overflow';
 768                 $q = wrap('', '', $q);
 769                 my $rows = ($q =~ tr/\n/\n/) + 1;
 770                 $q = ascii_html($q);
 771                 $related[0] = <<EOM;
 772 <form id=related
 773 action=$upfx
 774 ><pre>find likely ancestor, descendant, or conflicting patches for <a
 775 href=#t>this message</a>:
 776 <textarea name=q cols=${\COLS} rows=$rows>$q</textarea>
 777 <input type=submit value=search
 778 />\t(<a href=${upfx}_/text/help/#search>help</a>)</pre></form>
 779 EOM
 780         }
 781         if ($ctx->{ibx}->over) {
 782                 my $t = ts2str($ctx->{-t_max});
 783                 my $t_fmt = fmt_ts($ctx->{-t_max});
 784                 my $fallback = @related ? "\t" : "<a id=related>\t</a>";
 785                 $skel = <<EOF;
 786 ${fallback}other threads:[<a
 787 href="$upfx?t=$t">~$t_fmt UTC</a>|<a
 788 href="$upfx">newest</a>]
 789 EOF
 790                 thread_skel(\$skel, $ctx, $hdr);
 791                 my ($next, $prev);
 792                 my $parent = '       ';
 793                 $next = $prev = '    ';
 794
 795                 if (my $n = $ctx->{next_msg}) {
 796                         $n = mid_href($n);
 797                         $next = qq(<a\nhref="$upfx$n/"\nrel=next>next</a>);
 798                 }
 799                 my $par = $ctx->{parent_msg};
 800                 my $u = $par ? $upfx.mid_href($par).'/' : undef;
 801                 if (my $p = $ctx->{prev_msg}) {
 802                         $prev = mid_href($p);
 803                         if ($p && $par && $p eq $par) {
 804                                 $prev = qq(<a\nhref="$upfx$prev/"\n) .
 805                                         'rel=prev>prev parent</a>';
 806                                 $parent = '';
 807                         } else {
 808                                 $prev = qq(<a\nhref="$upfx$prev/"\n) .
 809                                         'rel=prev>prev</a>';
 810                                 $parent = qq( <a\nhref="$u">parent</a>) if $u;
 811                         }
 812                 } elsif ($u) { # unlikely
 813                         $parent = qq( <a\nhref="$u"\nrel=prev>parent</a>);
 814                 }
 815                 $foot .= "$next $prev$parent ";
 816         } else { # unindexed inboxes w/o over
 817                 $skel = qq( <a\nhref="$upfx">latest</a>);
 818         }
 819         # $skel may be big for big threads, don't append it to $foot
 820         print { $ctx->zfh } $foot, qq(<a\nhref="#R">reply</a>),
 821                                 $skel, '</pre>', @related,
 822                                 msg_reply($ctx, $hdr);
 823 }
 824
 825 sub ghost_parent {
 826         my ($upfx, $mid) = @_;
 827
 828         my $href = mid_href($mid);
 829         my $html = ascii_html($mid);
 830         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 831 }
 832
 833 sub indent_for {
 834         my ($level) = @_;
 835         $level ? INDENT x ($level - 1) : '';
 836 }
 837
 838 sub find_mid_root {
 839         my ($ctx, $level, $node, $idx) = @_;
 840         ++$ctx->{root_idx} if $level == 0;
 841         if ($node->{mid} eq $ctx->{mid}) {
 842                 $ctx->{found_mid_at} = $ctx->{root_idx};
 843                 return 0; # stop iterating
 844         }
 845         1;
 846 }
 847
 848 sub strict_loose_note ($) {
 849         my ($nr) = @_;
 850         my $msg =
 851 "  -- strict thread matches above, loose matches on Subject: below --\n";
 852
 853         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 854                 $msg .=
 855 "  -- use mbox.gz link to download all $nr messages --\n";
 856         }
 857         $msg;
 858 }
 859
 860 sub thread_results {
 861         my ($ctx, $msgs) = @_;
 862         require PublicInbox::SearchThread;
 863         my $rootset = PublicInbox::SearchThread::thread($msgs, \&sort_ds, $ctx);
 864
 865         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 866         # and preserved in the future.  This bug is hidden by `sid' matches
 867         # in get_thread, so we never noticed it until now.  And even when
 868         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 869         # bump since reindexing is expensive and users may not do it
 870
 871         # loose threading could've returned too many results,
 872         # put the root the message we care about at the top:
 873         my $mid = $ctx->{mid};
 874         if (defined($mid) && scalar(@$rootset) > 1) {
 875                 $ctx->{root_idx} = -1;
 876                 my $nr = scalar @$msgs;
 877                 walk_thread($rootset, $ctx, \&find_mid_root);
 878                 my $idx = $ctx->{found_mid_at};
 879                 if (defined($idx) && $idx != 0) {
 880                         my $tip = splice(@$rootset, $idx, 1);
 881                         @$rootset = reverse @$rootset;
 882                         unshift @$rootset, $tip;
 883                         $ctx->{sl_note} = strict_loose_note($nr);
 884                 }
 885         }
 886         $rootset
 887 }
 888
 889 sub missing_thread {
 890         my ($ctx) = @_;
 891         require PublicInbox::ExtMsg;
 892         PublicInbox::ExtMsg::ext_msg($ctx);
 893 }
 894
 895 sub dedupe_subject {
 896         my ($prev_subj, $subj, $val) = @_;
 897
 898         my $omit; # '"' denotes identical text omitted
 899         my (@prev_pop, @curr_pop);
 900         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 901                 push(@prev_pop, pop(@$prev_subj));
 902                 push(@curr_pop, pop(@$subj));
 903                 $omit //= $val;
 904         }
 905         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 906         if (scalar(@curr_pop) == 1) {
 907                 $omit = undef;
 908                 push @$prev_subj, @prev_pop;
 909                 push @$subj, @curr_pop;
 910         }
 911         $omit // '';
 912 }
 913
 914 sub skel_dump { # walk_thread callback
 915         my ($ctx, $level, $smsg) = @_;
 916         $smsg->{blob} or return _skel_ghost($ctx, $level, $smsg);
 917
 918         my $skel = $ctx->{skel};
 919         my $cur = $ctx->{cur};
 920         my $mid = $smsg->{mid};
 921
 922         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 923                 $$skel .= delete($ctx->{sl_note}) || '';
 924         }
 925
 926         my $f = ascii_html(delete $smsg->{from_name});
 927         my $obfs_ibx = $ctx->{-obfs_ibx};
 928         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 929
 930         my $d = fmt_ts($smsg->{ds});
 931         my $unmatched; # if lazy-loaded by SearchThread::Msg::visible()
 932         if (exists $ctx->{searchview}) {
 933                 if (defined(my $pct = $smsg->{pct})) {
 934                         $d .= (sprintf(' % 2u', $pct) . '%');
 935                 } else {
 936                         $unmatched = 1;
 937                         $d .= '    ';
 938                 }
 939         }
 940         $d .= ' ' . indent_for($level) . th_pfx($level);
 941         my $attr = $f;
 942         $ctx->{first_level} ||= $level;
 943
 944         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 945                 $ctx->{prev_attr} = $attr;
 946         }
 947         $ctx->{prev_level} = $level;
 948
 949         if ($cur) {
 950                 if ($cur eq $mid) {
 951                         delete $ctx->{cur};
 952                         $$skel .= "<b>$d<a\nid=r\nhref=\"#t\">".
 953                                  "$attr [this message]</a></b>\n";
 954                         return 1;
 955                 } else {
 956                         $ctx->{prev_msg} = $mid;
 957                 }
 958         } else {
 959                 $ctx->{next_msg} ||= $mid;
 960         }
 961
 962         # Subject is never undef, this mail was loaded from
 963         # our Xapian which would've resulted in '' if it were
 964         # really missing (and Filter rejects empty subjects)
 965         my @subj = split(/ /, subject_normalized($smsg->{subject}));
 966         # remove common suffixes from the subject if it matches the previous,
 967         # so we do not show redundant text at the end.
 968         my $prev_subj = $ctx->{prev_subj} || [];
 969         $ctx->{prev_subj} = [ @subj ];
 970         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 971         my $end;
 972         if (@subj) {
 973                 my $subj = join(' ', @subj);
 974                 $subj = ascii_html($subj);
 975                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 976                 $end = "$subj</a> $omit$f\n"
 977         } else {
 978                 $end = "$f</a>\n";
 979         }
 980         my $m;
 981         my $id = '';
 982         my $mapping = $unmatched ? undef : $ctx->{mapping};
 983         if ($mapping) {
 984                 my $map = $mapping->{$mid};
 985                 $id = id_compress($mid, 1);
 986                 $m = '#m'.$id;
 987                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 988                 $id = "\nid=r".$id;
 989         } else {
 990                 $m = $ctx->{-upfx}.mid_href($mid).'/';
 991         }
 992         $$skel .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 993         1;
 994 }
 995
 996 sub _skel_ghost {
 997         my ($ctx, $level, $node) = @_;
 998
 999         my $mid = $node->{mid};
1000         my $d = '     [not found] ';
1001         $d .= '    '  if exists $ctx->{searchview};
1002         $d .= indent_for($level) . th_pfx($level);
1003         my $upfx = $ctx->{-upfx};
1004         my $href = $upfx . mid_href($mid) . '/';
1005         my $html = ascii_html($mid);
1006
1007         my $mapping = $ctx->{mapping};
1008         my $map = $mapping->{$mid} if $mapping;
1009         if ($map) {
1010                 my $id = id_compress($mid, 1);
1011                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1012                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1013         } else {
1014                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1015         }
1016         ${$ctx->{skel}} .= $d;
1017         1;
1018 }
1019
1020 sub sort_ds {
1021         @{$_[0]} = sort {
1022                 (eval { $a->topmost->{ds} } || 0) <=>
1023                 (eval { $b->topmost->{ds} } || 0)
1024         } @{$_[0]};
1025 }
1026
1027 # accumulate recent topics if search is supported
1028 # returns 200 if done, 404 if not
1029 sub acc_topic { # walk_thread callback
1030         my ($ctx, $level, $smsg) = @_;
1031         my $mid = $smsg->{mid};
1032         my $has_blob = $smsg->{blob} // do {
1033                 if (my $by_mid = $ctx->{ibx}->smsg_by_mid($mid)) {
1034                         %$smsg = (%$smsg, %$by_mid);
1035                         1;
1036                 }
1037         };
1038         if ($has_blob) {
1039                 my $subj = subject_normalized($smsg->{subject});
1040                 $subj = '(no subject)' if $subj eq '';
1041                 my $ds = $smsg->{ds};
1042                 if ($level == 0) { # new, top-level topic
1043                         my $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1044                         $ctx->{-cur_topic} = $topic;
1045                         push @{$ctx->{order}}, $topic;
1046                         return 1;
1047                 }
1048
1049                 # continue existing topic
1050                 my $topic = $ctx->{-cur_topic}; # should never be undef
1051                 $topic->[0] = $ds if $ds > $topic->[0];
1052                 $topic->[1]++; # bump N+ message counter
1053                 my $seen = $topic->[2];
1054                 if (scalar(@$topic) == 3) { # parent was a ghost
1055                         push @$topic, $subj;
1056                 } elsif (!defined($seen->{$subj})) {
1057                         push @$topic, $level, $subj; # @extra messages
1058                 }
1059                 $seen->{$subj} = $mid; # latest for subject
1060         } else { # ghost message
1061                 return 1 if $level != 0; # ignore child ghosts
1062                 my $topic = $ctx->{-cur_topic} = [ -666, 0, {} ];
1063                 push @{$ctx->{order}}, $topic;
1064         }
1065         1;
1066 }
1067
1068 sub dump_topics {
1069         my ($ctx) = @_;
1070         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1071         unless ($order) {
1072                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1073                 return 404;
1074         }
1075
1076         my @out;
1077         my $obfs_ibx = $ctx->{ibx}->{obfuscate} ? $ctx->{ibx} : undef;
1078         if (my $note = delete $ctx->{t_note}) {
1079                 push @out, $note; # "messages from ... to ..."
1080         }
1081         # sort by recency, this allows new posts to "bump" old topics...
1082         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1083                 my ($ds, $n, $seen, $top_subj, @extra) = @$topic;
1084                 @$topic = ();
1085                 next unless defined $top_subj;  # ghost topic
1086                 my $mid = delete $seen->{$top_subj};
1087                 my $href = mid_href($mid);
1088                 my $prev_subj = [ split(/ /, $top_subj) ];
1089                 $top_subj = ascii_html($top_subj);
1090                 $ds = fmt_ts($ds);
1091
1092                 # $n isn't the total number of posts on the topic,
1093                 # just the number of posts in the current results window
1094                 my $anchor;
1095                 if ($n == 1) {
1096                         $n = '';
1097                         $anchor = '#u'; # top of only message
1098                 } else {
1099                         $n = " ($n+ messages)";
1100                         $anchor = '#t'; # thread skeleton
1101                 }
1102
1103                 my $s = "<a\nhref=\"$href/T/$anchor\">$top_subj</a>\n" .
1104                         " $ds UTC $n\n";
1105                 while (@extra) {
1106                         my $level = shift @extra;
1107                         my $subj = shift @extra; # already normalized
1108                         $mid = delete $seen->{$subj};
1109                         my @subj = split(/ /, $subj);
1110                         my @next_prev = @subj; # full copy
1111                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1112                         $prev_subj = \@next_prev;
1113                         $subj = join(' ', @subj);
1114                         $subj = ascii_html($subj);
1115                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1116                         $href = mid_href($mid);
1117                         $s .= indent_for($level) . TCHILD;
1118                         $s .= qq(<a\nhref="$href/T/#u">$subj</a>$omit\n);
1119                 }
1120                 push @out, $s;
1121         }
1122         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1123         200;
1124 }
1125
1126 sub str2ts ($) {
1127         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1128         timegm($ss || 0, $mm || 0, $hh || 0, $dd, $mon - 1, $yyyy);
1129 }
1130
1131 sub pagination_footer ($$) {
1132         my ($ctx, $latest) = @_;
1133         my $next = $ctx->{next_page} || '';
1134         my $prev = $ctx->{prev_page} || '';
1135         if ($prev) {  # aligned padding for: 'next (older) | '
1136                 $next = $next ? "$next | " : '             | ';
1137                 $prev .= qq[ | <a\nhref="$latest">latest</a>];
1138         }
1139         ($next || $prev) ? "<hr><pre id=nav>page: $next$prev</pre>" : '';
1140 }
1141
1142 sub paginate_recent ($$) {
1143         my ($ctx, $lim) = @_;
1144         my $t = $ctx->{qp}->{t} || '';
1145         my $opts = { limit => $lim };
1146         my ($after, $before);
1147
1148         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1149         # if only $after exists "YYYYMMDD.." because "." could be skipped
1150         # if interpreted as an end-of-sentence
1151         $t =~ s/\A([0-9]{8,14})-// and $after = str2ts($1);
1152         $t =~ /\A([0-9]{8,14})\z/ and $before = str2ts($1);
1153
1154         my $msgs = $ctx->{ibx}->over->recent($opts, $after, $before);
1155         if (defined($after) && scalar(@$msgs) < $lim) {
1156                 $after = $before = undef;
1157                 $msgs = $ctx->{ibx}->over->recent($opts);
1158         }
1159         my $more = scalar(@$msgs) == $lim;
1160         my ($newest, $oldest);
1161         if (@$msgs) {
1162                 $newest = $msgs->[0]->{ts};
1163                 $oldest = $msgs->[-1]->{ts};
1164                 # if we only had $after, our SQL query in ->recent ordered
1165                 if ($newest < $oldest) {
1166                         ($oldest, $newest) = ($newest, $oldest);
1167                         $more = undef if defined($after) && $after < $oldest;
1168                 }
1169                 if (defined($after // $before)) {
1170                         my $n = strftime('%Y-%m-%d %H:%M:%S', gmtime($newest));
1171                         my $o = strftime('%Y-%m-%d %H:%M:%S', gmtime($oldest));
1172                         $ctx->{t_note} = <<EOM;
1173  messages from $o to $n UTC [<a href="#nav">more...</a>]
1174 EOM
1175                         my $s = ts2str($newest);
1176                         $ctx->{prev_page} = qq[<a\nhref="?t=$s-"\nrel=prev>] .
1177                                                 'prev (newer)</a>';
1178                 }
1179         }
1180         if (defined($oldest) && $more) {
1181                 my $s = ts2str($oldest);
1182                 $ctx->{next_page} = qq[<a\nhref="?t=$s"\nrel=next>] .
1183                                         'next (older)</a>';
1184         }
1185         $msgs;
1186 }
1187
1188 # GET /$INBOX - top-level inbox view for indexed inboxes
1189 sub index_topics {
1190         my ($ctx) = @_;
1191         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1192         walk_thread(thread_results($ctx, $msgs), $ctx, \&acc_topic) if @$msgs;
1193         html_oneshot($ctx, dump_topics($ctx), pagination_footer($ctx, '.'));
1194 }
1195
1196 sub thread_adj_level {
1197         my ($ctx, $level) = @_;
1198
1199         my $max = $ctx->{cur_level};
1200         if ($level <= 0) {
1201                 return ('', '') if $max == 0; # flat output
1202
1203                 # reset existing lists
1204                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1205                 $ctx->{cur_level} = 0;
1206                 ("$beg</ul>", '');
1207         } elsif ($level == $max) { # continue existing list
1208                 qw(<li> </li>);
1209         } elsif ($level < $max) {
1210                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1211                 $ctx->{cur_level} = $level;
1212                 ("$beg<li>", '</li>');
1213         } else { # ($level > $max) # start a new level
1214                 $ctx->{cur_level} = $level;
1215                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1216                 ($beg, '</li>');
1217         }
1218 }
1219
1220 sub ghost_index_entry {
1221         my ($ctx, $level, $node) = @_;
1222         my ($beg, $end) = thread_adj_level($ctx,  $level);
1223         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{mid} // '?')
1224                 . '</pre>' . $end;
1225 }
1226
1227 1;