lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config;
  17 use PublicInbox::Hval;
  18 use URI::Escape qw(uri_unescape);
  19 use PublicInbox::MID qw(mid_escape);
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22 our $INBOX_RE = qr!\A/([\w\.\-]+)!;
  23 our $MID_RE = qr!([^/]+)!;
  24 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  25 our $ATTACH_RE = qr!(\d[\.\d]*)-([[:alnum:]][\w\.-]+[[:alnum:]])!i;
  26
  27 sub new {
  28         my ($class, $pi_config) = @_;
  29         $pi_config ||= PublicInbox::Config->new;
  30         bless { pi_config => $pi_config }, $class;
  31 }
  32
  33 # backwards compatibility, do not use
  34 sub run {
  35         my ($req, $method) = @_;
  36         PublicInbox::WWW->new->call($req->env);
  37 }
  38
  39 sub call {
  40         my ($self, $env) = @_;
  41         my $ctx = { env => $env, www => $self };
  42
  43         # we don't care about multi-value
  44         my %qp = map {
  45                 utf8::decode($_);
  46                 my ($k, $v) = split('=', uri_unescape($_), 2);
  47                 $v = '' unless defined $v;
  48                 $v =~ tr/+/ /;
  49                 ($k, $v)
  50         } split(/[&;]+/, $env->{QUERY_STRING});
  51         $ctx->{qp} = \%qp;
  52
  53         my $path_info = $env->{PATH_INFO};
  54         my $method = $env->{REQUEST_METHOD};
  55
  56         if ($method eq 'POST') {
  57                 if ($path_info =~ m!$INBOX_RE/(git-upload-pack)\z!) {
  58                         my $path = $2;
  59                         return invalid_inbox($ctx, $1) ||
  60                                 serve_git($ctx, $path);
  61                 } elsif ($path_info =~ m!$INBOX_RE/!o) {
  62                         return invalid_inbox($ctx, $1) || mbox_results($ctx);
  63                 }
  64         }
  65         elsif ($method !~ /\AGET|HEAD\z/) {
  66                 return r(405, 'Method Not Allowed');
  67         }
  68
  69         # top-level indices and feeds
  70         if ($path_info eq '/') {
  71                 r404();
  72         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  73                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  74         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  75                 invalid_inbox($ctx, $1) || get_index($ctx);
  76         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  77                 invalid_inbox($ctx, $1) || get_atom($ctx);
  78         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
  79                 invalid_inbox($ctx, $1) || get_new($ctx);
  80         } elsif ($path_info =~ m!$INBOX_RE/
  81                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  82                 my $path = $2;
  83                 invalid_inbox($ctx, $1) || serve_git($ctx, $path);
  84         } elsif ($path_info =~ m!$INBOX_RE/([\w-]+).mbox\.gz\z!o) {
  85                 serve_mbox_range($ctx, $1, $2);
  86         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
  87                 msg_page($ctx, $1, $2, $3);
  88
  89         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
  90                 my ($idx, $fn) = ($3, $4);
  91                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
  92         # in case people leave off the trailing slash:
  93         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
  94                 my ($inbox, $mid, $suffix) = ($1, $2, $3);
  95                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
  96                 r301($ctx, $inbox, $mid, $suffix);
  97
  98         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
  99                 my ($inbox, $mid) = ($1, $2);
 100                 r301($ctx, $inbox, $mid, '#R');
 101
 102         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
 103                 r301($ctx, $1, $2);
 104         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 105                 get_text($ctx, $1, $2);
 106
 107         # convenience redirects order matters
 108         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 109                 r301($ctx, $1, $2);
 110
 111         } else {
 112                 legacy_redirects($ctx, $path_info);
 113         }
 114 }
 115
 116 # for CoW-friendliness, MOOOOO!
 117 sub preload {
 118         require PublicInbox::Feed;
 119         require PublicInbox::View;
 120         require PublicInbox::SearchThread;
 121         require PublicInbox::MIME;
 122         require Digest::SHA;
 123         require POSIX;
 124
 125         foreach (qw(PublicInbox::Search PublicInbox::SearchView
 126                         PublicInbox::Mbox IO::Compress::Gzip
 127                         PublicInbox::NewsWWW)) {
 128                 eval "require $_;";
 129         }
 130 }
 131
 132 # private functions below
 133
 134 sub r404 {
 135         my ($ctx) = @_;
 136         if ($ctx && $ctx->{mid}) {
 137                 require PublicInbox::ExtMsg;
 138                 searcher($ctx);
 139                 return PublicInbox::ExtMsg::ext_msg($ctx);
 140         }
 141         r(404, 'Not Found');
 142 }
 143
 144 # simple response for errors
 145 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 146
 147 # returns undef if valid, array ref response if invalid
 148 sub invalid_inbox ($$) {
 149         my ($ctx, $inbox) = @_;
 150         my $www = $ctx->{www};
 151         my $obj = $www->{pi_config}->lookup_name($inbox);
 152         if (defined $obj) {
 153                 $ctx->{git_dir} = $obj->{mainrepo};
 154                 $ctx->{git} = $obj->git;
 155                 $ctx->{-inbox} = $obj;
 156                 $ctx->{inbox} = $inbox;
 157                 return;
 158         }
 159
 160         # sometimes linkifiers (not ours!) screw up automatic link
 161         # generation and link things intended for nntp:// to https?://,
 162         # so try to infer links and redirect them to the appropriate
 163         # list URL.
 164         $www->news_www->call($ctx->{env});
 165 }
 166
 167 # returns undef if valid, array ref response if invalid
 168 sub invalid_inbox_mid {
 169         my ($ctx, $inbox, $mid) = @_;
 170         my $ret = invalid_inbox($ctx, $inbox);
 171         return $ret if $ret;
 172
 173         $ctx->{mid} = $mid;
 174         if ($mid =~ /\A[a-f0-9]{40}\z/) {
 175                 # this is horiffically wasteful for legacy URLs:
 176                 if ($mid = mid2blob($ctx)) {
 177                         require Email::Simple;
 178                         use PublicInbox::MID qw/mid_clean/;
 179                         my $s = Email::Simple->new($mid);
 180                         $ctx->{mid} = mid_clean($s->header('Message-ID'));
 181                 }
 182         }
 183         undef;
 184 }
 185
 186 # /$INBOX/new.atom                     -> Atom feed, includes replies
 187 sub get_atom {
 188         my ($ctx) = @_;
 189         require PublicInbox::Feed;
 190         PublicInbox::Feed::generate($ctx);
 191 }
 192
 193 # /$INBOX/new.html                      -> HTML only
 194 sub get_new {
 195         my ($ctx) = @_;
 196         require PublicInbox::Feed;
 197         PublicInbox::Feed::new_html($ctx);
 198 }
 199
 200 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 201 sub get_index {
 202         my ($ctx) = @_;
 203         require PublicInbox::Feed;
 204         searcher($ctx);
 205         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 206                 require PublicInbox::SearchView;
 207                 PublicInbox::SearchView::sres_top_html($ctx);
 208         } else {
 209                 PublicInbox::Feed::generate_html_index($ctx);
 210         }
 211 }
 212
 213 # just returns a string ref for the blob in the current ctx
 214 sub mid2blob {
 215         my ($ctx) = @_;
 216         $ctx->{-inbox}->msg_by_mid($ctx->{mid});
 217 }
 218
 219 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 220 sub get_mid_txt {
 221         my ($ctx) = @_;
 222         my $x = mid2blob($ctx) or return r404($ctx);
 223         require PublicInbox::Mbox;
 224         PublicInbox::Mbox::emit1($ctx, $x);
 225 }
 226
 227 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 228 sub get_mid_html {
 229         my ($ctx) = @_;
 230         my $x = mid2blob($ctx) or return r404($ctx);
 231
 232         require PublicInbox::View;
 233         require PublicInbox::MIME;
 234         my $mime = PublicInbox::MIME->new($x);
 235         searcher($ctx);
 236         PublicInbox::View::msg_html($ctx, $mime);
 237 }
 238
 239 # /$INBOX/$MESSAGE_ID/t/
 240 sub get_thread {
 241         my ($ctx, $flat) = @_;
 242         searcher($ctx) or return need_search($ctx);
 243         $ctx->{flat} = $flat;
 244         require PublicInbox::View;
 245         PublicInbox::View::thread_html($ctx);
 246 }
 247
 248 # /$INBOX/_/text/$KEY/
 249 # /$INBOX/_/text/$KEY/raw
 250 # KEY may contain slashes
 251 sub get_text {
 252         my ($ctx, $inbox, $key) = @_;
 253         my $r404 = invalid_inbox($ctx, $inbox);
 254         return $r404 if $r404;
 255
 256         require PublicInbox::WwwText;
 257         PublicInbox::WwwText::get_text($ctx, $key);
 258 }
 259
 260 sub ctx_get {
 261         my ($ctx, $key) = @_;
 262         my $val = $ctx->{$key};
 263         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable";
 264         $val;
 265 }
 266
 267 # search support is optional, returns undef if Xapian is not installed
 268 # or not configured for the given GIT_DIR
 269 sub searcher {
 270         my ($ctx) = @_;
 271         eval {
 272                 require PublicInbox::Search;
 273                 $ctx->{srch} = $ctx->{-inbox}->search;
 274         };
 275 }
 276
 277 sub need_search {
 278         my ($ctx) = @_;
 279         my $msg = <<EOF;
 280 <html><head><title>Search not available for this
 281 public-inbox</title><body><pre>Search is not available for this public-inbox
 282 <a href="../">Return to index</a></pre></body></html>
 283 EOF
 284         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 285 }
 286
 287 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 288 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 289 # note: I'm not a big fan of other compression formats since they're
 290 # significantly more expensive on CPU than gzip and less-widely available,
 291 # especially on older systems.  Stick to zlib since that's what git uses.
 292 sub get_thread_mbox {
 293         my ($ctx, $sfx) = @_;
 294         my $srch = searcher($ctx) or return need_search($ctx);
 295         require PublicInbox::Mbox;
 296         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 297 }
 298
 299
 300 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 301 sub get_thread_atom {
 302         my ($ctx) = @_;
 303         searcher($ctx) or return need_search($ctx);
 304         require PublicInbox::Feed;
 305         PublicInbox::Feed::generate_thread_atom($ctx);
 306 }
 307
 308 sub legacy_redirects {
 309         my ($ctx, $path_info) = @_;
 310
 311         # single-message pages
 312         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 313                 r301($ctx, $1, $2);
 314         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 315                 r301($ctx, $1, $2, 'raw');
 316
 317         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 318                 r301($ctx, $1, $2);
 319
 320         # thread display
 321         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 322                 r301($ctx, $1, $2, 't/#u');
 323
 324         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 325                 r301($ctx, $1, $2, "t.mbox$3");
 326
 327         # even older legacy redirects
 328         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 329                 r301($ctx, $1, $2);
 330
 331         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 332                 r301($ctx, $1, $2, 't/#u');
 333
 334         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 335                 r301($ctx, $1, $2);
 336
 337         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 338                 r301($ctx, $1, $2, 'raw');
 339
 340         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 341                 r301($ctx, $1, $2, "t$3");
 342
 343         # legacy convenience redirects, order still matters
 344         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 345                 r301($ctx, $1, $2);
 346         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 347                 r301($ctx, $1, $2, 't/#u');
 348         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 349                 r301($ctx, $1, $2);
 350
 351         # some Message-IDs have slashes in them and the HTTP server
 352         # may try to be clever and unescape them :<
 353         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 354                 msg_page($ctx, $1, $2, $3);
 355
 356         # in case people leave off the trailing slash:
 357         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 358                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 359         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 360                 r301($ctx, $1, $2);
 361         } else {
 362                 $ctx->{www}->news_www->call($ctx->{env});
 363         }
 364 }
 365
 366 sub r301 {
 367         my ($ctx, $inbox, $mid, $suffix) = @_;
 368         my $obj = $ctx->{-inbox};
 369         unless ($obj) {
 370                 my $r404 = invalid_inbox($ctx, $inbox);
 371                 return $r404 if $r404;
 372                 $obj = $ctx->{-inbox};
 373         }
 374         my $url = $obj->base_url($ctx->{env});
 375         my $qs = $ctx->{env}->{QUERY_STRING};
 376         $url .= (mid_escape($mid) . '/') if (defined $mid);
 377         $url .= $suffix if (defined $suffix);
 378         $url .= "?$qs" if $qs ne '';
 379
 380         [ 301,
 381           [ Location => $url, 'Content-Type' => 'text/plain' ],
 382           [ "Redirecting to $url\n" ] ]
 383 }
 384
 385 sub msg_page {
 386         my ($ctx, $inbox, $mid, $e) = @_;
 387         my $ret;
 388         $ret = invalid_inbox_mid($ctx, $inbox, $mid) and return $ret;
 389         '' eq $e and return get_mid_html($ctx);
 390         'T/' eq $e and return get_thread($ctx, 1);
 391         't/' eq $e and return get_thread($ctx);
 392         't.atom' eq $e and return get_thread_atom($ctx);
 393         't.mbox' eq $e and return get_thread_mbox($ctx);
 394         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 395         'raw' eq $e and return get_mid_txt($ctx);
 396
 397         # legacy, but no redirect for compatibility:
 398         'f/' eq $e and return get_mid_html($ctx);
 399         r404($ctx);
 400 }
 401
 402 sub serve_git {
 403         my ($ctx, $path) = @_;
 404         PublicInbox::GitHTTPBackend::serve($ctx->{env}, $ctx->{git}, $path);
 405 }
 406
 407 sub mbox_results {
 408         my ($ctx) = @_;
 409         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 410                 searcher($ctx) or return need_search($ctx);
 411                 require PublicInbox::SearchView;
 412                 return PublicInbox::SearchView::mbox_results($ctx);
 413         }
 414         r404();
 415 }
 416
 417 sub serve_mbox_range {
 418         my ($ctx, $inbox, $range) = @_;
 419         invalid_inbox($ctx, $inbox) || eval {
 420                 require PublicInbox::Mbox;
 421                 searcher($ctx);
 422                 PublicInbox::Mbox::emit_range($ctx, $range);
 423         }
 424 }
 425
 426 sub news_www {
 427         my ($self) = @_;
 428         $self->{news_www} ||= do {
 429                 require PublicInbox::NewsWWW;
 430                 PublicInbox::NewsWWW->new($self->{pi_config});
 431         }
 432 }
 433
 434 sub get_attach {
 435         my ($ctx, $idx, $fn) = @_;
 436         require PublicInbox::WwwAttach;
 437         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 438 }
 439
 440 1;