lib/PublicInbox/ViewVCS.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # show any VCS object, similar to "git show"
   5 # FIXME: we only show blobs for now
   6 #
   7 # This can use a "solver" to reconstruct blobs based on git
   8 # patches (with abbreviated OIDs in the header).  However, the
   9 # abbreviated OIDs must match exactly what's in the original
  10 # email (unless a normal code repo already has the blob).
  11 #
  12 # In other words, we can only reliably reconstruct blobs based
  13 # on links generated by ViewDiff (and only if the emailed
  14 # patches apply 100% cleanly to published blobs).
  15
  16 package PublicInbox::ViewVCS;
  17 use strict;
  18 use warnings;
  19 use bytes (); # only for bytes::length
  20 use PublicInbox::SolverGit;
  21 use PublicInbox::WwwStream;
  22 use PublicInbox::Linkify;
  23 use PublicInbox::Hval qw(ascii_html to_filename);
  24 my $hl = eval {
  25         require PublicInbox::HlMod;
  26         PublicInbox::HlMod->new;
  27 };
  28
  29 my %QP_MAP = ( A => 'oid_a', B => 'oid_b', a => 'path_a', b => 'path_b' );
  30 my $max_size = 1024 * 1024; # TODO: configurable
  31 my $BIN_DETECT = 8000; # same as git
  32
  33 sub html_page ($$$) {
  34         my ($ctx, $code, $strref) = @_;
  35         my $wcb = delete $ctx->{-wcb};
  36         $ctx->{-upfx} = '../../'; # from "/$INBOX/$OID/s/"
  37         my $res = PublicInbox::WwwStream->response($ctx, $code, sub {
  38                 my ($nr, undef) =  @_;
  39                 $nr == 1 ? $$strref : undef;
  40         });
  41         $wcb ? $wcb->($res) : $res;
  42 }
  43
  44 sub stream_large_blob ($$$$) {
  45         my ($ctx, $res, $logref, $fn) = @_;
  46         my ($git, $oid, $type, $size, $di) = @$res;
  47         my $cmd = ['git', "--git-dir=$git->{git_dir}", 'cat-file', $type, $oid];
  48         my $qsp = PublicInbox::Qspawn->new($cmd);
  49         my @cl = ('Content-Length', $size);
  50         my $env = $ctx->{env};
  51         $env->{'qspawn.wcb'} = delete $ctx->{-wcb};
  52         $qsp->psgi_return($env, undef, sub {
  53                 my ($r, $bref) = @_;
  54                 if (!defined $r) { # error
  55                         html_page($ctx, 500, $logref);
  56                 } elsif (index($$bref, "\0") >= 0) {
  57                         my $ct = 'application/octet-stream';
  58                         [200, ['Content-Type', $ct, @cl ] ];
  59                 } else {
  60                         my $n = bytes::length($$bref);
  61                         if ($n >= $BIN_DETECT || $n == $size) {
  62                                 my $ct = 'text/plain; charset=UTF-8';
  63                                 return [200, ['Content-Type', $ct, @cl] ];
  64                         }
  65                         if ($r == 0) {
  66                                 warn "premature EOF on $oid $$logref\n";
  67                                 return html_page($ctx, 500, $logref);
  68                         }
  69                         undef; # bref keeps growing
  70                 }
  71         });
  72 }
  73
  74 sub solve_result {
  75         my ($ctx, $res, $log, $hints, $fn) = @_;
  76
  77         unless (seek($log, 0, 0)) {
  78                 $ctx->{env}->{'psgi.errors'}->print("seek(log): $!\n");
  79                 return html_page($ctx, 500, \'seek error');
  80         }
  81         $log = do { local $/; <$log> };
  82
  83         my $ref = ref($res);
  84         my $l = PublicInbox::Linkify->new;
  85         $l->linkify_1($log);
  86         $log = '<pre>debug log:</pre><hr /><pre>' .
  87                 $l->linkify_2(ascii_html($log)) . '</pre>';
  88
  89         $res or return html_page($ctx, 404, \$log);
  90         $ref eq 'ARRAY' or return html_page($ctx, 500, \$log);
  91
  92         my ($git, $oid, $type, $size, $di) = @$res;
  93         my $path = to_filename($di->{path_b} || $hints->{path_b} || 'blob');
  94         my $raw_link = "(<a\nhref=$path>raw</a>)";
  95         if ($size > $max_size) {
  96                 return stream_large_blob($ctx, $res, \$log, $fn) if defined $fn;
  97                 $log = "<pre><b>Too big to show, download available</b>\n" .
  98                         "$oid $type $size bytes $raw_link</pre>" . $log;
  99                 return html_page($ctx, 500, \$log);
 100         }
 101
 102         my $blob = $git->cat_file($oid);
 103         if (!$blob) { # WTF?
 104                 my $e = "Failed to retrieve generated blob ($oid)";
 105                 $ctx->{env}->{'psgi.errors'}->print("$e ($git->{git_dir})\n");
 106                 $log = "<pre><b>$e</b></pre>" . $log;
 107                 return html_page($ctx, 500, \$log);
 108         }
 109
 110         my $binary = index($$blob, "\0") >= 0;
 111         if (defined $fn) {
 112                 my $h = [ 'Content-Length', $size, 'Content-Type' ];
 113                 push(@$h, ($binary ? 'application/octet-stream' : 'text/plain'));
 114                 return delete($ctx->{-wcb})->([200, $h, [ $$blob ]]);
 115         }
 116
 117         if ($binary) {
 118                 $log = "<pre>$oid $type $size bytes (binary)" .
 119                         " $raw_link</pre>" . $log;
 120                 return html_page($ctx, 200, \$log);
 121         }
 122
 123         # TODO: detect + convert to ensure validity
 124         utf8::decode($$blob);
 125         my $nl = ($$blob =~ tr/\n/\n/);
 126         my $pad = length($nl);
 127
 128         $l->linkify_1($$blob);
 129         my $ok = $hl->do_hl($blob, $path) if $hl;
 130         if ($ok) {
 131                 $blob = $ok;
 132         } else {
 133                 $$blob = ascii_html($$blob);
 134         }
 135
 136         # using some of the same CSS class names and ids as cgit
 137         $log = "<pre>$oid $type $size bytes $raw_link</pre>" .
 138                 "<hr /><table\nclass=blob>".
 139                 "<tr><td\nclass=linenumbers><pre>" . join('', map {
 140                         sprintf("<a id=n$_ href=#n$_>% ${pad}u</a>\n", $_)
 141                 } (1..$nl)) . '</pre></td>' .
 142                 '<td><pre> </pre></td>'. # pad for non-CSS users
 143                 "<td\nclass=lines><pre\nstyle='white-space:pre'><code>" .
 144                 $l->linkify_2($$blob) .
 145                 '</code></pre></td></tr></table>' . $log;
 146
 147         html_page($ctx, 200, \$log);
 148 }
 149
 150 sub show ($$;$) {
 151         my ($ctx, $oid_b, $fn) = @_;
 152         my $qp = $ctx->{qp};
 153         my $hints = {};
 154         while (my ($from, $to) = each %QP_MAP) {
 155                 defined(my $v = $qp->{$from}) or next;
 156                 $hints->{$to} = $v;
 157         }
 158
 159         open my $log, '+>', undef or die "open: $!";
 160         my $solver = PublicInbox::SolverGit->new($ctx->{-inbox}, sub {
 161                 solve_result($ctx, $_[0], $log, $hints, $fn);
 162         });
 163
 164         # PSGI server will call this and give us a callback
 165         sub {
 166                 $ctx->{-wcb} = $_[0]; # HTTP write callback
 167                 $solver->solve($ctx->{env}, $log, $oid_b, $hints);
 168         };
 169 }
 170
 171 1;