lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 # - No JavaScript, graphics or icons allowed.
  10 # - Must not rely on static content
  11 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  12 package PublicInbox::WWW;
  13 use 5.008;
  14 use strict;
  15 use warnings;
  16 use PublicInbox::Config qw(try_cat);
  17 use URI::Escape qw(uri_escape_utf8 uri_unescape);
  18 use constant SSOMA_URL => 'http://ssoma.public-inbox.org/';
  19 use constant PI_URL => 'http://public-inbox.org/';
  20 require PublicInbox::Git;
  21 use PublicInbox::GitHTTPBackend;
  22 our $LISTNAME_RE = qr!\A/([\w\.\-]+)!;
  23 our $MID_RE = qr!([^/]+)!;
  24 our $END_RE = qr!(f/|T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  25 our $pi_config;
  26
  27 sub run {
  28         my ($cgi, $method) = @_;
  29         $pi_config ||= PublicInbox::Config->new;
  30         my $ctx = { cgi => $cgi, pi_config => $pi_config };
  31         my $path_info = $cgi->path_info;
  32
  33         if ($method eq 'POST' &&
  34                  $path_info =~ m!$LISTNAME_RE/(git-upload-pack)\z!) {
  35                 my $path = $2;
  36                 return (invalid_list($ctx, $1) ||
  37                         serve_git($cgi, $ctx->{git}, $path));
  38         }
  39         elsif ($method !~ /\AGET|HEAD\z/) {
  40                 return r(405, 'Method Not Allowed');
  41         }
  42
  43         # top-level indices and feeds
  44         if ($path_info eq '/') {
  45                 r404();
  46         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  47                 invalid_list($ctx, $1) || r301($ctx, $1);
  48         } elsif ($path_info =~ m!$LISTNAME_RE(?:/|/index\.html)?\z!o) {
  49                 invalid_list($ctx, $1) || get_index($ctx);
  50         } elsif ($path_info =~ m!$LISTNAME_RE/(?:atom\.xml|new\.atom)\z!o) {
  51                 invalid_list($ctx, $1) || get_atom($ctx);
  52
  53         } elsif ($path_info =~ m!$LISTNAME_RE/
  54                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
  55                 my $path = $2;
  56                 invalid_list($ctx, $1) || serve_git($cgi, $ctx->{git}, $path);
  57         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/$END_RE\z!o) {
  58                 msg_page($ctx, $1, $2, $3);
  59
  60         # in case people leave off the trailing slash:
  61         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/(f|T|t)\z!o) {
  62                 my ($listname, $mid, $suffix) = ($1, $2, $3);
  63                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
  64                 r301($ctx, $listname, $mid, $suffix);
  65
  66         # convenience redirects order matters
  67         } elsif ($path_info =~ m!$LISTNAME_RE/([^/]{2,})\z!o) {
  68                 r301($ctx, $1, $2);
  69
  70         } else {
  71                 legacy_redirects($ctx, $path_info);
  72         }
  73 }
  74
  75 # for CoW-friendliness, MOOOOO!
  76 sub preload {
  77         require PublicInbox::Feed;
  78         require PublicInbox::View;
  79         require PublicInbox::Thread;
  80         require Email::MIME;
  81         require Digest::SHA;
  82         require POSIX;
  83
  84         eval {
  85                 require PublicInbox::Search;
  86                 require PublicInbox::SearchView;
  87                 require PublicInbox::Mbox;
  88                 require IO::Compress::Gzip;
  89         };
  90 }
  91
  92 # private functions below
  93
  94 sub r404 {
  95         my ($ctx) = @_;
  96         if ($ctx && $ctx->{mid}) {
  97                 require PublicInbox::ExtMsg;
  98                 searcher($ctx);
  99                 return PublicInbox::ExtMsg::ext_msg($ctx);
 100         }
 101         r(404, 'Not Found');
 102 }
 103
 104 # simple response for errors
 105 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 106
 107 # returns undef if valid, array ref response if invalid
 108 sub invalid_list {
 109         my ($ctx, $listname) = @_;
 110         my $git_dir = $pi_config->get($listname, "mainrepo");
 111         if (defined $git_dir) {
 112                 $ctx->{git_dir} = $git_dir;
 113                 $ctx->{git} = PublicInbox::Git->new($git_dir);
 114                 $ctx->{listname} = $listname;
 115                 return;
 116         }
 117         r404();
 118 }
 119
 120 # returns undef if valid, array ref response if invalid
 121 sub invalid_list_mid {
 122         my ($ctx, $listname, $mid) = @_;
 123         my $ret = invalid_list($ctx, $listname, $mid);
 124         return $ret if $ret;
 125
 126         $ctx->{mid} = $mid = uri_unescape($mid);
 127         if ($mid =~ /\A[a-f0-9]{40}\z/) {
 128                 if ($mid = mid2blob($ctx)) {
 129                         require Email::Simple;
 130                         use PublicInbox::MID qw/mid_clean/;
 131                         $mid = Email::Simple->new($mid);
 132                         $ctx->{mid} = mid_clean($mid->header('Message-ID'));
 133                 }
 134         }
 135         undef;
 136 }
 137
 138 # /$LISTNAME/new.atom                     -> Atom feed, includes replies
 139 sub get_atom {
 140         my ($ctx) = @_;
 141         require PublicInbox::Feed;
 142         PublicInbox::Feed::generate($ctx);
 143 }
 144
 145 # /$LISTNAME/?r=$GIT_COMMIT                 -> HTML only
 146 sub get_index {
 147         my ($ctx) = @_;
 148         require PublicInbox::Feed;
 149         my $srch = searcher($ctx);
 150         footer($ctx);
 151         if (defined $ctx->{cgi}->param('q')) {
 152                 require PublicInbox::SearchView;
 153                 PublicInbox::SearchView::sres_top_html($ctx);
 154         } else {
 155                 PublicInbox::Feed::generate_html_index($ctx);
 156         }
 157 }
 158
 159 # just returns a string ref for the blob in the current ctx
 160 sub mid2blob {
 161         my ($ctx) = @_;
 162         require PublicInbox::MID;
 163         my $path = PublicInbox::MID::mid2path($ctx->{mid});
 164         $ctx->{git}->cat_file("HEAD:$path");
 165 }
 166
 167 # /$LISTNAME/$MESSAGE_ID/raw                    -> raw mbox
 168 sub get_mid_txt {
 169         my ($ctx) = @_;
 170         my $x = mid2blob($ctx) or return r404($ctx);
 171         require PublicInbox::Mbox;
 172         PublicInbox::Mbox::emit1($ctx, $x);
 173 }
 174
 175 # /$LISTNAME/$MESSAGE_ID/                   -> HTML content (short quotes)
 176 sub get_mid_html {
 177         my ($ctx) = @_;
 178         my $x = mid2blob($ctx) or return r404($ctx);
 179
 180         require PublicInbox::View;
 181         my $foot = footer($ctx);
 182         require Email::MIME;
 183         my $mime = Email::MIME->new($x);
 184         searcher($ctx);
 185         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 186           [ PublicInbox::View::msg_html($ctx, $mime, 'f/', $foot) ] ];
 187 }
 188
 189 # /$LISTNAME/$MESSAGE_ID/f/                   -> HTML content (fullquotes)
 190 sub get_full_html {
 191         my ($ctx) = @_;
 192         my $x = mid2blob($ctx) or return r404($ctx);
 193
 194         require PublicInbox::View;
 195         my $foot = footer($ctx);
 196         require Email::MIME;
 197         my $mime = Email::MIME->new($x);
 198         searcher($ctx);
 199         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 200           [ PublicInbox::View::msg_html($ctx, $mime, undef, $foot)] ];
 201 }
 202
 203 # /$LISTNAME/$MESSAGE_ID/t/
 204 sub get_thread {
 205         my ($ctx, $flat) = @_;
 206         my $srch = searcher($ctx) or return need_search($ctx);
 207         require PublicInbox::View;
 208         my $foot = footer($ctx);
 209         $ctx->{flat} = $flat;
 210         PublicInbox::View::thread_html($ctx, $foot, $srch);
 211 }
 212
 213 sub self_url {
 214         my ($cgi) = @_;
 215                                                 # Plack::Request
 216         ref($cgi) eq 'CGI' ? $cgi->self_url : $cgi->uri->as_string;
 217 }
 218
 219 sub ctx_get {
 220         my ($ctx, $key) = @_;
 221         my $val = $ctx->{$key};
 222         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable\n";
 223         $val;
 224 }
 225
 226 sub footer {
 227         my ($ctx) = @_;
 228         return '' unless $ctx;
 229         my $git_dir = ctx_get($ctx, 'git_dir');
 230
 231         # favor user-supplied footer
 232         my $footer = try_cat("$git_dir/public-inbox/footer.html");
 233         if (defined $footer) {
 234                 chomp $footer;
 235                 $ctx->{footer} = $footer;
 236                 return $footer;
 237         }
 238
 239         # auto-generate a footer
 240         my $listname = ctx_get($ctx, 'listname');
 241         my $desc = try_cat("$git_dir/description");
 242         $desc = '$GIT_DIR/description missing' unless defined $desc;
 243         chomp $desc;
 244
 245         my $urls = try_cat("$git_dir/cloneurl");
 246         my @urls = split(/\r?\n/, $urls || '');
 247         my $nurls = scalar @urls;
 248         if ($nurls == 0) {
 249                 $urls = '($GIT_DIR/cloneurl missing)';
 250         } elsif ($nurls == 1) {
 251                 $urls = "git URL for <a\nhref=\"" . SSOMA_URL .
 252                         '">ssoma</a>: ' . $urls[0];
 253         } else {
 254                 $urls = "git URLs for <a\nhref=\"" . SSOMA_URL .
 255                         "\">ssoma</a>:\n" . join("\n", map { "\t$_" } @urls);
 256         }
 257
 258         my $addr = $pi_config->get($listname, 'address');
 259         if (ref($addr) eq 'ARRAY') {
 260                 $addr = $addr->[0]; # first address is primary
 261         }
 262
 263         $addr = "<a\nhref=\"mailto:$addr\">$addr</a>";
 264
 265         $ctx->{footer} = join("\n",
 266                 '- ' . $desc,
 267                 "A <a\nhref=\"" . PI_URL .  '">public-inbox</a>, ' .
 268                         'anybody may post in plain-text (not HTML):',
 269                 $addr,
 270                 $urls
 271         );
 272 }
 273
 274 # search support is optional, returns undef if Xapian is not installed
 275 # or not configured for the given GIT_DIR
 276 sub searcher {
 277         my ($ctx) = @_;
 278         eval {
 279                 require PublicInbox::Search;
 280                 $ctx->{srch} = PublicInbox::Search->new($ctx->{git_dir});
 281         };
 282 }
 283
 284 sub need_search {
 285         my ($ctx) = @_;
 286         my $msg = <<EOF;
 287 <html><head><title>Search not available for this
 288 public-inbox</title><body><pre>Search is not available for this public-inbox
 289 <a href="../">Return to index</a></pre></body></html>
 290 EOF
 291         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 292 }
 293
 294 # /$LISTNAME/$MESSAGE_ID/t.mbox           -> thread as mbox
 295 # /$LISTNAME/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 296 # note: I'm not a big fan of other compression formats since they're
 297 # significantly more expensive on CPU than gzip and less-widely available,
 298 # especially on older systems.  Stick to zlib since that's what git uses.
 299 sub get_thread_mbox {
 300         my ($ctx, $sfx) = @_;
 301         my $srch = searcher($ctx) or return need_search($ctx);
 302         require PublicInbox::Mbox;
 303         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 304 }
 305
 306
 307 # /$LISTNAME/$MESSAGE_ID/t.atom           -> thread as Atom feed
 308 sub get_thread_atom {
 309         my ($ctx) = @_;
 310         searcher($ctx) or return need_search($ctx);
 311         $ctx->{self_url} = self_url($ctx->{cgi});
 312         require PublicInbox::Feed;
 313         PublicInbox::Feed::generate_thread_atom($ctx);
 314 }
 315
 316 sub legacy_redirects {
 317         my ($ctx, $path_info) = @_;
 318
 319         # single-message pages
 320         if ($path_info =~ m!$LISTNAME_RE/m/(\S+)/\z!o) {
 321                 r301($ctx, $1, $2);
 322         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)/raw\z!o) {
 323                 r301($ctx, $1, $2, 'raw');
 324
 325         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)/\z!o) {
 326                 r301($ctx, $1, $2, 'f/');
 327
 328         # thread display
 329         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/\z!o) {
 330                 r301($ctx, $1, $2, 't/#u');
 331
 332         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 333                 r301($ctx, $1, $2, "t.mbox$3");
 334
 335         # even older legacy redirects
 336         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
 337                 r301($ctx, $1, $2);
 338
 339         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\.html\z!o) {
 340                 r301($ctx, $1, $2, 't/#u');
 341
 342         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
 343                 r301($ctx, $1, $2, 'f/');
 344
 345         } elsif ($path_info =~ m!$LISTNAME_RE/(?:m|f)/(\S+)\.txt\z!o) {
 346                 r301($ctx, $1, $2, 'raw');
 347
 348         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 349                 r301($ctx, $1, $2, "t$3");
 350
 351         # legacy convenience redirects, order still matters
 352         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\z!o) {
 353                 r301($ctx, $1, $2);
 354         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\z!o) {
 355                 r301($ctx, $1, $2, 't/#u');
 356         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\z!o) {
 357                 r301($ctx, $1, $2, 'f/');
 358
 359         # some Message-IDs have slashes in them and the HTTP server
 360         # may try to be clever and unescape them :<
 361         } elsif ($path_info =~ m!$LISTNAME_RE/(\S+/\S+)/$END_RE\z!o) {
 362                 msg_page($ctx, $1, $2, $3);
 363
 364         # in case people leave off the trailing slash:
 365         } elsif ($path_info =~ m!$LISTNAME_RE/(\S+/\S+)/(f|T|t)\z!o) {
 366                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 367         } else {
 368                 r404();
 369         }
 370 }
 371
 372 sub r301 {
 373         my ($ctx, $listname, $mid, $suffix) = @_;
 374         my $cgi = $ctx->{cgi};
 375         my $url;
 376         my $qs;
 377         if (ref($cgi) eq 'CGI') {
 378                 $url = $cgi->url(-base) . '/';
 379                 $qs = $cgi->query_string;
 380         } else { # Plack::Request
 381                 $url = $cgi->base->as_string;
 382                 $qs = $cgi->env->{QUERY_STRING};
 383         }
 384
 385         $url .= $listname . '/';
 386         $url .= (uri_escape_utf8($mid) . '/') if (defined $mid);
 387         $url .= $suffix if (defined $suffix);
 388         $url .= "?$qs" if $qs ne '';
 389
 390         [ 301,
 391           [ Location => $url, 'Content-Type' => 'text/plain' ],
 392           [ "Redirecting to $url\n" ] ]
 393 }
 394
 395 sub msg_page {
 396         my ($ctx, $list, $mid, $e) = @_;
 397         unless (invalid_list_mid($ctx, $list, $mid)) {
 398                 '' eq $e and return get_mid_html($ctx);
 399                 't/' eq $e and return get_thread($ctx);
 400                 't.atom' eq $e and return get_thread_atom($ctx);
 401                 't.mbox' eq $e and return get_thread_mbox($ctx);
 402                 't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 403                 'T/' eq $e and return get_thread($ctx, 1);
 404                 'raw' eq $e and return get_mid_txt($ctx);
 405                 'f/' eq $e and return get_full_html($ctx);
 406         }
 407         r404($ctx);
 408 }
 409
 410 sub serve_git {
 411         my ($cgi, $git, $path) = @_;
 412         PublicInbox::GitHTTPBackend::serve($cgi, $git, $path);
 413 }
 414
 415 1;