lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # We focus on the lowest common denominators here:
   5 # - targeted at text-only console browsers (w3m, links, etc..)
   6 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   7 # - No JavaScript, graphics or icons allowed.
   8 # - Must not rely on static content
   9 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  10 package PublicInbox::WWW;
  11 use 5.008;
  12 use strict;
  13 use warnings;
  14 use PublicInbox::Config;
  15 use URI::Escape qw(uri_escape_utf8 uri_unescape);
  16 use constant SSOMA_URL => 'http://ssoma.public-inbox.org/';
  17 use constant PI_URL => 'http://public-inbox.org/';
  18 our $LISTNAME_RE = qr!\A/([\w\.\-]+)!;
  19 our $MID_RE = qr!([^/]+)!;
  20 our $pi_config;
  21
  22 sub run {
  23         my ($cgi, $method) = @_;
  24         $pi_config ||= PublicInbox::Config->new;
  25         my %ctx = (cgi => $cgi, pi_config => $pi_config);
  26         if ($method !~ /\AGET|HEAD\z/) {
  27                 return r(405, 'Method Not Allowed');
  28         }
  29         my $path_info = $cgi->path_info;
  30
  31         # top-level indices and feeds
  32         if ($path_info eq '/') {
  33                 r404();
  34         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  35                 invalid_list(\%ctx, $1) || r301(\%ctx, $1);
  36         } elsif ($path_info =~ m!$LISTNAME_RE(?:/|/index\.html)?\z!o) {
  37                 invalid_list(\%ctx, $1) || get_index(\%ctx);
  38         } elsif ($path_info =~ m!$LISTNAME_RE/(?:atom\.xml|new\.atom)\z!o) {
  39                 invalid_list(\%ctx, $1) || get_atom(\%ctx);
  40
  41         # thread display
  42         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/t/\z!o) {
  43                 invalid_list_mid(\%ctx, $1, $2) || get_thread(\%ctx);
  44         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/t\.mbox(\.gz)?\z!o) {
  45                 my $sfx = $3;
  46                 invalid_list_mid(\%ctx, $1, $2) || get_thread_mbox(\%ctx, $sfx);
  47         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/t\.atom\z!o) {
  48                 invalid_list_mid(\%ctx, $1, $2) || get_thread_atom(\%ctx);
  49         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/T/\z!o) {
  50                 $ctx{flat} = 1;
  51                 invalid_list_mid(\%ctx, $1, $2) || get_thread(\%ctx);
  52
  53         # single-message pages
  54         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/\z!o) {
  55                 invalid_list_mid(\%ctx, $1, $2) || get_mid_html(\%ctx);
  56         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/raw\z!o) {
  57                 invalid_list_mid(\%ctx, $1, $2) || get_mid_txt(\%ctx);
  58
  59         # full-message page
  60         } elsif ($path_info =~ m!$LISTNAME_RE/$MID_RE/f/\z!o) {
  61                 invalid_list_mid(\%ctx, $1, $2) || get_full_html(\%ctx);
  62
  63         # convenience redirects order matters
  64         } elsif ($path_info =~ m!$LISTNAME_RE/([^/]{2,})\z!o) {
  65                 r301(\%ctx, $1, $2);
  66
  67         } else {
  68                 legacy_redirects(\%ctx, $path_info);
  69         }
  70 }
  71
  72 # for CoW-friendliness, MOOOOO!
  73 sub preload {
  74         require PublicInbox::Feed;
  75         require PublicInbox::View;
  76         require PublicInbox::Thread;
  77         require PublicInbox::GitCatFile;
  78         require Email::MIME;
  79         require Digest::SHA;
  80         require POSIX;
  81
  82         eval {
  83                 require PublicInbox::Search;
  84                 require PublicInbox::Mbox;
  85                 require IO::Compress::Gzip;
  86         };
  87 }
  88
  89 # private functions below
  90
  91 sub r404 { r(404, 'Not Found') }
  92
  93 # simple response for errors
  94 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
  95
  96 # returns undef if valid, array ref response if invalid
  97 sub invalid_list {
  98         my ($ctx, $listname) = @_;
  99         my $git_dir = $pi_config->get($listname, "mainrepo");
 100         if (defined $git_dir) {
 101                 $ctx->{git_dir} = $git_dir;
 102                 $ctx->{listname} = $listname;
 103                 return;
 104         }
 105         r404();
 106 }
 107
 108 # returns undef if valid, array ref response if invalid
 109 sub invalid_list_mid {
 110         my ($ctx, $listname, $mid) = @_;
 111         my $ret = invalid_list($ctx, $listname, $mid);
 112         $ctx->{mid} = uri_unescape($mid) unless $ret;
 113         $ret;
 114 }
 115
 116 # /$LISTNAME/new.atom                     -> Atom feed, includes replies
 117 sub get_atom {
 118         my ($ctx) = @_;
 119         require PublicInbox::Feed;
 120         PublicInbox::Feed::generate($ctx);
 121 }
 122
 123 # /$LISTNAME/?r=$GIT_COMMIT                 -> HTML only
 124 sub get_index {
 125         my ($ctx) = @_;
 126         require PublicInbox::Feed;
 127         my $srch = searcher($ctx);
 128         footer($ctx);
 129         PublicInbox::Feed::generate_html_index($ctx);
 130 }
 131
 132 # just returns a string ref for the blob in the current ctx
 133 sub mid2blob {
 134         my ($ctx) = @_;
 135         require PublicInbox::MID;
 136         my $path = PublicInbox::MID::mid2path($ctx->{mid});
 137         my @cmd = ('git', "--git-dir=$ctx->{git_dir}",
 138                         qw(cat-file blob), "HEAD:$path");
 139         my $pid = open my $fh, '-|';
 140         defined $pid or die "fork failed: $!\n";
 141         if ($pid == 0) {
 142                 open STDERR, '>', '/dev/null'; # ignore errors
 143                 exec @cmd or die "exec failed: $!\n";
 144         } else {
 145                 my $blob = eval { local $/; <$fh> };
 146                 close $fh;
 147                 $? == 0 ? \$blob : undef;
 148         }
 149 }
 150
 151 # /$LISTNAME/$MESSAGE_ID/raw                    -> raw mbox
 152 sub get_mid_txt {
 153         my ($ctx) = @_;
 154         my $x = mid2blob($ctx) or return r404();
 155         require PublicInbox::Mbox;
 156         PublicInbox::Mbox::emit1($x);
 157 }
 158
 159 # /$LISTNAME/$MESSAGE_ID/                   -> HTML content (short quotes)
 160 sub get_mid_html {
 161         my ($ctx) = @_;
 162         my $x = mid2blob($ctx) or return r404();
 163
 164         require PublicInbox::View;
 165         my $foot = footer($ctx);
 166         require Email::MIME;
 167         my $mime = Email::MIME->new($x);
 168         searcher($ctx);
 169         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 170           [ PublicInbox::View::msg_html($ctx, $mime, 'f/', $foot) ] ];
 171 }
 172
 173 # /$LISTNAME/$MESSAGE_ID/f/                   -> HTML content (fullquotes)
 174 sub get_full_html {
 175         my ($ctx) = @_;
 176         my $x = mid2blob($ctx) or return r404();
 177
 178         require PublicInbox::View;
 179         my $foot = footer($ctx);
 180         require Email::MIME;
 181         my $mime = Email::MIME->new($x);
 182         searcher($ctx);
 183         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 184           [ PublicInbox::View::msg_html($ctx, $mime, undef, $foot)] ];
 185 }
 186
 187 # /$LISTNAME/$MESSAGE_ID/t/
 188 sub get_thread {
 189         my ($ctx) = @_;
 190         my $srch = searcher($ctx) or return need_search($ctx);
 191         require PublicInbox::View;
 192         my $foot = footer($ctx);
 193         PublicInbox::View::thread_html($ctx, $foot, $srch);
 194 }
 195
 196 sub self_url {
 197         my ($cgi) = @_;
 198         ref($cgi) eq 'CGI' ? $cgi->self_url : $cgi->uri->as_string;
 199 }
 200
 201 sub ctx_get {
 202         my ($ctx, $key) = @_;
 203         my $val = $ctx->{$key};
 204         (defined $val && $val ne '') or die "BUG: bad ctx, $key unusable\n";
 205         $val;
 206 }
 207
 208 sub try_cat {
 209         my ($path) = @_;
 210         my $rv;
 211         if (open(my $fh, '<', $path)) {
 212                 local $/;
 213                 $rv = <$fh>;
 214                 close $fh;
 215         }
 216         $rv;
 217 }
 218
 219 sub footer {
 220         my ($ctx) = @_;
 221         return '' unless $ctx;
 222         my $git_dir = ctx_get($ctx, 'git_dir');
 223
 224         # favor user-supplied footer
 225         my $footer = try_cat("$git_dir/public-inbox/footer.html");
 226         if (defined $footer) {
 227                 chomp $footer;
 228                 $ctx->{footer} = $footer;
 229                 return $footer;
 230         }
 231
 232         # auto-generate a footer
 233         my $listname = ctx_get($ctx, 'listname');
 234         my $desc = try_cat("$git_dir/description");
 235         $desc = '$GIT_DIR/description missing' unless defined $desc;
 236         chomp $desc;
 237
 238         my $urls = try_cat("$git_dir/cloneurl");
 239         my @urls = split(/\r?\n/, $urls || '');
 240         my $nurls = scalar @urls;
 241         if ($nurls == 0) {
 242                 $urls = '($GIT_DIR/cloneurl missing)';
 243         } elsif ($nurls == 1) {
 244                 $urls = "git URL for <a\nhref=\"" . SSOMA_URL .
 245                         '">ssoma</a>: ' . $urls[0];
 246         } else {
 247                 $urls = "git URLs for <a\nhref=\"" . SSOMA_URL .
 248                         "\">ssoma</a>:\n" . join("\n", map { "\t$_" } @urls);
 249         }
 250
 251         my $addr = $pi_config->get($listname, 'address');
 252         if (ref($addr) eq 'ARRAY') {
 253                 $addr = $addr->[0]; # first address is primary
 254         }
 255
 256         $addr = "<a\nhref=\"mailto:$addr\">$addr</a>";
 257
 258         $ctx->{footer} = join("\n",
 259                 '- ' . $desc,
 260                 "A <a\nhref=\"" . PI_URL .  '">public-inbox</a>, ' .
 261                         'anybody may post in plain-text (not HTML):',
 262                 $addr,
 263                 $urls
 264         );
 265 }
 266
 267 # search support is optional, returns undef if Xapian is not installed
 268 # or not configured for the given GIT_DIR
 269 sub searcher {
 270         my ($ctx) = @_;
 271         eval {
 272                 require PublicInbox::Search;
 273                 $ctx->{srch} = PublicInbox::Search->new($ctx->{git_dir});
 274         };
 275 }
 276
 277 sub need_search {
 278         my ($ctx) = @_;
 279         my $msg = <<EOF;
 280 <html><head><title>Search not available for this
 281 public-inbox</title><body><pre>Search is not available for this public-inbox
 282 <a href="../">Return to index</a></pre></body></html>
 283 EOF
 284         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 285 }
 286
 287 # /$LISTNAME/$MESSAGE_ID/t.mbox           -> thread as mbox
 288 # /$LISTNAME/$MESSAGE_ID/t.mbox.gz        -> thread as gzipped mbox
 289 # note: I'm not a big fan of other compression formats since they're
 290 # significantly more expensive on CPU than gzip and less-widely available,
 291 # especially on older systems.  Stick to zlib since that's what git uses.
 292 sub get_thread_mbox {
 293         my ($ctx, $sfx) = @_;
 294         my $srch = searcher($ctx) or return need_search($ctx);
 295         require PublicInbox::Mbox;
 296         PublicInbox::Mbox::thread_mbox($ctx, $srch, $sfx);
 297 }
 298
 299
 300 # /$LISTNAME/$MESSAGE_ID/t.atom           -> thread as Atom feed
 301 sub get_thread_atom {
 302         my ($ctx) = @_;
 303         searcher($ctx) or return need_search($ctx);
 304         $ctx->{self_url} = self_url($ctx->{cgi});
 305         require PublicInbox::Feed;
 306         PublicInbox::Feed::generate_thread_atom($ctx);
 307 }
 308
 309 sub legacy_redirects {
 310         my ($ctx, $path_info) = @_;
 311
 312         # single-message pages
 313         if ($path_info =~ m!$LISTNAME_RE/m/(\S+)/\z!o) {
 314                 r301($ctx, $1, $2);
 315         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)/raw\z!o) {
 316                 r301($ctx, $1, $2, 'raw');
 317
 318         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)/\z!o) {
 319                 r301($ctx, $1, $2, 'f/');
 320
 321         # thread display
 322         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/\z!o) {
 323                 r301($ctx, $1, $2, 't/#u');
 324
 325         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)/mbox(\.gz)?\z!o) {
 326                 r301($ctx, $1, $2, "t.mbox$3");
 327
 328         # even older legacy redirects
 329         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
 330                 r301($ctx, $1, $2);
 331
 332         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\.html\z!o) {
 333                 r301($ctx, $1, $2, 't/#u');
 334
 335         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
 336                 r301($ctx, $1, $2, 'f/');
 337
 338         } elsif ($path_info =~ m!$LISTNAME_RE/(?:m|f)/(\S+)\.txt\z!o) {
 339                 r301($ctx, $1, $2, 'raw');
 340
 341         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)(\.mbox(?:\.gz)?)\z!o) {
 342                 r301($ctx, $1, $2, "t$3");
 343
 344         # legacy convenience redirects, order still matters
 345         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\z!o) {
 346                 r301($ctx, $1, $2);
 347         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\z!o) {
 348                 r301($ctx, $1, $2, 't/#u');
 349         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\z!o) {
 350                 r301($ctx, $1, $2, 'f/');
 351
 352         } else {
 353                 r404();
 354         }
 355 }
 356
 357 sub r301 {
 358         my ($ctx, $listname, $mid, $suffix) = @_;
 359         my $cgi = $ctx->{cgi};
 360         my $url;
 361         if (ref($cgi) eq 'CGI') {
 362                 $url = $cgi->url(-base) . '/';
 363         } else {
 364                 $url = $cgi->base->as_string;
 365         }
 366
 367         $url .= $listname . '/';
 368         $url .= (uri_escape_utf8($mid) . '/') if (defined $mid);
 369         $url .= $suffix if (defined $suffix);
 370
 371         [ 301,
 372           [ Location => $url, 'Content-Type' => 'text/plain' ],
 373           [ "Redirecting to $url\n" ] ]
 374 }
 375
 376 1;