lib/PublicInbox/ViewVCS.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # show any VCS object, similar to "git show"
   5 #
   6 # This can use a "solver" to reconstruct blobs based on git
   7 # patches (with abbreviated OIDs in the header).  However, the
   8 # abbreviated OIDs must match exactly what's in the original
   9 # email (unless a normal code repo already has the blob).
  10 #
  11 # In other words, we can only reliably reconstruct blobs based
  12 # on links generated by ViewDiff (and only if the emailed
  13 # patches apply 100% cleanly to published blobs).
  14
  15 package PublicInbox::ViewVCS;
  16 use strict;
  17 use v5.10.1;
  18 use File::Temp 0.19 (); # newdir
  19 use PublicInbox::SolverGit;
  20 use PublicInbox::GitAsyncCat;
  21 use PublicInbox::WwwStream qw(html_oneshot);
  22 use PublicInbox::Linkify;
  23 use PublicInbox::Tmpfile;
  24 use PublicInbox::ViewDiff qw(flush_diff uri_escape_path);
  25 use PublicInbox::View;
  26 use PublicInbox::Eml;
  27 use Text::Wrap qw(wrap);
  28 use PublicInbox::Hval qw(ascii_html to_filename);
  29 my $hl = eval {
  30         require PublicInbox::HlMod;
  31         PublicInbox::HlMod->new;
  32 };
  33
  34 my %QP_MAP = ( A => 'oid_a', a => 'path_a', b => 'path_b' );
  35 our $MAX_SIZE = 1024 * 1024; # TODO: configurable
  36 my $BIN_DETECT = 8000; # same as git
  37 my $SHOW_FMT = '--pretty=format:'.join('%n', '%P', '%p', '%H', '%T', '%s', '%f',
  38         '%an <%ae>  %ai', '%cn <%ce>  %ci', '%b%x00');
  39
  40 my %GIT_MODE = (
  41         '100644' => ' ', # blob
  42         '100755' => 'x', # executable blob
  43         '040000' => 'd', # tree
  44         '120000' => 'l', # symlink
  45         '160000' => 'g', # commit (gitlink)
  46 );
  47
  48 sub html_page ($$;@) {
  49         my ($ctx, $code) = @_[0, 1];
  50         my $wcb = delete $ctx->{-wcb};
  51         $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
  52         my $res = html_oneshot($ctx, $code, @_[2..$#_]);
  53         $wcb ? $wcb->($res) : $res;
  54 }
  55
  56 sub dbg_log ($) {
  57         my ($ctx) = @_;
  58         my $log = delete $ctx->{lh} // die 'BUG: already captured debug log';
  59         if (!seek($log, 0, 0)) {
  60                 warn "seek(log): $!";
  61                 return '<pre>debug log seek error</pre>';
  62         }
  63         $log = do { local $/; <$log> } // do {
  64                 warn "readline(log): $!";
  65                 return '<pre>debug log read error</pre>';
  66         };
  67         $ctx->{-linkify} //= PublicInbox::Linkify->new;
  68         "<hr><pre>debug log:\n\n".
  69                 $ctx->{-linkify}->to_html($log).'</pre>';
  70 }
  71
  72 sub stream_blob_parse_hdr { # {parse_hdr} for Qspawn
  73         my ($r, $bref, $ctx) = @_;
  74         my ($git, $oid, $type, $size, $di) = @{$ctx->{-res}};
  75         my @cl = ('Content-Length', $size);
  76         if (!defined $r) { # sysread error
  77                 html_page($ctx, 500, dbg_log($ctx));
  78         } elsif (index($$bref, "\0") >= 0) {
  79                 [200, [qw(Content-Type application/octet-stream), @cl] ];
  80         } else {
  81                 my $n = length($$bref);
  82                 if ($n >= $BIN_DETECT || $n == $size) {
  83                         return [200, [ 'Content-Type',
  84                                 'text/plain; charset=UTF-8', @cl ] ];
  85                 }
  86                 if ($r == 0) {
  87                         my $log = dbg_log($ctx);
  88                         warn "premature EOF on $oid $log";
  89                         return html_page($ctx, 500, $log);
  90                 }
  91                 undef; # bref keeps growing
  92         }
  93 }
  94
  95 sub stream_large_blob ($$) {
  96         my ($ctx, $res) = @_;
  97         $ctx->{-res} = $res;
  98         my ($git, $oid, $type, $size, $di) = @$res;
  99         my $cmd = ['git', "--git-dir=$git->{git_dir}", 'cat-file', $type, $oid];
 100         my $qsp = PublicInbox::Qspawn->new($cmd);
 101         my $env = $ctx->{env};
 102         $env->{'qspawn.wcb'} = delete $ctx->{-wcb};
 103         $qsp->psgi_return($env, undef, \&stream_blob_parse_hdr, $ctx);
 104 }
 105
 106 sub show_other_result ($$) { # tag
 107         my ($bref, $ctx) = @_;
 108         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 109                 return html_page($ctx, 500, dbg_log($ctx) .
 110                                 "git show error:$qsp_err");
 111         }
 112         my $l = PublicInbox::Linkify->new;
 113         utf8::decode($$bref);
 114         html_page($ctx, 200, '<pre>', $l->to_html($$bref), '</pre><hr>',
 115                 dbg_log($ctx));
 116 }
 117
 118 sub cmt_title { # git->cat_async callback
 119         my ($bref, $oid, $type, $size, $ctx) = @_;
 120         utf8::decode($$bref);
 121         my $title = $$bref =~ /\r?\n\r?\n([^\r\n]+)\r?\n?/ ? $1 : '';
 122         push(@{$ctx->{-cmt_pt}} , ascii_html($title)) == @{$ctx->{-cmt_P}} and
 123                 cmt_finalize($ctx);
 124 }
 125
 126 sub show_commit_start { # ->psgi_qx callback
 127         my ($bref, $ctx) = @_;
 128         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 129                 return html_page($ctx, 500, dbg_log($ctx) .
 130                                 "git show/patch-id error:$qsp_err");
 131         }
 132         my $patchid = (split(/ /, $$bref))[0]; # ignore commit
 133         $ctx->{-q_value_html} = "patchid:$patchid" if defined $patchid;
 134         open my $fh, '<:utf8', "$ctx->{-tmp}/h" or
 135                 die "open $ctx->{-tmp}/h: $!";
 136         chop(my $buf = do { local $/ = "\0"; <$fh> });
 137         chomp $buf;
 138         my ($P, $p);
 139         ($P, $p, @{$ctx->{cmt_info}}) = split(/\n/, $buf, 9);
 140         return cmt_finalize($ctx) if !$P;
 141         @{$ctx->{-cmt_P}} = split(/ /, $P);
 142         @{$ctx->{-cmt_p}} = split(/ /, $p); # abbreviated
 143         if ($ctx->{env}->{'pi-httpd.async'}) {
 144                 for (@{$ctx->{-cmt_P}}) {
 145                         ibx_async_cat($ctx, $_, \&cmt_title, $ctx);
 146                 }
 147         } else { # synchronous
 148                 for (@{$ctx->{-cmt_P}}) {
 149                         $ctx->{git}->cat_async($_, \&cmt_title, $ctx);
 150                 }
 151                 $ctx->{git}->cat_async_wait;
 152         }
 153 }
 154
 155 sub cmt_finalize {
 156         my ($ctx) = @_;
 157         $ctx->{-linkify} //= PublicInbox::Linkify->new;
 158         my $upfx = $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
 159         my ($H, $T, $s, $f, $au, $co, $bdy) = @{delete $ctx->{cmt_info}};
 160         # try to keep author and committer dates lined up
 161         my $x = length($au) - length($co);
 162         if ($x > 0) {
 163                 $x = ' ' x $x;
 164                 $co =~ s/>/>$x/;
 165         } elsif ($x < 0) {
 166                 $x = ' ' x (-$x);
 167                 $au =~ s/>/>$x/;
 168         }
 169         $_ = ascii_html($_) for ($au, $co);
 170         $au =~ s!(&gt; +)([0-9]{4,}-\S+ \S+)!
 171                 my ($gt, $t) = ($1, $2);
 172                 $t =~ tr/ :-//d;
 173                 qq($gt<a
 174 href="$upfx?t=$t"
 175 title="list contemporary emails">$2</a>)
 176                 !e;
 177         $ctx->{-title_html} = $s = $ctx->{-linkify}->to_html($s);
 178         my ($P, $p, $pt) = delete @$ctx{qw(-cmt_P -cmt_p -cmt_pt)};
 179         $_ = qq(<a href="$upfx$_/s/">).shift(@$p).'</a> '.shift(@$pt) for @$P;
 180         if (@$P == 1) {
 181                 $x = qq{ (<a
 182 href="$f.patch">patch</a>)\n   <a href=#parent>parent</a> $P->[0]};
 183         } elsif (@$P > 1) {
 184                 $x = qq(\n  <a href=#parents>parents</a> $P->[0]\n);
 185                 shift @$P;
 186                 $x .= qq(          $_\n) for @$P;
 187                 chop $x;
 188         } else {
 189                 $x = ' (<a href=#root_commit>root commit</a>)';
 190         }
 191         PublicInbox::WwwStream::html_init($ctx);
 192         $ctx->zmore(<<EOM);
 193 <pre>   <a href=#commit>commit</a> $H$x
 194      <a href=#tree>tree</a> <a href="$upfx$T/s/">$T</a>
 195    author $au
 196 committer $co
 197
 198 <b>$s</b>
 199 EOM
 200         $ctx->zmore("\n", $ctx->{-linkify}->to_html($bdy)) if length($bdy);
 201         $bdy = '';
 202         open my $fh, '<:utf8', "$ctx->{-tmp}/p" or
 203                 die "open $ctx->{-tmp}/p: $!";
 204         if (-s $fh > $MAX_SIZE) {
 205                 $ctx->zmore("---\n patch is too large to show\n");
 206         } else { # prepare flush_diff:
 207                 read($fh, $x, -s _);
 208                 $ctx->{obuf} = \$bdy;
 209                 $ctx->{-apfx} = $ctx->{-spfx} = $upfx;
 210                 $x =~ s/\r?\n/\n/gs;
 211                 $ctx->{-anchors} = {} if $x =~ /^diff --git /sm;
 212                 flush_diff($ctx, \$x); # undefs $x
 213                 # TODO: should there be another textarea which attempts to
 214                 # search for the exact email which was applied to make this
 215                 # commit?
 216                 if (my $qry = delete $ctx->{-qry}) {
 217                         my $q = '';
 218                         for (@{$qry->{dfpost}}, @{$qry->{dfpre}}) {
 219                                 # keep blobs as short as reasonable, emails
 220                                 # are going to be older than what's in git
 221                                 substr($_, 7, 64, '');
 222                                 $q .= "dfblob:$_ ";
 223                         }
 224                         chop $q; # no trailing SP
 225                         local $Text::Wrap::columns = PublicInbox::View::COLS;
 226                         local $Text::Wrap::huge = 'overflow';
 227                         $q = wrap('', '', $q);
 228                         my $rows = ($q =~ tr/\n/\n/) + 1;
 229                         $q = ascii_html($q);
 230                         $ctx->zmore(<<EOM);
 231 <hr><form action=$upfx
 232 id=related><pre>find related emails, including ancestors/descendants/conflicts
 233 <textarea name=q cols=${\PublicInbox::View::COLS} rows=$rows>$q</textarea>
 234 <input type=submit value=search
 235 />\t(<a href=${upfx}_/text/help/>help</a>)</pre></form>
 236 EOM
 237                 }
 238         }
 239         chop($x = <<EOM);
 240 <hr><pre>glossary
 241 --------
 242 <dfn
 243 id=commit>Commit</dfn> objects reference one tree, and zero or more parents.
 244
 245 Single <dfn
 246 id=parent>parent</dfn> commits can typically generate a patch in
 247 unified diff format via `git format-patch'.
 248
 249 Multiple <dfn id=parents>parents</dfn> means the commit is a merge.
 250
 251 <dfn id=root_commit>Root commits</dfn> have no ancestor.  Note that it is
 252 possible to have multiple root commits when merging independent histories.
 253
 254 Every commit references one top-level <dfn id=tree>tree</dfn> object.</pre>
 255 EOM
 256         $x = $ctx->zflush($x, $ctx->_html_end);
 257         my $res_hdr = delete $ctx->{-res_hdr};
 258         push @$res_hdr, 'Content-Length', length($x);
 259         delete($ctx->{env}->{'qspawn.wcb'})->([200, $res_hdr, [$x]]);
 260 }
 261
 262 sub stream_patch_parse_hdr { # {parse_hdr} for Qspawn
 263         my ($r, $bref, $ctx) = @_;
 264         if (!defined $r) { # sysread error
 265                 html_page($ctx, 500, dbg_log($ctx));
 266         } elsif (index($$bref, "\n\n") >= 0) {
 267                 my $eml = bless { hdr => $bref }, 'PublicInbox::Eml';
 268                 my $fn = to_filename($eml->header('Subject') // '');
 269                 $fn = substr($fn // 'PATCH-no-subject', 6); # drop "PATCH-"
 270                 return [ 200, [ 'Content-Type', 'text/plain; charset=UTF-8',
 271                                 'Content-Disposition',
 272                                 qq(inline; filename=$fn.patch) ] ];
 273         } elsif ($r == 0) {
 274                 my $log = dbg_log($ctx);
 275                 warn "premature EOF on $ctx->{patch_oid} $log";
 276                 return html_page($ctx, 500, $log);
 277         } else {
 278                 undef; # bref keeps growing until "\n\n"
 279         }
 280 }
 281
 282 sub show_patch ($$) {
 283         my ($ctx, $res) = @_;
 284         my ($git, $oid) = @$res;
 285         my @cmd = ('git', "--git-dir=$git->{git_dir}",
 286                 qw(format-patch -1 --stdout -C),
 287                 "--signature=git format-patch -1 --stdout -C $oid", $oid);
 288         my $qsp = PublicInbox::Qspawn->new(\@cmd);
 289         $ctx->{env}->{'qspawn.wcb'} = delete $ctx->{-wcb};
 290         $ctx->{patch_oid} = $oid;
 291         $qsp->psgi_return($ctx->{env}, undef, \&stream_patch_parse_hdr, $ctx);
 292 }
 293
 294 sub show_commit ($$) {
 295         my ($ctx, $res) = @_;
 296         return show_patch($ctx, $res) if ($ctx->{fn} // '') =~ /\.patch\z/;
 297         my ($git, $oid) = @$res;
 298         # patch-id needs two passes, and we use the initial show to ensure
 299         # a patch embedded inside the commit message body doesn't get fed
 300         # to patch-id:
 301         my $cmd = [ '/bin/sh', '-c',
 302                 "git show --encoding=UTF-8 '$SHOW_FMT'".
 303                 " -z --no-notes --no-patch $oid >h && ".
 304                 'git show --encoding=UTF-8 --pretty=format:%n -M'.
 305                 " --stat -p $oid >p && ".
 306                 "git patch-id --stable <p" ];
 307         my $e = { GIT_DIR => $git->{git_dir} };
 308         my $qsp = PublicInbox::Qspawn->new($cmd, $e, { -C => "$ctx->{-tmp}" });
 309         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 310         $ctx->{env}->{'qspawn.wcb'} = delete $ctx->{-wcb};
 311         $ctx->{git} = $git;
 312         $qsp->psgi_qx($ctx->{env}, undef, \&show_commit_start, $ctx);
 313 }
 314
 315 sub show_other ($$) {
 316         my ($ctx, $res) = @_;
 317         my ($git, $oid, $type, $size) = @$res;
 318         $size > $MAX_SIZE and return html_page($ctx, 200,
 319                 ascii_html($type)." $oid is too big to show\n". dbg_log($ctx));
 320         my $cmd = ['git', "--git-dir=$git->{git_dir}",
 321                 qw(show --encoding=UTF-8 --no-color --no-abbrev), $oid ];
 322         my $qsp = PublicInbox::Qspawn->new($cmd);
 323         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 324         $qsp->psgi_qx($ctx->{env}, undef, \&show_other_result, $ctx);
 325 }
 326
 327 sub show_tree_result ($$) {
 328         my ($bref, $ctx) = @_;
 329         if (my $qsp_err = delete $ctx->{-qsp_err}) {
 330                 return html_page($ctx, 500, dbg_log($ctx) .
 331                                 "git ls-tree -z error:$qsp_err");
 332         }
 333         my @ent = split(/\0/, $$bref);
 334         my $qp = delete $ctx->{qp};
 335         my $l = $ctx->{-linkify} //= PublicInbox::Linkify->new;
 336         my $pfx = $qp->{b};
 337         $$bref = "<pre><a href=#tree>tree</a> $ctx->{tree_oid}";
 338         if (defined $pfx) {
 339                 my $x = ascii_html($pfx);
 340                 $pfx .= '/';
 341                 $$bref .= qq(  <a href=#path>path</a>: $x</a>\n);
 342         } else {
 343                 $pfx = '';
 344                 $$bref .= qq[  (<a href=#path>path</a> unknown)\n];
 345         }
 346         my ($x, $m, $t, $oid, $sz, $f, $n);
 347         $$bref .= "\n   size    name";
 348         for (@ent) {
 349                 ($x, $f) = split(/\t/, $_, 2);
 350                 undef $_;
 351                 ($m, $t, $oid, $sz) = split(/ +/, $x, 4);
 352                 $m = $GIT_MODE{$m} // '?';
 353                 utf8::decode($f);
 354                 $n = ascii_html($f);
 355                 if ($m eq 'g') { # gitlink submodule commit
 356                         $$bref .= "\ng\t\t$n @ <a\nhref=#g>commit</a>$oid";
 357                         next;
 358                 }
 359                 my $q = 'b='.ascii_html(uri_escape_path($pfx.$f));
 360                 if ($m eq 'd') { $n .= '/' }
 361                 elsif ($m eq 'x') { $n = "<b>$n</b>" }
 362                 elsif ($m eq 'l') { $n = "<i>$n</i>" }
 363                 $$bref .= qq(\n$m\t$sz\t<a\nhref="../../$oid/s/?$q">$n</a>);
 364         }
 365         $$bref .= dbg_log($ctx);
 366         $$bref .= <<EOM;
 367 <pre>glossary
 368 --------
 369 <dfn
 370 id=tree>Tree</dfn> objects belong to commits or other tree objects.  Trees may
 371 reference blobs, sub-trees, or commits of submodules.
 372
 373 <dfn
 374 id=path>Path</dfn> names are stored in tree objects, but trees do not know
 375 their own path name.  A tree's path name comes from their parent tree,
 376 or it is the root tree referenced by a commit object.  Thus, this web UI
 377 relies on the `b=' URI parameter as a hint to display the path name.
 378
 379 <dfn title="submodule commit"
 380 id=g>Commit</dfn> objects may be stored in trees to reference submodules.</pre>
 381 EOM
 382         chop $$bref;
 383         html_page($ctx, 200, $$bref);
 384 }
 385
 386 sub show_tree ($$) {
 387         my ($ctx, $res) = @_;
 388         my ($git, $oid, undef, $size) = @$res;
 389         $size > $MAX_SIZE and return html_page($ctx, 200,
 390                         "tree $oid is too big to show\n". dbg_log($ctx));
 391         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 392                 qw(ls-tree -z -l --no-abbrev), $oid ];
 393         my $qsp = PublicInbox::Qspawn->new($cmd);
 394         $ctx->{tree_oid} = $oid;
 395         $qsp->{qsp_err} = \($ctx->{-qsp_err} = '');
 396         $qsp->psgi_qx($ctx->{env}, undef, \&show_tree_result, $ctx);
 397 }
 398
 399 # user_cb for SolverGit, called as: user_cb->($result_or_error, $uarg)
 400 sub solve_result {
 401         my ($res, $ctx) = @_;
 402         my $hints = delete $ctx->{hints};
 403         $res or return html_page($ctx, 404, dbg_log($ctx));
 404         ref($res) eq 'ARRAY' or return html_page($ctx, 500, dbg_log($ctx));
 405
 406         my ($git, $oid, $type, $size, $di) = @$res;
 407         return show_commit($ctx, $res) if $type eq 'commit';
 408         return show_tree($ctx, $res) if $type eq 'tree';
 409         return show_other($ctx, $res) if $type ne 'blob';
 410         my $path = to_filename($di->{path_b} // $hints->{path_b} // 'blob');
 411         my $raw_link = "(<a\nhref=$path>raw</a>)";
 412         if ($size > $MAX_SIZE) {
 413                 return stream_large_blob($ctx, $res) if defined $ctx->{fn};
 414                 return html_page($ctx, 200, <<EOM . dbg_log($ctx));
 415 <pre><b>Too big to show, download available</b>
 416 blob $oid $size bytes $raw_link</pre>
 417 EOM
 418         }
 419
 420         my $blob = $git->cat_file($oid);
 421         if (!$blob) { # WTF?
 422                 my $e = "Failed to retrieve generated blob ($oid)";
 423                 warn "$e ($git->{git_dir})";
 424                 return html_page($ctx, 500, "<pre><b>$e</b></pre>".dbg_log($ctx))
 425         }
 426
 427         my $bin = index(substr($$blob, 0, $BIN_DETECT), "\0") >= 0;
 428         if (defined $ctx->{fn}) {
 429                 my $h = [ 'Content-Length', $size, 'Content-Type' ];
 430                 push(@$h, ($bin ? 'application/octet-stream' : 'text/plain'));
 431                 return delete($ctx->{-wcb})->([200, $h, [ $$blob ]]);
 432         }
 433
 434         $bin and return html_page($ctx, 200,
 435                                 "<pre>blob $oid $size bytes (binary)" .
 436                                 " $raw_link</pre>".dbg_log($ctx));
 437
 438         # TODO: detect + convert to ensure validity
 439         utf8::decode($$blob);
 440         my $nl = ($$blob =~ s/\r?\n/\n/sg);
 441         my $pad = length($nl);
 442
 443         ($ctx->{-linkify} //= PublicInbox::Linkify->new)->linkify_1($$blob);
 444         my $ok = $hl->do_hl($blob, $path) if $hl;
 445         if ($ok) {
 446                 $blob = $ok;
 447         } else {
 448                 $$blob = ascii_html($$blob);
 449         }
 450
 451         my $x = "<pre>blob $oid $size bytes $raw_link</pre>" .
 452                 "<hr /><table\nclass=blob>".
 453                 "<tr><td\nclass=linenumbers><pre>";
 454         $x .= sprintf("<a id=n$_ href=#n$_>% ${pad}u</a>\n", $_) for (1..$nl);
 455         $x .= '</pre></td><td><pre> </pre></td>'. # pad for non-CSS users
 456                 "<td\nclass=lines><pre\nstyle='white-space:pre'><code>";
 457
 458         # using some of the same CSS class names and ids as cgit
 459         html_page($ctx, 200, $x, $ctx->{-linkify}->linkify_2($$blob),
 460                 '</code></pre></td></tr></table>'.dbg_log($ctx));
 461 }
 462
 463 # GET /$INBOX/$GIT_OBJECT_ID/s/
 464 # GET /$INBOX/$GIT_OBJECT_ID/s/$FILENAME
 465 sub show ($$;$) {
 466         my ($ctx, $oid_b, $fn) = @_;
 467         my $qp = $ctx->{qp};
 468         my $hints = $ctx->{hints} = {};
 469         while (my ($from, $to) = each %QP_MAP) {
 470                 defined(my $v = $qp->{$from}) or next;
 471                 $hints->{$to} = $v if $v ne '';
 472         }
 473         $ctx->{fn} = $fn;
 474         $ctx->{-tmp} = File::Temp->newdir("solver.$oid_b-XXXX", TMPDIR => 1);
 475         open $ctx->{lh}, '+>>', "$ctx->{-tmp}/solve.log" or die "open: $!";
 476         my $solver = PublicInbox::SolverGit->new($ctx->{ibx},
 477                                                 \&solve_result, $ctx);
 478         $solver->{tmp} = $ctx->{-tmp}; # share tmpdir
 479         # PSGI server will call this immediately and give us a callback (-wcb)
 480         sub {
 481                 $ctx->{-wcb} = $_[0]; # HTTP write callback
 482                 $solver->solve($ctx->{env}, $ctx->{lh}, $oid_b, $hints);
 483         };
 484 }
 485
 486 1;