lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 #   and diff/syntax-highlighting (optional)
  10 # - No JavaScript, graphics or icons allowed.
  11 # - Must not rely on static content
  12 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  13 package PublicInbox::WWW;
  14 use 5.010_001;
  15 use strict;
  16 use warnings;
  17 use bytes (); # only for bytes::length
  18 use Plack::Util;
  19 use PublicInbox::Config;
  20 use PublicInbox::Hval;
  21 use URI::Escape qw(uri_unescape);
  22 use PublicInbox::MID qw(mid_escape);
  23 require PublicInbox::Git;
  24 use PublicInbox::GitHTTPBackend;
  25 use PublicInbox::UserContent;
  26
  27 # TODO: consider a routing tree now that we have more endpoints:
  28 our $INBOX_RE = qr!\A/([\w\-][\w\.\-]*)!;
  29 our $MID_RE = qr!([^/]+)!;
  30 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  31 our $ATTACH_RE = qr!([0-9][0-9\.]*)-($PublicInbox::Hval::FN)!;
  32 our $OID_RE = qr![a-f0-9]{7,40}!;
  33
  34 sub new {
  35         my ($class, $pi_config) = @_;
  36         $pi_config ||= PublicInbox::Config->new;
  37         bless { pi_config => $pi_config }, $class;
  38 }
  39
  40 # backwards compatibility, do not use
  41 sub run {
  42         my ($req, $method) = @_;
  43         PublicInbox::WWW->new->call($req->env);
  44 }
  45
  46 my %path_re_cache;
  47
  48 sub path_re ($) {
  49         my $sn = $_[0]->{SCRIPT_NAME};
  50         $path_re_cache{$sn} ||= do {
  51                 $sn = '/'.$sn unless index($sn, '/') == 0;
  52                 $sn =~ s!/\z!!;
  53                 qr!\A(?:https?://[^/]+)?\Q$sn\E(/[^\?\#]+)!;
  54         };
  55 }
  56
  57 sub call {
  58         my ($self, $env) = @_;
  59         my $ctx = { env => $env, www => $self };
  60
  61         # we don't care about multi-value
  62         %{$ctx->{qp}} = map {
  63                 utf8::decode($_);
  64                 tr/+/ /;
  65                 my ($k, $v) = split('=', $_, 2);
  66                 $v = uri_unescape($v // '');
  67                 # none of the keys we care about will need escaping
  68                 $k => $v;
  69         } split(/[&;]+/, $env->{QUERY_STRING});
  70
  71         # avoiding $env->{PATH_INFO} here since that's already decoded
  72         my ($path_info) = ($env->{REQUEST_URI} =~ path_re($env));
  73         $path_info //= $env->{PATH_INFO};
  74         my $method = $env->{REQUEST_METHOD};
  75
  76         if ($method eq 'POST') {
  77                 if ($path_info =~ m!$INBOX_RE/(?:(?:git/)?([0-9]+)(?:\.git)?/)?
  78                                         (git-upload-pack)\z!x) {
  79                         my ($epoch, $path) = ($2, $3);
  80                         return invalid_inbox($ctx, $1) ||
  81                                 serve_git($ctx, $epoch, $path);
  82                 } elsif ($path_info =~ m!$INBOX_RE/!o) {
  83                         return invalid_inbox($ctx, $1) || mbox_results($ctx);
  84                 }
  85         }
  86         elsif ($method !~ /\AGET|HEAD\z/) {
  87                 return r(405, 'Method Not Allowed');
  88         }
  89
  90         # top-level indices and feeds
  91         if ($path_info eq '/' || $path_info eq '/manifest.js.gz') {
  92                 www_listing($self)->call($env);
  93         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  94                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  95         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  96                 invalid_inbox($ctx, $1) || get_index($ctx);
  97         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  98                 invalid_inbox($ctx, $1) || get_atom($ctx);
  99         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
 100                 invalid_inbox($ctx, $1) || get_new($ctx);
 101         } elsif ($path_info =~ m!$INBOX_RE/(?:(?:git/)?([0-9]+)(?:\.git)?/)?
 102                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
 103                 my ($epoch, $path) = ($2, $3);
 104                 invalid_inbox($ctx, $1) || serve_git($ctx, $epoch, $path);
 105         } elsif ($path_info =~ m!$INBOX_RE/([a-zA-Z0-9_\-]+).mbox\.gz\z!o) {
 106                 serve_mbox_range($ctx, $1, $2);
 107         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
 108                 msg_page($ctx, $1, $2, $3);
 109
 110         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
 111                 my ($idx, $fn) = ($3, $4);
 112                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
 113         # in case people leave off the trailing slash:
 114         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
 115                 my ($inbox, $mid_ue, $suffix) = ($1, $2, $3);
 116                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
 117                 r301($ctx, $inbox, $mid_ue, $suffix);
 118
 119         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
 120                 my ($inbox, $mid_ue) = ($1, $2);
 121                 r301($ctx, $inbox, $mid_ue, '#R');
 122
 123         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
 124                 r301($ctx, $1, $2);
 125         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 126                 get_text($ctx, $1, $2);
 127         } elsif ($path_info =~ m!$INBOX_RE/([a-zA-Z0-9_\-\.]+)\.css\z!o) {
 128                 get_css($ctx, $1, $2);
 129         } elsif ($path_info =~ m!$INBOX_RE/manifest\.js\.gz\z!o) {
 130                 get_inbox_manifest($ctx, $1, $2);
 131         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s/\z!o) {
 132                 get_vcs_object($ctx, $1, $2);
 133         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s/
 134                                 ($PublicInbox::Hval::FN)\z!ox) {
 135                 get_vcs_object($ctx, $1, $2, $3);
 136         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s\z!o) {
 137                 r301($ctx, $1, $2, 's/');
 138         # convenience redirects order matters
 139         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 140                 r301($ctx, $1, $2);
 141
 142         } else {
 143                 legacy_redirects($ctx, $path_info);
 144         }
 145 }
 146
 147 # for CoW-friendliness, MOOOOO!
 148 sub preload {
 149         my ($self) = @_;
 150         require PublicInbox::Feed;
 151         require PublicInbox::View;
 152         require PublicInbox::SearchThread;
 153         require PublicInbox::MIME;
 154         require Digest::SHA;
 155         require POSIX;
 156         eval {
 157                 require PublicInbox::Search;
 158                 PublicInbox::Search::load_xapian();
 159         };
 160         foreach (qw(PublicInbox::SearchView
 161                         PublicInbox::Mbox IO::Compress::Gzip
 162                         PublicInbox::NewsWWW)) {
 163                 eval "require $_;";
 164         }
 165         if (ref($self)) {
 166                 $self->cgit;
 167                 $self->stylesheets_prepare($_) for ('', '../', '../../');
 168                 $self->www_listing;
 169         }
 170 }
 171
 172 # private functions below
 173
 174 sub r404 {
 175         my ($ctx) = @_;
 176         if ($ctx && $ctx->{mid}) {
 177                 require PublicInbox::ExtMsg;
 178                 return PublicInbox::ExtMsg::ext_msg($ctx);
 179         }
 180         r(404, 'Not Found');
 181 }
 182
 183 # simple response for errors
 184 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 185
 186 sub news_cgit_fallback ($) {
 187         my ($ctx) = @_;
 188         my $www = $ctx->{www};
 189         my $env = $ctx->{env};
 190         my $res = $www->news_www->call($env);
 191         $res->[0] == 404 ? $www->cgit->call($env) : $res;
 192 }
 193
 194 # returns undef if valid, array ref response if invalid
 195 sub invalid_inbox ($$) {
 196         my ($ctx, $inbox) = @_;
 197         my $ibx = $ctx->{www}->{pi_config}->lookup_name($inbox);
 198         if (defined $ibx) {
 199                 $ctx->{-inbox} = $ibx;
 200                 return;
 201         }
 202
 203         # sometimes linkifiers (not ours!) screw up automatic link
 204         # generation and link things intended for nntp:// to https?://,
 205         # so try to infer links and redirect them to the appropriate
 206         # list URL.
 207         news_cgit_fallback($ctx);
 208 }
 209
 210 # returns undef if valid, array ref response if invalid
 211 sub invalid_inbox_mid {
 212         my ($ctx, $inbox, $mid_ue) = @_;
 213         my $ret = invalid_inbox($ctx, $inbox);
 214         return $ret if $ret;
 215
 216         my $mid = $ctx->{mid} = uri_unescape($mid_ue);
 217         my $ibx = $ctx->{-inbox};
 218         if ($mid =~ m!\A([a-f0-9]{2})([a-f0-9]{38})\z!) {
 219                 my ($x2, $x38) = ($1, $2);
 220                 # this is horrifically wasteful for legacy URLs:
 221                 my $str = $ctx->{-inbox}->msg_by_path("$x2/$x38") or return;
 222                 require Email::Simple;
 223                 my $s = Email::Simple->new($str);
 224                 $mid = PublicInbox::MID::mid_clean($s->header('Message-ID'));
 225                 return r301($ctx, $inbox, mid_escape($mid));
 226         }
 227         undef;
 228 }
 229
 230 # /$INBOX/new.atom                     -> Atom feed, includes replies
 231 sub get_atom {
 232         my ($ctx) = @_;
 233         require PublicInbox::Feed;
 234         PublicInbox::Feed::generate($ctx);
 235 }
 236
 237 # /$INBOX/new.html                      -> HTML only
 238 sub get_new {
 239         my ($ctx) = @_;
 240         require PublicInbox::Feed;
 241         PublicInbox::Feed::new_html($ctx);
 242 }
 243
 244 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 245 sub get_index {
 246         my ($ctx) = @_;
 247         require PublicInbox::Feed;
 248         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 249                 require PublicInbox::SearchView;
 250                 PublicInbox::SearchView::sres_top_html($ctx);
 251         } else {
 252                 PublicInbox::Feed::generate_html_index($ctx);
 253         }
 254 }
 255
 256 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 257 sub get_mid_txt {
 258         my ($ctx) = @_;
 259         require PublicInbox::Mbox;
 260         PublicInbox::Mbox::emit_raw($ctx) || r404($ctx);
 261 }
 262
 263 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 264 sub get_mid_html {
 265         my ($ctx) = @_;
 266         require PublicInbox::View;
 267         PublicInbox::View::msg_page($ctx) || r404($ctx);
 268 }
 269
 270 # /$INBOX/$MESSAGE_ID/t/
 271 sub get_thread {
 272         my ($ctx, $flat) = @_;
 273         $ctx->{-inbox}->over or return need($ctx, 'Overview');
 274         $ctx->{flat} = $flat;
 275         require PublicInbox::View;
 276         PublicInbox::View::thread_html($ctx);
 277 }
 278
 279 # /$INBOX/_/text/$KEY/
 280 # /$INBOX/_/text/$KEY/raw
 281 # KEY may contain slashes
 282 sub get_text {
 283         my ($ctx, $inbox, $key) = @_;
 284         my $r404 = invalid_inbox($ctx, $inbox);
 285         return $r404 if $r404;
 286
 287         require PublicInbox::WwwText;
 288         PublicInbox::WwwText::get_text($ctx, $key);
 289 }
 290
 291 # show git objects (blobs and commits)
 292 # /$INBOX/_/$OBJECT_ID/show
 293 # /$INBOX/_/${OBJECT_ID}_${FILENAME}
 294 # KEY may contain slashes
 295 sub get_vcs_object ($$$;$) {
 296         my ($ctx, $inbox, $oid, $filename) = @_;
 297         my $r404 = invalid_inbox($ctx, $inbox);
 298         return $r404 if $r404;
 299         require PublicInbox::ViewVCS;
 300         PublicInbox::ViewVCS::show($ctx, $oid, $filename);
 301 }
 302
 303 sub need {
 304         my ($ctx, $extra) = @_;
 305         my $msg = <<EOF;
 306 <html><head><title>$extra not available for this
 307 public-inbox</title><body><pre>$extra is not available for this public-inbox
 308 <a href="../">Return to index</a></pre></body></html>
 309 EOF
 310         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 311 }
 312
 313 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 314 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 315 # note: I'm not a big fan of other compression formats since they're
 316 # significantly more expensive on CPU than gzip and less-widely available,
 317 # especially on older systems.  Stick to zlib since that's what git uses.
 318 sub get_thread_mbox {
 319         my ($ctx, $sfx) = @_;
 320         my $over = $ctx->{-inbox}->over or return need($ctx, 'Overview');
 321         require PublicInbox::Mbox;
 322         PublicInbox::Mbox::thread_mbox($ctx, $over, $sfx);
 323 }
 324
 325
 326 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 327 sub get_thread_atom {
 328         my ($ctx) = @_;
 329         $ctx->{-inbox}->over or return need($ctx, 'Overview');
 330         require PublicInbox::Feed;
 331         PublicInbox::Feed::generate_thread_atom($ctx);
 332 }
 333
 334 sub legacy_redirects {
 335         my ($ctx, $path_info) = @_;
 336
 337         # single-message pages
 338         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 339                 r301($ctx, $1, $2);
 340         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 341                 r301($ctx, $1, $2, 'raw');
 342
 343         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 344                 r301($ctx, $1, $2);
 345
 346         # thread display
 347         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 348                 r301($ctx, $1, $2, 't/#u');
 349
 350         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 351                 r301($ctx, $1, $2, "t.mbox$3");
 352
 353         # even older legacy redirects
 354         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 355                 r301($ctx, $1, $2);
 356
 357         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 358                 r301($ctx, $1, $2, 't/#u');
 359
 360         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 361                 r301($ctx, $1, $2);
 362
 363         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 364                 r301($ctx, $1, $2, 'raw');
 365
 366         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 367                 r301($ctx, $1, $2, "t$3");
 368
 369         # legacy convenience redirects, order still matters
 370         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 371                 r301($ctx, $1, $2);
 372         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 373                 r301($ctx, $1, $2, 't/#u');
 374         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 375                 r301($ctx, $1, $2);
 376
 377         # some Message-IDs have slashes in them and the HTTP server
 378         # may try to be clever and unescape them :<
 379         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 380                 msg_page($ctx, $1, $2, $3);
 381
 382         # in case people leave off the trailing slash:
 383         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 384                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 385         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 386                 r301($ctx, $1, $2);
 387         } else {
 388                 news_cgit_fallback($ctx);
 389         }
 390 }
 391
 392 sub r301 {
 393         my ($ctx, $inbox, $mid_ue, $suffix) = @_;
 394         my $ibx = $ctx->{-inbox};
 395         unless ($ibx) {
 396                 my $r404 = invalid_inbox($ctx, $inbox);
 397                 return $r404 if $r404;
 398                 $ibx = $ctx->{-inbox};
 399         }
 400         my $url = $ibx->base_url($ctx->{env});
 401         my $qs = $ctx->{env}->{QUERY_STRING};
 402         if (defined $mid_ue) {
 403                 # common, and much nicer as '@' than '%40':
 404                 $mid_ue =~ s/%40/@/g;
 405                 $url .= $mid_ue . '/';
 406         }
 407         $url .= $suffix if (defined $suffix);
 408         $url .= "?$qs" if $qs ne '';
 409
 410         [ 301,
 411           [ Location => $url, 'Content-Type' => 'text/plain' ],
 412           [ "Redirecting to $url\n" ] ]
 413 }
 414
 415 sub msg_page {
 416         my ($ctx, $inbox, $mid_ue, $e) = @_;
 417         my $ret;
 418         $ret = invalid_inbox_mid($ctx, $inbox, $mid_ue) and return $ret;
 419         '' eq $e and return get_mid_html($ctx);
 420         'T/' eq $e and return get_thread($ctx, 1);
 421         't/' eq $e and return get_thread($ctx);
 422         't.atom' eq $e and return get_thread_atom($ctx);
 423         't.mbox' eq $e and return get_thread_mbox($ctx);
 424         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 425         'raw' eq $e and return get_mid_txt($ctx);
 426
 427         # legacy, but no redirect for compatibility:
 428         'f/' eq $e and return get_mid_html($ctx);
 429         r404($ctx);
 430 }
 431
 432 sub serve_git {
 433         my ($ctx, $epoch, $path) = @_;
 434         my $env = $ctx->{env};
 435         my $ibx = $ctx->{-inbox};
 436         my $git = defined $epoch ? $ibx->git_epoch($epoch) : $ibx->git;
 437         $git ? PublicInbox::GitHTTPBackend::serve($env, $git, $path) : r404();
 438 }
 439
 440 sub mbox_results {
 441         my ($ctx) = @_;
 442         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 443                 $ctx->{-inbox}->search or return need($ctx, 'search');
 444                 require PublicInbox::SearchView;
 445                 return PublicInbox::SearchView::mbox_results($ctx);
 446         }
 447         r404();
 448 }
 449
 450 sub serve_mbox_range {
 451         my ($ctx, $inbox, $range) = @_;
 452         invalid_inbox($ctx, $inbox) || eval {
 453                 require PublicInbox::Mbox;
 454                 PublicInbox::Mbox::emit_range($ctx, $range);
 455         }
 456 }
 457
 458 sub news_www {
 459         my ($self) = @_;
 460         $self->{news_www} ||= do {
 461                 require PublicInbox::NewsWWW;
 462                 PublicInbox::NewsWWW->new($self->{pi_config});
 463         }
 464 }
 465
 466 sub cgit {
 467         my ($self) = @_;
 468         $self->{cgit} ||= do {
 469                 my $pi_config = $self->{pi_config};
 470
 471                 if (defined($pi_config->{'publicinbox.cgitrc'})) {
 472                         require PublicInbox::Cgit;
 473                         PublicInbox::Cgit->new($pi_config);
 474                 } else {
 475                         Plack::Util::inline_object(call => sub { r404() });
 476                 }
 477         }
 478 }
 479
 480 sub www_listing {
 481         my ($self) = @_;
 482         $self->{www_listing} ||= do {
 483                 require PublicInbox::WwwListing;
 484                 PublicInbox::WwwListing->new($self);
 485         }
 486 }
 487
 488 # GET $INBOX/manifest.js.gz
 489 sub get_inbox_manifest ($$$) {
 490         my ($ctx, $inbox, $key) = @_;
 491         my $r404 = invalid_inbox($ctx, $inbox);
 492         return $r404 if $r404;
 493         require PublicInbox::WwwListing;
 494         PublicInbox::WwwListing::js($ctx->{env}, [$ctx->{-inbox}]);
 495 }
 496
 497 sub get_attach {
 498         my ($ctx, $idx, $fn) = @_;
 499         require PublicInbox::WwwAttach;
 500         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 501 }
 502
 503 # User-generated content (UGC) may have excessively long lines
 504 # and screw up rendering on some browsers, so we use pre-wrap.
 505 #
 506 # We also force everything to the same scaled font-size because GUI
 507 # browsers (tested both Firefox and surf (webkit)) uses a larger font
 508 # for the Search <form> element than the rest of the page.  Font size
 509 # uniformity is important to people who rely on gigantic fonts.
 510 # Finally, we use monospace to ensure the Search field and button
 511 # has the same size and spacing as everything else which is
 512 # <pre>-formatted anyways.
 513 our $STYLE = 'pre{white-space:pre-wrap}*{font-size:100%;font-family:monospace}';
 514
 515 sub stylesheets_prepare ($$) {
 516         my ($self, $upfx) = @_;
 517         my $mini = eval {
 518                 require CSS::Minifier;
 519                 sub { CSS::Minifier::minify(input => $_[0]) };
 520         } || eval {
 521                 require CSS::Minifier::XS;
 522                 sub { CSS::Minifier::XS::minify($_[0]) };
 523         } || sub { $_[0] };
 524
 525         my $css_map = {};
 526         my $stylesheets = $self->{pi_config}->{css} || [];
 527         my $links = [];
 528         my $inline_ok = 1;
 529
 530         foreach my $s (@$stylesheets) {
 531                 my $attr = {};
 532                 local $_ = $s;
 533                 foreach my $k (qw(media title href)) {
 534                         if (s/\s*$k='([^']+)'// || s/\s*$k=(\S+)//) {
 535                                 $attr->{$k} = $1;
 536                         }
 537                 }
 538
 539                 if (defined $attr->{href}) {
 540                         $inline_ok = 0;
 541                 } else {
 542                         my $fn = $_;
 543                         my ($key) = (m!([^/]+?)(?:\.css)?\z!i);
 544                         if ($key !~ /\A[a-zA-Z0-9_\-\.]+\z/) {
 545                                 warn "ignoring $fn, non-ASCII word character\n";
 546                                 next;
 547                         }
 548                         open(my $fh, '<', $fn) or do {
 549                                 warn "failed to open $fn: $!\n";
 550                                 next;
 551                         };
 552                         my $ctime = 0;
 553                         my $local = do { local $/; <$fh> };
 554                         if ($local =~ /\S/) {
 555                                 $ctime = sprintf('%x',(stat($fh))[10]);
 556                                 $local = $mini->($local);
 557                         }
 558
 559                         # do not let BOFHs override userContent.css:
 560                         if ($local =~ /!\s*important\b/i) {
 561                                 warn "ignoring $fn since it uses `!important'\n";
 562                                 next;
 563                         }
 564
 565                         $css_map->{$key} = $local;
 566                         $attr->{href} = "$upfx$key.css?$ctime";
 567                         if (defined($attr->{title})) {
 568                                 $inline_ok = 0;
 569                         } elsif (($attr->{media}||'screen') eq 'screen') {
 570                                 $attr->{-inline} = $local;
 571                         }
 572                 }
 573                 push @$links, $attr;
 574         }
 575
 576         my $buf = "<style>$STYLE";
 577         if ($inline_ok) {
 578                 my @ext; # for media=print and whatnot
 579                 foreach my $attr (@$links) {
 580                         if (defined(my $str = delete $attr->{-inline})) {
 581                                 $buf .= $str;
 582                         } else {
 583                                 push @ext, $attr;
 584                         }
 585                 }
 586                 $links = \@ext;
 587         }
 588         $buf .= '</style>';
 589
 590         if (@$links) {
 591                 foreach my $attr (@$links) {
 592                         delete $attr->{-inline};
 593                         $buf .= "<link\ntype=text/css\nrel=stylesheet";
 594                         while (my ($k, $v) = each %$attr) {
 595                                 $v = qq{"$v"} if $v =~ /[\s=]/;
 596                                 $buf .= qq{\n$k=$v};
 597                         }
 598                         $buf .= ' />';
 599                 }
 600                 $self->{"-style-$upfx"} = $buf;
 601         } else {
 602                 $self->{-style_inline} = $buf;
 603         }
 604         $self->{-css_map} = $css_map;
 605 }
 606
 607 # returns an HTML fragment with <style> or <link> tags in them
 608 # Called by WwwStream by nearly every HTML page
 609 sub style {
 610         my ($self, $upfx) = @_;
 611         $self->{-style_inline} || $self->{"-style-$upfx"} || do {
 612                 stylesheets_prepare($self, $upfx);
 613                 $self->{-style_inline} || $self->{"-style-$upfx"}
 614         };
 615 }
 616
 617 # /$INBOX/$KEY.css endpoint
 618 # CSS is configured globally for all inboxes, but we access them on
 619 # a per-inbox basis.  This allows administrators to setup per-inbox
 620 # static routes to intercept the request before it hits PSGI
 621 sub get_css ($$$) {
 622         my ($ctx, $inbox, $key) = @_;
 623         my $r404 = invalid_inbox($ctx, $inbox);
 624         return $r404 if $r404;
 625         my $self = $ctx->{www};
 626         my $css_map = $self->{-css_map} || stylesheets_prepare($self, '');
 627         my $css = $css_map->{$key};
 628         if (!defined($css) && $key eq 'userContent') {
 629                 my $env = $ctx->{env};
 630                 $css = PublicInbox::UserContent::sample($ctx->{-inbox}, $env);
 631         }
 632         defined $css or return r404();
 633         my $h = [ 'Content-Length', bytes::length($css),
 634                 'Content-Type', 'text/css' ];
 635         PublicInbox::GitHTTPBackend::cache_one_year($h);
 636         [ 200, $h, [ $css ] ];
 637 }
 638
 639 1;