lib/PublicInbox/ViewVCS.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # show any VCS object, similar to "git show"
   5 # FIXME: we only show blobs for now
   6 #
   7 # This can use a "solver" to reconstruct blobs based on git
   8 # patches (with abbreviated OIDs in the header).  However, the
   9 # abbreviated OIDs must match exactly what's in the original
  10 # email (unless a normal code repo already has the blob).
  11 #
  12 # In other words, we can only reliably reconstruct blobs based
  13 # on links generated by ViewDiff (and only if the emailed
  14 # patches apply 100% cleanly to published blobs).
  15
  16 package PublicInbox::ViewVCS;
  17 use strict;
  18 use warnings;
  19 use Encode qw(find_encoding);
  20 use PublicInbox::SolverGit;
  21 use PublicInbox::WwwStream;
  22 use PublicInbox::Linkify;
  23 use PublicInbox::Hval qw(ascii_html to_filename);
  24 my $hl = eval {
  25         require PublicInbox::HlMod;
  26         PublicInbox::HlMod->new;
  27 };
  28
  29 my %QP_MAP = ( A => 'oid_a', B => 'oid_b', a => 'path_a', b => 'path_b' );
  30 my $max_size = 1024 * 1024; # TODO: configurable
  31 my $enc_utf8 = find_encoding('UTF-8');
  32
  33 sub html_page ($$$) {
  34         my ($ctx, $code, $strref) = @_;
  35         my $wcb = delete $ctx->{-wcb};
  36         $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
  37         my $res = PublicInbox::WwwStream->response($ctx, $code, sub {
  38                 my ($nr, undef) =  @_;
  39                 $nr == 1 ? $$strref : undef;
  40         });
  41         $wcb->($res);
  42 }
  43
  44 sub solve_result {
  45         my ($ctx, $res, $log, $hints, $fn) = @_;
  46
  47         unless (seek($log, 0, 0)) {
  48                 $ctx->{env}->{'psgi.errors'}->print("seek(log): $!\n");
  49                 return html_page($ctx, 500, \'seek error');
  50         }
  51         $log = do { local $/; <$log> };
  52
  53         my $ref = ref($res);
  54         my $l = PublicInbox::Linkify->new;
  55         $l->linkify_1($log);
  56         $log = '<pre>debug log:</pre><hr /><pre>' .
  57                 $l->linkify_2(ascii_html($log)) . '</pre>';
  58
  59         $res or return html_page($ctx, 404, \$log);
  60         $ref eq 'ARRAY' or return html_page($ctx, 500, \$log);
  61
  62         my ($git, $oid, $type, $size, $di) = @$res;
  63         if ($size > $max_size) {
  64                 # TODO: stream the raw file if it's gigantic, at least
  65                 $log = '<pre><b>Too big to show</b></pre>' . $log;
  66                 return html_page($ctx, 500, \$log);
  67         }
  68
  69         my $blob = $git->cat_file($oid);
  70         if (!$blob) { # WTF?
  71                 my $e = "Failed to retrieve generated blob ($oid)";
  72                 $ctx->{env}->{'psgi.errors'}->print("$e ($git->{git_dir})\n");
  73                 $log = "<pre><b>$e</b></pre>" . $log;
  74                 return html_page($ctx, 500, \$log);
  75         }
  76
  77         my $binary = index($$blob, "\0") >= 0;
  78         if ($fn) {
  79                 my $h = [ 'Content-Length', $size, 'Content-Type' ];
  80                 push(@$h, ($binary ? 'application/octet-stream' : 'text/plain'));
  81                 return delete($ctx->{-wcb})->([200, $h, [ $$blob ]]);
  82         }
  83
  84         my $path = to_filename($di->{path_b} || $hints->{path_b} || 'blob');
  85         my $raw_link = "(<a\nhref=$path>raw</a>)";
  86         if ($binary) {
  87                 $log = "<pre>$oid $type $size bytes (binary)" .
  88                         " $raw_link</pre>" . $log;
  89                 return html_page($ctx, 200, \$log);
  90         }
  91
  92         $$blob = $enc_utf8->decode($$blob);
  93         my $nl = ($$blob =~ tr/\n/\n/);
  94         my $pad = length($nl);
  95
  96         $l->linkify_1($$blob);
  97         my $ok = $hl->do_hl($blob, $path) if $hl;
  98         if ($ok) {
  99                 $blob = $ok;
 100         } else {
 101                 $$blob = ascii_html($$blob);
 102         }
 103
 104         # using some of the same CSS class names and ids as cgit
 105         $log = "<pre>$oid $type $size bytes $raw_link</pre>" .
 106                 "<hr /><table\nclass=blob>".
 107                 "<tr><td\nclass=linenumbers><pre>" . join('', map {
 108                         sprintf("<a id=n$_ href=#n$_>% ${pad}u</a>\n", $_)
 109                 } (1..$nl)) . '</pre></td>' .
 110                 '<td><pre> </pre></td>'. # pad for non-CSS users
 111                 "<td\nclass=lines><pre\nstyle='white-space:pre'><code>" .
 112                 $l->linkify_2($$blob) .
 113                 '</code></pre></td></tr></table>' . $log;
 114
 115         html_page($ctx, 200, \$log);
 116 }
 117
 118 sub show ($$;$) {
 119         my ($ctx, $oid_b, $fn) = @_;
 120         my $qp = $ctx->{qp};
 121         my $hints = {};
 122         while (my ($from, $to) = each %QP_MAP) {
 123                 defined(my $v = $qp->{$from}) or next;
 124                 $hints->{$to} = $v;
 125         }
 126
 127         open my $log, '+>', undef or die "open: $!";
 128         my $solver = PublicInbox::SolverGit->new($ctx->{-inbox}, sub {
 129                 solve_result($ctx, $_[0], $log, $hints, $fn);
 130         });
 131
 132         # PSGI server will call this and give us a callback
 133         sub {
 134                 $ctx->{-wcb} = $_[0]; # HTTP write callback
 135                 $solver->solve($ctx->{env}, $log, $oid_b, $hints);
 136         };
 137 }
 138
 139 1;