lib/PublicInbox/WWW.pm

   1 # Copyright (C) 2014, Eric Wong <normalperson@yhbt.net> and all contributors
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # We focus on the lowest common denominators here:
   5 # - targeted at text-only console browsers (lynx, w3m, etc..)
   6 # - Only basic HTML, CSS only for line-wrapping <pre> text content for GUIs
   7 # - No JavaScript, graphics or icons allowed.
   8 # - Must not rely on static content
   9 # - UTF-8 is only for user-content, 7-bit US-ASCII for us
  10 package PublicInbox::WWW;
  11 use 5.008;
  12 use strict;
  13 use warnings;
  14 use PublicInbox::Config;
  15 use URI::Escape qw(uri_escape_utf8 uri_unescape);
  16 use constant SSOMA_URL => 'http://ssoma.public-inbox.org/';
  17 use constant PI_URL => 'http://public-inbox.org/';
  18 our $LISTNAME_RE = qr!\A/([\w\.\-]+)!;
  19 our $pi_config;
  20 BEGIN {
  21         $pi_config = PublicInbox::Config->new;
  22 }
  23
  24 sub run {
  25         my ($cgi, $method) = @_;
  26         my %ctx;
  27         if ($method !~ /\AGET|HEAD\z/) {
  28                 return r(405, 'Method Not Allowed');
  29         }
  30         my $path_info = $cgi->path_info;
  31
  32         # top-level indices and feeds
  33         if ($path_info eq '/') {
  34                 r404();
  35         } elsif ($path_info =~ m!$LISTNAME_RE\z!o) {
  36                 invalid_list(\%ctx, $1) || redirect_list_index(\%ctx, $cgi);
  37         } elsif ($path_info =~ m!$LISTNAME_RE(?:/|/index\.html)?\z!o) {
  38                 invalid_list(\%ctx, $1) || get_index(\%ctx, $cgi, 0);
  39         } elsif ($path_info =~ m!$LISTNAME_RE/atom\.xml\z!o) {
  40                 invalid_list(\%ctx, $1) || get_atom(\%ctx, $cgi, 0);
  41
  42         # single-message pages
  43         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.txt\z!o) {
  44                 invalid_list_mid(\%ctx, $1, $2) || get_mid_txt(\%ctx, $cgi);
  45         } elsif ($path_info =~ m!$LISTNAME_RE/m/(\S+)\.html\z!o) {
  46                 invalid_list_mid(\%ctx, $1, $2) || get_mid_html(\%ctx, $cgi);
  47
  48         # full-message page
  49         } elsif ($path_info =~ m!$LISTNAME_RE/f/(\S+)\.html\z!o) {
  50                 invalid_list_mid(\%ctx, $1, $2) || get_full_html(\%ctx, $cgi);
  51
  52         # thread display
  53         } elsif ($path_info =~ m!$LISTNAME_RE/t/(\S+)\.html\z!o) {
  54                 invalid_list_mid(\%ctx, $1, $2) || get_thread(\%ctx, $cgi);
  55
  56         # subject_path display
  57         } elsif ($path_info =~ m!$LISTNAME_RE/s/(\S+)\.html\z!o) {
  58                 my $sp = $2;
  59                 invalid_list(\%ctx, $1) || get_subject_path(\%ctx, $cgi, $sp);
  60
  61         # convenience redirects, order matters
  62         } elsif ($path_info =~ m!$LISTNAME_RE/(m|f|t|s)/(\S+)\z!o) {
  63                 my $pfx = $2;
  64                 invalid_list_mid(\%ctx, $1, $3) ||
  65                         redirect_mid(\%ctx, $cgi, $2);
  66
  67         } else {
  68                 r404();
  69         }
  70 }
  71
  72 # for CoW-friendliness, MOOOOO!
  73 sub preload {
  74         require PublicInbox::Feed;
  75         require PublicInbox::View;
  76         require PublicInbox::Thread;
  77         require Email::MIME;
  78         require Digest::SHA;
  79         require POSIX;
  80         require XML::Atom::SimpleFeed;
  81 }
  82
  83 # private functions below
  84
  85 sub r404 { r(404, 'Not Found') }
  86
  87 # simple response for errors
  88 sub r { [ $_[0], ['Content-Type' => 'text/plain'], [ join(' ', @_, "\n") ] ] }
  89
  90 # returns undef if valid, array ref response if invalid
  91 sub invalid_list {
  92         my ($ctx, $listname) = @_;
  93         my $git_dir = $pi_config->get($listname, "mainrepo");
  94         if (defined $git_dir) {
  95                 $ctx->{git_dir} = $git_dir;
  96                 $ctx->{listname} = $listname;
  97                 return;
  98         }
  99         r404();
 100 }
 101
 102 # returns undef if valid, array ref response if invalid
 103 sub invalid_list_mid {
 104         my ($ctx, $listname, $mid) = @_;
 105         my $ret = invalid_list($ctx, $listname, $mid);
 106         $ctx->{mid} = uri_unescape($mid) unless $ret;
 107         $ret;
 108 }
 109
 110 # /$LISTNAME/atom.xml                       -> Atom feed, includes replies
 111 sub get_atom {
 112         my ($ctx, $cgi, $top) = @_;
 113         require PublicInbox::Feed;
 114         [ 200, [ 'Content-Type' => 'application/xml' ],
 115           [ PublicInbox::Feed->generate({
 116                         git_dir => $ctx->{git_dir},
 117                         listname => $ctx->{listname},
 118                         pi_config => $pi_config,
 119                         cgi => $cgi,
 120                         top => $top,
 121                 }) ]
 122         ];
 123 }
 124
 125 # /$LISTNAME/?r=$GIT_COMMIT                 -> HTML only
 126 sub get_index {
 127         my ($ctx, $cgi, $top) = @_;
 128         require PublicInbox::Feed;
 129         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 130           [ PublicInbox::Feed->generate_html_index({
 131                         git_dir => $ctx->{git_dir},
 132                         listname => $ctx->{listname},
 133                         pi_config => $pi_config,
 134                         cgi => $cgi,
 135                         footer => footer($ctx),
 136                         top => $top,
 137                 }) ]
 138         ];
 139 }
 140
 141 # just returns a string ref for the blob in the current ctx
 142 sub mid2blob {
 143         my ($ctx) = @_;
 144         require PublicInbox::MID;
 145         my $path = PublicInbox::MID::mid2path($ctx->{mid});
 146         my @cmd = ('git', "--git-dir=$ctx->{git_dir}",
 147                         qw(cat-file blob), "HEAD:$path");
 148         my $cmd = join(' ', @cmd);
 149         my $pid = open my $fh, '-|';
 150         defined $pid or die "fork failed: $!\n";
 151         if ($pid == 0) {
 152                 open STDERR, '>', '/dev/null'; # ignore errors
 153                 exec @cmd or die "exec failed: $!\n";
 154         } else {
 155                 my $blob = eval { local $/; <$fh> };
 156                 close $fh;
 157                 $? == 0 ? \$blob : undef;
 158         }
 159 }
 160
 161 # /$LISTNAME/m/$MESSAGE_ID.txt                    -> raw original
 162 sub get_mid_txt {
 163         my ($ctx, $cgi) = @_;
 164         my $x = mid2blob($ctx);
 165         $x ? [ 200, [ 'Content-Type' => 'text/plain' ], [ $$x ] ] : r404();
 166 }
 167
 168 # /$LISTNAME/m/$MESSAGE_ID.html                   -> HTML content (short quotes)
 169 sub get_mid_html {
 170         my ($ctx, $cgi) = @_;
 171         my $x = mid2blob($ctx);
 172         return r404() unless $x;
 173
 174         require PublicInbox::View;
 175         my $pfx = msg_pfx($ctx);
 176         my $foot = footer($ctx);
 177         require Email::MIME;
 178         my $mime = Email::MIME->new($x);
 179         my $srch = searcher($ctx);
 180         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 181           [ PublicInbox::View->msg_html($mime, $pfx, $foot, $srch) ] ];
 182 }
 183
 184 # /$LISTNAME/f/$MESSAGE_ID.html                   -> HTML content (fullquotes)
 185 sub get_full_html {
 186         my ($ctx, $cgi) = @_;
 187         my $x = mid2blob($ctx);
 188         return r404() unless $x;
 189         require PublicInbox::View;
 190         my $foot = footer($ctx);
 191         require Email::MIME;
 192         my $mime = Email::MIME->new($x);
 193         my $srch = searcher($ctx);
 194         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 195           [ PublicInbox::View->msg_html($mime, undef, $foot, $srch)] ];
 196 }
 197
 198 # /$LISTNAME/t/$MESSAGE_ID.html
 199 sub get_thread {
 200         my ($ctx, $cgi) = @_;
 201         my $srch = searcher($ctx) or return need_search($ctx);
 202         require PublicInbox::View;
 203         my $foot = footer($ctx);
 204         my $body = PublicInbox::View->thread_html($ctx, $foot, $srch) or
 205                 return r404();
 206         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 207           [ $body ] ];
 208 }
 209
 210 # /$LISTNAME/s/$SUBJECT_PATH.html
 211 sub get_subject_path {
 212         my ($ctx, $cgi, $sp) = @_;
 213         $ctx->{subject_path} = $sp;
 214         my $srch = searcher($ctx) or return need_search($ctx);
 215         require PublicInbox::View;
 216         my $foot = footer($ctx);
 217         my $body = PublicInbox::View->subject_path_html($ctx, $foot, $srch) or
 218                 return r404();
 219         [ 200, [ 'Content-Type' => 'text/html; charset=UTF-8' ],
 220           [ $body ] ];
 221 }
 222
 223 sub self_url {
 224         my ($cgi) = @_;
 225         ref($cgi) eq 'CGI' ? $cgi->self_url : $cgi->uri->as_string;
 226 }
 227
 228 sub redirect_list_index {
 229         my ($ctx, $cgi) = @_;
 230         do_redirect(self_url($cgi) . "/");
 231 }
 232
 233 sub redirect_mid {
 234         my ($ctx, $cgi, $pfx) = @_;
 235         my $url = self_url($cgi);
 236         my $anchor = '';
 237         if (lc($pfx) eq 't') {
 238                 $anchor = '#u'; # <u id='#u'> is used to highlight in View.pm
 239         }
 240         do_redirect($url . ".html$anchor");
 241 }
 242
 243 sub do_redirect {
 244         my ($url) = @_;
 245         [ 301,
 246           [ Location => $url, 'Content-Type' => 'text/plain' ],
 247           [ "Redirecting to $url\n" ]
 248         ]
 249 }
 250
 251 sub ctx_get {
 252         my ($ctx, $key) = @_;
 253         my $val = $ctx->{$key};
 254         (defined $val && length $val) or die "BUG: bad ctx, $key unusable\n";
 255         $val;
 256 }
 257
 258 sub try_cat {
 259         my ($path) = @_;
 260         my $rv;
 261         if (open(my $fh, '<', $path)) {
 262                 local $/;
 263                 $rv = <$fh>;
 264                 close $fh;
 265         }
 266         $rv;
 267 }
 268
 269 sub footer {
 270         my ($ctx) = @_;
 271         return '' unless $ctx;
 272         my $git_dir = ctx_get($ctx, 'git_dir');
 273
 274         # favor user-supplied footer
 275         my $footer = try_cat("$git_dir/public-inbox/footer.html");
 276         if (defined $footer) {
 277                 chomp $footer;
 278                 return $footer;
 279         }
 280
 281         # auto-generate a footer
 282         my $listname = ctx_get($ctx, 'listname');
 283         my $desc = try_cat("$git_dir/description");
 284         $desc = '$GIT_DIR/description missing' unless defined $desc;
 285         chomp $desc;
 286
 287         my $urls = try_cat("$git_dir/cloneurl");
 288         my @urls = split(/\r?\n/, $urls || '');
 289         my $nurls = scalar @urls;
 290         if ($nurls == 0) {
 291                 $urls = '($GIT_DIR/cloneurl missing)';
 292         } elsif ($nurls == 1) {
 293                 $urls = "git URL for <a\nhref=\"" . SSOMA_URL .
 294                         '">ssoma</a>: ' . $urls[0];
 295         } else {
 296                 $urls = "git URLs for <a\nhref=\"" . SSOMA_URL .
 297                         "\">ssoma</a>:\n" . join("\n", map { "\t$_" } @urls);
 298         }
 299
 300         my $addr = $pi_config->get($listname, 'address');
 301         if (ref($addr) eq 'ARRAY') {
 302                 $addr = $addr->[0]; # first address is primary
 303         }
 304
 305         $addr = "<a\nhref=\"mailto:$addr\">$addr</a>";
 306         $desc =  $desc;
 307         join("\n",
 308                 '- ' . $desc,
 309                 "A <a\nhref=\"" . PI_URL .  '">public-inbox</a>, ' .
 310                         'anybody may post in plain-text (not HTML):',
 311                 $addr,
 312                 $urls
 313         );
 314 }
 315
 316 # search support is optional, returns undef if Xapian is not installed
 317 # or not configured for the given GIT_DIR
 318 sub searcher {
 319         my ($ctx) = @_;
 320         eval {
 321                 require PublicInbox::Search;
 322                 PublicInbox::Search->new($ctx->{git_dir});
 323         };
 324 }
 325
 326 sub need_search {
 327         my ($ctx) = @_;
 328         my $msg = <<EOF;
 329 <html><head><title>Search not available for this
 330 public-inbox</title><body><pre>Search is not available for this public-inbox
 331 <a href="../">Return to index</a></pre></body></html>
 332 EOF
 333         [ 501, [ 'Content-Type' => 'text/html; charset=UTF-8' ], [ $msg ] ];
 334 }
 335
 336 sub msg_pfx {
 337         my ($ctx) = @_;
 338         my $href = PublicInbox::Hval::ascii_html(uri_escape_utf8($ctx->{mid}));
 339         "../f/$href.html";
 340 }
 341
 342 1;