lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path warn_ignore_cb);
  11 use PublicInbox::Filter::Base qw(REJECT);
  12 use PublicInbox::Spamcheck;
  13 use PublicInbox::Sigfd;
  14 use PublicInbox::DS qw(now);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::ContentHash qw(content_hash);
  17 use POSIX qw(_exit);
  18
  19 sub compile_watchheaders ($) {
  20         my ($ibx) = @_;
  21         my $watch_hdrs = [];
  22         if (my $whs = $ibx->{watchheader}) {
  23                 for (@$whs) {
  24                         my ($k, $v) = split(/:/, $_, 2);
  25                         # XXX should this be case-insensitive?
  26                         # Or, mutt-style, case-sensitive iff
  27                         # a capital letter exists?
  28                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  29                 }
  30         }
  31         if (my $list_ids = $ibx->{listid}) {
  32                 for (@$list_ids) {
  33                         # RFC2919 section 6 stipulates
  34                         # "case insensitive equality"
  35                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  36                         push @$watch_hdrs, ['List-Id', $re ];
  37                 }
  38         }
  39         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  40 }
  41
  42 sub new {
  43         my ($class, $config) = @_;
  44         my (%mdmap, $spamc);
  45         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  46
  47         # "publicinboxwatch" is the documented namespace
  48         # "publicinboxlearn" is legacy but may be supported
  49         # indefinitely...
  50         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  51                 my $k = "$pfx.watchspam";
  52                 defined(my $dirs = $config->{$k}) or next;
  53                 $dirs = PublicInbox::Config::_array($dirs);
  54                 for my $dir (@$dirs) {
  55                         my $url;
  56                         if (is_maildir($dir)) {
  57                                 # skip "new", no MUA has seen it, yet.
  58                                 $mdmap{"$dir/cur"} = 'watchspam';
  59                         } elsif ($url = imap_url($dir)) {
  60                                 $imap{$url} = 'watchspam';
  61                         } elsif ($url = nntp_url($dir)) {
  62                                 $nntp{$url} = 'watchspam';
  63                         } else {
  64                                 warn "unsupported $k=$dir\n";
  65                         }
  66                 }
  67         }
  68
  69         my $k = 'publicinboxwatch.spamcheck';
  70         my $default = undef;
  71         my $spamcheck = PublicInbox::Spamcheck::get($config, $k, $default);
  72         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  73
  74         $config->each_inbox(sub {
  75                 # need to make all inboxes writable for spam removal:
  76                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  77
  78                 my $watches = $ibx->{watch} or return;
  79                 $watches = PublicInbox::Config::_array($watches);
  80                 for my $watch (@$watches) {
  81                         my $url;
  82                         if (is_maildir($watch)) {
  83                                 compile_watchheaders($ibx);
  84                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  85                                 my $cur_dst = $mdmap{$cur} //= [];
  86                                 return if is_watchspam($cur, $cur_dst, $ibx);
  87                                 push @{$mdmap{$new} //= []}, $ibx;
  88                                 push @$cur_dst, $ibx;
  89                         } elsif ($url = imap_url($watch)) {
  90                                 return if is_watchspam($url, $imap{$url}, $ibx);
  91                                 compile_watchheaders($ibx);
  92                                 push @{$imap{$url} ||= []}, $ibx;
  93                         } elsif ($url = nntp_url($watch)) {
  94                                 return if is_watchspam($url, $nntp{$url}, $ibx);
  95                                 compile_watchheaders($ibx);
  96                                 push @{$nntp{$url} ||= []}, $ibx;
  97                         } else {
  98                                 warn "watch unsupported: $k=$watch\n";
  99                         }
 100                 }
 101         });
 102
 103         my $mdre;
 104         if (scalar keys %mdmap) {
 105                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 106                 $mdre = qr!\A($mdre)/!;
 107         }
 108         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 109
 110         bless {
 111                 max_batch => 10, # avoid hogging locks for too long
 112                 spamcheck => $spamcheck,
 113                 mdmap => \%mdmap,
 114                 mdre => $mdre,
 115                 config => $config,
 116                 imap => scalar keys %imap ? \%imap : undef,
 117                 nntp => scalar keys %nntp? \%nntp : undef,
 118                 importers => {},
 119                 opendirs => {}, # dirname => dirhandle (in progress scans)
 120                 ops => [], # 'quit', 'full'
 121         }, $class;
 122 }
 123
 124 sub _done_for_now {
 125         my ($self) = @_;
 126         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 127         for my $im (values %{$self->{importers}}) {
 128                 next if !$im; # $im may be undef during cleanup
 129                 eval { $im->done };
 130                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 131         }
 132 }
 133
 134 sub remove_eml_i { # each_inbox callback
 135         my ($ibx, $arg) = @_;
 136         my ($self, $eml, $loc) = @$arg;
 137
 138         eval {
 139                 # try to avoid taking a lock or unnecessary spawning
 140                 my $im = $self->{importers}->{"$ibx"};
 141                 my $scrubbed;
 142                 if ((!$im || !$im->active) && $ibx->over) {
 143                         if (content_exists($ibx, $eml)) {
 144                                 # continue
 145                         } elsif (my $scrub = $ibx->filter($im)) {
 146                                 $scrubbed = $scrub->scrub($eml, 1);
 147                                 if ($scrubbed && $scrubbed != REJECT &&
 148                                           !content_exists($ibx, $scrubbed)) {
 149                                         return;
 150                                 }
 151                         } else {
 152                                 return;
 153                         }
 154                 }
 155
 156                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 157                 $im->remove($eml, 'spam');
 158                 $scrubbed //= do {
 159                         my $scrub = $ibx->filter($im);
 160                         $scrub ? $scrub->scrub($eml, 1) : undef;
 161                 };
 162                 if ($scrubbed && $scrubbed != REJECT) {
 163                         $im->remove($scrubbed, 'spam');
 164                 }
 165         };
 166         if ($@) {
 167                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 168                 _done_for_now($self);
 169         }
 170 }
 171
 172 sub _remove_spam {
 173         my ($self, $path) = @_;
 174         # path must be marked as (S)een
 175         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 176         my $eml = eml_from_path($path) or return;
 177         local $SIG{__WARN__} = warn_ignore_cb();
 178         $self->{config}->each_inbox(\&remove_eml_i, [ $self, $eml, $path ]);
 179 }
 180
 181 sub import_eml ($$$) {
 182         my ($self, $ibx, $eml) = @_;
 183
 184         # any header match means it's eligible for the inbox:
 185         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 186                 my $ok;
 187                 for my $wh (@$watch_hdrs) {
 188                         my @v = $eml->header_raw($wh->[0]);
 189                         $ok = grep(/$wh->[1]/, @v) and last;
 190                 }
 191                 return unless $ok;
 192         }
 193         eval {
 194                 my $im = _importer_for($self, $ibx);
 195                 if (my $scrub = $ibx->filter($im)) {
 196                         my $scrubbed = $scrub->scrub($eml) or return;
 197                         $scrubbed == REJECT and return;
 198                         $eml = $scrubbed;
 199                 }
 200                 $im->add($eml, $self->{spamcheck});
 201         };
 202         if ($@) {
 203                 warn "$ibx->{name} add failed: $@\n";
 204                 _done_for_now($self);
 205         }
 206 }
 207
 208 sub _try_path {
 209         my ($self, $path) = @_;
 210         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 211         if ($path !~ $self->{mdre}) {
 212                 warn "unrecognized path: $path\n";
 213                 return;
 214         }
 215         my $inboxes = $self->{mdmap}->{$1};
 216         unless ($inboxes) {
 217                 warn "unmappable dir: $1\n";
 218                 return;
 219         }
 220         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 221         local $SIG{__WARN__} = sub {
 222                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 223                 $warn_cb->($pfx, "path: $path\n", @_);
 224         };
 225         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 226                 return _remove_spam($self, $path);
 227         }
 228         foreach my $ibx (@$inboxes) {
 229                 my $eml = eml_from_path($path) or next;
 230                 import_eml($self, $ibx, $eml);
 231         }
 232 }
 233
 234 sub quit_done ($) {
 235         my ($self) = @_;
 236         return unless $self->{quit};
 237
 238         # don't have reliable wakeups, keep signalling
 239         my $done = 1;
 240         for (qw(idle_pids poll_pids)) {
 241                 my $pids = $self->{$_} or next;
 242                 for (keys %$pids) {
 243                         $done = undef if kill('QUIT', $_);
 244                 }
 245         }
 246         $done;
 247 }
 248
 249 sub quit {
 250         my ($self) = @_;
 251         $self->{quit} = 1;
 252         %{$self->{opendirs}} = ();
 253         _done_for_now($self);
 254         quit_done($self);
 255         if (my $idle_mic = $self->{idle_mic}) {
 256                 eval { $idle_mic->done };
 257                 if ($@) {
 258                         warn "IDLE DONE error: $@\n";
 259                         eval { $idle_mic->disconnect };
 260                         warn "IDLE LOGOUT error: $@\n" if $@;
 261                 }
 262         }
 263 }
 264
 265 sub watch_fs_init ($) {
 266         my ($self) = @_;
 267         my $done = sub {
 268                 delete $self->{done_timer};
 269                 _done_for_now($self);
 270         };
 271         my $cb = sub {
 272                 _try_path($self, $_[0]->fullname);
 273                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 274         };
 275         require PublicInbox::DirIdle;
 276         # inotify_create + EPOLL_CTL_ADD
 277         PublicInbox::DirIdle->new([keys %{$self->{mdmap}}], $cb);
 278 }
 279
 280 # avoid exposing deprecated "snews" to users.
 281 my %SCHEME_MAP = ('snews' => 'nntps');
 282
 283 sub uri_scheme ($) {
 284         my ($uri) = @_;
 285         my $scheme = $uri->scheme;
 286         $SCHEME_MAP{$scheme} // $scheme;
 287 }
 288
 289 # returns the git config section name, e.g [imap "imaps://user@example.com"]
 290 # without the mailbox, so we can share connections between different inboxes
 291 sub uri_section ($) {
 292         my ($uri) = @_;
 293         uri_scheme($uri) . '://' . $uri->authority;
 294 }
 295
 296 sub cfg_intvl ($$$) {
 297         my ($cfg, $key, $url) = @_;
 298         my $v = $cfg->urlmatch($key, $url) // return;
 299         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 300         if (ref($v) eq 'ARRAY') {
 301                 $v = join(', ', @$v);
 302                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 303         } else {
 304                 warn "W: $key=$v is not a numeric value in seconds\n";
 305         }
 306 }
 307
 308 sub cfg_bool ($$$) {
 309         my ($cfg, $key, $url) = @_;
 310         my $orig = $cfg->urlmatch($key, $url) // return;
 311         my $bool = $cfg->git_bool($orig);
 312         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 313         $bool;
 314 }
 315
 316 # flesh out common IMAP-specific data structures
 317 sub imap_common_init ($) {
 318         my ($self) = @_;
 319         my $cfg = $self->{config};
 320         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 321         for my $url (sort keys %{$self->{imap}}) {
 322                 my $uri = PublicInbox::URIimap->new($url);
 323                 my $sec = uri_section($uri);
 324                 for my $k (qw(Starttls Debug Compress)) {
 325                         my $bool = cfg_bool($cfg, "imap.$k", $url) // next;
 326                         $mic_args->{$sec}->{$k} = $bool;
 327                 }
 328                 my $to = cfg_intvl($cfg, 'imap.timeout', $url);
 329                 $mic_args->{$sec}->{Timeout} = $to if $to;
 330                 for my $k (qw(pollInterval idleInterval)) {
 331                         $to = cfg_intvl($cfg, "imap.$k", $url) // next;
 332                         $self->{imap_opt}->{$sec}->{$k} = $to;
 333                 }
 334                 my $k = 'imap.fetchBatchSize';
 335                 my $bs = $cfg->urlmatch($k, $url) // next;
 336                 if ($bs =~ /\A([0-9]+)\z/) {
 337                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 338                 } else {
 339                         warn "$k=$bs is not an integer\n";
 340                 }
 341         }
 342         $mic_args;
 343 }
 344
 345 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
 346
 347 sub mic_for ($$$) { # mic = Mail::IMAPClient
 348         my ($self, $url, $mic_args) = @_;
 349         my $uri = PublicInbox::URIimap->new($url);
 350         require PublicInbox::GitCredential;
 351         my $cred = bless {
 352                 url => $url,
 353                 protocol => $uri->scheme,
 354                 host => $uri->host,
 355                 username => $uri->user,
 356                 password => $uri->password,
 357         }, 'PublicInbox::GitCredential';
 358         my $common = $mic_args->{uri_section($uri)} // {};
 359         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 360         my $host = $cred->{host};
 361         $host = '127.0.0.1' if $host eq '0';
 362         my $mic_arg = {
 363                 Port => $uri->port,
 364                 Server => $host,
 365                 Ssl => $uri->scheme eq 'imaps',
 366                 Keepalive => 1, # SO_KEEPALIVE
 367                 %$common, # may set Starttls, Compress, Debug ....
 368         };
 369         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
 370                 die "E: <$url> new: $@\n";
 371
 372         # default to using STARTTLS if it's available, but allow
 373         # it to be disabled since I usually connect to localhost
 374         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 375                         $mic->has_capability('STARTTLS') &&
 376                         $mic->can('starttls')) {
 377                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
 378         }
 379
 380         # do we even need credentials?
 381         if (!defined($cred->{username}) &&
 382                         $mic->has_capability('AUTH=ANONYMOUS')) {
 383                 $cred = undef;
 384         }
 385         if ($cred) {
 386                 $cred->check_netrc unless defined $cred->{password};
 387                 $cred->fill; # may prompt user here
 388                 $mic->User($mic_arg->{User} = $cred->{username});
 389                 $mic->Password($mic_arg->{Password} = $cred->{password});
 390         } else { # AUTH=ANONYMOUS
 391                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 392                 $mic->Authcallback($mic_arg->{Authcallback} = \&auth_anon_cb);
 393         }
 394         if ($mic->login && $mic->IsAuthenticated) {
 395                 # success! keep IMAPClient->new arg in case we get disconnected
 396                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
 397         } else {
 398                 warn "E: <$url> LOGIN: $@\n";
 399                 $mic = undef;
 400         }
 401         $cred->run($mic ? 'approve' : 'reject') if $cred;
 402         $mic;
 403 }
 404
 405 sub imap_import_msg ($$$$$) {
 406         my ($self, $url, $uid, $raw, $flags) = @_;
 407         # our target audience expects LF-only, save storage
 408         $$raw =~ s/\r\n/\n/sg;
 409
 410         my $inboxes = $self->{imap}->{$url};
 411         if (ref($inboxes)) {
 412                 for my $ibx (@$inboxes) {
 413                         my $eml = PublicInbox::Eml->new($$raw);
 414                         my $x = import_eml($self, $ibx, $eml);
 415                 }
 416         } elsif ($inboxes eq 'watchspam') {
 417                 # we don't remove unseen messages
 418                 if ($flags =~ /\\Seen\b/) {
 419                         local $SIG{__WARN__} = warn_ignore_cb();
 420                         my $eml = PublicInbox::Eml->new($raw);
 421                         my $arg = [ $self, $eml, "$url UID:$uid" ];
 422                         $self->{config}->each_inbox(\&remove_eml_i, $arg);
 423                 }
 424         } else {
 425                 die "BUG: destination unknown $inboxes";
 426         }
 427 }
 428
 429 sub imap_fetch_all ($$$) {
 430         my ($self, $mic, $url) = @_;
 431         my $uri = PublicInbox::URIimap->new($url);
 432         my $sec = uri_section($uri);
 433         my $mbx = $uri->mailbox;
 434         $mic->Clear(1); # trim results history
 435         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 436         my ($r_uidval, $r_uidnext);
 437         for ($mic->Results) {
 438                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 439                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 440                 last if $r_uidval && $r_uidnext;
 441         }
 442         $r_uidval //= $mic->uidvalidity($mbx) //
 443                 return "E: $url cannot get UIDVALIDITY";
 444         $r_uidnext //= $mic->uidnext($mbx) //
 445                 return "E: $url cannot get UIDNEXT";
 446         my $itrk = PublicInbox::IMAPTracker->new($url);
 447         my ($l_uidval, $l_uid) = $itrk->get_last;
 448         $l_uidval //= $r_uidval; # first time
 449         $l_uid //= 1;
 450         if ($l_uidval != $r_uidval) {
 451                 return "E: $url UIDVALIDITY mismatch\n".
 452                         "E: local=$l_uidval != remote=$r_uidval";
 453         }
 454         my $r_uid = $r_uidnext - 1;
 455         if ($l_uid != 1 && $l_uid > $r_uid) {
 456                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 457                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 458         }
 459         return if $l_uid >= $r_uid; # nothing to do
 460
 461         warn "I: $url fetching UID $l_uid:$r_uid\n";
 462         $mic->Uid(1); # the default, we hope
 463         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 464         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 465
 466         # TODO: FLAGS may be useful for personal use
 467         my $key = $req;
 468         $key =~ s/\.PEEK//;
 469         my ($uids, $batch);
 470         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 471         local $SIG{__WARN__} = sub {
 472                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 473                 $batch //= '?';
 474                 $warn_cb->("$pfx$url UID:$batch\n", @_);
 475         };
 476         my $err;
 477         do {
 478                 # I wish "UID FETCH $START:*" could work, but:
 479                 # 1) servers do not need to return results in any order
 480                 # 2) Mail::IMAPClient doesn't offer a streaming API
 481                 $uids = $mic->search("UID $l_uid:*") or
 482                         return "E: $url UID SEARCH $l_uid:* error: $!";
 483                 return if scalar(@$uids) == 0;
 484
 485                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 486                 # responses, so sort it ourselves.  Order matters so
 487                 # IMAPTracker can store the newest UID.
 488                 @$uids = sort { $a <=> $b } @$uids;
 489
 490                 # Did we actually get new messages?
 491                 return if $uids->[0] < $l_uid;
 492
 493                 $l_uid = $uids->[-1] + 1; # for next search
 494                 my $last_uid;
 495                 my $n = $self->{max_batch};
 496
 497                 while (scalar @$uids) {
 498                         if (--$n < 0) {
 499                                 _done_for_now($self);
 500                                 $itrk->update_last($r_uidval, $last_uid);
 501                                 $n = $self->{max_batch};
 502                         }
 503                         my @batch = splice(@$uids, 0, $bs);
 504                         $batch = join(',', @batch);
 505                         local $0 = "UID:$batch $mbx $sec";
 506                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 507                         unless ($r) { # network error?
 508                                 $err = "E: $url UID FETCH $batch error: $!";
 509                                 last;
 510                         }
 511                         for my $uid (@batch) {
 512                                 # messages get deleted, so holes appear
 513                                 my $per_uid = delete $r->{$uid} // next;
 514                                 my $raw = delete($per_uid->{$key}) // next;
 515                                 my $fl = $per_uid->{FLAGS} // '';
 516                                 imap_import_msg($self, $url, $uid, \$raw, $fl);
 517                                 $last_uid = $uid;
 518                                 last if $self->{quit};
 519                         }
 520                         last if $self->{quit};
 521                 }
 522                 _done_for_now($self);
 523                 $itrk->update_last($r_uidval, $last_uid);
 524         } until ($err || $self->{quit});
 525         $err;
 526 }
 527
 528 sub imap_idle_once ($$$$) {
 529         my ($self, $mic, $intvl, $url) = @_;
 530         my $i = $intvl //= (29 * 60);
 531         my $end = now() + $intvl;
 532         warn "I: $url idling for ${intvl}s\n";
 533         local $0 = "IDLE $0";
 534         unless ($mic->idle) {
 535                 return if $self->{quit};
 536                 return "E: IDLE failed on $url: $!";
 537         }
 538         $self->{idle_mic} = $mic; # for ->quit
 539         my @res;
 540         until ($self->{quit} || !$mic->IsConnected ||
 541                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 542                 @res = $mic->idle_data($i);
 543                 $i = $end - now();
 544         }
 545         delete $self->{idle_mic};
 546         unless ($self->{quit}) {
 547                 $mic->IsConnected or return "E: IDLE disconnected on $url";
 548                 $mic->done or return "E: IDLE DONE failed on $url: $!";
 549         }
 550         undef;
 551 }
 552
 553 # idles on a single URI
 554 sub watch_imap_idle_1 ($$$) {
 555         my ($self, $url, $intvl) = @_;
 556         my $uri = PublicInbox::URIimap->new($url);
 557         my $sec = uri_section($uri);
 558         my $mic_arg = $self->{mic_arg}->{$sec} or
 559                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 560         my $mic;
 561         local $0 = $uri->mailbox." $sec";
 562         until ($self->{quit}) {
 563                 $mic //= PublicInbox::IMAPClient->new(%$mic_arg);
 564                 my $err;
 565                 if ($mic && $mic->IsConnected) {
 566                         $err = imap_fetch_all($self, $mic, $url);
 567                         $err //= imap_idle_once($self, $mic, $intvl, $url);
 568                 } else {
 569                         $err = "not connected: $!";
 570                 }
 571                 if ($err && !$self->{quit}) {
 572                         warn $err, "\n";
 573                         $mic = undef;
 574                         sleep 60 unless $self->{quit};
 575                 }
 576         }
 577 }
 578
 579 sub watch_atfork_child ($) {
 580         my ($self) = @_;
 581         delete $self->{idle_pids};
 582         delete $self->{poll_pids};
 583         delete $self->{opendirs};
 584         PublicInbox::DS->Reset;
 585         %SIG = (%SIG, %{$self->{sig}}, CHLD => 'DEFAULT');
 586         PublicInbox::Sigfd::sig_setmask($self->{oldset});
 587 }
 588
 589 sub watch_atfork_parent ($) {
 590         my ($self) = @_;
 591         _done_for_now($self);
 592 }
 593
 594 sub imap_idle_requeue ($) { # DS::add_timer callback
 595         my ($self, $url_intvl) = @{$_[0]};
 596         return if $self->{quit};
 597         push @{$self->{idle_todo}}, $url_intvl;
 598         event_step($self);
 599 }
 600
 601 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 602         my ($self, $pid) = @_;
 603         my $url_intvl = delete $self->{idle_pids}->{$pid} or
 604                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 605
 606         my ($url, $intvl) = @$url_intvl;
 607         return if $self->{quit};
 608         warn "W: PID=$pid on $url died: \$?=$?\n" if $?;
 609         PublicInbox::DS::add_timer(60,
 610                                 \&imap_idle_requeue, [ $self, $url_intvl ]);
 611 }
 612
 613 sub imap_idle_fork ($$) {
 614         my ($self, $url_intvl) = @_;
 615         my ($url, $intvl) = @$url_intvl;
 616         defined(my $pid = fork) or die "fork: $!";
 617         if ($pid == 0) {
 618                 watch_atfork_child($self);
 619                 watch_imap_idle_1($self, $url, $intvl);
 620                 _exit(0);
 621         }
 622         $self->{idle_pids}->{$pid} = $url_intvl;
 623         PublicInbox::DS::dwaitpid($pid, \&imap_idle_reap, $self);
 624 }
 625
 626 sub event_step {
 627         my ($self) = @_;
 628         return if $self->{quit};
 629         my $idle_todo = $self->{idle_todo};
 630         if ($idle_todo && @$idle_todo) {
 631                 watch_atfork_parent($self);
 632                 while (my $url_intvl = shift(@$idle_todo)) {
 633                         imap_idle_fork($self, $url_intvl);
 634                 }
 635         }
 636         goto(&fs_scan_step) if $self->{mdre};
 637 }
 638
 639 sub watch_imap_fetch_all ($$) {
 640         my ($self, $urls) = @_;
 641         for my $url (@$urls) {
 642                 my $uri = PublicInbox::URIimap->new($url);
 643                 my $sec = uri_section($uri);
 644                 my $mic_arg = $self->{mic_arg}->{$sec} or
 645                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 646                 my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or next;
 647                 my $err = imap_fetch_all($self, $mic, $url);
 648                 last if $self->{quit};
 649                 warn $err, "\n" if $err;
 650         }
 651 }
 652
 653 sub watch_nntp_fetch_all ($$) {
 654         my ($self, $urls) = @_;
 655         for my $url (@$urls) {
 656                 my $uri = uri_new($url);
 657                 my $sec = uri_section($uri);
 658                 my $nn_arg = $self->{nn_arg}->{$sec} or
 659                         die "BUG: no Net::NNTP->new arg for $sec";
 660                 my $nntp_opt = $self->{nntp_opt}->{$sec};
 661                 my $nn = nn_new($nn_arg, $nntp_opt, $url);
 662                 unless ($nn) {
 663                         warn "E: $url: \$!=$!\n";
 664                         next;
 665                 }
 666                 last if $self->{quit};
 667                 if (my $postconn = $nntp_opt->{-postconn}) {
 668                         for my $m_arg (@$postconn) {
 669                                 my ($method, @args) = @$m_arg;
 670                                 $nn->$method(@args) and next;
 671                                 warn "E: <$url> $method failed\n";
 672                                 $nn = undef;
 673                                 last;
 674                         }
 675                 }
 676                 last if $self->{quit};
 677                 if ($nn) {
 678                         my $err = nntp_fetch_all($self, $nn, $url);
 679                         warn $err, "\n" if $err;
 680                 }
 681         }
 682 }
 683
 684 sub poll_fetch_fork ($) { # DS::add_timer callback
 685         my ($self, $intvl, $urls) = @{$_[0]};
 686         return if $self->{quit};
 687         watch_atfork_parent($self);
 688         defined(my $pid = fork) or die "fork: $!";
 689         if ($pid == 0) {
 690                 watch_atfork_child($self);
 691                 if ($urls->[0] =~ m!\Aimaps?://!i) {
 692                         watch_imap_fetch_all($self, $urls);
 693                 } else {
 694                         watch_nntp_fetch_all($self, $urls);
 695                 }
 696                 _exit(0);
 697         }
 698         $self->{poll_pids}->{$pid} = [ $intvl, $urls ];
 699         PublicInbox::DS::dwaitpid($pid, \&poll_fetch_reap, $self);
 700 }
 701
 702 sub poll_fetch_reap { # PublicInbox::DS::dwaitpid callback
 703         my ($self, $pid) = @_;
 704         my $intvl_urls = delete $self->{poll_pids}->{$pid} or
 705                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 706         return if $self->{quit};
 707         my ($intvl, $urls) = @$intvl_urls;
 708         if ($?) {
 709                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$urls;
 710         }
 711         warn("I: will check $_ in ${intvl}s\n") for @$urls;
 712         PublicInbox::DS::add_timer($intvl, \&poll_fetch_fork,
 713                                         [$self, $intvl, $urls]);
 714 }
 715
 716 sub watch_imap_init ($$) {
 717         my ($self, $poll) = @_;
 718         eval { require PublicInbox::IMAPClient } or
 719                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 720         eval { require PublicInbox::IMAPTracker } or
 721                 die "DBD::SQLite is required for IMAP\n:$@\n";
 722
 723         my $mic_args = imap_common_init($self); # read args from config
 724
 725         # make sure we can connect and cache the credentials in memory
 726         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 727         my $mics = {}; # schema://authority => IMAPClient obj
 728         for my $url (sort keys %{$self->{imap}}) {
 729                 my $uri = PublicInbox::URIimap->new($url);
 730                 $mics->{uri_section($uri)} //= mic_for($self, $url, $mic_args);
 731         }
 732
 733         my $idle = []; # [ [ url1, intvl1 ], [url2, intvl2] ]
 734         for my $url (keys %{$self->{imap}}) {
 735                 my $uri = PublicInbox::URIimap->new($url);
 736                 my $sec = uri_section($uri);
 737                 my $mic = $mics->{$sec};
 738                 my $intvl = $self->{imap_opt}->{$sec}->{pollInterval};
 739                 if ($mic->has_capability('IDLE') && !$intvl) {
 740                         $intvl = $self->{imap_opt}->{$sec}->{idleInterval};
 741                         push @$idle, [ $url, $intvl // () ];
 742                 } else {
 743                         push @{$poll->{$intvl || 120}}, $url;
 744                 }
 745         }
 746         if (scalar @$idle) {
 747                 $self->{idle_todo} = $idle;
 748                 PublicInbox::DS::requeue($self); # ->event_step to fork
 749         }
 750 }
 751
 752 # flesh out common NNTP-specific data structures
 753 sub nntp_common_init ($) {
 754         my ($self) = @_;
 755         my $cfg = $self->{config};
 756         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 757         for my $url (sort keys %{$self->{nntp}}) {
 758                 my $sec = uri_section(uri_new($url));
 759
 760                 # Debug and Timeout are passed to Net::NNTP->new
 761                 my $v = cfg_bool($cfg, 'nntp.Debug', $url);
 762                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 763                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $url);
 764                 $nn_args->{$sec}->{Timeout} = $to if $to;
 765
 766                 # Net::NNTP post-connect commands
 767                 for my $k (qw(starttls compress)) {
 768                         $v = cfg_bool($cfg, "nntp.$k", $url) // next;
 769                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 770                 }
 771
 772                 # internal option
 773                 for my $k (qw(pollInterval)) {
 774                         $to = cfg_intvl($cfg, "nntp.$k", $url) // next;
 775                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 776                 }
 777         }
 778         $nn_args;
 779 }
 780
 781 # Net::NNTP doesn't support CAPABILITIES, yet
 782 sub try_starttls ($) {
 783         my ($host) = @_;
 784         return if $host =~ /\.onion\z/s;
 785         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 786         return if $host eq '::1';
 787         1;
 788 }
 789
 790 sub nn_new ($$$) {
 791         my ($nn_arg, $nntp_opt, $url) = @_;
 792         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 793
 794         # default to using STARTTLS if it's available, but allow
 795         # it to be disabled for localhost/VPN users
 796         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 797                 if (!defined($nntp_opt->{starttls}) &&
 798                                 try_starttls($nn_arg->{Host})) {
 799                         # soft fail by default
 800                         $nn->starttls or warn <<"";
 801 W: <$url> STARTTLS tried and failed (not requested)
 802
 803                 } elsif ($nntp_opt->{starttls}) {
 804                         # hard fail if explicitly configured
 805                         $nn->starttls or die <<"";
 806 E: <$url> STARTTLS requested and failed
 807
 808                 }
 809         } elsif ($nntp_opt->{starttls}) {
 810                 $nn->can('starttls') or
 811                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 812                 $nn->starttls or die <<"";
 813 E: <$url> STARTTLS requested and failed
 814
 815         }
 816         $nn;
 817 }
 818
 819 sub nn_for ($$$) { # nn = Net::NNTP
 820         my ($self, $url, $nn_args) = @_;
 821         my $uri = uri_new($url);
 822         my $sec = uri_section($uri);
 823         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 824         my $host = $uri->host;
 825         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 826         $host = '127.0.0.1' if $host eq '0';
 827         my $cred;
 828         my ($u, $p);
 829         if (defined(my $ui = $uri->userinfo)) {
 830                 require PublicInbox::GitCredential;
 831                 $cred = bless {
 832                         url => $sec,
 833                         protocol => uri_scheme($uri),
 834                         host => $host,
 835                 }, 'PublicInbox::GitCredential';
 836                 ($u, $p) = split(/:/, $ui, 2);
 837                 ($cred->{username}, $cred->{password}) = ($u, $p);
 838                 $cred->check_netrc unless defined $p;
 839         }
 840         my $common = $nn_args->{$sec} // {};
 841         my $nn_arg = {
 842                 Port => $uri->port,
 843                 Host => $host,
 844                 SSL => $uri->secure, # snews == nntps
 845                 %$common, # may Debug ....
 846         };
 847         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 848
 849         if ($cred) {
 850                 $cred->fill; # may prompt user here
 851                 if ($nn->authinfo($u, $p)) {
 852                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 853                 } else {
 854                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 855                         $nn = undef;
 856                 }
 857         }
 858
 859         if ($nntp_opt->{compress}) {
 860                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 861                 if ($nn->can('compress')) {
 862                         if ($nn->compress) {
 863                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 864                         } else {
 865                                 warn "W: <$url> COMPRESS failed\n";
 866                         }
 867                 } else {
 868                         delete $nntp_opt->{compress};
 869                         warn <<"";
 870 W: <$url> COMPRESS not supported by Net::NNTP
 871 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 872
 873                 }
 874         }
 875
 876         $self->{nn_arg}->{$sec} = $nn_arg;
 877         $cred->run($nn ? 'approve' : 'reject') if $cred;
 878         $nn;
 879 }
 880
 881 sub nntp_fetch_all ($$$) {
 882         my ($self, $nn, $url) = @_;
 883         my $uri = uri_new($url);
 884         my ($group, $num_a, $num_b) = $uri->group;
 885         my $sec = uri_section($uri);
 886         my ($nr, $beg, $end) = $nn->group($group);
 887         unless (defined($nr)) {
 888                 chomp(my $msg = $nn->message);
 889                 return "E: GROUP $group <$sec> $msg";
 890         }
 891
 892         # IMAPTracker is also used for tracking NNTP, UID == article number
 893         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 894         # expensive.  So we assume newsgroups don't change:
 895         my $itrk = PublicInbox::IMAPTracker->new($url);
 896         my (undef, $l_art) = $itrk->get_last;
 897         $l_art //= $beg; # initial import
 898
 899         # allow users to specify articles to refetch
 900         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 901         # nntp://example.com/inbox.foo/$num_a-$num_b
 902         $l_art = $num_a if defined($num_a) && $num_a < $l_art;
 903         $end = $num_b if defined($num_b) && $num_b < $end;
 904
 905         return if $l_art >= $end; # nothing to do
 906         $beg = $l_art + 1;
 907
 908         warn "I: $url fetching ARTICLE $beg..$end\n";
 909         my $warn_cb = $SIG{__WARN__} || sub { print STDERR @_ };
 910         my ($err, $art);
 911         local $SIG{__WARN__} = sub {
 912                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 913                 $warn_cb->("$pfx$url ", $art ? ("ARTICLE $art") : (), "\n", @_);
 914         };
 915         my $inboxes = $self->{nntp}->{$url};
 916         my $last_art;
 917         my $n = $self->{max_batch};
 918         for ($beg..$end) {
 919                 last if $self->{quit};
 920                 $art = $_;
 921                 if (--$n < 0) {
 922                         _done_for_now($self);
 923                         $itrk->update_last(0, $last_art);
 924                         $n = $self->{max_batch};
 925                 }
 926                 my $raw = $nn->article($art);
 927                 unless (defined($raw)) {
 928                         my $msg = $nn->message;
 929                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 930                                 $err = "E: $msg";
 931                                 last;
 932                         } else { # probably just a deleted message (spam)
 933                                 warn "W: $msg";
 934                                 next;
 935                         }
 936                 }
 937                 s/\r\n/\n/ for @$raw;
 938                 $raw = join('', @$raw);
 939                 if (ref($inboxes)) {
 940                         for my $ibx (@$inboxes) {
 941                                 my $eml = PublicInbox::Eml->new($raw);
 942                                 import_eml($self, $ibx, $eml);
 943                         }
 944                 } elsif ($inboxes eq 'watchspam') {
 945                         my $eml = PublicInbox::Eml->new(\$raw);
 946                         my $arg = [ $self, $eml, "$url ARTICLE $art" ];
 947                         $self->{config}->each_inbox(\&remove_eml_i, $arg);
 948                 } else {
 949                         die "BUG: destination unknown $inboxes";
 950                 }
 951                 $last_art = $art;
 952         }
 953         _done_for_now($self);
 954         $itrk->update_last(0, $last_art);
 955         $err;
 956 }
 957
 958 sub watch_nntp_init ($$) {
 959         my ($self, $poll) = @_;
 960         eval { require Net::NNTP } or
 961                 die "Net::NNTP is required for NNTP:\n$@\n";
 962         eval { require PublicInbox::IMAPTracker } or
 963                 die "DBD::SQLite is required for NNTP\n:$@\n";
 964
 965         my $nn_args = nntp_common_init($self); # read args from config
 966
 967         # make sure we can connect and cache the credentials in memory
 968         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 969         for my $url (sort keys %{$self->{nntp}}) {
 970                 nn_for($self, $url, $nn_args);
 971         }
 972         for my $url (keys %{$self->{nntp}}) {
 973                 my $uri = uri_new($url);
 974                 my $sec = uri_section($uri);
 975                 my $intvl = $self->{nntp_opt}->{$sec}->{pollInterval};
 976                 push @{$poll->{$intvl || 120}}, $url;
 977         }
 978 }
 979
 980 sub watch {
 981         my ($self, $sig, $oldset) = @_;
 982         $self->{oldset} = $oldset;
 983         $self->{sig} = $sig;
 984         my $poll = {}; # intvl_seconds => [ url1, url2 ]
 985         watch_imap_init($self, $poll) if $self->{imap};
 986         watch_nntp_init($self, $poll) if $self->{nntp};
 987         while (my ($intvl, $urls) = each %$poll) {
 988                 # poll all URLs for a given interval sequentially
 989                 PublicInbox::DS::add_timer(0, \&poll_fetch_fork,
 990                                                 [$self, $intvl, $urls]);
 991         }
 992         watch_fs_init($self) if $self->{mdre};
 993         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
 994         PublicInbox::DS->EventLoop;
 995         _done_for_now($self);
 996 }
 997
 998 sub trigger_scan {
 999         my ($self, $op) = @_;
1000         push @{$self->{ops}}, $op;
1001         PublicInbox::DS::requeue($self);
1002 }
1003
1004 sub fs_scan_step {
1005         my ($self) = @_;
1006         return if $self->{quit};
1007         my $op = shift @{$self->{ops}};
1008         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
1009
1010         # continue existing scan
1011         my $opendirs = $self->{opendirs};
1012         my @dirnames = keys %$opendirs;
1013         foreach my $dir (@dirnames) {
1014                 my $dh = delete $opendirs->{$dir};
1015                 my $n = $self->{max_batch};
1016                 while (my $fn = readdir($dh)) {
1017                         _try_path($self, "$dir/$fn");
1018                         last if --$n < 0;
1019                 }
1020                 $opendirs->{$dir} = $dh if $n < 0;
1021         }
1022         if ($op && $op eq 'full') {
1023                 foreach my $dir (keys %{$self->{mdmap}}) {
1024                         next if $opendirs->{$dir}; # already in progress
1025                         my $ok = opendir(my $dh, $dir);
1026                         unless ($ok) {
1027                                 warn "failed to open $dir: $!\n";
1028                                 next;
1029                         }
1030                         my $n = $self->{max_batch};
1031                         while (my $fn = readdir($dh)) {
1032                                 _try_path($self, "$dir/$fn");
1033                                 last if --$n < 0;
1034                         }
1035                         $opendirs->{$dir} = $dh if $n < 0;
1036                 }
1037         }
1038         _done_for_now($self);
1039         # do we have more work to do?
1040         PublicInbox::DS::requeue($self) if keys %$opendirs;
1041 }
1042
1043 sub scan {
1044         my ($self, $op) = @_;
1045         push @{$self->{ops}}, $op;
1046         goto &fs_scan_step;
1047 }
1048
1049 sub _importer_for {
1050         my ($self, $ibx) = @_;
1051         my $importers = $self->{importers};
1052         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
1053         if (scalar(keys(%$importers)) > 2) {
1054                 delete $importers->{"$ibx"};
1055                 _done_for_now($self);
1056         }
1057
1058         $importers->{"$ibx"} = $im;
1059 }
1060
1061 # XXX consider sharing with V2Writable, this only requires read-only access
1062 sub content_exists ($$) {
1063         my ($ibx, $eml) = @_;
1064         my $over = $ibx->over or return;
1065         my $mids = mids($eml);
1066         my $chash = content_hash($eml);
1067         my ($id, $prev);
1068         for my $mid (@$mids) {
1069                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1070                         my $cmp = $ibx->smsg_eml($smsg) or return;
1071                         return 1 if $chash eq content_hash($cmp);
1072                 }
1073         }
1074         undef;
1075 }
1076
1077 sub _spamcheck_cb {
1078         my ($sc) = @_;
1079         sub {
1080                 my ($mime, $ibx) = @_;
1081                 return if content_exists($ibx, $mime);
1082                 my $tmp = '';
1083                 if ($sc->spamcheck($mime, \$tmp)) {
1084                         return PublicInbox::Eml->new(\$tmp);
1085                 }
1086                 warn $mime->header('Message-ID')." failed spam check\n";
1087                 undef;
1088         }
1089 }
1090
1091 sub is_maildir {
1092         $_[0] =~ s!\Amaildir:!! or return;
1093         $_[0] =~ tr!/!/!s;
1094         $_[0] =~ s!/\z!!;
1095         $_[0];
1096 }
1097
1098 sub is_watchspam {
1099         my ($cur, $ws, $ibx) = @_;
1100         if ($ws && !ref($ws) && $ws eq 'watchspam') {
1101                 warn <<EOF;
1102 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
1103 EOF
1104                 return 1;
1105         }
1106         undef;
1107 }
1108
1109 sub uri_new {
1110         my ($url) = @_;
1111
1112         # URI::snews exists, URI::nntps does not, so use URI::snews
1113         $url =~ s!\Anntps://!snews://!i;
1114         URI->new($url);
1115 }
1116
1117 sub imap_url {
1118         my ($url) = @_;
1119         require PublicInbox::URIimap;
1120         my $uri = PublicInbox::URIimap->new($url);
1121         $uri ? $uri->canonical->as_string : undef;
1122 }
1123
1124 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
1125 sub nntp_url {
1126         my ($url) = @_;
1127         require URI;
1128         my $uri = uri_new($url);
1129         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
1130         $url = $uri->canonical->as_string;
1131         # nntps is IANA registered, snews is deprecated
1132         $url =~ s!\Asnews://!nntps://!;
1133         $url;
1134 }
1135
1136 1;