lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # We focus on the lowest common denominators here:
   5 # - targeted at text-only console browsers (lynx, w3m, etc..)
   6 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   7 # - No JavaScript, graphics or icons allowed.
   8 # - Must not rely on static content
   9 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  10 package PublicInbox::WWW;
  11 use 5.008;
  12 use strict;
  13 use warnings;
  14 use PublicInbox::Config;
  15 use URI::Escape qw(uri_escape_utf8 uri_unescape);
  16 use constant SSOMA_URL => 'http://ssoma.public-inbox.org/';
  17 use constant PI_URL => 'http://public-inbox.org/';
  18 our $LISTNAME_RE = qr!\A/([\w\.\-]+)!;
  19 our $pi_config;
  20 BEGIN {
  21         $pi_config = PublicInbox::Config->new;
  22 }
  23
  24 sub run {
  25         my ($cgi, $method) = @_;
  26         my %ctx;
  27         if ($method !~ /\AGET|HEAD\z/) {
  28                 return r(405, 'Method Not Allowed');
  29         }
  30         my $path_info = $cgi->path_info;
  31
  32         # top-level indices and feeds
  33         if ($path_info eq '/') {
  34                 r404();
  35         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  36                 invalid_list(\%ctx, $1) || redirect_list_index(\%ctx, $cgi);
  37         } elsif ($path_info =~ m!$LISTNAME_RE(?:/|/index\.html)?\z!o) {
  38                 invalid_list(\%ctx, $1) || get_index(\%ctx, $cgi);
  39         } elsif ($path_info =~ m!$LISTNAME_RE/atom\.xml\z!o) {
  40                 invalid_list(\%ctx, $1) || get_atom(\%ctx, $cgi);
  41
  42         # single-message pages
  43         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.txt\z!o) {
  44                 invalid_list_mid(\%ctx, $1, $2) || get_mid_txt(\%ctx, $cgi);
  45         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
  46                 invalid_list_mid(\%ctx, $1, $2) || get_mid_html(\%ctx, $cgi);
  47
  48         # full-message page
  49         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
  50                 invalid_list_mid(\%ctx, $1, $2) || get_full_html(\%ctx, $cgi);
  51
  52         # thread display
  53         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\.html\z!o) {
  54                 invalid_list_mid(\%ctx, $1, $2) || get_thread(\%ctx, $cgi);
  55
  56         # subject_path display
  57         } elsif ($path_info =~ m!$LISTNAME_RE/s/(\S+)\.html\z!o) {
  58                 my $sp = $2;
  59                 invalid_list(\%ctx, $1) || get_subject_path(\%ctx, $cgi, $sp);
  60
  61         # convenience redirects, order matters
  62         } elsif ($path_info =~ m!$LISTNAME_RE/(m|f|t|s)/(\S+)\z!o) {
  63                 my $pfx = $2;
  64                 invalid_list_mid(\%ctx, $1, $3) ||
  65                         redirect_mid(\%ctx, $cgi, $2);
  66
  67         } else {
  68                 r404();
  69         }
  70 }
  71
  72 # for CoW-friendliness, MOOOOO!
  73 sub preload {
  74         require PublicInbox::Feed;
  75         require PublicInbox::View;
  76         require PublicInbox::Thread;
  77         require Email::MIME;
  78         require Digest::SHA;
  79         require POSIX;
  80         require XML::Atom::SimpleFeed;
  81 }
  82
  83 # private functions below
  84
  85 sub r404 { r(404, 'Not Found') }
  86
  87 # simple response for errors
  88 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
  89
  90 # returns undef if valid, array ref response if invalid
  91 sub invalid_list {
  92         my ($ctx, $listname) = @_;
  93         my $git_dir = $pi_config->get($listname, "mainrepo");
  94         if (defined $git_dir) {
  95                 $ctx->{git_dir} = $git_dir;
  96                 $ctx->{listname} = $listname;
  97                 return;
  98         }
  99         r404();
 100 }
 101
 102 # returns undef if valid, array ref response if invalid
 103 sub invalid_list_mid {
 104         my ($ctx, $listname, $mid) = @_;
 105         my $ret = invalid_list($ctx, $listname, $mid);
 106         $ctx->{mid} = uri_unescape($mid) unless $ret;
 107         $ret;
 108 }
 109
 110 # /$LISTNAME/atom.xml                       -> Atom feed, includes replies
 111 sub get_atom {
 112         my ($ctx, $cgi) = @_;
 113         require PublicInbox::Feed;
 114         $ctx->{pi_config} = $pi_config;
 115         $ctx->{cgi} = $cgi;
 116         [ 200, [ 'Content-Type' => 'application/xml' ],
 117           [ PublicInbox::Feed->generate($ctx) ] ]
 118 }
 119
 120 # /$LISTNAME/?r=$GIT_COMMIT                 -> HTML only
 121 sub get_index {
 122         my ($ctx, $cgi) = @_;
 123         require PublicInbox::Feed;
 124         my $srch = searcher($ctx);
 125         $ctx->{pi_config} = $pi_config;
 126         $ctx->{cgi} = $cgi;
 127         footer($ctx);
 128         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 129           [ PublicInbox::Feed->generate_html_index($ctx) ] ]
 130 }
 131
 132 # just returns a string ref for the blob in the current ctx
 133 sub mid2blob {
 134         my ($ctx) = @_;
 135         require PublicInbox::MID;
 136         my $path = PublicInbox::MID::mid2path($ctx->{mid});
 137         my @cmd = ('git', "--git-dir=$ctx->{git_dir}",
 138                         qw(cat-file blob), "HEAD:$path");
 139         my $cmd = join(' ', @cmd);
 140         my $pid = open my $fh, '-|';
 141         defined $pid or die "fork failed: $!\n";
 142         if ($pid == 0) {
 143                 open STDERR, '>', '/dev/null'; # ignore errors
 144                 exec @cmd or die "exec failed: $!\n";
 145         } else {
 146                 my $blob = eval { local $/; <$fh> };
 147                 close $fh;
 148                 $? == 0 ? \$blob : undef;
 149         }
 150 }
 151
 152 # /$LISTNAME/m/$MESSAGE_ID.txt                    -> raw original
 153 sub get_mid_txt {
 154         my ($ctx, $cgi) = @_;
 155         my $x = mid2blob($ctx);
 156         $x ? [ 200, [ 'Content-Type' => 'text/plain' ], [ $$x ] ] : r404();
 157 }
 158
 159 # /$LISTNAME/m/$MESSAGE_ID.html                   -> HTML content (short quotes)
 160 sub get_mid_html {
 161         my ($ctx, $cgi) = @_;
 162         my $x = mid2blob($ctx);
 163         return r404() unless $x;
 164
 165         require PublicInbox::View;
 166         my $pfx = msg_pfx($ctx);
 167         my $foot = footer($ctx);
 168         require Email::MIME;
 169         my $mime = Email::MIME->new($x);
 170         my $srch = searcher($ctx);
 171         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 172           [ PublicInbox::View->msg_html($mime, $pfx, $foot, $srch) ] ];
 173 }
 174
 175 # /$LISTNAME/f/$MESSAGE_ID.html                   -> HTML content (fullquotes)
 176 sub get_full_html {
 177         my ($ctx, $cgi) = @_;
 178         my $x = mid2blob($ctx);
 179         return r404() unless $x;
 180         require PublicInbox::View;
 181         my $foot = footer($ctx);
 182         require Email::MIME;
 183         my $mime = Email::MIME->new($x);
 184         my $srch = searcher($ctx);
 185         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 186           [ PublicInbox::View->msg_html($mime, undef, $foot, $srch)] ];
 187 }
 188
 189 # /$LISTNAME/t/$MESSAGE_ID.html
 190 sub get_thread {
 191         my ($ctx, $cgi) = @_;
 192         my $srch = searcher($ctx) or return need_search($ctx);
 193         require PublicInbox::View;
 194         my $foot = footer($ctx);
 195         my $body = PublicInbox::View->thread_html($ctx, $foot, $srch) or
 196                 return r404();
 197         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 198           [ $body ] ];
 199 }
 200
 201 # /$LISTNAME/s/$SUBJECT_PATH.html
 202 sub get_subject_path {
 203         my ($ctx, $cgi, $sp) = @_;
 204         $ctx->{subject_path} = $sp;
 205         my $srch = searcher($ctx) or return need_search($ctx);
 206         require PublicInbox::View;
 207         my $foot = footer($ctx);
 208         my $body = PublicInbox::View->subject_path_html($ctx, $foot, $srch) or
 209                 return r404();
 210         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 211           [ $body ] ];
 212 }
 213
 214 sub self_url {
 215         my ($cgi) = @_;
 216         ref($cgi) eq 'CGI' ? $cgi->self_url : $cgi->uri->as_string;
 217 }
 218
 219 sub redirect_list_index {
 220         my ($ctx, $cgi) = @_;
 221         do_redirect(self_url($cgi) . "/");
 222 }
 223
 224 sub redirect_mid {
 225         my ($ctx, $cgi, $pfx) = @_;
 226         my $url = self_url($cgi);
 227         my $anchor = '';
 228         if (lc($pfx) eq 't') {
 229                 $anchor = '#u'; # <u id='#u'> is used to highlight in View.pm
 230         }
 231         do_redirect($url . ".html$anchor");
 232 }
 233
 234 sub do_redirect {
 235         my ($url) = @_;
 236         [ 301,
 237           [ Location => $url, 'Content-Type' => 'text/plain' ],
 238           [ "Redirecting to $url\n" ]
 239         ]
 240 }
 241
 242 sub ctx_get {
 243         my ($ctx, $key) = @_;
 244         my $val = $ctx->{$key};
 245         (defined $val && length $val) or die "BUG: bad ctx, $key unusable\n";
 246         $val;
 247 }
 248
 249 sub try_cat {
 250         my ($path) = @_;
 251         my $rv;
 252         if (open(my $fh, '<', $path)) {
 253                 local $/;
 254                 $rv = <$fh>;
 255                 close $fh;
 256         }
 257         $rv;
 258 }
 259
 260 sub footer {
 261         my ($ctx) = @_;
 262         return '' unless $ctx;
 263         my $git_dir = ctx_get($ctx, 'git_dir');
 264
 265         # favor user-supplied footer
 266         my $footer = try_cat("$git_dir/public-inbox/footer.html");
 267         if (defined $footer) {
 268                 chomp $footer;
 269                 $ctx->{footer} = $footer;
 270                 return $footer;
 271         }
 272
 273         # auto-generate a footer
 274         my $listname = ctx_get($ctx, 'listname');
 275         my $desc = try_cat("$git_dir/description");
 276         $desc = '$GIT_DIR/description missing' unless defined $desc;
 277         chomp $desc;
 278
 279         my $urls = try_cat("$git_dir/cloneurl");
 280         my @urls = split(/\r?\n/, $urls || '');
 281         my $nurls = scalar @urls;
 282         if ($nurls == 0) {
 283                 $urls = '($GIT_DIR/cloneurl missing)';
 284         } elsif ($nurls == 1) {
 285                 $urls = "git URL for <a\nhref=\"" . SSOMA_URL .
 286                         '">ssoma</a>: ' . $urls[0];
 287         } else {
 288                 $urls = "git URLs for <a\nhref=\"" . SSOMA_URL .
 289                         "\">ssoma</a>:\n" . join("\n", map { "\t$_" } @urls);
 290         }
 291
 292         my $addr = $pi_config->get($listname, 'address');
 293         if (ref($addr) eq 'ARRAY') {
 294                 $addr = $addr->[0]; # first address is primary
 295         }
 296
 297         $addr = "<a\nhref=\"mailto:$addr\">$addr</a>";
 298         $desc =  $desc;
 299
 300         $ctx->{footer} = join("\n",
 301                 '- ' . $desc,
 302                 "A <a\nhref=\"" . PI_URL .  '">public-inbox</a>, ' .
 303                         'anybody may post in plain-text (not HTML):',
 304                 $addr,
 305                 $urls
 306         );
 307 }
 308
 309 # search support is optional, returns undef if Xapian is not installed
 310 # or not configured for the given GIT_DIR
 311 sub searcher {
 312         my ($ctx) = @_;
 313         eval {
 314                 require PublicInbox::Search;
 315                 $ctx->{srch} = PublicInbox::Search->new($ctx->{git_dir});
 316         };
 317 }
 318
 319 sub need_search {
 320         my ($ctx) = @_;
 321         my $msg = <<EOF;
 322 <html><head><title>Search not available for this
 323 public-inbox</title><body><pre>Search is not available for this public-inbox
 324 <a href="../">Return to index</a></pre></body></html>
 325 EOF
 326         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 327 }
 328
 329 sub msg_pfx {
 330         my ($ctx) = @_;
 331         my $href = PublicInbox::Hval::ascii_html(uri_escape_utf8($ctx->{mid}));
 332         "../f/$href.html";
 333 }
 334
 335 1;