lib/PublicInbox/ViewDiff.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # used by PublicInbox::View
   5 # This adds CSS spans for diff highlighting.
   6 # It also generates links for ViewVCS + SolverGit to show
   7 # (or reconstruct) blobs.
   8
   9 package PublicInbox::ViewDiff;
  10 use strict;
  11 use warnings;
  12 use base qw(Exporter);
  13 our @EXPORT_OK = qw(flush_diff);
  14 use URI::Escape qw(uri_escape_utf8);
  15 use PublicInbox::Hval qw(ascii_html);
  16 use PublicInbox::Git qw(git_unquote);
  17
  18 sub DSTATE_INIT () { 0 }
  19 sub DSTATE_STAT () { 1 } # TODO
  20 sub DSTATE_HEAD () { 2 } # /^diff --git /, /^index /, /^--- /, /^\+\+\+ /
  21 sub DSTATE_CTX () { 3 } # /^ /
  22 sub DSTATE_ADD () { 4 } # /^\+/
  23 sub DSTATE_DEL () { 5 } # /^\-/
  24 my @state2class = (
  25         '', # init
  26         '', # stat
  27         'head',
  28         '', # ctx
  29         'add',
  30         'del'
  31 );
  32
  33 sub UNSAFE () { "^A-Za-z0-9\-\._~/" }
  34
  35 my $OID_NULL = '0{7,40}';
  36 my $OID_BLOB = '[a-f0-9]{7,40}';
  37 my $PATH_A = '"?a/.+|/dev/null';
  38 my $PATH_B = '"?b/.+|/dev/null';
  39
  40 sub to_html ($$) {
  41         $_[0]->linkify_1($_[1]);
  42         $_[0]->linkify_2(ascii_html($_[1]));
  43 }
  44
  45 # link to line numbers in blobs
  46 sub diff_hunk ($$$$) {
  47         my ($dctx, $spfx, $ca, $cb) = @_;
  48         my $oid_a = $dctx->{oid_a};
  49         my $oid_b = $dctx->{oid_b};
  50
  51         (defined($spfx) && defined($oid_a) && defined($oid_b)) or
  52                 return "@@ $ca $cb @@";
  53
  54         my ($n) = ($ca =~ /^-(\d+)/);
  55         $n = defined($n) ? do { ++$n; "#n$n" } : '';
  56
  57         my $rv = qq(@@ <a\nhref="$spfx$oid_a/s/$dctx->{Q}$n">$ca</a>);
  58
  59         ($n) = ($cb =~ /^\+(\d+)/);
  60         $n = defined($n) ? do { ++$n; "#n$n" } : '';
  61
  62         $rv .= qq( <a\nhref="$spfx$oid_b/s/$dctx->{Q}$n">$cb</a> @@);
  63 }
  64
  65 sub oid ($$$) {
  66         my ($dctx, $spfx, $oid) = @_;
  67         defined($spfx) ? qq(<a\nhref="$spfx$oid/s/$dctx->{Q}">$oid</a>) : $oid;
  68 }
  69
  70 sub to_state ($$$) {
  71         my ($dst, $state, $new_state) = @_;
  72         $$dst .= '</span>' if $state2class[$state];
  73         $_[1] = $new_state;
  74         my $class = $state2class[$new_state] or return;
  75         $$dst .= qq(<span\nclass="$class">);
  76 }
  77
  78 sub flush_diff ($$$$) {
  79         my ($dst, $spfx, $linkify, $diff) = @_;
  80         my $state = DSTATE_INIT;
  81         my $dctx = { Q => '' }; # {}, keys: oid_a, oid_b, path_a, path_b
  82
  83         foreach my $s (@$diff) {
  84                 if ($s =~ /^ /) {
  85                         if ($state2class[$state]) {
  86                                 to_state($dst, $state, DSTATE_CTX);
  87                         }
  88                         $$dst .= to_html($linkify, $s);
  89                 } elsif ($s =~ /^-- $/) { # email signature begins
  90                         $state == DSTATE_INIT or
  91                                 to_state($dst, $state, DSTATE_INIT);
  92                         $$dst .= $s;
  93                 } elsif ($s =~ m!^diff --git ($PATH_A) ($PATH_B)$!) {
  94                         if ($state != DSTATE_HEAD) {
  95                                 my ($pa, $pb) = ($1, $2);
  96                                 to_state($dst, $state, DSTATE_HEAD);
  97                                 $pa = (split('/', git_unquote($pa), 2))[1];
  98                                 $pb = (split('/', git_unquote($pb), 2))[1];
  99                                 $dctx = {
 100                                         Q => "?b=".uri_escape_utf8($pb, UNSAFE),
 101                                 };
 102                                 if ($pa ne $pb) {
 103                                         $dctx->{Q} .=
 104                                              "&a=".uri_escape_utf8($pa, UNSAFE);
 105                                 }
 106                         }
 107                         $$dst .= to_html($linkify, $s);
 108                 } elsif ($s =~ s/^(index $OID_NULL\.\.)($OID_BLOB)\b//o) {
 109                         $$dst .= $1 . oid($dctx, $spfx, $2);
 110                         $$dst .= to_html($linkify, $s) ;
 111                 } elsif ($s =~ s/^index ($OID_NULL)(\.\.$OID_BLOB)\b//o) {
 112                         $$dst .= 'index ' . oid($dctx, $spfx, $1) . $2;
 113                         $$dst .= to_html($linkify, $s);
 114                 } elsif ($s =~ /^index ($OID_BLOB)\.\.($OID_BLOB)/o) {
 115                         $dctx->{oid_a} = $1;
 116                         $dctx->{oid_b} = $2;
 117                         $$dst .= to_html($linkify, $s);
 118                 } elsif ($s =~ s/^@@ (\S+) (\S+) @@//) {
 119                         $$dst .= '</span>' if $state2class[$state];
 120                         $$dst .= qq(<span\nclass="hunk">);
 121                         $$dst .= diff_hunk($dctx, $spfx, $1, $2);
 122                         $$dst .= '</span>';
 123                         $state = DSTATE_CTX;
 124                         $$dst .= to_html($linkify, $s);
 125                 } elsif ($s =~ m!^--- $PATH_A! ||
 126                          $s =~ m!^\+{3} $PATH_B!)  {
 127                         # color only (no oid link)
 128                         $state == DSTATE_INIT and
 129                                 to_state($dst, $state, DSTATE_HEAD);
 130                         $$dst .= to_html($linkify, $s);
 131                 } elsif ($s =~ /^\+/) {
 132                         if ($state != DSTATE_ADD && $state != DSTATE_INIT) {
 133                                 to_state($dst, $state, DSTATE_ADD);
 134                         }
 135                         $$dst .= to_html($linkify, $s);
 136                 } elsif ($s =~ /^-/) {
 137                         if ($state != DSTATE_DEL && $state != DSTATE_INIT) {
 138                                 to_state($dst, $state, DSTATE_DEL);
 139                         }
 140                         $$dst .= to_html($linkify, $s);
 141                 # ignore the following lines in headers:
 142                 } elsif ($s =~ /^(?:dis)similarity index/ ||
 143                          $s =~ /^(?:old|new) mode/ ||
 144                          $s =~ /^(?:deleted|new) file mode/ ||
 145                          $s =~ /^(?:copy|rename) (?:from|to) / ||
 146                          $s =~ /^(?:dis)?similarity index /) {
 147                         $$dst .= to_html($linkify, $s);
 148                 } else {
 149                         $state == DSTATE_INIT or
 150                                 to_state($dst, $state, DSTATE_INIT);
 151                         $$dst .= to_html($linkify, $s);
 152                 }
 153         }
 154         @$diff = ();
 155         $$dst .= '</span>' if $state2class[$state];
 156         undef;
 157 }
 158
 159 1;