lib/PublicInbox/ViewVCS.pm

   1 # Copyright (C) 2019-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # show any VCS object, similar to "git show"
   5 # FIXME: we only show blobs for now
   6 #
   7 # This can use a "solver" to reconstruct blobs based on git
   8 # patches (with abbreviated OIDs in the header).  However, the
   9 # abbreviated OIDs must match exactly what's in the original
  10 # email (unless a normal code repo already has the blob).
  11 #
  12 # In other words, we can only reliably reconstruct blobs based
  13 # on links generated by ViewDiff (and only if the emailed
  14 # patches apply 100% cleanly to published blobs).
  15
  16 package PublicInbox::ViewVCS;
  17 use strict;
  18 use v5.10.1;
  19 use PublicInbox::SolverGit;
  20 use PublicInbox::WwwStream qw(html_oneshot);
  21 use PublicInbox::Linkify;
  22 use PublicInbox::Tmpfile;
  23 use PublicInbox::Hval qw(ascii_html to_filename);
  24 my $hl = eval {
  25         require PublicInbox::HlMod;
  26         PublicInbox::HlMod->new;
  27 };
  28
  29 my %QP_MAP = ( A => 'oid_a', a => 'path_a', b => 'path_b' );
  30 our $MAX_SIZE = 1024 * 1024; # TODO: configurable
  31 my $BIN_DETECT = 8000; # same as git
  32
  33 sub html_page ($$$) {
  34         my ($ctx, $code, $strref) = @_;
  35         my $wcb = delete $ctx->{-wcb};
  36         $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
  37         my $res = html_oneshot($ctx, $code, $strref);
  38         $wcb ? $wcb->($res) : $res;
  39 }
  40
  41 sub stream_blob_parse_hdr { # {parse_hdr} for Qspawn
  42         my ($r, $bref, $ctx) = @_;
  43         my ($res, $logref) = delete @$ctx{qw(-res -logref)};
  44         my ($git, $oid, $type, $size, $di) = @$res;
  45         my @cl = ('Content-Length', $size);
  46         if (!defined $r) { # error
  47                 html_page($ctx, 500, $logref);
  48         } elsif (index($$bref, "\0") >= 0) {
  49                 [200, [qw(Content-Type application/octet-stream), @cl] ];
  50         } else {
  51                 my $n = length($$bref);
  52                 if ($n >= $BIN_DETECT || $n == $size) {
  53                         return [200, [ 'Content-Type',
  54                                 'text/plain; charset=UTF-8', @cl ] ];
  55                 }
  56                 if ($r == 0) {
  57                         warn "premature EOF on $oid $$logref";
  58                         return html_page($ctx, 500, $logref);
  59                 }
  60                 @$ctx{qw(-res -logref)} = ($res, $logref);
  61                 undef; # bref keeps growing
  62         }
  63 }
  64
  65 sub stream_large_blob ($$$$) {
  66         my ($ctx, $res, $logref, $fn) = @_;
  67         $ctx->{-logref} = $logref;
  68         $ctx->{-res} = $res;
  69         my ($git, $oid, $type, $size, $di) = @$res;
  70         my $cmd = ['git', "--git-dir=$git->{git_dir}", 'cat-file', $type, $oid];
  71         my $qsp = PublicInbox::Qspawn->new($cmd);
  72         my $env = $ctx->{env};
  73         $env->{'qspawn.wcb'} = delete $ctx->{-wcb};
  74         $qsp->psgi_return($env, undef, \&stream_blob_parse_hdr, $ctx);
  75 }
  76
  77 sub show_other_result ($$) {
  78         my ($bref, $ctx) = @_;
  79         my ($qsp, $logref) = delete @$ctx{qw(-qsp -logref)};
  80         if (my $err = $qsp->{err}) {
  81                 utf8::decode($$err);
  82                 $$logref .= "git show error: $err";
  83                 return html_page($ctx, 500, $logref);
  84         }
  85         my $l = PublicInbox::Linkify->new;
  86         utf8::decode($$bref);
  87         $$bref = '<pre>'. $l->to_html($$bref);
  88         $$bref .= '</pre><hr>' . $$logref;
  89         html_page($ctx, 200, $bref);
  90 }
  91
  92 sub show_other ($$$$) {
  93         my ($ctx, $res, $logref, $fn) = @_;
  94         my ($git, $oid, $type, $size) = @$res;
  95         if ($size > $MAX_SIZE) {
  96                 $$logref = "$oid is too big to show\n" . $$logref;
  97                 return html_page($ctx, 200, $logref);
  98         }
  99         my $cmd = ['git', "--git-dir=$git->{git_dir}",
 100                 qw(show --encoding=UTF-8 --no-color --no-abbrev), $oid ];
 101         my $qsp = PublicInbox::Qspawn->new($cmd);
 102         my $env = $ctx->{env};
 103         $ctx->{-qsp} = $qsp;
 104         $ctx->{-logref} = $logref;
 105         $qsp->psgi_qx($env, undef, \&show_other_result, $ctx);
 106 }
 107
 108 # user_cb for SolverGit, called as: user_cb->($result_or_error, $uarg)
 109 sub solve_result {
 110         my ($res, $ctx) = @_;
 111         my ($log, $hints, $fn) = delete @$ctx{qw(log hints fn)};
 112
 113         unless (seek($log, 0, 0)) {
 114                 warn "seek(log): $!";
 115                 return html_page($ctx, 500, \'seek error');
 116         }
 117         $log = do { local $/; <$log> };
 118
 119         my $ref = ref($res);
 120         my $l = PublicInbox::Linkify->new;
 121         $log = '<pre>debug log:</pre><hr /><pre>' .
 122                 $l->to_html($log) . '</pre>';
 123
 124         $res or return html_page($ctx, 404, \$log);
 125         $ref eq 'ARRAY' or return html_page($ctx, 500, \$log);
 126
 127         my ($git, $oid, $type, $size, $di) = @$res;
 128         return show_other($ctx, $res, \$log, $fn) if $type ne 'blob';
 129         my $path = to_filename($di->{path_b} // $hints->{path_b} // 'blob');
 130         my $raw_link = "(<a\nhref=$path>raw</a>)";
 131         if ($size > $MAX_SIZE) {
 132                 return stream_large_blob($ctx, $res, \$log, $fn) if defined $fn;
 133                 $log = "<pre><b>Too big to show, download available</b>\n" .
 134                         "$oid $type $size bytes $raw_link</pre>" . $log;
 135                 return html_page($ctx, 200, \$log);
 136         }
 137
 138         my $blob = $git->cat_file($oid);
 139         if (!$blob) { # WTF?
 140                 my $e = "Failed to retrieve generated blob ($oid)";
 141                 warn "$e ($git->{git_dir})";
 142                 $log = "<pre><b>$e</b></pre>" . $log;
 143                 return html_page($ctx, 500, \$log);
 144         }
 145
 146         my $bin = index(substr($$blob, 0, $BIN_DETECT), "\0") >= 0;
 147         if (defined $fn) {
 148                 my $h = [ 'Content-Length', $size, 'Content-Type' ];
 149                 push(@$h, ($bin ? 'application/octet-stream' : 'text/plain'));
 150                 return delete($ctx->{-wcb})->([200, $h, [ $$blob ]]);
 151         }
 152
 153         if ($bin) {
 154                 $log = "<pre>$oid $type $size bytes (binary)" .
 155                         " $raw_link</pre>" . $log;
 156                 return html_page($ctx, 200, \$log);
 157         }
 158
 159         # TODO: detect + convert to ensure validity
 160         utf8::decode($$blob);
 161         my $nl = ($$blob =~ s/\r?\n/\n/sg);
 162         my $pad = length($nl);
 163
 164         $l->linkify_1($$blob);
 165         my $ok = $hl->do_hl($blob, $path) if $hl;
 166         if ($ok) {
 167                 $blob = $ok;
 168         } else {
 169                 $$blob = ascii_html($$blob);
 170         }
 171
 172         # using some of the same CSS class names and ids as cgit
 173         $log = "<pre>$oid $type $size bytes $raw_link</pre>" .
 174                 "<hr /><table\nclass=blob>".
 175                 "<tr><td\nclass=linenumbers><pre>" . join('', map {
 176                         sprintf("<a id=n$_ href=#n$_>% ${pad}u</a>\n", $_)
 177                 } (1..$nl)) . '</pre></td>' .
 178                 '<td><pre> </pre></td>'. # pad for non-CSS users
 179                 "<td\nclass=lines><pre\nstyle='white-space:pre'><code>" .
 180                 $l->linkify_2($$blob) .
 181                 '</code></pre></td></tr></table>' . $log;
 182
 183         html_page($ctx, 200, \$log);
 184 }
 185
 186 # GET /$INBOX/$GIT_OBJECT_ID/s/
 187 # GET /$INBOX/$GIT_OBJECT_ID/s/$FILENAME
 188 sub show ($$;$) {
 189         my ($ctx, $oid_b, $fn) = @_;
 190         my $qp = $ctx->{qp};
 191         my $hints = $ctx->{hints} = {};
 192         while (my ($from, $to) = each %QP_MAP) {
 193                 defined(my $v = $qp->{$from}) or next;
 194                 $hints->{$to} = $v if $v ne '';
 195         }
 196
 197         $ctx->{'log'} = tmpfile("solve.$oid_b") // die "tmpfile: $!";
 198         $ctx->{fn} = $fn;
 199         my $solver = PublicInbox::SolverGit->new($ctx->{ibx},
 200                                                 \&solve_result, $ctx);
 201         # PSGI server will call this immediately and give us a callback (-wcb)
 202         sub {
 203                 $ctx->{-wcb} = $_[0]; # HTTP write callback
 204                 $solver->solve($ctx->{env}, $ctx->{log}, $oid_b, $hints);
 205         };
 206 }
 207
 208 1;