lib/PublicInbox/View.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Used for displaying the HTML web interface.
   5 # See Documentation/design_www.txt for this.
   6 package PublicInbox::View;
   7 use strict;
   8 use warnings;
   9 use bytes (); # only for bytes::length
  10 use PublicInbox::MsgTime qw(msg_datestamp);
  11 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  12 use PublicInbox::Linkify;
  13 use PublicInbox::MID qw/id_compress mid_escape mids references/;
  14 use PublicInbox::MsgIter;
  15 use PublicInbox::Address;
  16 use PublicInbox::WwwStream;
  17 use PublicInbox::Reply;
  18 use PublicInbox::ViewDiff qw(flush_diff);
  19 require POSIX;
  20 use Time::Local qw(timegm);
  21
  22 use constant COLS => 72;
  23 use constant INDENT => '  ';
  24 use constant TCHILD => '` ';
  25 sub th_pfx ($) { $_[0] == 0 ? '' : TCHILD };
  26
  27 # public functions: (unstable)
  28
  29 sub msg_html {
  30         my ($ctx, $mime, $more, $smsg) = @_;
  31         my $hdr = $mime->header_obj;
  32         my $ibx = $ctx->{-inbox};
  33         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
  34         my $tip = _msg_html_prepare($hdr, $ctx, $more, 0);
  35         my $end = 2;
  36         PublicInbox::WwwStream->response($ctx, 200, sub {
  37                 my ($nr, undef) = @_;
  38                 if ($nr == 1) {
  39                         # $more cannot be true w/o $smsg being defined:
  40                         my $upfx = $more ? '../'.mid_escape($smsg->mid).'/' : '';
  41                         $tip . multipart_text_as_html($mime, $upfx, $ctx) .
  42                                 '</pre><hr>'
  43                 } elsif ($more && @$more) {
  44                         ++$end;
  45                         msg_html_more($ctx, $more, $nr);
  46                 } elsif ($nr == $end) {
  47                         # fake an EOF if generating the footer fails;
  48                         # we want to at least show the message if something
  49                         # here crashes:
  50                         eval {
  51                                 '<pre>' . html_footer($hdr, 1, $ctx) .
  52                                 '</pre>' . msg_reply($ctx, $hdr)
  53                         };
  54                 } else {
  55                         undef
  56                 }
  57         });
  58 }
  59
  60 sub msg_page {
  61         my ($ctx) = @_;
  62         my $mid = $ctx->{mid};
  63         my $ibx = $ctx->{-inbox};
  64         my ($first, $more);
  65         my $smsg;
  66         if (my $srch = $ibx->search) {
  67                 my ($id, $prev);
  68                 $smsg = $srch->next_by_mid($mid, \$id, \$prev);
  69                 $first = $ibx->msg_by_smsg($smsg) if $smsg;
  70                 if ($first) {
  71                         my $next = $srch->next_by_mid($mid, \$id, \$prev);
  72                         $more = [ $id, $prev, $next ] if $next;
  73                 }
  74                 return unless $first;
  75         } else {
  76                 $first = $ibx->msg_by_mid($mid) or return;
  77         }
  78         msg_html($ctx, PublicInbox::MIME->new($first), $more, $smsg);
  79 }
  80
  81 sub msg_html_more {
  82         my ($ctx, $more, $nr) = @_;
  83         my $str = eval {
  84                 my ($id, $prev, $smsg) = @$more;
  85                 my $mid = $ctx->{mid};
  86                 my $ibx = $ctx->{-inbox};
  87                 $smsg = $ibx->smsg_mime($smsg);
  88                 my $next = $ctx->{srch}->next_by_mid($mid, \$id, \$prev);
  89                 @$more = $next ? ($id, $prev, $next) : ();
  90                 if ($smsg) {
  91                         my $mime = $smsg->{mime};
  92                         my $upfx = '../' . mid_escape($smsg->mid) . '/';
  93                         _msg_html_prepare($mime->header_obj, $ctx, $more, $nr) .
  94                                 multipart_text_as_html($mime, $upfx, $ctx) .
  95                                 '</pre><hr>'
  96                 } else {
  97                         '';
  98                 }
  99         };
 100         if ($@) {
 101                 warn "Error lookup up additional messages: $@\n";
 102                 $str = '<pre>Error looking up additional messages</pre>';
 103         }
 104         $str;
 105 }
 106
 107 # /$INBOX/$MESSAGE_ID/#R
 108 sub msg_reply {
 109         my ($ctx, $hdr) = @_;
 110         my $se_url =
 111          'https://kernel.org/pub/software/scm/git/docs/git-send-email.html';
 112         my $p_url =
 113          'https://en.wikipedia.org/wiki/Posting_style#Interleaved_style';
 114
 115         my $info = '';
 116         my $ibx = $ctx->{-inbox};
 117         if (my $url = $ibx->{infourl}) {
 118                 $url = PublicInbox::Hval::prurl($ctx->{env}, $url);
 119                 $info = qq(\n  List information: <a\nhref="$url">$url</a>\n);
 120         }
 121
 122         my ($arg, $link, $reply_to_all) =
 123                         PublicInbox::Reply::mailto_arg_link($ibx, $hdr);
 124         if (ref($arg) eq 'SCALAR') {
 125                 return '<pre id=R>'.ascii_html($$arg).'</pre>';
 126         }
 127
 128         # mailto: link only works if address obfuscation is disabled
 129         if ($link) {
 130                 $link = <<EOF;
 131
 132 * If your mail client supports setting the <b>In-Reply-To</b> header
 133   via mailto: links, try the <a
 134 href="$link">mailto: link</a>
 135 EOF
 136         }
 137
 138         push @$arg, '/path/to/YOUR_REPLY';
 139         $arg = ascii_html(join(" \\\n    ", '', @$arg));
 140         <<EOF
 141 <hr><pre
 142 id=R><b>Reply instructions:</b>
 143
 144 You may reply publically to <a
 145 href=#t>this message</a> via plain-text email
 146 using any one of the following methods:
 147
 148 * Save the following mbox file, import it into your mail client,
 149   and $reply_to_all from there: <a
 150 href=raw>mbox</a>
 151
 152   Avoid top-posting and favor interleaved quoting:
 153   <a
 154 href="$p_url">$p_url</a>
 155 $info
 156 * Reply using the <b>--to</b>, <b>--cc</b>, and <b>--in-reply-to</b>
 157   switches of git-send-email(1):
 158
 159   git send-email$arg
 160
 161   <a
 162 href="$se_url">$se_url</a>
 163 $link</pre>
 164 EOF
 165 }
 166
 167 sub in_reply_to {
 168         my ($hdr) = @_;
 169         my $refs = references($hdr);
 170         $refs->[-1];
 171 }
 172
 173 sub fold_addresses ($) {
 174         return $_[0] if length($_[0]) <= COLS;
 175         # try to fold on commas after non-word chars before $lim chars,
 176         # Try to get the "," preceeded by ">" or ")", but avoid folding
 177         # on the comma where somebody uses "Lastname, Firstname".
 178         # We also try to keep the last and penultimate addresses in
 179         # the list on the same line if possible, hence the extra \z
 180         # Fall back to folding on spaces at $lim + 1 chars
 181         my $lim = COLS - 8; # 8 = "\t" display width
 182         my $too_long = $lim + 1;
 183         $_[0] =~ s/\s*\z//s; # Email::Simple doesn't strip trailing spaces
 184         $_[0] = join("\n\t",
 185                 ($_[0] =~ /(.{0,$lim}\W(?:,|\z)|
 186                                 .{1,$lim}(?:,|\z)|
 187                                 .{1,$lim}|
 188                                 .{$too_long,}?)(?:\s|\z)/xgo));
 189 }
 190
 191 sub _hdr_names_html ($$) {
 192         my ($hdr, $field) = @_;
 193         my $val = $hdr->header($field) or return '';
 194         ascii_html(join(', ', PublicInbox::Address::names($val)));
 195 }
 196
 197 sub nr_to_s ($$$) {
 198         my ($nr, $singular, $plural) = @_;
 199         return "0 $plural" if $nr == 0;
 200         $nr == 1 ? "$nr $singular" : "$nr $plural";
 201 }
 202
 203 # this is already inside a <pre>
 204 sub index_entry {
 205         my ($smsg, $ctx, $more) = @_;
 206         my $srch = $ctx->{srch};
 207         my $subj = $smsg->subject;
 208         my $mid_raw = $smsg->mid;
 209         my $id = id_compress($mid_raw, 1);
 210         my $id_m = 'm'.$id;
 211
 212         my $root_anchor = $ctx->{root_anchor} || '';
 213         my $irt;
 214         my $obfs_ibx = $ctx->{-obfs_ibx};
 215
 216         $subj = '(no subject)' if $subj eq '';
 217         my $rv = "<a\nhref=#e$id\nid=m$id>*</a> ";
 218         $subj = '<b>'.ascii_html($subj).'</b>';
 219         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 220         $subj = "<u\nid=u>$subj</u>" if $root_anchor eq $id_m;
 221         $rv .= $subj . "\n";
 222         $rv .= _th_index_lite($mid_raw, \$irt, $id, $ctx);
 223         my @tocc;
 224         my $ds = $smsg->ds; # for v1 non-Xapian/SQLite users
 225         # deleting {mime} is critical to memory use,
 226         # the rest of the fields saves about 400K as we iterate across 1K msgs
 227         my ($mime) = delete @$smsg{qw(mime ds ts blob subject)};
 228
 229         my $hdr = $mime->header_obj;
 230         my $from = _hdr_names_html($hdr, 'From');
 231         obfuscate_addrs($obfs_ibx, $from) if $obfs_ibx;
 232         $rv .= "From: $from @ ".fmt_ts($ds)." UTC";
 233         my $upfx = $ctx->{-upfx};
 234         my $mhref = $upfx . mid_escape($mid_raw) . '/';
 235         $rv .= qq{ (<a\nhref="$mhref">permalink</a> / };
 236         $rv .= qq{<a\nhref="${mhref}raw">raw</a>)\n};
 237         my $to = fold_addresses(_hdr_names_html($hdr, 'To'));
 238         my $cc = fold_addresses(_hdr_names_html($hdr, 'Cc'));
 239         my ($tlen, $clen) = (length($to), length($cc));
 240         my $to_cc = '';
 241         if (($tlen + $clen) > COLS) {
 242                 $to_cc .= '  To: '.$to."\n" if $tlen;
 243                 $to_cc .= '  Cc: '.$cc."\n" if $clen;
 244         } else {
 245                 if ($tlen) {
 246                         $to_cc .= '  To: '.$to;
 247                         $to_cc .= '; <b>+Cc:</b> '.$cc if $clen;
 248                 } else {
 249                         $to_cc .= '  Cc: '.$cc if $clen;
 250                 }
 251                 $to_cc .= "\n";
 252         }
 253         obfuscate_addrs($obfs_ibx, $to_cc) if $obfs_ibx;
 254         $rv .= $to_cc;
 255
 256         my $mapping = $ctx->{mapping};
 257         if (!$mapping && (defined($irt) || defined($irt = in_reply_to($hdr)))) {
 258                 my $mirt = PublicInbox::Hval->new_msgid($irt);
 259                 my $href = $upfx . $mirt->{href}. '/';
 260                 my $html = $mirt->as_html;
 261                 $rv .= qq(In-Reply-To: &lt;<a\nhref="$href">$html</a>&gt;\n)
 262         }
 263         $rv .= "\n";
 264
 265         # scan through all parts, looking for displayable text
 266         my $ibx = $ctx->{-inbox};
 267         msg_iter($mime, sub { $rv .= add_text_body($mhref, $ctx, $_[0]) });
 268
 269         # add the footer
 270         $rv .= "\n<a\nhref=#$id_m\nid=e$id>^</a> ".
 271                 "<a\nhref=\"$mhref\">permalink</a>" .
 272                 " <a\nhref=\"${mhref}raw\">raw</a>" .
 273                 " <a\nhref=\"${mhref}#R\">reply</a>";
 274
 275         my $hr;
 276         if (my $pct = $ctx->{pct}) { # used by SearchView.pm
 277                 $rv .= "\t[relevance $pct->{$mid_raw}%]";
 278                 $hr = 1;
 279         } elsif ($mapping) {
 280                 my $nested = 'nested';
 281                 my $flat = 'flat';
 282                 my $end = '';
 283                 if ($ctx->{flat}) {
 284                         $hr = 1;
 285                         $flat = "<b>$flat</b>";
 286                 } else {
 287                         $nested = "<b>$nested</b>";
 288                 }
 289                 $rv .= "\t[<a\nhref=\"${mhref}T/#u\">$flat</a>";
 290                 $rv .= "|<a\nhref=\"${mhref}t/#u\">$nested</a>]";
 291                 $rv .= " <a\nhref=#r$id>$ctx->{s_nr}</a>";
 292         } else {
 293                 $hr = $ctx->{-hr};
 294         }
 295
 296         $rv .= $more ? '</pre><hr><pre>' : '</pre>' if $hr;
 297         $rv;
 298 }
 299
 300 sub pad_link ($$;$) {
 301         my ($mid, $level, $s) = @_;
 302         $s ||= '...';
 303         my $id = id_compress($mid, 1);
 304         (' 'x19).indent_for($level).th_pfx($level)."<a\nhref=#r$id>($s)</a>\n";
 305 }
 306
 307 sub _th_index_lite {
 308         my ($mid_raw, $irt, $id, $ctx) = @_;
 309         my $rv = '';
 310         my $mapping = $ctx->{mapping} or return $rv;
 311         my $pad = '  ';
 312         my $mid_map = $mapping->{$mid_raw};
 313         defined $mid_map or
 314                 return 'public-inbox BUG: '.ascii_html($mid_raw).' not mapped';
 315         my ($attr, $node, $idx, $level) = @$mid_map;
 316         my $children = $node->{children};
 317         my $nr_c = scalar @$children;
 318         my $nr_s = 0;
 319         my $siblings;
 320         if (my $smsg = $node->{smsg}) {
 321                 # delete saves about 200KB on a 1K message thread
 322                 if (my $refs = delete $smsg->{references}) {
 323                         ($$irt) = ($refs =~ m/<([^>]+)>\z/);
 324                 }
 325         }
 326         my $irt_map = $mapping->{$$irt} if defined $$irt;
 327         if (defined $irt_map) {
 328                 $siblings = $irt_map->[1]->{children};
 329                 $nr_s = scalar(@$siblings) - 1;
 330                 $rv .= $pad . $irt_map->[0];
 331                 if ($idx > 0) {
 332                         my $prev = $siblings->[$idx - 1];
 333                         my $pmid = $prev->{id};
 334                         if ($idx > 2) {
 335                                 my $s = ($idx - 1). ' preceding siblings ...';
 336                                 $rv .= pad_link($pmid, $level, $s);
 337                         } elsif ($idx == 2) {
 338                                 my $ppmid = $siblings->[0]->{id};
 339                                 $rv .= $pad . $mapping->{$ppmid}->[0];
 340                         }
 341                         $rv .= $pad . $mapping->{$pmid}->[0];
 342                 }
 343         }
 344         my $s_s = nr_to_s($nr_s, 'sibling', 'siblings');
 345         my $s_c = nr_to_s($nr_c, 'reply', 'replies');
 346         $attr =~ s!\n\z!</b>\n!s;
 347         $attr =~ s!<a\nhref.*</a> !!s; # no point in duplicating subject
 348         $attr =~ s!<a\nhref=[^>]+>([^<]+)</a>!$1!s; # no point linking to self
 349         $rv .= "<b>@ $attr";
 350         if ($nr_c) {
 351                 my $cmid = $children->[0]->{id};
 352                 $rv .= $pad . $mapping->{$cmid}->[0];
 353                 if ($nr_c > 2) {
 354                         my $s = ($nr_c - 1). ' more replies';
 355                         $rv .= pad_link($cmid, $level + 1, $s);
 356                 } elsif (my $cn = $children->[1]) {
 357                         $rv .= $pad . $mapping->{$cn->{id}}->[0];
 358                 }
 359         }
 360
 361         my $next = $siblings->[$idx+1] if $siblings && $idx >= 0;
 362         if ($next) {
 363                 my $nmid = $next->{id};
 364                 $rv .= $pad . $mapping->{$nmid}->[0];
 365                 my $nnext = $nr_s - $idx;
 366                 if ($nnext > 2) {
 367                         my $s = ($nnext - 1).' subsequent siblings';
 368                         $rv .= pad_link($nmid, $level, $s);
 369                 } elsif (my $nn = $siblings->[$idx + 2]) {
 370                         $rv .= $pad . $mapping->{$nn->{id}}->[0];
 371                 }
 372         }
 373         $rv .= $pad ."<a\nhref=#r$id>$s_s, $s_c; $ctx->{s_nr}</a>\n";
 374 }
 375
 376 sub walk_thread {
 377         my ($rootset, $ctx, $cb) = @_;
 378         my @q = map { (0, $_, -1) } @$rootset;
 379         while (@q) {
 380                 my ($level, $node, $i) = splice(@q, 0, 3);
 381                 defined $node or next;
 382                 $cb->($ctx, $level, $node, $i) or return;
 383                 ++$level;
 384                 $i = 0;
 385                 unshift @q, map { ($level, $_, $i++) } @{$node->{children}};
 386         }
 387 }
 388
 389 sub pre_thread  {
 390         my ($ctx, $level, $node, $idx) = @_;
 391         $ctx->{mapping}->{$node->{id}} = [ '', $node, $idx, $level ];
 392         skel_dump($ctx, $level, $node);
 393 }
 394
 395 sub thread_index_entry {
 396         my ($ctx, $level, $smsg) = @_;
 397         my ($beg, $end) = thread_adj_level($ctx, $level);
 398         $beg . '<pre>' . index_entry($smsg, $ctx, 0) . '</pre>' . $end;
 399 }
 400
 401 sub stream_thread ($$) {
 402         my ($rootset, $ctx) = @_;
 403         my $ibx = $ctx->{-inbox};
 404         my @q = map { (0, $_) } @$rootset;
 405         my $level;
 406         my $smsg;
 407         while (@q) {
 408                 $level = shift @q;
 409                 my $node = shift @q or next;
 410                 my $cl = $level + 1;
 411                 unshift @q, map { ($cl, $_) } @{$node->{children}};
 412                 $smsg = $ibx->smsg_mime($node->{smsg}) and last;
 413         }
 414         return missing_thread($ctx) unless $smsg;
 415
 416         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 417         $ctx->{-title_html} = ascii_html($smsg->subject);
 418         $ctx->{-html_tip} = thread_index_entry($ctx, $level, $smsg);
 419         $smsg = undef;
 420         PublicInbox::WwwStream->response($ctx, 200, sub {
 421                 return unless $ctx;
 422                 while (@q) {
 423                         $level = shift @q;
 424                         my $node = shift @q or next;
 425                         my $cl = $level + 1;
 426                         unshift @q, map { ($cl, $_) } @{$node->{children}};
 427                         if ($smsg = $ibx->smsg_mime($node->{smsg})) {
 428                                 return thread_index_entry($ctx, $level, $smsg);
 429                         } else {
 430                                 return ghost_index_entry($ctx, $level, $node);
 431                         }
 432                 }
 433                 my $ret = join('', thread_adj_level($ctx, 0));
 434                 $ret .= ${$ctx->{dst}}; # skel
 435                 $ctx = undef;
 436                 $ret;
 437         });
 438 }
 439
 440 sub thread_html {
 441         my ($ctx) = @_;
 442         my $mid = $ctx->{mid};
 443         my $srch = $ctx->{srch};
 444         my ($nr, $msgs) = $srch->get_thread($mid);
 445         return missing_thread($ctx) if $nr == 0;
 446         my $skel = '<hr><pre>';
 447         $skel .= $nr == 1 ? 'only message in thread' : 'end of thread';
 448         $skel .= ", back to <a\nhref=\"../../\">index</a>\n\n";
 449         $skel .= "<b\nid=t>Thread overview:</b> ";
 450         $skel .= $nr == 1 ? '(only message)' : "$nr+ messages";
 451         $skel .= " (download: <a\nhref=\"../t.mbox.gz\">mbox.gz</a>";
 452         $skel .= " / follow: <a\nhref=\"../t.atom\">Atom feed</a>)\n";
 453         $skel .= "-- links below jump to the message on this page --\n";
 454         $ctx->{-upfx} = '../../';
 455         $ctx->{cur_level} = 0;
 456         $ctx->{dst} = \$skel;
 457         $ctx->{prev_attr} = '';
 458         $ctx->{prev_level} = 0;
 459         $ctx->{root_anchor} = anchor_for($mid);
 460         $ctx->{mapping} = {};
 461         $ctx->{s_nr} = "$nr+ messages in thread";
 462
 463         my $rootset = thread_results($ctx, $msgs);
 464
 465         # reduce hash lookups in pre_thread->skel_dump
 466         my $ibx = $ctx->{-inbox};
 467         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 468         walk_thread($rootset, $ctx, *pre_thread);
 469
 470         $skel .= '</pre>';
 471         return stream_thread($rootset, $ctx) unless $ctx->{flat};
 472
 473         # flat display: lazy load the full message from smsg
 474         my $smsg;
 475         while (my $m = shift @$msgs) {
 476                 $smsg = $ibx->smsg_mime($m) and last;
 477         }
 478         return missing_thread($ctx) unless $smsg;
 479         $ctx->{-title_html} = ascii_html($smsg->subject);
 480         $ctx->{-html_tip} = '<pre>'.index_entry($smsg, $ctx, scalar @$msgs);
 481         $smsg = undef;
 482         PublicInbox::WwwStream->response($ctx, 200, sub {
 483                 return unless $msgs;
 484                 $smsg = undef;
 485                 while (my $m = shift @$msgs) {
 486                         $smsg = $ibx->smsg_mime($m) and last;
 487                 }
 488                 return index_entry($smsg, $ctx, scalar @$msgs) if $smsg;
 489                 $msgs = undef;
 490                 $skel;
 491         });
 492 }
 493
 494 sub multipart_text_as_html {
 495         my ($mime, $upfx, $ctx) = @_;
 496         my $rv = "";
 497
 498         # scan through all parts, looking for displayable text
 499         msg_iter($mime, sub { $rv .= add_text_body($upfx, $ctx, $_[0]) });
 500         $rv;
 501 }
 502
 503 sub flush_quote {
 504         my ($s, $l, $quot) = @_;
 505
 506         # show everything in the full version with anchor from
 507         # short version (see above)
 508         my $rv = $l->linkify_1($$quot);
 509
 510         # we use a <span> here to allow users to specify their own
 511         # color for quoted text
 512         $rv = $l->linkify_2(ascii_html($rv));
 513         $$quot = undef;
 514         $$s .= qq(<span\nclass="q">) . $rv . '</span>'
 515 }
 516
 517 sub attach_link ($$$$;$) {
 518         my ($upfx, $ct, $p, $fn, $err) = @_;
 519         my ($part, $depth, @idx) = @$p;
 520         my $nl = $idx[-1] > 1 ? "\n" : '';
 521         my $idx = join('.', @idx);
 522         my $size = bytes::length($part->body);
 523
 524         # hide attributes normally, unless we want to aid users in
 525         # spotting MUA problems:
 526         $ct =~ s/;.*// unless $err;
 527         $ct = ascii_html($ct);
 528         my $desc = $part->header('Content-Description');
 529         $desc = $fn unless defined $desc;
 530         $desc = '' unless defined $desc;
 531         my $sfn;
 532         if (defined $fn && $fn =~ /\A[[:alnum:]][\w\.-]+[[:alnum:]]\z/) {
 533                 $sfn = $fn;
 534         } elsif ($ct eq 'text/plain') {
 535                 $sfn = 'a.txt';
 536         } else {
 537                 $sfn = 'a.bin';
 538         }
 539         my $ret = qq($nl<a\nhref="$upfx$idx-$sfn">);
 540         if ($err) {
 541                 $ret .=
 542 "[-- Warning: decoded text below may be mangled --]\n";
 543         }
 544         $ret .= "[-- Attachment #$idx: ";
 545         my $ts = "Type: $ct, Size: $size bytes";
 546         $desc = ascii_html($desc);
 547         $ret .= ($desc eq '') ? "$ts --]" : "$desc --]\n[-- $ts --]";
 548         $ret .= "</a>\n";
 549 }
 550
 551 sub add_text_body {
 552         my ($upfx, $ctx, $p) = @_;
 553         my $ibx = $ctx->{-inbox};
 554         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 555         # $p - from msg_iter: [ Email::MIME, depth, @idx ]
 556         my ($part, $depth, @idx) = @$p;
 557         my $ct = $part->content_type || 'text/plain';
 558         my $fn = $part->filename;
 559         my ($s, $err) = msg_part_text($part, $ct);
 560
 561         return attach_link($upfx, $ct, $p, $fn) unless defined $s;
 562
 563         # makes no difference to browsers, and don't screw up filename
 564         # link generation in diffs with the extra '%0D'
 565         $s =~ s/\r\n/\n/sg;
 566
 567         # always support diff-highlighting, but we can't linkify hunk
 568         # headers for solver unless some coderepo are configured:
 569         my $diff;
 570         if ($s =~ /^(?:diff|---|\+{3}) /ms) {
 571                 # diffstat anchors do not link across attachments or messages:
 572                 $idx[0] = $upfx . $idx[0] if $upfx ne '';
 573                 $ctx->{-apfx} = join('/', @idx);
 574                 $ctx->{-anchors} = {}; # attr => filename
 575                 $ctx->{-diff} = $diff = [];
 576                 delete $ctx->{-long_path};
 577                 my $spfx;
 578                 if ($ibx->{-repo_objs}) {
 579                         if (index($upfx, '//') >= 0) { # absolute URL (Atom feeds)
 580                                 $spfx = $upfx;
 581                                 $spfx =~ s!/([^/]*)/\z!/!;
 582                         } else {
 583                                 my $n_slash = $upfx =~ tr!/!/!;
 584                                 if ($n_slash == 0) {
 585                                         $spfx = '../';
 586                                 } elsif ($n_slash == 1) {
 587                                         $spfx = '';
 588                                 } else { # nslash == 2
 589                                         $spfx = '../../';
 590                                 }
 591                         }
 592                 }
 593                 $ctx->{-spfx} = $spfx;
 594         };
 595
 596         # some editors don't put trailing newlines at the end:
 597         $s .= "\n" unless $s =~ /\n\z/s;
 598
 599         # split off quoted and unquoted blocks:
 600         my @sections = split(/((?:^>[^\n]*\n)+)/sm, $s);
 601         $s = '';
 602         if (defined($fn) || $depth > 0 || $err) {
 603                 # badly-encoded message with $err? tell the world about it!
 604                 $s .= attach_link($upfx, $ct, $p, $fn, $err);
 605                 $s .= "\n";
 606         }
 607         my $l = PublicInbox::Linkify->new;
 608         foreach my $cur (@sections) {
 609                 if ($cur =~ /\A>/) {
 610                         flush_quote(\$s, $l, \$cur);
 611                 } elsif ($diff) {
 612                         @$diff = split(/^/m, $cur);
 613                         $cur = undef;
 614                         flush_diff(\$s, $ctx, $l);
 615                 } else {
 616                         # regular lines, OK
 617                         $l->linkify_1($cur);
 618                         $s .= $l->linkify_2(ascii_html($cur));
 619                         $cur = undef;
 620                 }
 621         }
 622
 623         obfuscate_addrs($obfs_ibx, $s) if $obfs_ibx;
 624         $s;
 625 }
 626
 627 sub _msg_html_prepare {
 628         my ($hdr, $ctx, $more, $nr) = @_;
 629         my $srch = $ctx->{srch} if $ctx;
 630         my $atom = '';
 631         my $obfs_ibx = $ctx->{-obfs_ibx};
 632         my $rv = '';
 633         my $mids = mids($hdr);
 634         my $multiple = scalar(@$mids) > 1; # zero, one, infinity
 635         if ($nr == 0) {
 636                 if ($more) {
 637                         $rv .=
 638 "<pre>WARNING: multiple messages refer to this Message-ID\n</pre>";
 639                 }
 640                 $rv .= "<pre\nid=b>"; # anchor for body start
 641         } else {
 642                 $rv .= '<pre>';
 643         }
 644         if ($srch) {
 645                 $ctx->{-upfx} = '../';
 646         }
 647         my @title;
 648         my $v;
 649         if (defined($v = $hdr->header('From'))) {
 650                 $v = PublicInbox::Hval->new($v);
 651                 my @n = PublicInbox::Address::names($v->raw);
 652                 $title[1] = ascii_html(join(', ', @n));
 653                 $v = $v->as_html;
 654                 if ($obfs_ibx) {
 655                         obfuscate_addrs($obfs_ibx, $v);
 656                         obfuscate_addrs($obfs_ibx, $title[1]);
 657                 }
 658                 $rv .= "From: $v\n" if $v ne '';
 659         }
 660         foreach my $h (qw(To Cc)) {
 661                 defined($v = $hdr->header($h)) or next;
 662                 fold_addresses($v);
 663                 $v = ascii_html($v);
 664                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 665                 $rv .= "$h: $v\n" if $v ne '';
 666         }
 667         if (defined($v = $hdr->header('Subject')) && ($v ne '')) {
 668                 $v = ascii_html($v);
 669                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx;
 670                 if ($srch) {
 671                         $rv .= qq(Subject: <a\nhref="#r"\nid=t>$v</a>\n);
 672                 } else {
 673                         $rv .= "Subject: $v\n";
 674                 }
 675                 $title[0] = $v;
 676         } else { # dummy anchor for thread skeleton at bottom of page
 677                 $rv .= qq(<a\nhref="#r"\nid=t></a>) if $srch;
 678                 $title[0] = '(no subject)';
 679         }
 680         if (defined($v = $hdr->header('Date'))) {
 681                 $v = ascii_html($v);
 682                 obfuscate_addrs($obfs_ibx, $v) if $obfs_ibx; # possible :P
 683                 $rv .= "Date: $v\n";
 684         }
 685         $ctx->{-title_html} = join(' - ', @title);
 686         foreach (@$mids) {
 687                 my $mid = PublicInbox::Hval->new_msgid($_) ;
 688                 my $mhtml = $mid->as_html;
 689                 if ($multiple) {
 690                         my $href = $mid->{href};
 691                         $rv .= "Message-ID: ";
 692                         $rv .= "<a\nhref=\"../$href/\">";
 693                         $rv .= "&lt;$mhtml&gt;</a> ";
 694                         $rv .= "(<a\nhref=\"../$href/raw\">raw</a>)\n";
 695                 } else {
 696                         $rv .= "Message-ID: &lt;$mhtml&gt; ";
 697                         $rv .= "(<a\nhref=\"raw\">raw</a>)\n";
 698                 }
 699         }
 700         $rv .= _parent_headers($hdr, $srch);
 701         $rv .= "\n";
 702 }
 703
 704 sub thread_skel {
 705         my ($dst, $ctx, $hdr, $tpfx) = @_;
 706         my $srch = $ctx->{srch};
 707         my $mid = mids($hdr)->[0];
 708         my ($nr, $msgs) = $srch->get_thread($mid);
 709         my $expand = qq(expand[<a\nhref="${tpfx}T/#u">flat</a>) .
 710                         qq(|<a\nhref="${tpfx}t/#u">nested</a>]  ) .
 711                         qq(<a\nhref="${tpfx}t.mbox.gz">mbox.gz</a>  ) .
 712                         qq(<a\nhref="${tpfx}t.atom">Atom feed</a>);
 713
 714         my $parent = in_reply_to($hdr);
 715         $$dst .= "\n<b>Thread overview: </b>";
 716         if ($nr <= 1) {
 717                 if (defined $parent) {
 718                         $$dst .= "$expand\n ";
 719                         $$dst .= ghost_parent("$tpfx../", $parent) . "\n";
 720                 } else {
 721                         $$dst .= "[no followups] $expand\n";
 722                 }
 723                 $ctx->{next_msg} = undef;
 724                 $ctx->{parent_msg} = $parent;
 725                 return;
 726         }
 727
 728         $$dst .= "$nr+ messages / $expand";
 729         $$dst .= qq!  <a\nhref="#b">top</a>\n!;
 730
 731         my $subj = $hdr->header('Subject');
 732         defined $subj or $subj = '';
 733         $subj = '(no subject)' if $subj eq '';
 734         $ctx->{prev_subj} = [ split(/ /, $srch->subject_normalized($subj)) ];
 735         $ctx->{cur} = $mid;
 736         $ctx->{prev_attr} = '';
 737         $ctx->{prev_level} = 0;
 738         $ctx->{dst} = $dst;
 739
 740         # reduce hash lookups in skel_dump
 741         my $ibx = $ctx->{-inbox};
 742         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 743         walk_thread(thread_results($ctx, $msgs), $ctx, *skel_dump);
 744
 745         $ctx->{parent_msg} = $parent;
 746 }
 747
 748 sub _parent_headers {
 749         my ($hdr, $srch) = @_;
 750         my $rv = '';
 751
 752         my $refs = references($hdr);
 753         my $irt = pop @$refs;
 754         if (defined $irt) {
 755                 my $v = PublicInbox::Hval->new_msgid($irt);
 756                 my $html = $v->as_html;
 757                 my $href = $v->{href};
 758                 $rv .= "In-Reply-To: &lt;";
 759                 $rv .= "<a\nhref=\"../$href/\">$html</a>&gt;\n";
 760         }
 761
 762         # do not display References: if search is present,
 763         # we show the thread skeleton at the bottom, instead.
 764         return $rv if $srch;
 765
 766         if (@$refs) {
 767                 @$refs = map { linkify_ref_nosrch($_) } @$refs;
 768                 $rv .= 'References: '. join("\n\t", @$refs) . "\n";
 769         }
 770         $rv;
 771 }
 772
 773 sub html_footer {
 774         my ($hdr, $standalone, $ctx, $rhref) = @_;
 775
 776         my $srch = $ctx->{srch} if $ctx;
 777         my $upfx = '../';
 778         my $tpfx = '';
 779         my $idx = $standalone ? " <a\nhref=\"$upfx\">index</a>" : '';
 780         my $irt = '';
 781         if ($idx && $srch) {
 782                 $idx .= "\n";
 783                 thread_skel(\$idx, $ctx, $hdr, $tpfx);
 784                 my ($next, $prev);
 785                 my $parent = '       ';
 786                 $next = $prev = '    ';
 787
 788                 if (my $n = $ctx->{next_msg}) {
 789                         $n = PublicInbox::Hval->new_msgid($n)->{href};
 790                         $next = "<a\nhref=\"$upfx$n/\"\nrel=next>next</a>";
 791                 }
 792                 my $u;
 793                 my $par = $ctx->{parent_msg};
 794                 if ($par) {
 795                         $u = PublicInbox::Hval->new_msgid($par)->{href};
 796                         $u = "$upfx$u/";
 797                 }
 798                 if (my $p = $ctx->{prev_msg}) {
 799                         $prev = PublicInbox::Hval->new_msgid($p)->{href};
 800                         if ($p && $par && $p eq $par) {
 801                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 802                                         'rel=prev>prev parent</a>';
 803                                 $parent = '';
 804                         } else {
 805                                 $prev = "<a\nhref=\"$upfx$prev/\"\n" .
 806                                         'rel=prev>prev</a>';
 807                                 $parent = " <a\nhref=\"$u\">parent</a>" if $u;
 808                         }
 809                 } elsif ($u) { # unlikely
 810                         $parent = " <a\nhref=\"$u\"\nrel=prev>parent</a>";
 811                 }
 812                 $irt = "$next $prev$parent ";
 813         } else {
 814                 $irt = '';
 815         }
 816         $rhref ||= '#R';
 817         $irt .= qq(<a\nhref="$rhref">reply</a>);
 818         $irt .= $idx;
 819 }
 820
 821 sub linkify_ref_nosrch {
 822         my $v = PublicInbox::Hval->new_msgid($_[0]);
 823         my $html = $v->as_html;
 824         my $href = $v->{href};
 825         "&lt;<a\nhref=\"../$href/\">$html</a>&gt;";
 826 }
 827
 828 sub anchor_for {
 829         my ($msgid) = @_;
 830         'm' . id_compress($msgid, 1);
 831 }
 832
 833 sub ghost_parent {
 834         my ($upfx, $mid) = @_;
 835
 836         $mid = PublicInbox::Hval->new_msgid($mid);
 837         my $href = $mid->{href};
 838         my $html = $mid->as_html;
 839         qq{[parent not found: &lt;<a\nhref="$upfx$href/">$html</a>&gt;]};
 840 }
 841
 842 sub indent_for {
 843         my ($level) = @_;
 844         $level ? INDENT x ($level - 1) : '';
 845 }
 846
 847 sub find_mid_root {
 848         my ($ctx, $level, $node, $idx) = @_;
 849         ++$ctx->{root_idx} if $level == 0;
 850         if ($node->{id} eq $ctx->{mid}) {
 851                 $ctx->{found_mid_at} = $ctx->{root_idx};
 852                 return 0;
 853         }
 854         1;
 855 }
 856
 857 sub strict_loose_note ($) {
 858         my ($nr) = @_;
 859         my $msg =
 860 "  -- strict thread matches above, loose matches on Subject: below --\n";
 861
 862         if ($nr > PublicInbox::Over::DEFAULT_LIMIT()) {
 863                 $msg .=
 864 "  -- use mbox.gz link to download all $nr messages --\n";
 865         }
 866         $msg;
 867 }
 868
 869 sub thread_results {
 870         my ($ctx, $msgs) = @_;
 871         require PublicInbox::SearchThread;
 872         my $ibx = $ctx->{-inbox};
 873         my $rootset = PublicInbox::SearchThread::thread($msgs, *sort_ds, $ibx);
 874
 875         # FIXME: `tid' is broken on --reindex, so that needs to be fixed
 876         # and preserved in the future.  This bug is hidden by `sid' matches
 877         # in get_thread, so we never noticed it until now.  And even when
 878         # reindexing is fixed, we'll keep this code until a SCHEMA_VERSION
 879         # bump since reindexing is expensive and users may not do it
 880
 881         # loose threading could've returned too many results,
 882         # put the root the message we care about at the top:
 883         my $mid = $ctx->{mid};
 884         if (defined($mid) && scalar(@$rootset) > 1) {
 885                 $ctx->{root_idx} = -1;
 886                 my $nr = scalar @$msgs;
 887                 walk_thread($rootset, $ctx, *find_mid_root);
 888                 my $idx = $ctx->{found_mid_at};
 889                 if (defined($idx) && $idx != 0) {
 890                         my $tip = splice(@$rootset, $idx, 1);
 891                         @$rootset = reverse @$rootset;
 892                         unshift @$rootset, $tip;
 893                         $ctx->{sl_note} = strict_loose_note($nr);
 894                 }
 895         }
 896         $rootset
 897 }
 898
 899 sub missing_thread {
 900         my ($ctx) = @_;
 901         require PublicInbox::ExtMsg;
 902         PublicInbox::ExtMsg::ext_msg($ctx);
 903 }
 904
 905 sub fmt_ts { POSIX::strftime('%Y-%m-%d %k:%M', gmtime($_[0])) }
 906
 907 sub dedupe_subject {
 908         my ($prev_subj, $subj, $val) = @_;
 909
 910         my $omit = ''; # '"' denotes identical text omitted
 911         my (@prev_pop, @curr_pop);
 912         while (@$prev_subj && @$subj && $subj->[-1] eq $prev_subj->[-1]) {
 913                 push(@prev_pop, pop(@$prev_subj));
 914                 push(@curr_pop, pop(@$subj));
 915                 $omit ||= $val;
 916         }
 917         pop @$subj if @$subj && $subj->[-1] =~ /^re:\s*/i;
 918         if (scalar(@curr_pop) == 1) {
 919                 $omit = '';
 920                 push @$prev_subj, @prev_pop;
 921                 push @$subj, @curr_pop;
 922         }
 923         $omit;
 924 }
 925
 926 sub skel_dump {
 927         my ($ctx, $level, $node) = @_;
 928         my $smsg = $node->{smsg} or return _skel_ghost($ctx, $level, $node);
 929
 930         my $dst = $ctx->{dst};
 931         my $cur = $ctx->{cur};
 932         my $mid = $smsg->{mid};
 933
 934         if ($level == 0 && $ctx->{skel_dump_roots}++) {
 935                 $$dst .= delete $ctx->{sl_note} || '';
 936         }
 937
 938         my $f = ascii_html($smsg->from_name);
 939         my $obfs_ibx = $ctx->{-obfs_ibx};
 940         obfuscate_addrs($obfs_ibx, $f) if $obfs_ibx;
 941
 942         my $d = fmt_ts($smsg->{ds}) . ' ' . indent_for($level) . th_pfx($level);
 943         my $attr = $f;
 944         $ctx->{first_level} ||= $level;
 945
 946         if ($attr ne $ctx->{prev_attr} || $ctx->{prev_level} > $level) {
 947                 $ctx->{prev_attr} = $attr;
 948         }
 949         $ctx->{prev_level} = $level;
 950
 951         if ($cur) {
 952                 if ($cur eq $mid) {
 953                         delete $ctx->{cur};
 954                         $$dst .= "<b>$d<a\nid=r\nhref=\"#t\">".
 955                                  "$attr [this message]</a></b>\n";
 956                         return 1;
 957                 } else {
 958                         $ctx->{prev_msg} = $mid;
 959                 }
 960         } else {
 961                 $ctx->{next_msg} ||= $mid;
 962         }
 963
 964         # Subject is never undef, this mail was loaded from
 965         # our Xapian which would've resulted in '' if it were
 966         # really missing (and Filter rejects empty subjects)
 967         my @subj = split(/ /, $ctx->{srch}->subject_normalized($smsg->subject));
 968
 969         # remove common suffixes from the subject if it matches the previous,
 970         # so we do not show redundant text at the end.
 971         my $prev_subj = $ctx->{prev_subj} || [];
 972         $ctx->{prev_subj} = [ @subj ];
 973         my $omit = dedupe_subject($prev_subj, \@subj, '&#34; ');
 974         my $end;
 975         if (@subj) {
 976                 my $subj = join(' ', @subj);
 977                 $subj = ascii_html($subj);
 978                 obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
 979                 $end = "$subj</a> $omit$f\n"
 980         } else {
 981                 $end = "$f</a>\n";
 982         }
 983         my $m;
 984         my $id = '';
 985         my $mapping = $ctx->{mapping};
 986         if ($mapping) {
 987                 my $map = $mapping->{$mid};
 988                 $id = id_compress($mid, 1);
 989                 $m = '#m'.$id;
 990                 $map->[0] = "$d<a\nhref=\"$m\">$end";
 991                 $id = "\nid=r".$id;
 992         } else {
 993                 $m = $ctx->{-upfx}.mid_escape($mid).'/';
 994         }
 995         $$dst .=  $d . "<a\nhref=\"$m\"$id>" . $end;
 996         1;
 997 }
 998
 999 sub _skel_ghost {
1000         my ($ctx, $level, $node) = @_;
1001
1002         my $mid = $node->{id};
1003         my $d = $ctx->{pct} ? '    [irrelevant] ' # search result
1004                             : '     [not found] ';
1005         $d .= indent_for($level) . th_pfx($level);
1006         my $upfx = $ctx->{-upfx};
1007         my $m = PublicInbox::Hval->new_msgid($mid);
1008         my $href = $upfx . $m->{href} . '/';
1009         my $html = $m->as_html;
1010
1011         my $mapping = $ctx->{mapping};
1012         my $map = $mapping->{$mid} if $mapping;
1013         if ($map) {
1014                 my $id = id_compress($mid, 1);
1015                 $map->[0] = $d . qq{&lt;<a\nhref=#r$id>$html</a>&gt;\n};
1016                 $d .= qq{&lt;<a\nhref="$href"\nid=r$id>$html</a>&gt;\n};
1017         } else {
1018                 $d .= qq{&lt;<a\nhref="$href">$html</a>&gt;\n};
1019         }
1020         my $dst = $ctx->{dst};
1021         $$dst .= $d;
1022         1;
1023 }
1024
1025 sub sort_ds {
1026         [ sort {
1027                 (eval { $a->topmost->{smsg}->ds } || 0) <=>
1028                 (eval { $b->topmost->{smsg}->ds } || 0)
1029         } @{$_[0]} ];
1030 }
1031
1032 # accumulate recent topics if search is supported
1033 # returns 200 if done, 404 if not
1034 sub acc_topic {
1035         my ($ctx, $level, $node) = @_;
1036         my $srch = $ctx->{srch};
1037         my $mid = $node->{id};
1038         my $x = $node->{smsg} || $ctx->{-inbox}->smsg_by_mid($mid);
1039         my ($subj, $ds);
1040         my $topic;
1041         if ($x) {
1042                 $subj = $x->subject;
1043                 $subj = $srch->subject_normalized($subj);
1044                 $subj = '(no subject)' if $subj eq '';
1045                 $ds = $x->ds;
1046                 if ($level == 0) {
1047                         $topic = [ $ds, 1, { $subj => $mid }, $subj ];
1048                         $ctx->{-cur_topic} = $topic;
1049                         push @{$ctx->{order}}, $topic;
1050                         return 1;
1051                 }
1052
1053                 $topic = $ctx->{-cur_topic}; # should never be undef
1054                 $topic->[0] = $ds if $ds > $topic->[0];
1055                 $topic->[1]++;
1056                 my $seen = $topic->[2];
1057                 if (scalar(@$topic) == 3) { # parent was a ghost
1058                         push @$topic, $subj;
1059                 } elsif (!$seen->{$subj}) {
1060                         push @$topic, $level, $subj;
1061                 }
1062                 $seen->{$subj} = $mid; # latest for subject
1063         } else { # ghost message
1064                 return 1 if $level != 0; # ignore child ghosts
1065                 $topic = [ -666, 0, {} ];
1066                 $ctx->{-cur_topic} = $topic;
1067                 push @{$ctx->{order}}, $topic;
1068         }
1069         1;
1070 }
1071
1072 sub dump_topics {
1073         my ($ctx) = @_;
1074         my $order = delete $ctx->{order}; # [ ds, subj1, subj2, subj3, ... ]
1075         if (!@$order) {
1076                 $ctx->{-html_tip} = '<pre>[No topics in range]</pre>';
1077                 return 404;
1078         }
1079
1080         my @out;
1081         my $ibx = $ctx->{-inbox};
1082         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
1083         my $srch = $ctx->{srch};
1084
1085         # sort by recency, this allows new posts to "bump" old topics...
1086         foreach my $topic (sort { $b->[0] <=> $a->[0] } @$order) {
1087                 my ($ds, $n, $seen, $top, @ex) = @$topic;
1088                 @$topic = ();
1089                 next unless defined $top;  # ghost topic
1090                 my $mid = delete $seen->{$top};
1091                 my $href = mid_escape($mid);
1092                 my $prev_subj = [ split(/ /, $top) ];
1093                 $top = PublicInbox::Hval->new($top)->as_html;
1094                 $ds = fmt_ts($ds);
1095
1096                 # $n isn't the total number of posts on the topic,
1097                 # just the number of posts in the current results window
1098                 my $anchor;
1099                 if ($n == 1) {
1100                         $n = '';
1101                         $anchor = '#u'; # top of only message
1102                 } else {
1103                         $n = " ($n+ messages)";
1104                         $anchor = '#t'; # thread skeleton
1105                 }
1106
1107                 my $mbox = qq(<a\nhref="$href/t.mbox.gz">mbox.gz</a>);
1108                 my $atom = qq(<a\nhref="$href/t.atom">Atom</a>);
1109                 my $s = "<a\nhref=\"$href/T/$anchor\">$top</a>\n" .
1110                         " $ds UTC $n - $mbox / $atom\n";
1111                 for (my $i = 0; $i < scalar(@ex); $i += 2) {
1112                         my $level = $ex[$i];
1113                         my $subj = $ex[$i + 1];
1114                         $mid = delete $seen->{$subj};
1115                         my @subj = split(/ /, $srch->subject_normalized($subj));
1116                         my @next_prev = @subj; # full copy
1117                         my $omit = dedupe_subject($prev_subj, \@subj, ' &#34;');
1118                         $prev_subj = \@next_prev;
1119                         $subj = ascii_html(join(' ', @subj));
1120                         obfuscate_addrs($obfs_ibx, $subj) if $obfs_ibx;
1121                         $href = mid_escape($mid);
1122                         $s .= indent_for($level) . TCHILD;
1123                         $s .= "<a\nhref=\"$href/T/#u\">$subj</a>$omit\n";
1124                 }
1125                 push @out, $s;
1126         }
1127         $ctx->{-html_tip} = '<pre>' . join("\n", @out) . '</pre>';
1128         200;
1129 }
1130
1131 sub ts2str ($) {
1132         my ($ts) = @_;
1133         POSIX::strftime('%Y%m%d%H%M%S', gmtime($ts));
1134 }
1135
1136 sub str2ts ($) {
1137         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $_[0]);
1138         timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
1139 }
1140
1141 sub pagination_footer ($$) {
1142         my ($ctx, $latest) = @_;
1143         delete $ctx->{qp} or return;
1144         my $next = $ctx->{next_page} || '';
1145         my $prev = $ctx->{prev_page} || '';
1146         if ($prev) {
1147                 $next = $next ? "$next " : '     ';
1148                 $prev .= qq! <a\nhref='$latest'>latest</a>!;
1149         }
1150         "<hr><pre>page: $next$prev</pre>";
1151 }
1152
1153 sub index_nav { # callback for WwwStream
1154         my (undef, $ctx) = @_;
1155         pagination_footer($ctx, '.')
1156 }
1157
1158 sub paginate_recent ($$) {
1159         my ($ctx, $lim) = @_;
1160         my $t = $ctx->{qp}->{t} || '';
1161         my $opts = { limit => $lim };
1162         my ($after, $before);
1163
1164         # Xapian uses '..' but '-' is perhaps friendier to URL linkifiers
1165         # if only $after exists "YYYYMMDD.." because "." could be skipped
1166         # if interpreted as an end-of-sentence
1167         $t =~ s/\A(\d{8,14})-// and $after = str2ts($1);
1168         $t =~ /\A(\d{8,14})\z/ and $before = str2ts($1);
1169
1170         my $ibx = $ctx->{-inbox};
1171         my $msgs = $ibx->recent($opts, $after, $before);
1172         my $nr = scalar @$msgs;
1173         if ($nr < $lim && defined($after)) {
1174                 $after = $before = undef;
1175                 $msgs = $ibx->recent($opts);
1176                 $nr = scalar @$msgs;
1177         }
1178         my $more = $nr == $lim;
1179         my ($newest, $oldest);
1180         if ($nr) {
1181                 $newest = $msgs->[0]->{ts};
1182                 $oldest = $msgs->[-1]->{ts};
1183                 # if we only had $after, our SQL query in ->recent ordered
1184                 if ($newest < $oldest) {
1185                         ($oldest, $newest) = ($newest, $oldest);
1186                         $more = 0 if defined($after) && $after < $oldest;
1187                 }
1188         }
1189         if (defined($oldest) && $more) {
1190                 my $s = ts2str($oldest);
1191                 $ctx->{next_page} = qq!<a\nhref="?t=$s"\nrel=next>next</a>!;
1192         }
1193         if (defined($newest) && (defined($before) || defined($after))) {
1194                 my $s = ts2str($newest);
1195                 $ctx->{prev_page} = qq!<a\nhref="?t=$s-"\nrel=prev>prev</a>!;
1196         }
1197         $msgs;
1198 }
1199
1200 sub index_topics {
1201         my ($ctx) = @_;
1202         my $msgs = paginate_recent($ctx, 200); # 200 is our window
1203         if (@$msgs) {
1204                 walk_thread(thread_results($ctx, $msgs), $ctx, *acc_topic);
1205         }
1206         PublicInbox::WwwStream->response($ctx, dump_topics($ctx), *index_nav);
1207 }
1208
1209 sub thread_adj_level {
1210         my ($ctx, $level) = @_;
1211
1212         my $max = $ctx->{cur_level};
1213         if ($level <= 0) {
1214                 return ('', '') if $max == 0; # flat output
1215
1216                 # reset existing lists
1217                 my $beg = $max > 1 ? ('</ul></li>' x ($max - 1)) : '';
1218                 $ctx->{cur_level} = 0;
1219                 ("$beg</ul>", '');
1220         } elsif ($level == $max) { # continue existing list
1221                 qw(<li> </li>);
1222         } elsif ($level < $max) {
1223                 my $beg = $max > 1 ? ('</ul></li>' x ($max - $level)) : '';
1224                 $ctx->{cur_level} = $level;
1225                 ("$beg<li>", '</li>');
1226         } else { # ($level > $max) # start a new level
1227                 $ctx->{cur_level} = $level;
1228                 my $beg = ($max ? '<li>' : '') . '<ul><li>';
1229                 ($beg, '</li>');
1230         }
1231 }
1232
1233 sub ghost_index_entry {
1234         my ($ctx, $level, $node) = @_;
1235         my ($beg, $end) = thread_adj_level($ctx,  $level);
1236         $beg . '<pre>'. ghost_parent($ctx->{-upfx}, $node->{id})
1237                 . '</pre>' . $end;
1238 }
1239
1240 1;