lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config qw(try_cat);
  17 use URI::Escape qw(uri_escape_utf8 uri_unescape);
  18 use constant SSOMA_URL => 'http://ssoma.public-inbox.org/';
  19 use constant PI_URL => 'http://public-inbox.org/';
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22 our $LISTNAME_RE = qr!\A/([\w\.\-]+)!;
  23 our $MID_RE = qr!([^/]+)!;
  24 our $END_RE = qr!(f/|T/|t/|R/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  25 our $pi_config;
  26
  27 sub run {
  28         my ($cgi, $method) = @_;
  29         $pi_config ||= PublicInbox::Config->new;
  30         my $ctx = { cgi => $cgi, pi_config => $pi_config };
  31         my $path_info = $cgi->path_info;
  32
  33         if ($method eq 'POST' &&
  34                  $path_info =~ m!$LISTNAME_RE/(git-upload-pack)\z!) {
  35                 my $path = $2;
  36                 return (invalid_list($ctx, $1) ||
  37                         serve_git($cgi, $ctx->{git}, $path));
  38         }
  39         elsif ($method !~ /\AGET|HEAD\z/) {
  40                 return r(405, 'Method Not Allowed');
  41         }
  42
  43         # top-level indices and feeds
  44         if ($path_info eq '/') {
  45                 r404();
  46         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  47                 invalid_list($ctx, $1) || r301($ctx, $1);
  48         } elsif ($path_info =~ m!$LISTNAME_RE(?:/|/index\.html)?\z!o) {
  49                 invalid_list($ctx, $1) || get_index($ctx);
  50         } elsif ($path_info =~ m!$LISTNAME_RE/(?:atom\.xml|new\.atom)\z!o) {
  51                 invalid_list($ctx, $1) || get_atom($ctx);
  52
  53         } elsif ($path_info =~ m!$LISTNAME_RE/
  54                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  55                 my $path = $2;
  56                 invalid_list($ctx, $1) || serve_git($cgi, $ctx->{git}, $path);
  57         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/$END_RE\z!o) {
  58                 msg_page($ctx, $1, $2, $3);
  59
  60         # in case people leave off the trailing slash:
  61         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/(f|T|t|R)\z!o) {
  62                 my ($listname, $mid, $suffix) = ($1, $2, $3);
  63                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
  64                 r301($ctx, $listname, $mid, $suffix);
  65
  66         # convenience redirects order matters
  67         } elsif ($path_info =~ m!$LISTNAME_RE/([^/]{2,})\z!o) {
  68                 r301($ctx, $1, $2);
  69
  70         } else {
  71                 legacy_redirects($ctx, $path_info);
  72         }
  73 }
  74
  75 # for CoW-friendliness, MOOOOO!
  76 sub preload {
  77         require PublicInbox::Feed;
  78         require PublicInbox::View;
  79         require PublicInbox::Thread;
  80         require Email::MIME;
  81         require Digest::SHA;
  82         require POSIX;
  83
  84         eval {
  85                 require PublicInbox::Search;
  86                 require PublicInbox::SearchView;
  87                 require PublicInbox::Mbox;
  88                 require IO::Compress::Gzip;
  89         };
  90 }
  91
  92 # private functions below
  93
  94 sub r404 {
  95         my ($ctx) = @_;
  96         if ($ctx && $ctx->{mid}) {
  97                 require PublicInbox::ExtMsg;
  98                 searcher($ctx);
  99                 return PublicInbox::ExtMsg::ext_msg($ctx);
 100         }
 101         r(404, 'Not Found');
 102 }
 103
 104 # simple response for errors
 105 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 106
 107 # returns undef if valid, array ref response if invalid
 108 sub invalid_list {
 109         my ($ctx, $listname) = @_;
 110         my $git_dir = $pi_config->get($listname, "mainrepo");
 111         if (defined $git_dir) {
 112                 $ctx->{git_dir} = $git_dir;
 113                 $ctx->{git} = PublicInbox::Git->new($git_dir);
 114                 $ctx->{listname} = $listname;
 115                 return;
 116         }
 117         r404();
 118 }
 119
 120 # returns undef if valid, array ref response if invalid
 121 sub invalid_list_mid {
 122         my ($ctx, $listname, $mid) = @_;
 123         my $ret = invalid_list($ctx, $listname, $mid);
 124         return $ret if $ret;
 125
 126         $ctx->{mid} = $mid = uri_unescape($mid);
 127         if ($mid =~ /\A[a-f0-9]{40}\z/) {
 128                 if ($mid = mid2blob($ctx)) {
 129                         require Email::Simple;
 130                         use PublicInbox::MID qw/mid_clean/;
 131                         $mid = Email::Simple->new($mid);
 132                         $ctx->{mid} = mid_clean($mid->header('Message-ID'));
 133                 }
 134         }
 135         undef;
 136 }
 137
 138 # /$LISTNAME/new.atom                     -> Atom feed, includes replies
 139 sub get_atom {
 140         my ($ctx) = @_;
 141         require PublicInbox::Feed;
 142         PublicInbox::Feed::generate($ctx);
 143 }
 144
 145 # /$LISTNAME/?r=$GIT_COMMIT                 -> HTML only
 146 sub get_index {
 147         my ($ctx) = @_;
 148         require PublicInbox::Feed;
 149         my $srch = searcher($ctx);
 150         footer($ctx);
 151         if (defined $ctx->{cgi}->param('q')) {
 152                 require PublicInbox::SearchView;
 153                 PublicInbox::SearchView::sres_top_html($ctx);
 154         } else {
 155                 PublicInbox::Feed::generate_html_index($ctx);
 156         }
 157 }
 158
 159 # just returns a string ref for the blob in the current ctx
 160 sub mid2blob {
 161         my ($ctx) = @_;
 162         require PublicInbox::MID;
 163         my $path = PublicInbox::MID::mid2path($ctx->{mid});
 164         $ctx->{git}->cat_file("HEAD:$path");
 165 }
 166
 167 # /$LISTNAME/$MESSAGE_ID/raw                    -> raw mbox
 168 sub get_mid_txt {
 169         my ($ctx) = @_;
 170         my $x = mid2blob($ctx) or return r404($ctx);
 171         require PublicInbox::Mbox;
 172         PublicInbox::Mbox::emit1($ctx, $x);
 173 }
 174
 175 # /$LISTNAME/$MESSAGE_ID/                   -> HTML content (short quotes)
 176 sub get_mid_html {
 177         my ($ctx) = @_;
 178         my $x = mid2blob($ctx) or return r404($ctx);
 179
 180         require PublicInbox::View;
 181         my $foot = footer($ctx);
 182         require Email::MIME;
 183         my $mime = Email::MIME->new($x);
 184         searcher($ctx);
 185         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 186           [ PublicInbox::View::msg_html($ctx, $mime, 'f/', $foot) ] ];
 187 }
 188
 189 # /$LISTNAME/$MESSAGE_ID/f/                   -> HTML content (fullquotes)
 190 sub get_full_html {
 191         my ($ctx) = @_;
 192         my $x = mid2blob($ctx) or return r404($ctx);
 193
 194         require PublicInbox::View;
 195         my $foot = footer($ctx);
 196         require Email::MIME;
 197         my $mime = Email::MIME->new($x);
 198         searcher($ctx);
 199         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 200           [ PublicInbox::View::msg_html($ctx, $mime, undef, $foot)] ];
 201 }
 202
 203 # /$LISTNAME/$MESSAGE_ID/R/                   -> HTML content (fullquotes)
 204 sub get_reply_html {
 205         my ($ctx) = @_;
 206         my $x = mid2blob($ctx) or return r404($ctx);
 207
 208         require PublicInbox::View;
 209         my $foot = footer($ctx);
 210         require Email::MIME;
 211         my $hdr = Email::MIME->new($x)->header_obj;
 212         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 213           [ PublicInbox::View::msg_reply($ctx, $hdr, $foot)] ];
 214 }
 215
 216 # /$LISTNAME/$MESSAGE_ID/t/
 217 sub get_thread {
 218         my ($ctx, $flat) = @_;
 219         my $srch = searcher($ctx) or return need_search($ctx);
 220         require PublicInbox::View;
 221         my $foot = footer($ctx);
 222         $ctx->{flat} = $flat;
 223         PublicInbox::View::thread_html($ctx, $foot, $srch);
 224 }
 225
 226 sub ctx_get {
 227         my ($ctx, $key) = @_;
 228         my $val = $ctx->{$key};
 229         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable\n";
 230         $val;
 231 }
 232
 233 sub footer {
 234         my ($ctx) = @_;
 235         return '' unless $ctx;
 236         my $git_dir = ctx_get($ctx, 'git_dir');
 237
 238         # favor user-supplied footer
 239         my $footer = try_cat("$git_dir/public-inbox/footer.html");
 240         if (defined $footer) {
 241                 chomp $footer;
 242                 $ctx->{footer} = $footer;
 243                 return $footer;
 244         }
 245
 246         # auto-generate a footer
 247         my $listname = ctx_get($ctx, 'listname');
 248         my $desc = try_cat("$git_dir/description");
 249         $desc = '$GIT_DIR/description missing' unless defined $desc;
 250         chomp $desc;
 251
 252         my $urls = try_cat("$git_dir/cloneurl");
 253         my @urls = split(/\r?\n/, $urls || '');
 254         my %seen = map { $_ => 1 } @urls;
 255         my $http = $ctx->{cgi}->base->as_string . $listname;
 256         $seen{$http} or unshift @urls, $http;
 257         if (scalar(@urls) == 1) {
 258                 $urls = "URL for <a\nhref=\"" . SSOMA_URL .
 259                         qq(">ssoma</a> or <b>git clone --mirror \$URL</b> :) .
 260                         $urls[0];
 261         } else {
 262                 $urls = "URLs for <a\nhref=\"" . SSOMA_URL .
 263                         qq(">ssoma</a> or <b>git clone --mirror \$URL</b>\n) .
 264                         join("\n", map { "\t$_" } @urls);
 265         }
 266
 267         my $addr = $pi_config->get($listname, 'address');
 268         if (ref($addr) eq 'ARRAY') {
 269                 $addr = $addr->[0]; # first address is primary
 270         }
 271
 272         $addr = "<a\nhref=\"mailto:$addr\">$addr</a>";
 273
 274         $ctx->{footer} = join("\n",
 275                 '- ' . $desc,
 276                 "A <a\nhref=\"" . PI_URL .  '">public-inbox</a>, ' .
 277                         'anybody may post in plain-text (not HTML):',
 278                 $addr,
 279                 $urls
 280         );
 281 }
 282
 283 # search support is optional, returns undef if Xapian is not installed
 284 # or not configured for the given GIT_DIR
 285 sub searcher {
 286         my ($ctx) = @_;
 287         eval {
 288                 require PublicInbox::Search;
 289                 $ctx->{srch} = PublicInbox::Search->new($ctx->{git_dir});
 290         };
 291 }
 292
 293 sub need_search {
 294         my ($ctx) = @_;
 295         my $msg = <<EOF;
 296 <html><head><title>Search not available for this
 297 public-inbox</title><body><pre>Search is not available for this public-inbox
 298 <a href="../">Return to index</a></pre></body></html>
 299 EOF
 300         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 301 }
 302
 303 # /$LISTNAME/$MESSAGE_ID/t.mbox           -> thread as mbox
 304 # /$LISTNAME/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 305 # note: I'm not a big fan of other compression formats since they're
 306 # significantly more expensive on CPU than gzip and less-widely available,
 307 # especially on older systems.  Stick to zlib since that's what git uses.
 308 sub get_thread_mbox {
 309         my ($ctx, $sfx) = @_;
 310         my $srch = searcher($ctx) or return need_search($ctx);
 311         require PublicInbox::Mbox;
 312         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 313 }
 314
 315
 316 # /$LISTNAME/$MESSAGE_ID/t.atom           -> thread as Atom feed
 317 sub get_thread_atom {
 318         my ($ctx) = @_;
 319         searcher($ctx) or return need_search($ctx);
 320         $ctx->{self_url} = $ctx->{cgi}->uri->as_string;
 321         require PublicInbox::Feed;
 322         PublicInbox::Feed::generate_thread_atom($ctx);
 323 }
 324
 325 sub legacy_redirects {
 326         my ($ctx, $path_info) = @_;
 327
 328         # single-message pages
 329         if ($path_info =~ m!$LISTNAME_RE/m/(\S+)/\z!o) {
 330                 r301($ctx, $1, $2);
 331         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)/raw\z!o) {
 332                 r301($ctx, $1, $2, 'raw');
 333
 334         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)/\z!o) {
 335                 r301($ctx, $1, $2, 'f/');
 336
 337         # thread display
 338         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/\z!o) {
 339                 r301($ctx, $1, $2, 't/#u');
 340
 341         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 342                 r301($ctx, $1, $2, "t.mbox$3");
 343
 344         # even older legacy redirects
 345         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
 346                 r301($ctx, $1, $2);
 347
 348         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\.html\z!o) {
 349                 r301($ctx, $1, $2, 't/#u');
 350
 351         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
 352                 r301($ctx, $1, $2, 'f/');
 353
 354         } elsif ($path_info =~ m!$LISTNAME_RE/(?:m|f)/(\S+)\.txt\z!o) {
 355                 r301($ctx, $1, $2, 'raw');
 356
 357         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 358                 r301($ctx, $1, $2, "t$3");
 359
 360         # legacy convenience redirects, order still matters
 361         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\z!o) {
 362                 r301($ctx, $1, $2);
 363         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\z!o) {
 364                 r301($ctx, $1, $2, 't/#u');
 365         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\z!o) {
 366                 r301($ctx, $1, $2, 'f/');
 367
 368         # some Message-IDs have slashes in them and the HTTP server
 369         # may try to be clever and unescape them :<
 370         } elsif ($path_info =~ m!$LISTNAME_RE/(\S+/\S+)/$END_RE\z!o) {
 371                 msg_page($ctx, $1, $2, $3);
 372
 373         # in case people leave off the trailing slash:
 374         } elsif ($path_info =~ m!$LISTNAME_RE/(\S+/\S+)/(f|T|t)\z!o) {
 375                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 376         } else {
 377                 r404();
 378         }
 379 }
 380
 381 sub r301 {
 382         my ($ctx, $listname, $mid, $suffix) = @_;
 383         my $cgi = $ctx->{cgi};
 384         my $url;
 385         my $qs = $cgi->env->{QUERY_STRING};
 386         $url = $cgi->base->as_string . $listname . '/';
 387         $url .= (uri_escape_utf8($mid) . '/') if (defined $mid);
 388         $url .= $suffix if (defined $suffix);
 389         $url .= "?$qs" if $qs ne '';
 390
 391         [ 301,
 392           [ Location => $url, 'Content-Type' => 'text/plain' ],
 393           [ "Redirecting to $url\n" ] ]
 394 }
 395
 396 sub msg_page {
 397         my ($ctx, $list, $mid, $e) = @_;
 398         unless (invalid_list_mid($ctx, $list, $mid)) {
 399                 '' eq $e and return get_mid_html($ctx);
 400                 't/' eq $e and return get_thread($ctx);
 401                 't.atom' eq $e and return get_thread_atom($ctx);
 402                 't.mbox' eq $e and return get_thread_mbox($ctx);
 403                 't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 404                 'T/' eq $e and return get_thread($ctx, 1);
 405                 'raw' eq $e and return get_mid_txt($ctx);
 406                 'f/' eq $e and return get_full_html($ctx);
 407                 'R/' eq $e and return get_reply_html($ctx);
 408         }
 409         r404($ctx);
 410 }
 411
 412 sub serve_git {
 413         my ($cgi, $git, $path) = @_;
 414         PublicInbox::GitHTTPBackend::serve($cgi, $git, $path);
 415 }
 416
 417 1;