lib/PublicInbox/ViewDiff.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # used by PublicInbox::View
   5 package PublicInbox::ViewDiff;
   6 use strict;
   7 use warnings;
   8 use base qw(Exporter);
   9 our @EXPORT_OK = qw(flush_diff);
  10
  11 use PublicInbox::Hval qw(ascii_html);
  12 use PublicInbox::Git qw(git_unquote);
  13
  14 sub DSTATE_INIT () { 0 }
  15 sub DSTATE_STAT () { 1 } # TODO
  16 sub DSTATE_HEAD () { 2 } # /^diff --git /, /^index /, /^--- /, /^\+\+\+ /
  17 sub DSTATE_HUNK () { 3 } # /^@@ /
  18 sub DSTATE_CTX () { 4 } # /^ /
  19 sub DSTATE_ADD () { 5 } # /^\+/
  20 sub DSTATE_DEL () { 6 } # /^\-/
  21
  22 my $OID_NULL = '0{7,40}';
  23 my $OID_BLOB = '[a-f0-9]{7,40}';
  24 my $PATH_A = '"?a/.+|/dev/null';
  25 my $PATH_B = '"?b/.+|/dev/null';
  26
  27 sub to_html ($$) {
  28         $_[0]->linkify_1($_[1]);
  29         $_[0]->linkify_2(ascii_html($_[1]));
  30 }
  31
  32 # link to line numbers in blobs
  33 sub diff_hunk ($$$$) {
  34         my ($dctx, $spfx, $ca, $cb) = @_;
  35         my $oid_a = $dctx->{oid_a};
  36         my $oid_b = $dctx->{oid_b};
  37
  38         (defined($oid_a) && defined($oid_b)) or return "@@ $ca $cb @@";
  39
  40         my ($n) = ($ca =~ /^-(\d+)/);
  41         $n = defined($n) ? do { ++$n; "#n$n" } : '';
  42
  43         my $rv = qq(@@ <a\nhref=$spfx$oid_a/s$n>$ca</a>);
  44
  45         ($n) = ($cb =~ /^\+(\d+)/);
  46         $n = defined($n) ? do { ++$n; "#n$n" } : '';
  47
  48         $rv .= qq( <a\nhref=$spfx$oid_b/s$n>$cb</a> @@);
  49 }
  50
  51 sub flush_diff ($$$$) {
  52         my ($dst, $spfx, $linkify, $diff) = @_;
  53         my $state = DSTATE_INIT;
  54         my $dctx; # {}, keys: oid_a, oid_b, path_a, path_b
  55
  56         foreach my $s (@$diff) {
  57                 if ($s =~ /^ /) {
  58                         if ($state == DSTATE_HUNK || $state == DSTATE_ADD ||
  59                             $state == DSTATE_DEL || $state == DSTATE_HEAD) {
  60                                 $$dst .= "</span><span\nclass=ctx>";
  61                                 $state = DSTATE_CTX;
  62                         }
  63                         $$dst .= to_html($linkify, $s);
  64                 } elsif ($s =~ /^-- $/) { # email signature begins
  65                         if ($state != DSTATE_INIT) {
  66                                 $state = DSTATE_INIT;
  67                                 $$dst .= '</span>';
  68                         }
  69                         $$dst .= $s;
  70                 } elsif ($s =~ m!^diff --git ($PATH_A) ($PATH_B)$!x) {
  71                         if ($state != DSTATE_HEAD) {
  72                                 my ($pa, $pb) = ($1, $2);
  73                                 $$dst .= '</span>' if $state != DSTATE_INIT;
  74                                 $$dst .= "<span\nclass=head>";
  75                                 $state = DSTATE_HEAD;
  76                                 $pa = (split('/', git_unquote($pa), 2))[1];
  77                                 $pb = (split('/', git_unquote($pb), 2))[1];
  78                                 $dctx = { path_a => $pa, path_b => $pb };
  79                         }
  80                         $$dst .= to_html($linkify, $s);
  81                 } elsif ($s =~ s/^(index $OID_NULL\.\.)($OID_BLOB)\b//o) {
  82                         $$dst .= qq($1<a\nhref=$spfx$2/s>$2</a>);
  83                         $$dst .= to_html($linkify, $s) ;
  84                 } elsif ($s =~ s/^index ($OID_NULL)(\.\.$OID_BLOB)\b//o) {
  85                         $$dst .= 'index ';
  86                         $$dst .= qq(<a\nhref=$spfx$1/s>$1</a>$2);
  87                         $$dst .= to_html($linkify, $s);
  88                 } elsif ($s =~ /^index ($OID_BLOB)\.\.($OID_BLOB)/o) {
  89                         $dctx->{oid_a} = $1;
  90                         $dctx->{oid_b} = $2;
  91                         $$dst .= to_html($linkify, $s);
  92                 } elsif ($s =~ s/^@@ (\S+) (\S+) @@//) {
  93                         my ($ca, $cb) = ($1, $2);
  94                         if ($state == DSTATE_HEAD || $state == DSTATE_CTX ||
  95                             $state == DSTATE_ADD || $state == DSTATE_DEL) {
  96                                 $$dst .= "</span><span\nclass=hunk>";
  97                                 $state = DSTATE_HUNK;
  98                                 $$dst .= diff_hunk($dctx, $spfx, $ca, $cb);
  99                         } else {
 100                                 $$dst .= to_html($linkify, "@@ $ca $cb @@");
 101                         }
 102                         $$dst .= to_html($linkify, $s);
 103                 } elsif ($s =~ m!^--- $PATH_A!) {
 104                         if ($state == DSTATE_INIT) { # color only (no oid link)
 105                                 $state = DSTATE_HEAD;
 106                                 $$dst .= "<span\nclass=head>";
 107                         }
 108                         $$dst .= to_html($linkify, $s);
 109                 } elsif ($s =~ m!^\+{3} $PATH_B!)  {
 110                         if ($state == DSTATE_INIT) { # color only (no oid link)
 111                                 $state = DSTATE_HEAD;
 112                                 $$dst .= "<span\nclass=head>";
 113                         }
 114                         $$dst .= to_html($linkify, $s);
 115                 } elsif ($s =~ /^\+/) {
 116                         if ($state != DSTATE_ADD && $state != DSTATE_INIT) {
 117                                 $$dst .= "</span><span\nclass=add>";
 118                                 $state = DSTATE_ADD;
 119                         }
 120                         $$dst .= to_html($linkify, $s);
 121                 } elsif ($s =~ /^-/) {
 122                         if ($state != DSTATE_DEL && $state != DSTATE_INIT) {
 123                                 $$dst .= "</span><span\nclass=del>";
 124                                 $state = DSTATE_DEL;
 125                         }
 126                         $$dst .= to_html($linkify, $s);
 127                 # ignore the following lines in headers:
 128                 } elsif ($s =~ /^(?:dis)similarity index/ ||
 129                          $s =~ /^(?:old|new) mode/ ||
 130                          $s =~ /^(?:deleted|new) file mode/ ||
 131                          $s =~ /^(?:copy|rename) (?:from|to) / ||
 132                          $s =~ /^(?:dis)?similarity index /) {
 133                         $$dst .= to_html($linkify, $s);
 134                 } else {
 135                         if ($state != DSTATE_INIT) {
 136                                 $$dst .= '</span>';
 137                                 $state = DSTATE_INIT;
 138                         }
 139                         $$dst .= to_html($linkify, $s);
 140                 }
 141         }
 142         @$diff = ();
 143         $$dst .= '</span>' if $state != DSTATE_INIT;
 144         undef;
 145 }
 146
 147 1;