lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Main web interface for mailing list archives
   5 #
   6 # We focus on the lowest common denominators here:
   7 # - targeted at text-only console browsers (w3m, links, etc..)
   8 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   9 #   and diff/syntax-highlighting (optional)
  10 # - No JavaScript, graphics or icons allowed.
  11 # - Must not rely on static content
  12 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  13 package PublicInbox::WWW;
  14 use 5.008;
  15 use strict;
  16 use warnings;
  17 use bytes (); # only for bytes::length
  18 use Plack::Util;
  19 use PublicInbox::Config;
  20 use PublicInbox::Hval;
  21 use URI::Escape qw(uri_unescape);
  22 use PublicInbox::MID qw(mid_escape);
  23 require PublicInbox::Git;
  24 use PublicInbox::GitHTTPBackend;
  25 use PublicInbox::UserContent;
  26
  27 # TODO: consider a routing tree now that we have more endpoints:
  28 our $INBOX_RE = qr!\A/([\w\-][\w\.\-]*)!;
  29 our $MID_RE = qr!([^/]+)!;
  30 our $END_RE = qr!(T/|t/|t\.mbox(?:\.gz)?|t\.atom|raw|)!;
  31 our $ATTACH_RE = qr!(\d[\.\d]*)-([[:alnum:]][\w\.-]+[[:alnum:]])!i;
  32 our $OID_RE = qr![a-f0-9]{7,40}!;
  33
  34 sub new {
  35         my ($class, $pi_config) = @_;
  36         $pi_config ||= PublicInbox::Config->new;
  37         bless { pi_config => $pi_config }, $class;
  38 }
  39
  40 # backwards compatibility, do not use
  41 sub run {
  42         my ($req, $method) = @_;
  43         PublicInbox::WWW->new->call($req->env);
  44 }
  45
  46 my %path_re_cache;
  47
  48 sub path_re ($) {
  49         my $sn = $_[0]->{SCRIPT_NAME};
  50         $path_re_cache{$sn} ||= do {
  51                 $sn = '/'.$sn unless index($sn, '/') == 0;
  52                 $sn =~ s!/\z!!;
  53                 qr!\A(?:https?://[^/]+)?\Q$sn\E(/[^\?\#]+)!;
  54         };
  55 }
  56
  57 sub call {
  58         my ($self, $env) = @_;
  59         my $ctx = { env => $env, www => $self };
  60
  61         # we don't care about multi-value
  62         my %qp = map {
  63                 utf8::decode($_);
  64                 my ($k, $v) = split('=', uri_unescape($_), 2);
  65                 $v = '' unless defined $v;
  66                 $v =~ tr/+/ /;
  67                 ($k, $v)
  68         } split(/[&;]+/, $env->{QUERY_STRING});
  69         $ctx->{qp} = \%qp;
  70
  71         # not using $env->{PATH_INFO} here since that's already decoded
  72         my ($path_info) = ($env->{REQUEST_URI} =~ path_re($env));
  73         my $method = $env->{REQUEST_METHOD};
  74
  75         if ($method eq 'POST') {
  76                 if ($path_info =~ m!$INBOX_RE/(?:(\d+)/)?(git-upload-pack)\z!) {
  77                         my ($part, $path) = ($2, $3);
  78                         return invalid_inbox($ctx, $1) ||
  79                                 serve_git($ctx, $part, $path);
  80                 } elsif ($path_info =~ m!$INBOX_RE/!o) {
  81                         return invalid_inbox($ctx, $1) || mbox_results($ctx);
  82                 }
  83         }
  84         elsif ($method !~ /\AGET|HEAD\z/) {
  85                 return r(405, 'Method Not Allowed');
  86         }
  87
  88         # top-level indices and feeds
  89         if ($path_info eq '/') {
  90                 r404();
  91         } elsif ($path_info =~ m!$INBOX_RE\z!o) {
  92                 invalid_inbox($ctx, $1) || r301($ctx, $1);
  93         } elsif ($path_info =~ m!$INBOX_RE(?:/|/index\.html)?\z!o) {
  94                 invalid_inbox($ctx, $1) || get_index($ctx);
  95         } elsif ($path_info =~ m!$INBOX_RE/(?:atom\.xml|new\.atom)\z!o) {
  96                 invalid_inbox($ctx, $1) || get_atom($ctx);
  97         } elsif ($path_info =~ m!$INBOX_RE/new\.html\z!o) {
  98                 invalid_inbox($ctx, $1) || get_new($ctx);
  99         } elsif ($path_info =~ m!$INBOX_RE/(?:(\d+)/)?
 100                                 ($PublicInbox::GitHTTPBackend::ANY)\z!ox) {
 101                 my ($part, $path) = ($2, $3);
 102                 invalid_inbox($ctx, $1) || serve_git($ctx, $part, $path);
 103         } elsif ($path_info =~ m!$INBOX_RE/([\w-]+).mbox\.gz\z!o) {
 104                 serve_mbox_range($ctx, $1, $2);
 105         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$END_RE\z!o) {
 106                 msg_page($ctx, $1, $2, $3);
 107
 108         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/$ATTACH_RE\z!o) {
 109                 my ($idx, $fn) = ($3, $4);
 110                 invalid_inbox_mid($ctx, $1, $2) || get_attach($ctx, $idx, $fn);
 111         # in case people leave off the trailing slash:
 112         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/(T|t)\z!o) {
 113                 my ($inbox, $mid_ue, $suffix) = ($1, $2, $3);
 114                 $suffix .= $suffix =~ /\A[tT]\z/ ? '/#u' : '/';
 115                 r301($ctx, $inbox, $mid_ue, $suffix);
 116
 117         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/R/?\z!o) {
 118                 my ($inbox, $mid_ue) = ($1, $2);
 119                 r301($ctx, $inbox, $mid_ue, '#R');
 120
 121         } elsif ($path_info =~ m!$INBOX_RE/$MID_RE/f/?\z!o) {
 122                 r301($ctx, $1, $2);
 123         } elsif ($path_info =~ m!$INBOX_RE/_/text(?:/(.*))?\z!o) {
 124                 get_text($ctx, $1, $2);
 125         } elsif ($path_info =~ m!$INBOX_RE/([\w\-\.]+)\.css\z!o) {
 126                 get_css($ctx, $1, $2);
 127         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s/\z!o) {
 128                 get_vcs_object($ctx, $1, $2);
 129         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s/([\w\.\-]+)\z!o) {
 130                 get_vcs_object($ctx, $1, $2, $3);
 131         } elsif ($path_info =~ m!$INBOX_RE/($OID_RE)/s\z!o) {
 132                 r301($ctx, $1, $2, 's/');
 133         # convenience redirects order matters
 134         } elsif ($path_info =~ m!$INBOX_RE/([^/]{2,})\z!o) {
 135                 r301($ctx, $1, $2);
 136
 137         } else {
 138                 legacy_redirects($ctx, $path_info);
 139         }
 140 }
 141
 142 # for CoW-friendliness, MOOOOO!
 143 sub preload {
 144         my ($self) = @_;
 145         require PublicInbox::Feed;
 146         require PublicInbox::View;
 147         require PublicInbox::SearchThread;
 148         require PublicInbox::MIME;
 149         require Digest::SHA;
 150         require POSIX;
 151
 152         foreach (qw(PublicInbox::Search PublicInbox::SearchView
 153                         PublicInbox::Mbox IO::Compress::Gzip
 154                         PublicInbox::NewsWWW)) {
 155                 eval "require $_;";
 156         }
 157         if (ref($self)) {
 158                 $self->cgit;
 159                 $self->stylesheets_prepare($_) for ('', '../', '../../');
 160         }
 161 }
 162
 163 # private functions below
 164
 165 sub r404 {
 166         my ($ctx) = @_;
 167         if ($ctx && $ctx->{mid}) {
 168                 require PublicInbox::ExtMsg;
 169                 searcher($ctx);
 170                 return PublicInbox::ExtMsg::ext_msg($ctx);
 171         }
 172         r(404, 'Not Found');
 173 }
 174
 175 # simple response for errors
 176 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
 177
 178 sub news_cgit_fallback ($) {
 179         my ($ctx) = @_;
 180         my $www = $ctx->{www};
 181         my $env = $ctx->{env};
 182         my $res = $www->news_www->call($env);
 183         $res->[0] == 404 ? $www->cgit->call($env) : $res;
 184 }
 185
 186 # returns undef if valid, array ref response if invalid
 187 sub invalid_inbox ($$) {
 188         my ($ctx, $inbox) = @_;
 189         my $obj = $ctx->{www}->{pi_config}->lookup_name($inbox);
 190         if (defined $obj) {
 191                 $ctx->{git} = $obj->git;
 192                 $ctx->{-inbox} = $obj;
 193                 return;
 194         }
 195
 196         # sometimes linkifiers (not ours!) screw up automatic link
 197         # generation and link things intended for nntp:// to https?://,
 198         # so try to infer links and redirect them to the appropriate
 199         # list URL.
 200         news_cgit_fallback($ctx);
 201 }
 202
 203 # returns undef if valid, array ref response if invalid
 204 sub invalid_inbox_mid {
 205         my ($ctx, $inbox, $mid_ue) = @_;
 206         my $ret = invalid_inbox($ctx, $inbox);
 207         return $ret if $ret;
 208
 209         my $mid = $ctx->{mid} = uri_unescape($mid_ue);
 210         my $ibx = $ctx->{-inbox};
 211         if ($mid =~ m!\A([a-f0-9]{2})([a-f0-9]{38})\z!) {
 212                 my ($x2, $x38) = ($1, $2);
 213                 # this is horrifically wasteful for legacy URLs:
 214                 my $str = $ctx->{-inbox}->msg_by_path("$x2/$x38") or return;
 215                 require Email::Simple;
 216                 my $s = Email::Simple->new($str);
 217                 $mid = PublicInbox::MID::mid_clean($s->header('Message-ID'));
 218                 return r301($ctx, $inbox, mid_escape($mid));
 219         }
 220         undef;
 221 }
 222
 223 # /$INBOX/new.atom                     -> Atom feed, includes replies
 224 sub get_atom {
 225         my ($ctx) = @_;
 226         require PublicInbox::Feed;
 227         PublicInbox::Feed::generate($ctx);
 228 }
 229
 230 # /$INBOX/new.html                      -> HTML only
 231 sub get_new {
 232         my ($ctx) = @_;
 233         require PublicInbox::Feed;
 234         PublicInbox::Feed::new_html($ctx);
 235 }
 236
 237 # /$INBOX/?r=$GIT_COMMIT                 -> HTML only
 238 sub get_index {
 239         my ($ctx) = @_;
 240         require PublicInbox::Feed;
 241         searcher($ctx);
 242         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 243                 require PublicInbox::SearchView;
 244                 PublicInbox::SearchView::sres_top_html($ctx);
 245         } else {
 246                 PublicInbox::Feed::generate_html_index($ctx);
 247         }
 248 }
 249
 250 # /$INBOX/$MESSAGE_ID/raw                    -> raw mbox
 251 sub get_mid_txt {
 252         my ($ctx) = @_;
 253         require PublicInbox::Mbox;
 254         PublicInbox::Mbox::emit_raw($ctx) || r404($ctx);
 255 }
 256
 257 # /$INBOX/$MESSAGE_ID/                   -> HTML content (short quotes)
 258 sub get_mid_html {
 259         my ($ctx) = @_;
 260         require PublicInbox::View;
 261         searcher($ctx);
 262         PublicInbox::View::msg_page($ctx) || r404($ctx);
 263 }
 264
 265 # /$INBOX/$MESSAGE_ID/t/
 266 sub get_thread {
 267         my ($ctx, $flat) = @_;
 268         searcher($ctx) or return need_search($ctx);
 269         $ctx->{flat} = $flat;
 270         require PublicInbox::View;
 271         PublicInbox::View::thread_html($ctx);
 272 }
 273
 274 # /$INBOX/_/text/$KEY/
 275 # /$INBOX/_/text/$KEY/raw
 276 # KEY may contain slashes
 277 sub get_text {
 278         my ($ctx, $inbox, $key) = @_;
 279         my $r404 = invalid_inbox($ctx, $inbox);
 280         return $r404 if $r404;
 281
 282         require PublicInbox::WwwText;
 283         PublicInbox::WwwText::get_text($ctx, $key);
 284 }
 285
 286 # show git objects (blobs and commits)
 287 # /$INBOX/_/$OBJECT_ID/show
 288 # /$INBOX/_/${OBJECT_ID}_${FILENAME}
 289 # KEY may contain slashes
 290 sub get_vcs_object ($$$;$) {
 291         my ($ctx, $inbox, $oid, $filename) = @_;
 292         my $r404 = invalid_inbox($ctx, $inbox);
 293         return $r404 if $r404;
 294         require PublicInbox::ViewVCS;
 295         PublicInbox::ViewVCS::show($ctx, $oid, $filename);
 296 }
 297
 298 sub ctx_get {
 299         my ($ctx, $key) = @_;
 300         my $val = $ctx->{$key};
 301         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable";
 302         $val;
 303 }
 304
 305 # search support is optional, returns undef if Xapian is not installed
 306 # or not configured for the given GIT_DIR
 307 sub searcher {
 308         my ($ctx) = @_;
 309         eval {
 310                 require PublicInbox::Search;
 311                 $ctx->{srch} = $ctx->{-inbox}->search;
 312         };
 313 }
 314
 315 sub need_search {
 316         my ($ctx) = @_;
 317         my $msg = <<EOF;
 318 <html><head><title>Search not available for this
 319 public-inbox</title><body><pre>Search is not available for this public-inbox
 320 <a href="../">Return to index</a></pre></body></html>
 321 EOF
 322         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 323 }
 324
 325 # /$INBOX/$MESSAGE_ID/t.mbox           -> thread as mbox
 326 # /$INBOX/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 327 # note: I'm not a big fan of other compression formats since they're
 328 # significantly more expensive on CPU than gzip and less-widely available,
 329 # especially on older systems.  Stick to zlib since that's what git uses.
 330 sub get_thread_mbox {
 331         my ($ctx, $sfx) = @_;
 332         my $srch = searcher($ctx) or return need_search($ctx);
 333         require PublicInbox::Mbox;
 334         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 335 }
 336
 337
 338 # /$INBOX/$MESSAGE_ID/t.atom              -> thread as Atom feed
 339 sub get_thread_atom {
 340         my ($ctx) = @_;
 341         searcher($ctx) or return need_search($ctx);
 342         require PublicInbox::Feed;
 343         PublicInbox::Feed::generate_thread_atom($ctx);
 344 }
 345
 346 sub legacy_redirects {
 347         my ($ctx, $path_info) = @_;
 348
 349         # single-message pages
 350         if ($path_info =~ m!$INBOX_RE/m/(\S+)/\z!o) {
 351                 r301($ctx, $1, $2);
 352         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)/raw\z!o) {
 353                 r301($ctx, $1, $2, 'raw');
 354
 355         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)/\z!o) {
 356                 r301($ctx, $1, $2);
 357
 358         # thread display
 359         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/\z!o) {
 360                 r301($ctx, $1, $2, 't/#u');
 361
 362         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 363                 r301($ctx, $1, $2, "t.mbox$3");
 364
 365         # even older legacy redirects
 366         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\.html\z!o) {
 367                 r301($ctx, $1, $2);
 368
 369         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\.html\z!o) {
 370                 r301($ctx, $1, $2, 't/#u');
 371
 372         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\.html\z!o) {
 373                 r301($ctx, $1, $2);
 374
 375         } elsif ($path_info =~ m!$INBOX_RE/(?:m|f)/(\S+)\.txt\z!o) {
 376                 r301($ctx, $1, $2, 'raw');
 377
 378         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 379                 r301($ctx, $1, $2, "t$3");
 380
 381         # legacy convenience redirects, order still matters
 382         } elsif ($path_info =~ m!$INBOX_RE/m/(\S+)\z!o) {
 383                 r301($ctx, $1, $2);
 384         } elsif ($path_info =~ m!$INBOX_RE/t/(\S+)\z!o) {
 385                 r301($ctx, $1, $2, 't/#u');
 386         } elsif ($path_info =~ m!$INBOX_RE/f/(\S+)\z!o) {
 387                 r301($ctx, $1, $2);
 388
 389         # some Message-IDs have slashes in them and the HTTP server
 390         # may try to be clever and unescape them :<
 391         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/$END_RE\z!o) {
 392                 msg_page($ctx, $1, $2, $3);
 393
 394         # in case people leave off the trailing slash:
 395         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/(T|t)\z!o) {
 396                 r301($ctx, $1, $2, $3 eq 't' ? 't/#u' : $3);
 397         } elsif ($path_info =~ m!$INBOX_RE/(\S+/\S+)/f\z!o) {
 398                 r301($ctx, $1, $2);
 399         } else {
 400                 news_cgit_fallback($ctx);
 401         }
 402 }
 403
 404 sub r301 {
 405         my ($ctx, $inbox, $mid_ue, $suffix) = @_;
 406         my $obj = $ctx->{-inbox};
 407         unless ($obj) {
 408                 my $r404 = invalid_inbox($ctx, $inbox);
 409                 return $r404 if $r404;
 410                 $obj = $ctx->{-inbox};
 411         }
 412         my $url = $obj->base_url($ctx->{env});
 413         my $qs = $ctx->{env}->{QUERY_STRING};
 414         if (defined $mid_ue) {
 415                 # common, and much nicer as '@' than '%40':
 416                 $mid_ue =~ s/%40/@/g;
 417                 $url .= $mid_ue . '/';
 418         }
 419         $url .= $suffix if (defined $suffix);
 420         $url .= "?$qs" if $qs ne '';
 421
 422         [ 301,
 423           [ Location => $url, 'Content-Type' => 'text/plain' ],
 424           [ "Redirecting to $url\n" ] ]
 425 }
 426
 427 sub msg_page {
 428         my ($ctx, $inbox, $mid_ue, $e) = @_;
 429         my $ret;
 430         $ret = invalid_inbox_mid($ctx, $inbox, $mid_ue) and return $ret;
 431         '' eq $e and return get_mid_html($ctx);
 432         'T/' eq $e and return get_thread($ctx, 1);
 433         't/' eq $e and return get_thread($ctx);
 434         't.atom' eq $e and return get_thread_atom($ctx);
 435         't.mbox' eq $e and return get_thread_mbox($ctx);
 436         't.mbox.gz' eq $e and return get_thread_mbox($ctx, '.gz');
 437         'raw' eq $e and return get_mid_txt($ctx);
 438
 439         # legacy, but no redirect for compatibility:
 440         'f/' eq $e and return get_mid_html($ctx);
 441         r404($ctx);
 442 }
 443
 444 sub serve_git {
 445         my ($ctx, $part, $path) = @_;
 446         my $env = $ctx->{env};
 447         my $ibx = $ctx->{-inbox};
 448         my $git = defined $part ? $ibx->git_part($part) : $ibx->git;
 449         $git ? PublicInbox::GitHTTPBackend::serve($env, $git, $path) : r404();
 450 }
 451
 452 sub mbox_results {
 453         my ($ctx) = @_;
 454         if ($ctx->{env}->{QUERY_STRING} =~ /(?:\A|[&;])q=/) {
 455                 searcher($ctx) or return need_search($ctx);
 456                 require PublicInbox::SearchView;
 457                 return PublicInbox::SearchView::mbox_results($ctx);
 458         }
 459         r404();
 460 }
 461
 462 sub serve_mbox_range {
 463         my ($ctx, $inbox, $range) = @_;
 464         invalid_inbox($ctx, $inbox) || eval {
 465                 require PublicInbox::Mbox;
 466                 searcher($ctx);
 467                 PublicInbox::Mbox::emit_range($ctx, $range);
 468         }
 469 }
 470
 471 sub news_www {
 472         my ($self) = @_;
 473         $self->{news_www} ||= do {
 474                 require PublicInbox::NewsWWW;
 475                 PublicInbox::NewsWWW->new($self->{pi_config});
 476         }
 477 }
 478
 479 sub cgit {
 480         my ($self) = @_;
 481         $self->{cgit} ||= do {
 482                 my $pi_config = $self->{pi_config};
 483
 484                 if (defined($pi_config->{'publicinbox.cgitrc'})) {
 485                         require PublicInbox::Cgit;
 486                         PublicInbox::Cgit->new($pi_config);
 487                 } else {
 488                         Plack::Util::inline_object(call => sub { r404() });
 489                 }
 490         }
 491 }
 492
 493 sub get_attach {
 494         my ($ctx, $idx, $fn) = @_;
 495         require PublicInbox::WwwAttach;
 496         PublicInbox::WwwAttach::get_attach($ctx, $idx, $fn);
 497 }
 498
 499 # User-generated content (UGC) may have excessively long lines
 500 # and screw up rendering on some browsers, so we use pre-wrap.
 501 #
 502 # We also force everything to the same scaled font-size because GUI
 503 # browsers (tested both Firefox and surf (webkit)) uses a larger font
 504 # for the Search <form> element than the rest of the page.  Font size
 505 # uniformity is important to people who rely on gigantic fonts.
 506 # Finally, we use monospace to ensure the Search field and button
 507 # has the same size and spacing as everything else which is
 508 # <pre>-formatted anyways.
 509 our $STYLE = 'pre{white-space:pre-wrap}*{font-size:100%;font-family:monospace}';
 510
 511 sub stylesheets_prepare ($$) {
 512         my ($self, $upfx) = @_;
 513         my $mini = eval {
 514                 require CSS::Minifier;
 515                 sub { CSS::Minifier::minify(input => $_[0]) };
 516         } || eval {
 517                 require CSS::Minifier::XS;
 518                 sub { CSS::Minifier::XS::minify($_[0]) };
 519         } || sub { $_[0] };
 520
 521         my $css_map = {};
 522         my $stylesheets = $self->{pi_config}->{css} || [];
 523         my $links = [];
 524         my $inline_ok = 1;
 525
 526         foreach my $s (@$stylesheets) {
 527                 my $attr = {};
 528                 local $_ = $s;
 529                 foreach my $k (qw(media title href)) {
 530                         if (s/\s*$k='([^']+)'// || s/\s*$k=(\S+)//) {
 531                                 $attr->{$k} = $1;
 532                         }
 533                 }
 534
 535                 if (defined $attr->{href}) {
 536                         $inline_ok = 0;
 537                 } else {
 538                         my $fn = $_;
 539                         open(my $fh, '<', $fn) or do {
 540                                 warn "failed to open $fn: $!\n";
 541                                 next;
 542                         };
 543                         my ($key) = (m!([^/]+?)(?:\.css)?\z!i);
 544                         my $ctime = 0;
 545                         my $local = do { local $/; <$fh> };
 546                         if ($local =~ /\S/) {
 547                                 $ctime = sprintf('%x',(stat($fh))[10]);
 548                                 $local = $mini->($local);
 549                         }
 550
 551                         # do not let BOFHs override userContent.css:
 552                         if ($local =~ /!\s*important\b/i) {
 553                                 warn "ignoring $fn since it uses `!important'\n";
 554                                 next;
 555                         }
 556
 557                         $css_map->{$key} = $local;
 558                         $attr->{href} = "$upfx$key.css?$ctime";
 559                         if (defined($attr->{title})) {
 560                                 $inline_ok = 0;
 561                         } elsif (($attr->{media}||'screen') eq 'screen') {
 562                                 $attr->{-inline} = $local;
 563                         }
 564                 }
 565                 push @$links, $attr;
 566         }
 567
 568         my $buf = "<style>$STYLE";
 569         if ($inline_ok) {
 570                 my @ext; # for media=print and whatnot
 571                 foreach my $attr (@$links) {
 572                         if (defined(my $str = delete $attr->{-inline})) {
 573                                 $buf .= $str;
 574                         } else {
 575                                 push @ext, $attr;
 576                         }
 577                 }
 578                 $links = \@ext;
 579         }
 580         $buf .= '</style>';
 581
 582         if (@$links) {
 583                 foreach my $attr (@$links) {
 584                         delete $attr->{-inline};
 585                         $buf .= "<link\ntype=text/css\nrel=stylesheet";
 586                         while (my ($k, $v) = each %$attr) {
 587                                 $v = qq{"$v"} if $v =~ /[\s=]/;
 588                                 $buf .= qq{\n$k=$v};
 589                         }
 590                         $buf .= ' />';
 591                 }
 592                 $self->{"-style-$upfx"} = $buf;
 593         } else {
 594                 $self->{-style_inline} = $buf;
 595         }
 596         $self->{-css_map} = $css_map;
 597 }
 598
 599 # returns an HTML fragment with <style> or <link> tags in them
 600 # Called by WwwStream by nearly every HTML page
 601 sub style {
 602         my ($self, $upfx) = @_;
 603         $self->{-style_inline} || $self->{"-style-$upfx"} || do {
 604                 stylesheets_prepare($self, $upfx);
 605                 $self->{-style_inline} || $self->{"-style-$upfx"}
 606         };
 607 }
 608
 609 # /$INBOX/$KEY.css endpoint
 610 # CSS is configured globally for all inboxes, but we access them on
 611 # a per-inbox basis.  This allows administrators to setup per-inbox
 612 # static routes to intercept the request before it hits PSGI
 613 sub get_css ($$$) {
 614         my ($ctx, $inbox, $key) = @_;
 615         my $r404 = invalid_inbox($ctx, $inbox);
 616         return $r404 if $r404;
 617         my $self = $ctx->{www};
 618         my $css_map = $self->{-css_map} || stylesheets_prepare($self, '');
 619         my $css = $css_map->{$key};
 620         if (!defined($css) && $key eq 'userContent') {
 621                 my $env = $ctx->{env};
 622                 $css = PublicInbox::UserContent::sample($ctx->{-inbox}, $env);
 623         }
 624         defined $css or return r404();
 625         my $h = [ 'Content-Length', bytes::length($css),
 626                 'Content-Type', 'text/css' ];
 627         PublicInbox::GitHTTPBackend::cache_one_year($h);
 628         [ 200, $h, [ $css ] ];
 629 }
 630
 631 1;