lib/PublicInbox/ViewVCS.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # show any VCS object, similar to "git show"
   5 #
   6 # This can use a "solver" to reconstruct blobs based on git
   7 # patches (with abbreviated OIDs in the header).  However, the
   8 # abbreviated OIDs must match exactly what's in the original
   9 # email (unless a normal code repo already has the blob).
  10 #
  11 # In other words, we can only reliably reconstruct blobs based
  12 # on links generated by ViewDiff (and only if the emailed
  13 # patches apply 100% cleanly to published blobs).
  14
  15 package PublicInbox::ViewVCS;
  16 use strict;
  17 use v5.10.1;
  18 use File::Temp 0.19 (); # newdir
  19 use PublicInbox::SolverGit;
  20 use PublicInbox::GitAsyncCat;
  21 use PublicInbox::WwwStream qw(html_oneshot);
  22 use PublicInbox::Linkify;
  23 use PublicInbox::Tmpfile;
  24 use PublicInbox::ViewDiff qw(flush_diff uri_escape_path);
  25 use PublicInbox::View;
  26 use PublicInbox::Eml;
  27 use Text::Wrap qw(wrap);
  28 use PublicInbox::Hval qw(ascii_html to_filename);
  29 my $hl = eval {
  30         require PublicInbox::HlMod;
  31         PublicInbox::HlMod->new;
  32 };
  33
  34 my %QP_MAP = ( A => 'oid_a', a => 'path_a', b => 'path_b' );
  35 our $MAX_SIZE = 1024 * 1024; # TODO: configurable
  36 my $BIN_DETECT = 8000; # same as git
  37 my $SHOW_FMT = '--pretty=format:'.join('%n', '%P', '%p', '%H', '%T', '%s', '%f',
  38         '%an <%ae>  %ai', '%cn <%ce>  %ci', '%b%x00');
  39
  40 my %GIT_MODE = (
  41         '100644' => ' ', # blob
  42         '100755' => 'x', # executable blob
  43         '040000' => 'd', # tree
  44         '120000' => 'l', # symlink
  45         '160000' => 'g', # commit (gitlink)
  46 );
  47
  48 sub html_page ($$;@) {
  49         my ($ctx, $code) = @_[0, 1];
  50         my $wcb = delete $ctx->{-wcb};
  51         $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
  52         my $res = html_oneshot($ctx, $code, @_[2..$#_]);
  53         $wcb ? $wcb->($res) : $res;
  54 }
  55
  56 sub dbg_log ($) {
  57         my ($ctx) = @_;
  58         my $log = delete $ctx->{lh} // die 'BUG: already captured debug log';
  59         if (!seek($log, 0, 0)) {
  60                 warn "seek(log): $!";
  61                 return '<pre>debug log seek error</pre>';
  62         }
  63         $log = do { local $/; <$log> } // do {
  64                 warn "readline(log): $!";
  65                 return '<pre>debug log read error</pre>';
  66         };
  67         $ctx->{-linkify} //= PublicInbox::Linkify->new;
  68         "<hr><pre>debug log:\n\n".
  69                 $ctx->{-linkify}->to_html($log).'</pre>';
  70 }
  71
  72 sub stream_blob_parse_hdr { # {parse_hdr} for Qspawn
  73         my ($r, $bref, $ctx) = @_;
  74         my ($git, $oid, $type, $size, $di) = @{$ctx->{-res}};
  75         my @cl = ('Content-Length', $size);
  76         if (!defined $r) { # sysread error
  77                 html_page($ctx, 500, dbg_log($ctx));
  78         } elsif (index($$bref, "\0") >= 0) {
  79                 [200, [qw(Content-Type application/octet-stream), @cl] ];
  80         } else {
  81                 my $n = length($$bref);
  82                 if ($n >= $BIN_DETECT || $n == $size) {
  83                         return [200, [ 'Content-Type',
  84                                 'text/plain; charset=UTF-8', @cl ] ];
  85                 }
  86                 if ($r == 0) {
  87                         my $log = dbg_log($ctx);
  88                         warn "premature EOF on $oid $log";
  89                         return html_page($ctx, 500, $log);
  90                 }
  91                 undef; # bref keeps growing
  92         }
  93 }
  94
  95 sub stream_large_blob ($$) {
  96         my ($ctx, $res) = @_;
  97         $ctx->{-res} = $res;
  98         my ($git, $oid, $type, $size, $di) = @$res;
  99         my $cmd = ['git', "--git-dir=$git->{git_dir}", 'cat-file', $type, $oid];
 100         my $qsp = PublicInbox::Qspawn->new($cmd);
 101         my $env = $ctx->{env};
 102         $env->{'qspawn.wcb'} = delete $ctx->{-wcb};
 103         $qsp->psgi_return($env, undef, \&stream_blob_parse_hdr, $ctx);
 104 }
 105
 106 sub show_other_result ($$) { # tag
 107         my ($bref, $ctx) = @_;
 108         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 109                 return html_page($ctx, 500, dbg_log($ctx) .
 110                                 "git show error:$qsp_err");
 111         }
 112         my $l = PublicInbox::Linkify->new;
 113         utf8::decode($$bref);
 114         html_page($ctx, 200, '<pre>', $l->to_html($$bref), '</pre><hr>',
 115                 dbg_log($ctx));
 116 }
 117
 118 sub cmt_title { # git->cat_async callback
 119         my ($bref, $oid, $type, $size, $ctx) = @_;
 120         utf8::decode($$bref);
 121         my $title = $$bref =~ /\r?\n\r?\n([^\r\n]+)\r?\n?/ ? $1 : '';
 122         push(@{$ctx->{-cmt_pt}} , ascii_html($title)) == @{$ctx->{-cmt_P}} and
 123                 cmt_finalize($ctx);
 124 }
 125
 126 sub show_commit_start { # ->psgi_qx callback
 127         my ($bref, $ctx) = @_;
 128         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 129                 return html_page($ctx, 500, dbg_log($ctx) .
 130                                 "git show/patch-id error:$qsp_err");
 131         }
 132         my $patchid = (split(/ /, $$bref))[0]; # ignore commit
 133         $ctx->{-q_value_html} = "patchid:$patchid" if defined $patchid;
 134         open my $fh, '<:utf8', "$ctx->{-tmp}/h" or
 135                 die "open $ctx->{-tmp}/h: $!";
 136         chop(my $buf = do { local $/ = "\0"; <$fh> });
 137         chomp $buf;
 138         my ($P, $p);
 139         ($P, $p, @{$ctx->{cmt_info}}) = split(/\n/, $buf, 9);
 140         return cmt_finalize($ctx) if !$P;
 141         @{$ctx->{-cmt_P}} = split(/ /, $P);
 142         @{$ctx->{-cmt_p}} = split(/ /, $p); # abbreviated
 143         if ($ctx->{env}->{'pi-httpd.async'}) {
 144                 for (@{$ctx->{-cmt_P}}) {
 145                         ibx_async_cat($ctx, $_, \&cmt_title, $ctx);
 146                 }
 147         } else { # synchronous
 148                 for (@{$ctx->{-cmt_P}}) {
 149                         $ctx->{git}->cat_async($_, \&cmt_title, $ctx);
 150                 }
 151                 $ctx->{git}->cat_async_wait;
 152         }
 153 }
 154
 155 sub cmt_finalize {
 156         my ($ctx) = @_;
 157         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 158         my $upfx = $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
 159         my ($H, $T, $s, $f, $au, $co, $bdy) = @{delete $ctx->{cmt_info}};
 160         # try to keep author and committer dates lined up
 161         my $x = length($au) - length($co);
 162         if ($x > 0) {
 163                 $x = ' ' x $x;
 164                 $co =~ s/>/>$x/;
 165         } elsif ($x < 0) {
 166                 $x = ' ' x (-$x);
 167                 $au =~ s/>/>$x/;
 168         }
 169         $_ = ascii_html($_) for ($au, $co);
 170         $au =~ s!(&gt; +)([0-9]{4,}-\S+ \S+)!
 171                 my ($gt, $t) = ($1, $2);
 172                 $t =~ tr/ :-//d;
 173                 qq($gt<a
 174 href="$upfx?t=$t"
 175 title="list contemporary emails">$2</a>)
 176                 !e;
 177         $ctx->{-title_html} = $s = $ctx->{-linkify}->to_html($s);
 178         my ($P, $p, $pt) = delete @$ctx{qw(-cmt_P -cmt_p -cmt_pt)};
 179         $_ = qq(<a href="$upfx$_/s/">).shift(@$p).'</a> '.shift(@$pt) for @$P;
 180         if (@$P == 1) {
 181                 $x = qq{ (<a
 182 href="$f.patch">patch</a>)\n   parent $P->[0]};
 183         } elsif (@$P > 1) {
 184                 $x = qq(\n  parents $P->[0]\n);
 185                 shift @$P;
 186                 $x .= qq(          $_\n) for @$P;
 187                 chop $x;
 188         } else {
 189                 $x = ' (root commit)';
 190         }
 191         PublicInbox::WwwStream::html_init($ctx);
 192         $ctx->zmore(<<EOM);
 193 <pre>   commit $H$x
 194      tree <a href="$upfx$T/s/">$T</a>
 195    author $au
 196 committer $co
 197
 198 <b>$s</b>
 199 EOM
 200         $ctx->zmore("\n", $ctx->{-linkify}->to_html($bdy)) if length($bdy);
 201         $bdy = '';
 202         open my $fh, '<:utf8', "$ctx->{-tmp}/p" or
 203                 die "open $ctx->{-tmp}/p: $!";
 204         if (-s $fh > $MAX_SIZE) {
 205                 $ctx->zmore("---\n patch is too large to show\n");
 206         } else { # prepare flush_diff:
 207                 read($fh, $x, -s _);
 208                 $ctx->{obuf} = \$bdy;
 209                 $ctx->{-apfx} = $ctx->{-spfx} = $upfx;
 210                 $x =~ s/\r?\n/\n/gs;
 211                 $ctx->{-anchors} = {} if $x =~ /^diff --git /sm;
 212                 flush_diff($ctx, \$x); # undefs $x
 213                 $ctx->zmore($bdy);
 214                 undef $bdy;
 215                 # TODO: should there be another textarea which attempts to
 216                 # search for the exact email which was applied to make this
 217                 # commit?
 218                 if (my $qry = delete $ctx->{-qry}) {
 219                         my $q = '';
 220                         for (@{$qry->{dfpost}}, @{$qry->{dfpre}}) {
 221                                 # keep blobs as short as reasonable, emails
 222                                 # are going to be older than what's in git
 223                                 substr($_, 7, 64, '');
 224                                 $q .= "dfblob:$_ ";
 225                         }
 226                         chop $q; # no trailing SP
 227                         local $Text::Wrap::columns = PublicInbox::View::COLS;
 228                         local $Text::Wrap::huge = 'overflow';
 229                         $q = wrap('', '', $q);
 230                         my $rows = ($q =~ tr/\n/\n/) + 1;
 231                         $q = ascii_html($q);
 232                         $ctx->zmore(<<EOM);
 233 <hr><form action=$upfx
 234 id=related><pre>find related emails, including ancestors/descendants/conflicts
 235 <textarea name=q cols=${\PublicInbox::View::COLS} rows=$rows>$q</textarea>
 236 <input type=submit value=search
 237 />\t(<a href=${upfx}_/text/help/>help</a>)</pre></form>
 238 EOM
 239                 }
 240         }
 241         $x = $ctx->zflush($ctx->_html_end);
 242         my $res_hdr = delete $ctx->{-res_hdr};
 243         push @$res_hdr, 'Content-Length', length($x);
 244         delete($ctx->{env}->{'qspawn.wcb'})->([200, $res_hdr, [$x]]);
 245 }
 246
 247 sub stream_patch_parse_hdr { # {parse_hdr} for Qspawn
 248         my ($r, $bref, $ctx) = @_;
 249         if (!defined $r) { # sysread error
 250                 html_page($ctx, 500, dbg_log($ctx));
 251         } elsif (index($$bref, "\n\n") >= 0) {
 252                 my $eml = bless { hdr => $bref }, 'PublicInbox::Eml';
 253                 my $fn = to_filename($eml->header('Subject') // '');
 254                 $fn = substr($fn // 'PATCH-no-subject', 6); # drop "PATCH-"
 255                 return [ 200, [ 'Content-Type', 'text/plain; charset=UTF-8',
 256                                 'Content-Disposition',
 257                                 qq(inline; filename=$fn.patch) ] ];
 258         } elsif ($r == 0) {
 259                 my $log = dbg_log($ctx);
 260                 warn "premature EOF on $ctx->{patch_oid} $log";
 261                 return html_page($ctx, 500, $log);
 262         } else {
 263                 undef; # bref keeps growing until "\n\n"
 264         }
 265 }
 266
 267 sub show_patch ($$) {
 268         my ($ctx, $res) = @_;
 269         my ($git, $oid) = @$res;
 270         my @cmd = ('git', "--git-dir=$git->{git_dir}",
 271                 qw(format-patch -1 --stdout -C),
 272                 "--signature=git format-patch -1 --stdout -C $oid", $oid);
 273         my $qsp = PublicInbox::Qspawn->new(\@cmd);
 274         $ctx->{env}->{'qspawn.wcb'} = delete $ctx->{-wcb};
 275         $ctx->{patch_oid} = $oid;
 276         $qsp->psgi_return($ctx->{env}, undef, \&stream_patch_parse_hdr, $ctx);
 277 }
 278
 279 sub show_commit ($$) {
 280         my ($ctx, $res) = @_;
 281         return show_patch($ctx, $res) if ($ctx->{fn} // '') =~ /\.patch\z/;
 282         my ($git, $oid) = @$res;
 283         # patch-id needs two passes, and we use the initial show to ensure
 284         # a patch embedded inside the commit message body doesn't get fed
 285         # to patch-id:
 286         my $cmd = [ '/bin/sh', '-c',
 287                 "git show --encoding=UTF-8 '$SHOW_FMT'".
 288                 " -z --no-notes --no-patch $oid >h && ".
 289                 'git show --encoding=UTF-8 --pretty=format:%n -M'.
 290                 " --stat -p $oid >p && ".
 291                 "git patch-id --stable <p" ];
 292         my $e = { GIT_DIR => $git->{git_dir} };
 293         my $qsp = PublicInbox::Qspawn->new($cmd, $e, { -C => "$ctx->{-tmp}" });
 294         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 295         $ctx->{env}->{'qspawn.wcb'} = delete $ctx->{-wcb};
 296         $ctx->{git} = $git;
 297         $qsp->psgi_qx($ctx->{env}, undef, \&show_commit_start, $ctx);
 298 }
 299
 300 sub show_other ($$) {
 301         my ($ctx, $res) = @_;
 302         my ($git, $oid, $type, $size) = @$res;
 303         $size > $MAX_SIZE and return html_page($ctx, 200,
 304                 ascii_html($type)." $oid is too big to show\n". dbg_log($ctx));
 305         my $cmd = ['git', "--git-dir=$git->{git_dir}",
 306                 qw(show --encoding=UTF-8 --no-color --no-abbrev), $oid ];
 307         my $qsp = PublicInbox::Qspawn->new($cmd);
 308         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 309         $qsp->psgi_qx($ctx->{env}, undef, \&show_other_result, $ctx);
 310 }
 311
 312 sub show_tree_result ($$) {
 313         my ($bref, $ctx) = @_;
 314         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 315                 return html_page($ctx, 500, dbg_log($ctx) .
 316                                 "git ls-tree -z error:$qsp_err");
 317         }
 318         my @ent = split(/\0/, $$bref);
 319         my $qp = delete $ctx->{qp};
 320         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 321         my $pfx = $qp->{b};
 322         $$bref = "<pre><a href=#tree>tree</a> $ctx->{tree_oid}";
 323         if (defined $pfx) {
 324                 my $x = ascii_html($pfx);
 325                 $pfx .= '/';
 326                 $$bref .= qq(  <a href=#path>path</a>: $x</a>\n);
 327         } else {
 328                 $pfx = '';
 329                 $$bref .= qq[  (<a href=#path>path</a> unknown)\n];
 330         }
 331         my ($x, $m, $t, $oid, $sz, $f, $n);
 332         $$bref .= "\n   size    name";
 333         for (@ent) {
 334                 ($x, $f) = split(/\t/, $_, 2);
 335                 undef $_;
 336                 ($m, $t, $oid, $sz) = split(/ +/, $x, 4);
 337                 $m = $GIT_MODE{$m} // '?';
 338                 utf8::decode($f);
 339                 $n = ascii_html($f);
 340                 if ($m eq 'g') { # gitlink submodule commit
 341                         $$bref .= "\ng\t\t$n @ <a\nhref=#g>commit</a>$oid";
 342                         next;
 343                 }
 344                 my $q = 'b='.ascii_html(uri_escape_path($pfx.$f));
 345                 if ($m eq 'd') { $n .= '/' }
 346                 elsif ($m eq 'x') { $n = "<b>$n</b>" }
 347                 elsif ($m eq 'l') { $n = "<i>$n</i>" }
 348                 $$bref .= qq(\n$m\t$sz\t<a\nhref="../../$oid/s/?$q">$n</a>);
 349         }
 350         $$bref .= dbg_log($ctx);
 351         $$bref .= <<EOM;
 352 <pre>glossary
 353 --------
 354 <dfn
 355 id=tree>Tree</dfn> objects belong to commits or other tree objects.  Trees may
 356 reference blobs, sub-trees, or commits of submodules.
 357
 358 <dfn
 359 id=path>Path</dfn> names are stored in tree objects, but trees do not know
 360 their own path name.  A tree's path name comes from their parent tree,
 361 or it is the root tree referenced by a commit object.  Thus, this web UI
 362 relies on the `b=' URI parameter as a hint to display the path name.
 363
 364 <dfn title="submodule commit"
 365 id=g>Commit</dfn> objects may be stored in trees to reference submodules.</pre>
 366 EOM
 367         chop $$bref;
 368         html_page($ctx, 200, $$bref);
 369 }
 370
 371 sub show_tree ($$) {
 372         my ($ctx, $res) = @_;
 373         my ($git, $oid, undef, $size) = @$res;
 374         $size > $MAX_SIZE and return html_page($ctx, 200,
 375                         "tree $oid is too big to show\n". dbg_log($ctx));
 376         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 377                 qw(ls-tree -z -l --no-abbrev), $oid ];
 378         my $qsp = PublicInbox::Qspawn->new($cmd);
 379         $ctx->{tree_oid} = $oid;
 380         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 381         $qsp->psgi_qx($ctx->{env}, undef, \&show_tree_result, $ctx);
 382 }
 383
 384 # user_cb for SolverGit, called as: user_cb->($result_or_error, $uarg)
 385 sub solve_result {
 386         my ($res, $ctx) = @_;
 387         my $hints = delete $ctx->{hints};
 388         $res or return html_page($ctx, 404, dbg_log($ctx));
 389         ref($res) eq 'ARRAY' or return html_page($ctx, 500, dbg_log($ctx));
 390
 391         my ($git, $oid, $type, $size, $di) = @$res;
 392         return show_commit($ctx, $res) if $type eq 'commit';
 393         return show_tree($ctx, $res) if $type eq 'tree';
 394         return show_other($ctx, $res) if $type ne 'blob';
 395         my $path = to_filename($di->{path_b} // $hints->{path_b} // 'blob');
 396         my $raw_link = "(<a\nhref=$path>raw</a>)";
 397         if ($size > $MAX_SIZE) {
 398                 return stream_large_blob($ctx, $res) if defined $ctx->{fn};
 399                 return html_page($ctx, 200, <<EOM . dbg_log($ctx));
 400 <pre><b>Too big to show, download available</b>
 401 "$oid $type $size bytes $raw_link</pre>
 402 EOM
 403         }
 404
 405         my $blob = $git->cat_file($oid);
 406         if (!$blob) { # WTF?
 407                 my $e = "Failed to retrieve generated blob ($oid)";
 408                 warn "$e ($git->{git_dir})";
 409                 return html_page($ctx, 500, "<pre><b>$e</b></pre>".dbg_log($ctx))
 410         }
 411
 412         my $bin = index(substr($$blob, 0, $BIN_DETECT), "\0") >= 0;
 413         if (defined $ctx->{fn}) {
 414                 my $h = [ 'Content-Length', $size, 'Content-Type' ];
 415                 push(@$h, ($bin ? 'application/octet-stream' : 'text/plain'));
 416                 return delete($ctx->{-wcb})->([200, $h, [ $$blob ]]);
 417         }
 418
 419         $bin and return html_page($ctx, 200,
 420                                 "<pre>$oid $type $size bytes (binary)" .
 421                                 " $raw_link</pre>".dbg_log($ctx));
 422
 423         # TODO: detect + convert to ensure validity
 424         utf8::decode($$blob);
 425         my $nl = ($$blob =~ s/\r?\n/\n/sg);
 426         my $pad = length($nl);
 427
 428         ($ctx->{-linkify} //= PublicInbox::Linkify->new)->linkify_1($$blob);
 429         my $ok = $hl->do_hl($blob, $path) if $hl;
 430         if ($ok) {
 431                 $blob = $ok;
 432         } else {
 433                 $$blob = ascii_html($$blob);
 434         }
 435
 436         my $x = "<pre>$oid $type $size bytes $raw_link</pre>" .
 437                 "<hr /><table\nclass=blob>".
 438                 "<tr><td\nclass=linenumbers><pre>";
 439         $x .= sprintf("<a id=n$_ href=#n$_>% ${pad}u</a>\n", $_) for (1..$nl);
 440         $x .= '</pre></td><td><pre> </pre></td>'. # pad for non-CSS users
 441                 "<td\nclass=lines><pre\nstyle='white-space:pre'><code>";
 442
 443         # using some of the same CSS class names and ids as cgit
 444         html_page($ctx, 200, $x, $ctx->{-linkify}->linkify_2($$blob),
 445                 '</code></pre></td></tr></table>'.dbg_log($ctx));
 446 }
 447
 448 # GET /$INBOX/$GIT_OBJECT_ID/s/
 449 # GET /$INBOX/$GIT_OBJECT_ID/s/$FILENAME
 450 sub show ($$;$) {
 451         my ($ctx, $oid_b, $fn) = @_;
 452         my $qp = $ctx->{qp};
 453         my $hints = $ctx->{hints} = {};
 454         while (my ($from, $to) = each %QP_MAP) {
 455                 defined(my $v = $qp->{$from}) or next;
 456                 $hints->{$to} = $v if $v ne '';
 457         }
 458         $ctx->{fn} = $fn;
 459         $ctx->{-tmp} = File::Temp->newdir("solver.$oid_b-XXXX", TMPDIR => 1);
 460         open $ctx->{lh}, '+>>', "$ctx->{-tmp}/solve.log" or die "open: $!";
 461         my $solver = PublicInbox::SolverGit->new($ctx->{ibx},
 462                                                 \&solve_result, $ctx);
 463         $solver->{tmp} = $ctx->{-tmp}; # share tmpdir
 464         # PSGI server will call this immediately and give us a callback (-wcb)
 465         sub {
 466                 $ctx->{-wcb} = $_[0]; # HTTP write callback
 467                 $solver->solve($ctx->{env}, $ctx->{lh}, $oid_b, $hints);
 468         };
 469 }
 470
 471 1;