lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config;
  17 use PublicInbox::Hval;
  18 use URI::Escape qw(uri_unescape);
  19 use PublicInbox::MID qw(mid_escape);
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22
  23 # TODO: consider a routing tree now that we have more endpoints:
  24 our $INBOX_RE = qr!\A/([\w\-][\w\.\-]*)!;
  25 our $MID_RE = qr!([^/]+)!;
  26 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  27 our $ATTACH_RE = qr!(\d[\.\d]*)-([[:alnum:]][\w\.-]+[[:alnum:]])!i;
  28 our $OID_RE = qr![a-f0-9]{7,40}!;
  29
  30 sub new {
  31         my ($class, $pi_config) = @_;
  32         $pi_config ||= PublicInbox::Config->new;
  33         bless { pi_config => $pi_config }, $class;
  34 }
  35
  36 # backwards compatibility, do not use
  37 sub run {
  38         my ($req, $method) = @_;
  39         PublicInbox::WWW->new->call($req->env);
  40 }
  41
  42 my %path_re_cache;
  43
  44 sub path_re ($) {
  45         my $sn = $_[0]->{SCRIPT_NAME};
  46         $path_re_cache{$sn} ||= do {
  47                 $sn = '/'.$sn unless index($sn, '/') == 0;
  48                 $sn =~ s!/\z!!;
  49                 qr!\A(?:https?://[^/]+)?\Q$sn\E(/[^\?\#]+)!;
  50         };
  51 }
  52
  53 sub call {
  54         my ($self, $env) = @_;
  55         my $ctx = { env => $env, www => $self };
  56
  57         # we don't care about multi-value
  58         my %qp = map {
  59                 utf8::decode($_);
  60                 my ($k, $v) = split('=', uri_unescape($_), 2);
  61                 $v = '' unless defined $v;
  62                 $v =~ tr/+/ /;
  63                 ($k, $v)
  64         } split(/[&;]+/, $env->{QUERY_STRING});
  65         $ctx->{qp} = \%qp;
  66
  67         # not using $env->{PATH_INFO} here since that's already decoded
  68         my ($path_info) = ($env->{REQUEST_URI} =~ path_re($env));
  69         my $method = $env->{REQUEST_METHOD};
  70
  71         if ($method eq 'POST') {
  72                 if ($path_info =~ m!$INBOX_RE/(?:(\d+)/)?(git-upload-pack)\z!) {
  73                         my ($part, $path) = ($2, $3);
  74                         return invalid_inbox($ctx, $1) ||
  75                                 serve_git($ctx, $part, $path);
  76                 } elsif ($path_info =~ m!$INBOX_RE/!o) {
  77                         return invalid_inbox($ctx, $1) || mbox_results($ctx);
  78                 }
  79         }
  80         elsif ($method !~ /\AGET|HEAD\z/) {
  81                 return r(405, 'Method Not Allowed');
  82         }
  83
  84         # top-level indices and feeds
  85         if ($path_info eq '/') {
  86                 r404();
  87         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  88                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  89         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  90                 invalid_inbox($ctx, $1) || get_index($ctx);
  91         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  92                 invalid_inbox($ctx, $1) || get_atom($ctx);
  93         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
  94                 invalid_inbox($ctx, $1) || get_new($ctx);
  95         } elsif ($path_info =~ m!$INBOX_RE/(?:(\d+)/)?
  96                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  97                 my ($part, $path) = ($2, $3);
  98                 invalid_inbox($ctx, $1) || serve_git($ctx, $part, $path);
  99         } elsif ($path_info =~ m!$INBOX_RE/([\w-]+).mbox\.gz\z!o) {
 100                 serve_mbox_range($ctx, $1, $2);
 101         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
 102                 msg_page($ctx, $1, $2, $3);
 103
 104         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
 105                 my ($idx, $fn) = ($3, $4);
 106                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
 107         # in case people leave off the trailing slash:
 108         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
 109                 my ($inbox, $mid_ue, $suffix) = ($1, $2, $3);
 110                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
 111                 r301($ctx, $inbox, $mid_ue, $suffix);
 112
 113         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
 114                 my ($inbox, $mid_ue) = ($1, $2);
 115                 r301($ctx, $inbox, $mid_ue, '#R');
 116
 117         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
 118                 r301($ctx, $1, $2);
 119         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 120                 get_text($ctx, $1, $2);
 121         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s\z!o) {
 122                 get_vcs_object($ctx, $1, $2);
 123         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/_([\w\.\-]+)\z!o) {
 124                 get_vcs_object($ctx, $1, $2, $3);
 125         # convenience redirects order matters
 126         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 127                 r301($ctx, $1, $2);
 128
 129         } else {
 130                 legacy_redirects($ctx, $path_info);
 131         }
 132 }
 133
 134 # for CoW-friendliness, MOOOOO!
 135 sub preload {
 136         require PublicInbox::Feed;
 137         require PublicInbox::View;
 138         require PublicInbox::SearchThread;
 139         require PublicInbox::MIME;
 140         require Digest::SHA;
 141         require POSIX;
 142
 143         foreach (qw(PublicInbox::Search PublicInbox::SearchView
 144                         PublicInbox::Mbox IO::Compress::Gzip
 145                         PublicInbox::NewsWWW)) {
 146                 eval "require $_;";
 147         }
 148 }
 149
 150 # private functions below
 151
 152 sub r404 {
 153         my ($ctx) = @_;
 154         if ($ctx && $ctx->{mid}) {
 155                 require PublicInbox::ExtMsg;
 156                 searcher($ctx);
 157                 return PublicInbox::ExtMsg::ext_msg($ctx);
 158         }
 159         r(404, 'Not Found');
 160 }
 161
 162 # simple response for errors
 163 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 164
 165 # returns undef if valid, array ref response if invalid
 166 sub invalid_inbox ($$) {
 167         my ($ctx, $inbox) = @_;
 168         my $www = $ctx->{www};
 169         my $obj = $www->{pi_config}->lookup_name($inbox);
 170         if (defined $obj) {
 171                 $ctx->{git} = $obj->git;
 172                 $ctx->{-inbox} = $obj;
 173                 return;
 174         }
 175
 176         # sometimes linkifiers (not ours!) screw up automatic link
 177         # generation and link things intended for nntp:// to https?://,
 178         # so try to infer links and redirect them to the appropriate
 179         # list URL.
 180         $www->news_www->call($ctx->{env});
 181 }
 182
 183 # returns undef if valid, array ref response if invalid
 184 sub invalid_inbox_mid {
 185         my ($ctx, $inbox, $mid_ue) = @_;
 186         my $ret = invalid_inbox($ctx, $inbox);
 187         return $ret if $ret;
 188
 189         my $mid = $ctx->{mid} = uri_unescape($mid_ue);
 190         my $ibx = $ctx->{-inbox};
 191         if ($mid =~ m!\A([a-f0-9]{2})([a-f0-9]{38})\z!) {
 192                 my ($x2, $x38) = ($1, $2);
 193                 # this is horrifically wasteful for legacy URLs:
 194                 my $str = $ctx->{-inbox}->msg_by_path("$x2/$x38") or return;
 195                 require Email::Simple;
 196                 my $s = Email::Simple->new($str);
 197                 $mid = PublicInbox::MID::mid_clean($s->header('Message-ID'));
 198                 return r301($ctx, $inbox, mid_escape($mid));
 199         }
 200         undef;
 201 }
 202
 203 # /$INBOX/new.atom                     -> Atom feed, includes replies
 204 sub get_atom {
 205         my ($ctx) = @_;
 206         require PublicInbox::Feed;
 207         PublicInbox::Feed::generate($ctx);
 208 }
 209
 210 # /$INBOX/new.html                      -> HTML only
 211 sub get_new {
 212         my ($ctx) = @_;
 213         require PublicInbox::Feed;
 214         PublicInbox::Feed::new_html($ctx);
 215 }
 216
 217 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 218 sub get_index {
 219         my ($ctx) = @_;
 220         require PublicInbox::Feed;
 221         searcher($ctx);
 222         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 223                 require PublicInbox::SearchView;
 224                 PublicInbox::SearchView::sres_top_html($ctx);
 225         } else {
 226                 PublicInbox::Feed::generate_html_index($ctx);
 227         }
 228 }
 229
 230 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 231 sub get_mid_txt {
 232         my ($ctx) = @_;
 233         require PublicInbox::Mbox;
 234         PublicInbox::Mbox::emit_raw($ctx) || r404($ctx);
 235 }
 236
 237 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 238 sub get_mid_html {
 239         my ($ctx) = @_;
 240         require PublicInbox::View;
 241         searcher($ctx);
 242         PublicInbox::View::msg_page($ctx) || r404($ctx);
 243 }
 244
 245 # /$INBOX/$MESSAGE_ID/t/
 246 sub get_thread {
 247         my ($ctx, $flat) = @_;
 248         searcher($ctx) or return need_search($ctx);
 249         $ctx->{flat} = $flat;
 250         require PublicInbox::View;
 251         PublicInbox::View::thread_html($ctx);
 252 }
 253
 254 # /$INBOX/_/text/$KEY/
 255 # /$INBOX/_/text/$KEY/raw
 256 # KEY may contain slashes
 257 sub get_text {
 258         my ($ctx, $inbox, $key) = @_;
 259         my $r404 = invalid_inbox($ctx, $inbox);
 260         return $r404 if $r404;
 261
 262         require PublicInbox::WwwText;
 263         PublicInbox::WwwText::get_text($ctx, $key);
 264 }
 265
 266 # show git objects (blobs and commits)
 267 # /$INBOX/_/$OBJECT_ID/show
 268 # /$INBOX/_/${OBJECT_ID}_${FILENAME}
 269 # KEY may contain slashes
 270 sub get_vcs_object ($$$;$) {
 271         my ($ctx, $inbox, $oid, $filename) = @_;
 272         my $r404 = invalid_inbox($ctx, $inbox);
 273         return $r404 if $r404;
 274         require PublicInbox::ViewVCS;
 275         PublicInbox::ViewVCS::show($ctx, $oid, $filename);
 276 }
 277
 278 sub ctx_get {
 279         my ($ctx, $key) = @_;
 280         my $val = $ctx->{$key};
 281         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable";
 282         $val;
 283 }
 284
 285 # search support is optional, returns undef if Xapian is not installed
 286 # or not configured for the given GIT_DIR
 287 sub searcher {
 288         my ($ctx) = @_;
 289         eval {
 290                 require PublicInbox::Search;
 291                 $ctx->{srch} = $ctx->{-inbox}->search;
 292         };
 293 }
 294
 295 sub need_search {
 296         my ($ctx) = @_;
 297         my $msg = <<EOF;
 298 <html><head><title>Search not available for this
 299 public-inbox</title><body><pre>Search is not available for this public-inbox
 300 <a href="../">Return to index</a></pre></body></html>
 301 EOF
 302         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 303 }
 304
 305 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 306 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 307 # note: I'm not a big fan of other compression formats since they're
 308 # significantly more expensive on CPU than gzip and less-widely available,
 309 # especially on older systems.  Stick to zlib since that's what git uses.
 310 sub get_thread_mbox {
 311         my ($ctx, $sfx) = @_;
 312         my $srch = searcher($ctx) or return need_search($ctx);
 313         require PublicInbox::Mbox;
 314         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 315 }
 316
 317
 318 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 319 sub get_thread_atom {
 320         my ($ctx) = @_;
 321         searcher($ctx) or return need_search($ctx);
 322         require PublicInbox::Feed;
 323         PublicInbox::Feed::generate_thread_atom($ctx);
 324 }
 325
 326 sub legacy_redirects {
 327         my ($ctx, $path_info) = @_;
 328
 329         # single-message pages
 330         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 331                 r301($ctx, $1, $2);
 332         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 333                 r301($ctx, $1, $2, 'raw');
 334
 335         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 336                 r301($ctx, $1, $2);
 337
 338         # thread display
 339         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 340                 r301($ctx, $1, $2, 't/#u');
 341
 342         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 343                 r301($ctx, $1, $2, "t.mbox$3");
 344
 345         # even older legacy redirects
 346         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 347                 r301($ctx, $1, $2);
 348
 349         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 350                 r301($ctx, $1, $2, 't/#u');
 351
 352         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 353                 r301($ctx, $1, $2);
 354
 355         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 356                 r301($ctx, $1, $2, 'raw');
 357
 358         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 359                 r301($ctx, $1, $2, "t$3");
 360
 361         # legacy convenience redirects, order still matters
 362         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 363                 r301($ctx, $1, $2);
 364         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 365                 r301($ctx, $1, $2, 't/#u');
 366         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 367                 r301($ctx, $1, $2);
 368
 369         # some Message-IDs have slashes in them and the HTTP server
 370         # may try to be clever and unescape them :<
 371         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 372                 msg_page($ctx, $1, $2, $3);
 373
 374         # in case people leave off the trailing slash:
 375         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 376                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 377         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 378                 r301($ctx, $1, $2);
 379         } else {
 380                 $ctx->{www}->news_www->call($ctx->{env});
 381         }
 382 }
 383
 384 sub r301 {
 385         my ($ctx, $inbox, $mid_ue, $suffix) = @_;
 386         my $obj = $ctx->{-inbox};
 387         unless ($obj) {
 388                 my $r404 = invalid_inbox($ctx, $inbox);
 389                 return $r404 if $r404;
 390                 $obj = $ctx->{-inbox};
 391         }
 392         my $url = $obj->base_url($ctx->{env});
 393         my $qs = $ctx->{env}->{QUERY_STRING};
 394         if (defined $mid_ue) {
 395                 # common, and much nicer as '@' than '%40':
 396                 $mid_ue =~ s/%40/@/g;
 397                 $url .= $mid_ue . '/';
 398         }
 399         $url .= $suffix if (defined $suffix);
 400         $url .= "?$qs" if $qs ne '';
 401
 402         [ 301,
 403           [ Location => $url, 'Content-Type' => 'text/plain' ],
 404           [ "Redirecting to $url\n" ] ]
 405 }
 406
 407 sub msg_page {
 408         my ($ctx, $inbox, $mid_ue, $e) = @_;
 409         my $ret;
 410         $ret = invalid_inbox_mid($ctx, $inbox, $mid_ue) and return $ret;
 411         '' eq $e and return get_mid_html($ctx);
 412         'T/' eq $e and return get_thread($ctx, 1);
 413         't/' eq $e and return get_thread($ctx);
 414         't.atom' eq $e and return get_thread_atom($ctx);
 415         't.mbox' eq $e and return get_thread_mbox($ctx);
 416         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 417         'raw' eq $e and return get_mid_txt($ctx);
 418
 419         # legacy, but no redirect for compatibility:
 420         'f/' eq $e and return get_mid_html($ctx);
 421         r404($ctx);
 422 }
 423
 424 sub serve_git {
 425         my ($ctx, $part, $path) = @_;
 426         my $env = $ctx->{env};
 427         my $ibx = $ctx->{-inbox};
 428         my $git = defined $part ? $ibx->git_part($part) : $ibx->git;
 429         $git ? PublicInbox::GitHTTPBackend::serve($env, $git, $path) : r404();
 430 }
 431
 432 sub mbox_results {
 433         my ($ctx) = @_;
 434         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 435                 searcher($ctx) or return need_search($ctx);
 436                 require PublicInbox::SearchView;
 437                 return PublicInbox::SearchView::mbox_results($ctx);
 438         }
 439         r404();
 440 }
 441
 442 sub serve_mbox_range {
 443         my ($ctx, $inbox, $range) = @_;
 444         invalid_inbox($ctx, $inbox) || eval {
 445                 require PublicInbox::Mbox;
 446                 searcher($ctx);
 447                 PublicInbox::Mbox::emit_range($ctx, $range);
 448         }
 449 }
 450
 451 sub news_www {
 452         my ($self) = @_;
 453         $self->{news_www} ||= do {
 454                 require PublicInbox::NewsWWW;
 455                 PublicInbox::NewsWWW->new($self->{pi_config});
 456         }
 457 }
 458
 459 sub get_attach {
 460         my ($ctx, $idx, $fn) = @_;
 461         require PublicInbox::WwwAttach;
 462         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 463 }
 464
 465 1;