lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config;
  17 use PublicInbox::Hval;
  18 use URI::Escape qw(uri_unescape);
  19 use PublicInbox::MID qw(mid_escape);
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22 our $INBOX_RE = qr!\A/([\w\.\-]+)!;
  23 our $MID_RE = qr!([^/]+)!;
  24 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  25 our $ATTACH_RE = qr!(\d[\.\d]*)-([[:alnum:]][\w\.-]+[[:alnum:]])!i;
  26
  27 sub new {
  28         my ($class, $pi_config) = @_;
  29         $pi_config ||= PublicInbox::Config->new;
  30         bless { pi_config => $pi_config }, $class;
  31 }
  32
  33 # backwards compatibility, do not use
  34 sub run {
  35         my ($req, $method) = @_;
  36         PublicInbox::WWW->new->call($req->env);
  37 }
  38
  39 sub call {
  40         my ($self, $env) = @_;
  41         my $ctx = { env => $env, www => $self };
  42
  43         # we don't care about multi-value
  44         my %qp = map {
  45                 my ($k, $v) = split('=', uri_unescape($_), 2);
  46                 $v = '' unless defined $v;
  47                 $v =~ tr/+/ /;
  48                 ($k, $v)
  49         } split(/[&;]/, $env->{QUERY_STRING});
  50         $ctx->{qp} = \%qp;
  51
  52         my $path_info = $env->{PATH_INFO};
  53         my $method = $env->{REQUEST_METHOD};
  54
  55         if ($method eq 'POST' &&
  56                  $path_info =~ m!$INBOX_RE/(git-upload-pack)\z!) {
  57                 my $path = $2;
  58                 return invalid_inbox($ctx, $1) || serve_git($ctx, $path);
  59         }
  60         elsif ($method !~ /\AGET|HEAD\z/) {
  61                 return r(405, 'Method Not Allowed');
  62         }
  63
  64         # top-level indices and feeds
  65         if ($path_info eq '/') {
  66                 r404();
  67         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  68                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  69         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  70                 invalid_inbox($ctx, $1) || get_index($ctx);
  71         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  72                 invalid_inbox($ctx, $1) || get_atom($ctx);
  73         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
  74                 invalid_inbox($ctx, $1) || get_new($ctx);
  75         } elsif ($path_info =~ m!$INBOX_RE/
  76                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  77                 my $path = $2;
  78                 invalid_inbox($ctx, $1) || serve_git($ctx, $path);
  79         } elsif ($path_info =~ m!$INBOX_RE/([\w-]+).mbox\.gz\z!o) {
  80                 serve_mbox_range($ctx, $1, $2);
  81         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
  82                 msg_page($ctx, $1, $2, $3);
  83
  84         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
  85                 my ($idx, $fn) = ($3, $4);
  86                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
  87         # in case people leave off the trailing slash:
  88         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
  89                 my ($inbox, $mid, $suffix) = ($1, $2, $3);
  90                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
  91                 r301($ctx, $inbox, $mid, $suffix);
  92
  93         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
  94                 my ($inbox, $mid) = ($1, $2);
  95                 r301($ctx, $inbox, $mid, '#R');
  96
  97         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
  98                 r301($ctx, $1, $2);
  99         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 100                 get_text($ctx, $1, $2);
 101
 102         # convenience redirects order matters
 103         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 104                 r301($ctx, $1, $2);
 105
 106         } else {
 107                 legacy_redirects($ctx, $path_info);
 108         }
 109 }
 110
 111 # for CoW-friendliness, MOOOOO!
 112 sub preload {
 113         require PublicInbox::Feed;
 114         require PublicInbox::View;
 115         require PublicInbox::Thread;
 116         require Email::MIME;
 117         require Digest::SHA;
 118         require POSIX;
 119
 120         foreach (qw(PublicInbox::Search PublicInbox::SearchView
 121                         PublicInbox::Mbox IO::Compress::Gzip
 122                         PublicInbox::NewsWWW)) {
 123                 eval "require $_;";
 124         }
 125 }
 126
 127 # private functions below
 128
 129 sub r404 {
 130         my ($ctx) = @_;
 131         if ($ctx && $ctx->{mid}) {
 132                 require PublicInbox::ExtMsg;
 133                 searcher($ctx);
 134                 return PublicInbox::ExtMsg::ext_msg($ctx);
 135         }
 136         r(404, 'Not Found');
 137 }
 138
 139 # simple response for errors
 140 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 141
 142 # returns undef if valid, array ref response if invalid
 143 sub invalid_inbox ($$) {
 144         my ($ctx, $inbox) = @_;
 145         my $www = $ctx->{www};
 146         my $obj = $www->{pi_config}->lookup_name($inbox);
 147         if (defined $obj) {
 148                 $ctx->{git_dir} = $obj->{mainrepo};
 149                 $ctx->{git} = $obj->git;
 150                 $ctx->{-inbox} = $obj;
 151                 $ctx->{inbox} = $inbox;
 152                 return;
 153         }
 154
 155         # sometimes linkifiers (not ours!) screw up automatic link
 156         # generation and link things intended for nntp:// to https?://,
 157         # so try to infer links and redirect them to the appropriate
 158         # list URL.
 159         $www->news_www->call($ctx->{env});
 160 }
 161
 162 # returns undef if valid, array ref response if invalid
 163 sub invalid_inbox_mid {
 164         my ($ctx, $inbox, $mid) = @_;
 165         my $ret = invalid_inbox($ctx, $inbox);
 166         return $ret if $ret;
 167
 168         $ctx->{mid} = $mid = uri_unescape($mid);
 169         if ($mid =~ /\A[a-f0-9]{40}\z/) {
 170                 # this is horiffically wasteful for legacy URLs:
 171                 if ($mid = mid2blob($ctx)) {
 172                         require Email::Simple;
 173                         use PublicInbox::MID qw/mid_clean/;
 174                         my $s = Email::Simple->new($mid);
 175                         $ctx->{mid} = mid_clean($s->header('Message-ID'));
 176                 }
 177         }
 178         undef;
 179 }
 180
 181 # /$INBOX/new.atom                     -> Atom feed, includes replies
 182 sub get_atom {
 183         my ($ctx) = @_;
 184         require PublicInbox::Feed;
 185         PublicInbox::Feed::generate($ctx);
 186 }
 187
 188 # /$INBOX/new.html                      -> HTML only
 189 sub get_new {
 190         my ($ctx) = @_;
 191         require PublicInbox::Feed;
 192         PublicInbox::Feed::new_html($ctx);
 193 }
 194
 195 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 196 sub get_index {
 197         my ($ctx) = @_;
 198         require PublicInbox::Feed;
 199         searcher($ctx);
 200         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 201                 require PublicInbox::SearchView;
 202                 PublicInbox::SearchView::sres_top_html($ctx);
 203         } else {
 204                 PublicInbox::Feed::generate_html_index($ctx);
 205         }
 206 }
 207
 208 # just returns a string ref for the blob in the current ctx
 209 sub mid2blob {
 210         my ($ctx) = @_;
 211         $ctx->{-inbox}->msg_by_mid($ctx->{mid});
 212 }
 213
 214 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 215 sub get_mid_txt {
 216         my ($ctx) = @_;
 217         my $x = mid2blob($ctx) or return r404($ctx);
 218         require PublicInbox::Mbox;
 219         PublicInbox::Mbox::emit1($ctx, $x);
 220 }
 221
 222 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 223 sub get_mid_html {
 224         my ($ctx) = @_;
 225         my $x = mid2blob($ctx) or return r404($ctx);
 226
 227         require PublicInbox::View;
 228         require Email::MIME;
 229         my $mime = Email::MIME->new($x);
 230         searcher($ctx);
 231         PublicInbox::View::msg_html($ctx, $mime);
 232 }
 233
 234 # /$INBOX/$MESSAGE_ID/t/
 235 sub get_thread {
 236         my ($ctx, $flat) = @_;
 237         searcher($ctx) or return need_search($ctx);
 238         $ctx->{flat} = $flat;
 239         require PublicInbox::View;
 240         PublicInbox::View::thread_html($ctx);
 241 }
 242
 243 # /$INBOX/_/text/$KEY/
 244 # /$INBOX/_/text/$KEY/raw
 245 # KEY may contain slashes
 246 sub get_text {
 247         my ($ctx, $inbox, $key) = @_;
 248         my $r404 = invalid_inbox($ctx, $inbox);
 249         return $r404 if $r404;
 250
 251         require PublicInbox::WwwText;
 252         PublicInbox::WwwText::get_text($ctx, $key);
 253 }
 254
 255 sub ctx_get {
 256         my ($ctx, $key) = @_;
 257         my $val = $ctx->{$key};
 258         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable";
 259         $val;
 260 }
 261
 262 # search support is optional, returns undef if Xapian is not installed
 263 # or not configured for the given GIT_DIR
 264 sub searcher {
 265         my ($ctx) = @_;
 266         eval {
 267                 require PublicInbox::Search;
 268                 $ctx->{srch} = $ctx->{-inbox}->search;
 269         };
 270 }
 271
 272 sub need_search {
 273         my ($ctx) = @_;
 274         my $msg = <<EOF;
 275 <html><head><title>Search not available for this
 276 public-inbox</title><body><pre>Search is not available for this public-inbox
 277 <a href="../">Return to index</a></pre></body></html>
 278 EOF
 279         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 280 }
 281
 282 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 283 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 284 # note: I'm not a big fan of other compression formats since they're
 285 # significantly more expensive on CPU than gzip and less-widely available,
 286 # especially on older systems.  Stick to zlib since that's what git uses.
 287 sub get_thread_mbox {
 288         my ($ctx, $sfx) = @_;
 289         my $srch = searcher($ctx) or return need_search($ctx);
 290         require PublicInbox::Mbox;
 291         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 292 }
 293
 294
 295 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 296 sub get_thread_atom {
 297         my ($ctx) = @_;
 298         searcher($ctx) or return need_search($ctx);
 299         require PublicInbox::Feed;
 300         PublicInbox::Feed::generate_thread_atom($ctx);
 301 }
 302
 303 sub legacy_redirects {
 304         my ($ctx, $path_info) = @_;
 305
 306         # single-message pages
 307         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 308                 r301($ctx, $1, $2);
 309         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 310                 r301($ctx, $1, $2, 'raw');
 311
 312         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 313                 r301($ctx, $1, $2);
 314
 315         # thread display
 316         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 317                 r301($ctx, $1, $2, 't/#u');
 318
 319         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 320                 r301($ctx, $1, $2, "t.mbox$3");
 321
 322         # even older legacy redirects
 323         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 324                 r301($ctx, $1, $2);
 325
 326         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 327                 r301($ctx, $1, $2, 't/#u');
 328
 329         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 330                 r301($ctx, $1, $2);
 331
 332         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 333                 r301($ctx, $1, $2, 'raw');
 334
 335         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 336                 r301($ctx, $1, $2, "t$3");
 337
 338         # legacy convenience redirects, order still matters
 339         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 340                 r301($ctx, $1, $2);
 341         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 342                 r301($ctx, $1, $2, 't/#u');
 343         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 344                 r301($ctx, $1, $2);
 345
 346         # some Message-IDs have slashes in them and the HTTP server
 347         # may try to be clever and unescape them :<
 348         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 349                 msg_page($ctx, $1, $2, $3);
 350
 351         # in case people leave off the trailing slash:
 352         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 353                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 354         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 355                 r301($ctx, $1, $2);
 356         } else {
 357                 $ctx->{www}->news_www->call($ctx->{env});
 358         }
 359 }
 360
 361 sub r301 {
 362         my ($ctx, $inbox, $mid, $suffix) = @_;
 363         my $obj = $ctx->{-inbox};
 364         unless ($obj) {
 365                 my $r404 = invalid_inbox($ctx, $inbox);
 366                 return $r404 if $r404;
 367                 $obj = $ctx->{-inbox};
 368         }
 369         my $url = $obj->base_url($ctx->{env});
 370         my $qs = $ctx->{env}->{QUERY_STRING};
 371         $url .= (mid_escape($mid) . '/') if (defined $mid);
 372         $url .= $suffix if (defined $suffix);
 373         $url .= "?$qs" if $qs ne '';
 374
 375         [ 301,
 376           [ Location => $url, 'Content-Type' => 'text/plain' ],
 377           [ "Redirecting to $url\n" ] ]
 378 }
 379
 380 sub msg_page {
 381         my ($ctx, $inbox, $mid, $e) = @_;
 382         my $ret;
 383         $ret = invalid_inbox_mid($ctx, $inbox, $mid) and return $ret;
 384         '' eq $e and return get_mid_html($ctx);
 385         'T/' eq $e and return get_thread($ctx, 1);
 386         't/' eq $e and return get_thread($ctx);
 387         't.atom' eq $e and return get_thread_atom($ctx);
 388         't.mbox' eq $e and return get_thread_mbox($ctx);
 389         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 390         'raw' eq $e and return get_mid_txt($ctx);
 391
 392         # legacy, but no redirect for compatibility:
 393         'f/' eq $e and return get_mid_html($ctx);
 394         r404($ctx);
 395 }
 396
 397 sub serve_git {
 398         my ($ctx, $path) = @_;
 399         PublicInbox::GitHTTPBackend::serve($ctx->{env}, $ctx->{git}, $path);
 400 }
 401
 402 sub serve_mbox_range {
 403         my ($ctx, $inbox, $range) = @_;
 404         invalid_inbox($ctx, $inbox) || eval {
 405                 require PublicInbox::Mbox;
 406                 searcher($ctx);
 407                 PublicInbox::Mbox::emit_range($ctx, $range);
 408         }
 409 }
 410
 411 sub news_www {
 412         my ($self) = @_;
 413         $self->{news_www} ||= do {
 414                 require PublicInbox::NewsWWW;
 415                 PublicInbox::NewsWWW->new($self->{pi_config});
 416         }
 417 }
 418
 419 sub get_attach {
 420         my ($ctx, $idx, $fn) = @_;
 421         require PublicInbox::WwwAttach;
 422         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 423 }
 424
 425 1;