lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config;
  17 use PublicInbox::Hval;
  18 use URI::Escape qw(uri_unescape);
  19 use PublicInbox::MID qw(mid_escape);
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22 our $INBOX_RE = qr!\A/([\w\.\-]+)!;
  23 our $MID_RE = qr!([^/]+)!;
  24 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  25 our $ATTACH_RE = qr!(\d[\.\d]*)-([[:alnum:]][\w\.-]+[[:alnum:]])!i;
  26
  27 sub new {
  28         my ($class, $pi_config) = @_;
  29         $pi_config ||= PublicInbox::Config->new;
  30         bless { pi_config => $pi_config }, $class;
  31 }
  32
  33 # backwards compatibility, do not use
  34 sub run {
  35         my ($req, $method) = @_;
  36         PublicInbox::WWW->new->call($req->env);
  37 }
  38
  39 sub call {
  40         my ($self, $env) = @_;
  41         my $ctx = { env => $env, www => $self };
  42
  43         # we don't care about multi-value
  44         my %qp = map {
  45                 utf8::decode($_);
  46                 my ($k, $v) = split('=', uri_unescape($_), 2);
  47                 $v = '' unless defined $v;
  48                 $v =~ tr/+/ /;
  49                 ($k, $v)
  50         } split(/[&;]+/, $env->{QUERY_STRING});
  51         $ctx->{qp} = \%qp;
  52
  53         my $path_info = $env->{PATH_INFO};
  54         my $method = $env->{REQUEST_METHOD};
  55
  56         if ($method eq 'POST' &&
  57                  $path_info =~ m!$INBOX_RE/(git-upload-pack)\z!) {
  58                 my $path = $2;
  59                 return invalid_inbox($ctx, $1) || serve_git($ctx, $path);
  60         }
  61         elsif ($method !~ /\AGET|HEAD\z/) {
  62                 return r(405, 'Method Not Allowed');
  63         }
  64
  65         # top-level indices and feeds
  66         if ($path_info eq '/') {
  67                 r404();
  68         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  69                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  70         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  71                 invalid_inbox($ctx, $1) || get_index($ctx);
  72         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  73                 invalid_inbox($ctx, $1) || get_atom($ctx);
  74         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
  75                 invalid_inbox($ctx, $1) || get_new($ctx);
  76         } elsif ($path_info =~ m!$INBOX_RE/
  77                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  78                 my $path = $2;
  79                 invalid_inbox($ctx, $1) || serve_git($ctx, $path);
  80         } elsif ($path_info =~ m!$INBOX_RE/([\w-]+).mbox\.gz\z!o) {
  81                 serve_mbox_range($ctx, $1, $2);
  82         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
  83                 msg_page($ctx, $1, $2, $3);
  84
  85         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
  86                 my ($idx, $fn) = ($3, $4);
  87                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
  88         # in case people leave off the trailing slash:
  89         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
  90                 my ($inbox, $mid, $suffix) = ($1, $2, $3);
  91                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
  92                 r301($ctx, $inbox, $mid, $suffix);
  93
  94         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
  95                 my ($inbox, $mid) = ($1, $2);
  96                 r301($ctx, $inbox, $mid, '#R');
  97
  98         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
  99                 r301($ctx, $1, $2);
 100         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 101                 get_text($ctx, $1, $2);
 102
 103         # convenience redirects order matters
 104         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 105                 r301($ctx, $1, $2);
 106
 107         } else {
 108                 legacy_redirects($ctx, $path_info);
 109         }
 110 }
 111
 112 # for CoW-friendliness, MOOOOO!
 113 sub preload {
 114         require PublicInbox::Feed;
 115         require PublicInbox::View;
 116         require PublicInbox::SearchThread;
 117         require PublicInbox::MIME;
 118         require Digest::SHA;
 119         require POSIX;
 120
 121         foreach (qw(PublicInbox::Search PublicInbox::SearchView
 122                         PublicInbox::Mbox IO::Compress::Gzip
 123                         PublicInbox::NewsWWW)) {
 124                 eval "require $_;";
 125         }
 126 }
 127
 128 # private functions below
 129
 130 sub r404 {
 131         my ($ctx) = @_;
 132         if ($ctx && $ctx->{mid}) {
 133                 require PublicInbox::ExtMsg;
 134                 searcher($ctx);
 135                 return PublicInbox::ExtMsg::ext_msg($ctx);
 136         }
 137         r(404, 'Not Found');
 138 }
 139
 140 # simple response for errors
 141 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 142
 143 # returns undef if valid, array ref response if invalid
 144 sub invalid_inbox ($$) {
 145         my ($ctx, $inbox) = @_;
 146         my $www = $ctx->{www};
 147         my $obj = $www->{pi_config}->lookup_name($inbox);
 148         if (defined $obj) {
 149                 $ctx->{git_dir} = $obj->{mainrepo};
 150                 $ctx->{git} = $obj->git;
 151                 $ctx->{-inbox} = $obj;
 152                 $ctx->{inbox} = $inbox;
 153                 return;
 154         }
 155
 156         # sometimes linkifiers (not ours!) screw up automatic link
 157         # generation and link things intended for nntp:// to https?://,
 158         # so try to infer links and redirect them to the appropriate
 159         # list URL.
 160         $www->news_www->call($ctx->{env});
 161 }
 162
 163 # returns undef if valid, array ref response if invalid
 164 sub invalid_inbox_mid {
 165         my ($ctx, $inbox, $mid) = @_;
 166         my $ret = invalid_inbox($ctx, $inbox);
 167         return $ret if $ret;
 168
 169         $ctx->{mid} = $mid;
 170         if ($mid =~ /\A[a-f0-9]{40}\z/) {
 171                 # this is horiffically wasteful for legacy URLs:
 172                 if ($mid = mid2blob($ctx)) {
 173                         require Email::Simple;
 174                         use PublicInbox::MID qw/mid_clean/;
 175                         my $s = Email::Simple->new($mid);
 176                         $ctx->{mid} = mid_clean($s->header('Message-ID'));
 177                 }
 178         }
 179         undef;
 180 }
 181
 182 # /$INBOX/new.atom                     -> Atom feed, includes replies
 183 sub get_atom {
 184         my ($ctx) = @_;
 185         require PublicInbox::Feed;
 186         PublicInbox::Feed::generate($ctx);
 187 }
 188
 189 # /$INBOX/new.html                      -> HTML only
 190 sub get_new {
 191         my ($ctx) = @_;
 192         require PublicInbox::Feed;
 193         PublicInbox::Feed::new_html($ctx);
 194 }
 195
 196 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 197 sub get_index {
 198         my ($ctx) = @_;
 199         require PublicInbox::Feed;
 200         searcher($ctx);
 201         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 202                 require PublicInbox::SearchView;
 203                 PublicInbox::SearchView::sres_top_html($ctx);
 204         } else {
 205                 PublicInbox::Feed::generate_html_index($ctx);
 206         }
 207 }
 208
 209 # just returns a string ref for the blob in the current ctx
 210 sub mid2blob {
 211         my ($ctx) = @_;
 212         $ctx->{-inbox}->msg_by_mid($ctx->{mid});
 213 }
 214
 215 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 216 sub get_mid_txt {
 217         my ($ctx) = @_;
 218         my $x = mid2blob($ctx) or return r404($ctx);
 219         require PublicInbox::Mbox;
 220         PublicInbox::Mbox::emit1($ctx, $x);
 221 }
 222
 223 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 224 sub get_mid_html {
 225         my ($ctx) = @_;
 226         my $x = mid2blob($ctx) or return r404($ctx);
 227
 228         require PublicInbox::View;
 229         require PublicInbox::MIME;
 230         my $mime = PublicInbox::MIME->new($x);
 231         searcher($ctx);
 232         PublicInbox::View::msg_html($ctx, $mime);
 233 }
 234
 235 # /$INBOX/$MESSAGE_ID/t/
 236 sub get_thread {
 237         my ($ctx, $flat) = @_;
 238         searcher($ctx) or return need_search($ctx);
 239         $ctx->{flat} = $flat;
 240         require PublicInbox::View;
 241         PublicInbox::View::thread_html($ctx);
 242 }
 243
 244 # /$INBOX/_/text/$KEY/
 245 # /$INBOX/_/text/$KEY/raw
 246 # KEY may contain slashes
 247 sub get_text {
 248         my ($ctx, $inbox, $key) = @_;
 249         my $r404 = invalid_inbox($ctx, $inbox);
 250         return $r404 if $r404;
 251
 252         require PublicInbox::WwwText;
 253         PublicInbox::WwwText::get_text($ctx, $key);
 254 }
 255
 256 sub ctx_get {
 257         my ($ctx, $key) = @_;
 258         my $val = $ctx->{$key};
 259         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable";
 260         $val;
 261 }
 262
 263 # search support is optional, returns undef if Xapian is not installed
 264 # or not configured for the given GIT_DIR
 265 sub searcher {
 266         my ($ctx) = @_;
 267         eval {
 268                 require PublicInbox::Search;
 269                 $ctx->{srch} = $ctx->{-inbox}->search;
 270         };
 271 }
 272
 273 sub need_search {
 274         my ($ctx) = @_;
 275         my $msg = <<EOF;
 276 <html><head><title>Search not available for this
 277 public-inbox</title><body><pre>Search is not available for this public-inbox
 278 <a href="../">Return to index</a></pre></body></html>
 279 EOF
 280         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 281 }
 282
 283 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 284 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 285 # note: I'm not a big fan of other compression formats since they're
 286 # significantly more expensive on CPU than gzip and less-widely available,
 287 # especially on older systems.  Stick to zlib since that's what git uses.
 288 sub get_thread_mbox {
 289         my ($ctx, $sfx) = @_;
 290         my $srch = searcher($ctx) or return need_search($ctx);
 291         require PublicInbox::Mbox;
 292         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 293 }
 294
 295
 296 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 297 sub get_thread_atom {
 298         my ($ctx) = @_;
 299         searcher($ctx) or return need_search($ctx);
 300         require PublicInbox::Feed;
 301         PublicInbox::Feed::generate_thread_atom($ctx);
 302 }
 303
 304 sub legacy_redirects {
 305         my ($ctx, $path_info) = @_;
 306
 307         # single-message pages
 308         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 309                 r301($ctx, $1, $2);
 310         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 311                 r301($ctx, $1, $2, 'raw');
 312
 313         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 314                 r301($ctx, $1, $2);
 315
 316         # thread display
 317         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 318                 r301($ctx, $1, $2, 't/#u');
 319
 320         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 321                 r301($ctx, $1, $2, "t.mbox$3");
 322
 323         # even older legacy redirects
 324         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 325                 r301($ctx, $1, $2);
 326
 327         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 328                 r301($ctx, $1, $2, 't/#u');
 329
 330         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 331                 r301($ctx, $1, $2);
 332
 333         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 334                 r301($ctx, $1, $2, 'raw');
 335
 336         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 337                 r301($ctx, $1, $2, "t$3");
 338
 339         # legacy convenience redirects, order still matters
 340         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 341                 r301($ctx, $1, $2);
 342         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 343                 r301($ctx, $1, $2, 't/#u');
 344         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 345                 r301($ctx, $1, $2);
 346
 347         # some Message-IDs have slashes in them and the HTTP server
 348         # may try to be clever and unescape them :<
 349         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 350                 msg_page($ctx, $1, $2, $3);
 351
 352         # in case people leave off the trailing slash:
 353         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 354                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 355         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 356                 r301($ctx, $1, $2);
 357         } else {
 358                 $ctx->{www}->news_www->call($ctx->{env});
 359         }
 360 }
 361
 362 sub r301 {
 363         my ($ctx, $inbox, $mid, $suffix) = @_;
 364         my $obj = $ctx->{-inbox};
 365         unless ($obj) {
 366                 my $r404 = invalid_inbox($ctx, $inbox);
 367                 return $r404 if $r404;
 368                 $obj = $ctx->{-inbox};
 369         }
 370         my $url = $obj->base_url($ctx->{env});
 371         my $qs = $ctx->{env}->{QUERY_STRING};
 372         $url .= (mid_escape($mid) . '/') if (defined $mid);
 373         $url .= $suffix if (defined $suffix);
 374         $url .= "?$qs" if $qs ne '';
 375
 376         [ 301,
 377           [ Location => $url, 'Content-Type' => 'text/plain' ],
 378           [ "Redirecting to $url\n" ] ]
 379 }
 380
 381 sub msg_page {
 382         my ($ctx, $inbox, $mid, $e) = @_;
 383         my $ret;
 384         $ret = invalid_inbox_mid($ctx, $inbox, $mid) and return $ret;
 385         '' eq $e and return get_mid_html($ctx);
 386         'T/' eq $e and return get_thread($ctx, 1);
 387         't/' eq $e and return get_thread($ctx);
 388         't.atom' eq $e and return get_thread_atom($ctx);
 389         't.mbox' eq $e and return get_thread_mbox($ctx);
 390         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 391         'raw' eq $e and return get_mid_txt($ctx);
 392
 393         # legacy, but no redirect for compatibility:
 394         'f/' eq $e and return get_mid_html($ctx);
 395         r404($ctx);
 396 }
 397
 398 sub serve_git {
 399         my ($ctx, $path) = @_;
 400         PublicInbox::GitHTTPBackend::serve($ctx->{env}, $ctx->{git}, $path);
 401 }
 402
 403 sub serve_mbox_range {
 404         my ($ctx, $inbox, $range) = @_;
 405         invalid_inbox($ctx, $inbox) || eval {
 406                 require PublicInbox::Mbox;
 407                 searcher($ctx);
 408                 PublicInbox::Mbox::emit_range($ctx, $range);
 409         }
 410 }
 411
 412 sub news_www {
 413         my ($self) = @_;
 414         $self->{news_www} ||= do {
 415                 require PublicInbox::NewsWWW;
 416                 PublicInbox::NewsWWW->new($self->{pi_config});
 417         }
 418 }
 419
 420 sub get_attach {
 421         my ($ctx, $idx, $fn) = @_;
 422         require PublicInbox::WwwAttach;
 423         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 424 }
 425
 426 1;