lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       http://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path warn_ignore_cb);
  11 use PublicInbox::Filter::Base qw(REJECT);
  12 use PublicInbox::Spamcheck;
  13 use PublicInbox::Sigfd;
  14 use PublicInbox::DS qw(now);
  15 use PublicInbox::MID qw(mids);
  16 use PublicInbox::ContentHash qw(content_hash);
  17 use PublicInbox::EOFpipe;
  18 use POSIX qw(_exit WNOHANG);
  19
  20 sub compile_watchheaders ($) {
  21         my ($ibx) = @_;
  22         my $watch_hdrs = [];
  23         if (my $whs = $ibx->{watchheader}) {
  24                 for (@$whs) {
  25                         my ($k, $v) = split(/:/, $_, 2);
  26                         # XXX should this be case-insensitive?
  27                         # Or, mutt-style, case-sensitive iff
  28                         # a capital letter exists?
  29                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  30                 }
  31         }
  32         if (my $list_ids = $ibx->{listid}) {
  33                 for (@$list_ids) {
  34                         # RFC2919 section 6 stipulates
  35                         # "case insensitive equality"
  36                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  37                         push @$watch_hdrs, ['List-Id', $re ];
  38                 }
  39         }
  40         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  41 }
  42
  43 sub new {
  44         my ($class, $cfg) = @_;
  45         my (%mdmap, $spamc);
  46         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  47
  48         # "publicinboxwatch" is the documented namespace
  49         # "publicinboxlearn" is legacy but may be supported
  50         # indefinitely...
  51         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  52                 my $k = "$pfx.watchspam";
  53                 defined(my $dirs = $cfg->{$k}) or next;
  54                 $dirs = PublicInbox::Config::_array($dirs);
  55                 for my $dir (@$dirs) {
  56                         my $url;
  57                         if (is_maildir($dir)) {
  58                                 # skip "new", no MUA has seen it, yet.
  59                                 $mdmap{"$dir/cur"} = 'watchspam';
  60                         } elsif ($url = imap_url($dir)) {
  61                                 $imap{$url} = 'watchspam';
  62                         } elsif ($url = nntp_url($dir)) {
  63                                 $nntp{$url} = 'watchspam';
  64                         } else {
  65                                 warn "unsupported $k=$dir\n";
  66                         }
  67                 }
  68         }
  69
  70         my $k = 'publicinboxwatch.spamcheck';
  71         my $default = undef;
  72         my $spamcheck = PublicInbox::Spamcheck::get($cfg, $k, $default);
  73         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  74
  75         $cfg->each_inbox(sub {
  76                 # need to make all inboxes writable for spam removal:
  77                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  78
  79                 my $watches = $ibx->{watch} or return;
  80                 $watches = PublicInbox::Config::_array($watches);
  81                 for my $watch (@$watches) {
  82                         my $url;
  83                         if (is_maildir($watch)) {
  84                                 compile_watchheaders($ibx);
  85                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  86                                 my $cur_dst = $mdmap{$cur} //= [];
  87                                 return if is_watchspam($cur, $cur_dst, $ibx);
  88                                 push @{$mdmap{$new} //= []}, $ibx;
  89                                 push @$cur_dst, $ibx;
  90                         } elsif ($url = imap_url($watch)) {
  91                                 return if is_watchspam($url, $imap{$url}, $ibx);
  92                                 compile_watchheaders($ibx);
  93                                 push @{$imap{$url} ||= []}, $ibx;
  94                         } elsif ($url = nntp_url($watch)) {
  95                                 return if is_watchspam($url, $nntp{$url}, $ibx);
  96                                 compile_watchheaders($ibx);
  97                                 push @{$nntp{$url} ||= []}, $ibx;
  98                         } else {
  99                                 warn "watch unsupported: $k=$watch\n";
 100                         }
 101                 }
 102         });
 103
 104         my $mdre;
 105         if (scalar keys %mdmap) {
 106                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 107                 $mdre = qr!\A($mdre)/!;
 108         }
 109         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 110
 111         bless {
 112                 max_batch => 10, # avoid hogging locks for too long
 113                 spamcheck => $spamcheck,
 114                 mdmap => \%mdmap,
 115                 mdre => $mdre,
 116                 pi_cfg => $cfg,
 117                 imap => scalar keys %imap ? \%imap : undef,
 118                 nntp => scalar keys %nntp? \%nntp : undef,
 119                 importers => {},
 120                 opendirs => {}, # dirname => dirhandle (in progress scans)
 121                 ops => [], # 'quit', 'full'
 122         }, $class;
 123 }
 124
 125 sub _done_for_now {
 126         my ($self) = @_;
 127         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 128         for my $im (values %{$self->{importers}}) {
 129                 next if !$im; # $im may be undef during cleanup
 130                 eval { $im->done };
 131                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 132         }
 133 }
 134
 135 sub remove_eml_i { # each_inbox callback
 136         my ($ibx, $self, $eml, $loc) = @_;
 137
 138         eval {
 139                 # try to avoid taking a lock or unnecessary spawning
 140                 my $im = $self->{importers}->{"$ibx"};
 141                 my $scrubbed;
 142                 if ((!$im || !$im->active) && $ibx->over) {
 143                         if (content_exists($ibx, $eml)) {
 144                                 # continue
 145                         } elsif (my $scrub = $ibx->filter($im)) {
 146                                 $scrubbed = $scrub->scrub($eml, 1);
 147                                 if ($scrubbed && $scrubbed != REJECT &&
 148                                           !content_exists($ibx, $scrubbed)) {
 149                                         return;
 150                                 }
 151                         } else {
 152                                 return;
 153                         }
 154                 }
 155
 156                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 157                 $im->remove($eml, 'spam');
 158                 $scrubbed //= do {
 159                         my $scrub = $ibx->filter($im);
 160                         $scrub ? $scrub->scrub($eml, 1) : undef;
 161                 };
 162                 if ($scrubbed && $scrubbed != REJECT) {
 163                         $im->remove($scrubbed, 'spam');
 164                 }
 165         };
 166         if ($@) {
 167                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 168                 _done_for_now($self);
 169         }
 170 }
 171
 172 sub _remove_spam {
 173         my ($self, $path) = @_;
 174         # path must be marked as (S)een
 175         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 176         my $eml = eml_from_path($path) or return;
 177         local $SIG{__WARN__} = warn_ignore_cb();
 178         $self->{pi_cfg}->each_inbox(\&remove_eml_i, $self, $eml, $path);
 179 }
 180
 181 sub import_eml ($$$) {
 182         my ($self, $ibx, $eml) = @_;
 183
 184         # any header match means it's eligible for the inbox:
 185         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 186                 my $ok;
 187                 for my $wh (@$watch_hdrs) {
 188                         my @v = $eml->header_raw($wh->[0]);
 189                         $ok = grep(/$wh->[1]/, @v) and last;
 190                 }
 191                 return unless $ok;
 192         }
 193         eval {
 194                 my $im = _importer_for($self, $ibx);
 195                 if (my $scrub = $ibx->filter($im)) {
 196                         my $scrubbed = $scrub->scrub($eml) or return;
 197                         $scrubbed == REJECT and return;
 198                         $eml = $scrubbed;
 199                 }
 200                 $im->add($eml, $self->{spamcheck});
 201         };
 202         if ($@) {
 203                 warn "$ibx->{name} add failed: $@\n";
 204                 _done_for_now($self);
 205         }
 206 }
 207
 208 sub _try_path {
 209         my ($self, $path) = @_;
 210         return unless PublicInbox::InboxWritable::is_maildir_path($path);
 211         if ($path !~ $self->{mdre}) {
 212                 warn "unrecognized path: $path\n";
 213                 return;
 214         }
 215         my $inboxes = $self->{mdmap}->{$1};
 216         unless ($inboxes) {
 217                 warn "unmappable dir: $1\n";
 218                 return;
 219         }
 220         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 221         local $SIG{__WARN__} = sub {
 222                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 223                 $warn_cb->($pfx, "path: $path\n", @_);
 224         };
 225         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 226                 return _remove_spam($self, $path);
 227         }
 228         foreach my $ibx (@$inboxes) {
 229                 my $eml = eml_from_path($path) or next;
 230                 import_eml($self, $ibx, $eml);
 231         }
 232 }
 233
 234 sub quit_done ($) {
 235         my ($self) = @_;
 236         return unless $self->{quit};
 237
 238         # don't have reliable wakeups, keep signalling
 239         my $done = 1;
 240         for (qw(idle_pids poll_pids)) {
 241                 my $pids = $self->{$_} or next;
 242                 for (keys %$pids) {
 243                         $done = undef if kill('QUIT', $_);
 244                 }
 245         }
 246         $done;
 247 }
 248
 249 sub quit {
 250         my ($self) = @_;
 251         $self->{quit} = 1;
 252         %{$self->{opendirs}} = ();
 253         _done_for_now($self);
 254         quit_done($self);
 255         if (my $idle_mic = $self->{idle_mic}) {
 256                 eval { $idle_mic->done };
 257                 if ($@) {
 258                         warn "IDLE DONE error: $@\n";
 259                         eval { $idle_mic->disconnect };
 260                         warn "IDLE LOGOUT error: $@\n" if $@;
 261                 }
 262         }
 263 }
 264
 265 sub watch_fs_init ($) {
 266         my ($self) = @_;
 267         my $done = sub {
 268                 delete $self->{done_timer};
 269                 _done_for_now($self);
 270         };
 271         my $cb = sub { # called by PublicInbox::DirIdle::event_step
 272                 _try_path($self, $_[0]->fullname);
 273                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 274         };
 275         require PublicInbox::DirIdle;
 276         # inotify_create + EPOLL_CTL_ADD
 277         PublicInbox::DirIdle->new([keys %{$self->{mdmap}}], $cb);
 278 }
 279
 280 # avoid exposing deprecated "snews" to users.
 281 my %SCHEME_MAP = ('snews' => 'nntps');
 282
 283 sub uri_scheme ($) {
 284         my ($uri) = @_;
 285         my $scheme = $uri->scheme;
 286         $SCHEME_MAP{$scheme} // $scheme;
 287 }
 288
 289 # returns the git config section name, e.g [imap "imaps://user@example.com"]
 290 # without the mailbox, so we can share connections between different inboxes
 291 sub uri_section ($) {
 292         my ($uri) = @_;
 293         uri_scheme($uri) . '://' . $uri->authority;
 294 }
 295
 296 sub cfg_intvl ($$$) {
 297         my ($cfg, $key, $url) = @_;
 298         my $v = $cfg->urlmatch($key, $url) // return;
 299         $v =~ /\A[0-9]+(?:\.[0-9]+)?\z/s and return $v + 0;
 300         if (ref($v) eq 'ARRAY') {
 301                 $v = join(', ', @$v);
 302                 warn "W: $key has multiple values: $v\nW: $key ignored\n";
 303         } else {
 304                 warn "W: $key=$v is not a numeric value in seconds\n";
 305         }
 306 }
 307
 308 sub cfg_bool ($$$) {
 309         my ($cfg, $key, $url) = @_;
 310         my $orig = $cfg->urlmatch($key, $url) // return;
 311         my $bool = $cfg->git_bool($orig);
 312         warn "W: $key=$orig for $url is not boolean\n" unless defined($bool);
 313         $bool;
 314 }
 315
 316 # flesh out common IMAP-specific data structures
 317 sub imap_common_init ($) {
 318         my ($self) = @_;
 319         my $cfg = $self->{pi_cfg};
 320         my $mic_args = {}; # scheme://authority => Mail:IMAPClient arg
 321         for my $url (sort keys %{$self->{imap}}) {
 322                 my $uri = PublicInbox::URIimap->new($url);
 323                 my $sec = uri_section($uri);
 324                 for my $k (qw(Starttls Debug Compress)) {
 325                         my $bool = cfg_bool($cfg, "imap.$k", $url) // next;
 326                         $mic_args->{$sec}->{$k} = $bool;
 327                 }
 328                 my $to = cfg_intvl($cfg, 'imap.timeout', $url);
 329                 $mic_args->{$sec}->{Timeout} = $to if $to;
 330                 for my $k (qw(pollInterval idleInterval)) {
 331                         $to = cfg_intvl($cfg, "imap.$k", $url) // next;
 332                         $self->{imap_opt}->{$sec}->{$k} = $to;
 333                 }
 334                 my $k = 'imap.fetchBatchSize';
 335                 my $bs = $cfg->urlmatch($k, $url) // next;
 336                 if ($bs =~ /\A([0-9]+)\z/) {
 337                         $self->{imap_opt}->{$sec}->{batch_size} = $bs;
 338                 } else {
 339                         warn "$k=$bs is not an integer\n";
 340                 }
 341         }
 342         $mic_args;
 343 }
 344
 345 sub auth_anon_cb { '' }; # for Mail::IMAPClient::Authcallback
 346
 347 sub mic_for ($$$) { # mic = Mail::IMAPClient
 348         my ($self, $url, $mic_args) = @_;
 349         my $uri = PublicInbox::URIimap->new($url);
 350         require PublicInbox::GitCredential;
 351         my $cred = bless {
 352                 url => $url,
 353                 protocol => $uri->scheme,
 354                 host => $uri->host,
 355                 username => $uri->user,
 356                 password => $uri->password,
 357         }, 'PublicInbox::GitCredential';
 358         my $common = $mic_args->{uri_section($uri)} // {};
 359         # IMAPClient and Net::Netrc both mishandles `0', so we pass `127.0.0.1'
 360         my $host = $cred->{host};
 361         $host = '127.0.0.1' if $host eq '0';
 362         my $mic_arg = {
 363                 Port => $uri->port,
 364                 Server => $host,
 365                 Ssl => $uri->scheme eq 'imaps',
 366                 Keepalive => 1, # SO_KEEPALIVE
 367                 %$common, # may set Starttls, Compress, Debug ....
 368         };
 369         my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or
 370                 die "E: <$url> new: $@\n";
 371
 372         # default to using STARTTLS if it's available, but allow
 373         # it to be disabled since I usually connect to localhost
 374         if (!$mic_arg->{Ssl} && !defined($mic_arg->{Starttls}) &&
 375                         $mic->has_capability('STARTTLS') &&
 376                         $mic->can('starttls')) {
 377                 $mic->starttls or die "E: <$url> STARTTLS: $@\n";
 378         }
 379
 380         # do we even need credentials?
 381         if (!defined($cred->{username}) &&
 382                         $mic->has_capability('AUTH=ANONYMOUS')) {
 383                 $cred = undef;
 384         }
 385         if ($cred) {
 386                 $cred->check_netrc unless defined $cred->{password};
 387                 $cred->fill; # may prompt user here
 388                 $mic->User($mic_arg->{User} = $cred->{username});
 389                 $mic->Password($mic_arg->{Password} = $cred->{password});
 390         } else { # AUTH=ANONYMOUS
 391                 $mic->Authmechanism($mic_arg->{Authmechanism} = 'ANONYMOUS');
 392                 $mic->Authcallback($mic_arg->{Authcallback} = \&auth_anon_cb);
 393         }
 394         if ($mic->login && $mic->IsAuthenticated) {
 395                 # success! keep IMAPClient->new arg in case we get disconnected
 396                 $self->{mic_arg}->{uri_section($uri)} = $mic_arg;
 397         } else {
 398                 warn "E: <$url> LOGIN: $@\n";
 399                 $mic = undef;
 400         }
 401         $cred->run($mic ? 'approve' : 'reject') if $cred;
 402         $mic;
 403 }
 404
 405 sub imap_import_msg ($$$$$) {
 406         my ($self, $url, $uid, $raw, $flags) = @_;
 407         # our target audience expects LF-only, save storage
 408         $$raw =~ s/\r\n/\n/sg;
 409
 410         my $inboxes = $self->{imap}->{$url};
 411         if (ref($inboxes)) {
 412                 for my $ibx (@$inboxes) {
 413                         my $eml = PublicInbox::Eml->new($$raw);
 414                         import_eml($self, $ibx, $eml);
 415                 }
 416         } elsif ($inboxes eq 'watchspam') {
 417                 # we don't remove unseen messages
 418                 if ($flags =~ /\\Seen\b/) {
 419                         local $SIG{__WARN__} = warn_ignore_cb();
 420                         my $eml = PublicInbox::Eml->new($raw);
 421                         $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 422                                                 $self, $eml, "$url UID:$uid");
 423                 }
 424         } else {
 425                 die "BUG: destination unknown $inboxes";
 426         }
 427 }
 428
 429 sub imap_fetch_all ($$$) {
 430         my ($self, $mic, $url) = @_;
 431         my $uri = PublicInbox::URIimap->new($url);
 432         my $sec = uri_section($uri);
 433         my $mbx = $uri->mailbox;
 434         $mic->Clear(1); # trim results history
 435         $mic->examine($mbx) or return "E: EXAMINE $mbx ($sec) failed: $!";
 436         my ($r_uidval, $r_uidnext);
 437         for ($mic->Results) {
 438                 /^\* OK \[UIDVALIDITY ([0-9]+)\].*/ and $r_uidval = $1;
 439                 /^\* OK \[UIDNEXT ([0-9]+)\].*/ and $r_uidnext = $1;
 440                 last if $r_uidval && $r_uidnext;
 441         }
 442         $r_uidval //= $mic->uidvalidity($mbx) //
 443                 return "E: $url cannot get UIDVALIDITY";
 444         $r_uidnext //= $mic->uidnext($mbx) //
 445                 return "E: $url cannot get UIDNEXT";
 446         my $itrk = PublicInbox::IMAPTracker->new($url);
 447         my ($l_uidval, $l_uid) = $itrk->get_last;
 448         $l_uidval //= $r_uidval; # first time
 449         $l_uid //= 1;
 450         if ($l_uidval != $r_uidval) {
 451                 return "E: $url UIDVALIDITY mismatch\n".
 452                         "E: local=$l_uidval != remote=$r_uidval";
 453         }
 454         my $r_uid = $r_uidnext - 1;
 455         if ($l_uid != 1 && $l_uid > $r_uid) {
 456                 return "E: $url local UID exceeds remote ($l_uid > $r_uid)\n".
 457                         "E: $url strangely, UIDVALIDLITY matches ($l_uidval)\n";
 458         }
 459         return if $l_uid >= $r_uid; # nothing to do
 460
 461         warn "I: $url fetching UID $l_uid:$r_uid\n";
 462         $mic->Uid(1); # the default, we hope
 463         my $bs = $self->{imap_opt}->{$sec}->{batch_size} // 1;
 464         my $req = $mic->imap4rev1 ? 'BODY.PEEK[]' : 'RFC822.PEEK';
 465
 466         # TODO: FLAGS may be useful for personal use
 467         my $key = $req;
 468         $key =~ s/\.PEEK//;
 469         my ($uids, $batch);
 470         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 471         local $SIG{__WARN__} = sub {
 472                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 473                 $batch //= '?';
 474                 $warn_cb->("$pfx$url UID:$batch\n", @_);
 475         };
 476         my $err;
 477         do {
 478                 # I wish "UID FETCH $START:*" could work, but:
 479                 # 1) servers do not need to return results in any order
 480                 # 2) Mail::IMAPClient doesn't offer a streaming API
 481                 $uids = $mic->search("UID $l_uid:*") or
 482                         return "E: $url UID SEARCH $l_uid:* error: $!";
 483                 return if scalar(@$uids) == 0;
 484
 485                 # RFC 3501 doesn't seem to indicate order of UID SEARCH
 486                 # responses, so sort it ourselves.  Order matters so
 487                 # IMAPTracker can store the newest UID.
 488                 @$uids = sort { $a <=> $b } @$uids;
 489
 490                 # Did we actually get new messages?
 491                 return if $uids->[0] < $l_uid;
 492
 493                 $l_uid = $uids->[-1] + 1; # for next search
 494                 my $last_uid;
 495                 my $n = $self->{max_batch};
 496
 497                 while (scalar @$uids) {
 498                         if (--$n < 0) {
 499                                 _done_for_now($self);
 500                                 $itrk->update_last($r_uidval, $last_uid);
 501                                 $n = $self->{max_batch};
 502                         }
 503                         my @batch = splice(@$uids, 0, $bs);
 504                         $batch = join(',', @batch);
 505                         local $0 = "UID:$batch $mbx $sec";
 506                         my $r = $mic->fetch_hash($batch, $req, 'FLAGS');
 507                         unless ($r) { # network error?
 508                                 $err = "E: $url UID FETCH $batch error: $!";
 509                                 last;
 510                         }
 511                         for my $uid (@batch) {
 512                                 # messages get deleted, so holes appear
 513                                 my $per_uid = delete $r->{$uid} // next;
 514                                 my $raw = delete($per_uid->{$key}) // next;
 515                                 my $fl = $per_uid->{FLAGS} // '';
 516                                 imap_import_msg($self, $url, $uid, \$raw, $fl);
 517                                 $last_uid = $uid;
 518                                 last if $self->{quit};
 519                         }
 520                         last if $self->{quit};
 521                 }
 522                 _done_for_now($self);
 523                 $itrk->update_last($r_uidval, $last_uid);
 524         } until ($err || $self->{quit});
 525         $err;
 526 }
 527
 528 sub imap_idle_once ($$$$) {
 529         my ($self, $mic, $intvl, $url) = @_;
 530         my $i = $intvl //= (29 * 60);
 531         my $end = now() + $intvl;
 532         warn "I: $url idling for ${intvl}s\n";
 533         local $0 = "IDLE $0";
 534         unless ($mic->idle) {
 535                 return if $self->{quit};
 536                 return "E: IDLE failed on $url: $!";
 537         }
 538         $self->{idle_mic} = $mic; # for ->quit
 539         my @res;
 540         until ($self->{quit} || !$mic->IsConnected ||
 541                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 542                 @res = $mic->idle_data($i);
 543                 $i = $end - now();
 544         }
 545         delete $self->{idle_mic};
 546         unless ($self->{quit}) {
 547                 $mic->IsConnected or return "E: IDLE disconnected on $url";
 548                 $mic->done or return "E: IDLE DONE failed on $url: $!";
 549         }
 550         undef;
 551 }
 552
 553 # idles on a single URI
 554 sub watch_imap_idle_1 ($$$) {
 555         my ($self, $url, $intvl) = @_;
 556         my $uri = PublicInbox::URIimap->new($url);
 557         my $sec = uri_section($uri);
 558         my $mic_arg = $self->{mic_arg}->{$sec} or
 559                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 560         my $mic;
 561         local $0 = $uri->mailbox." $sec";
 562         until ($self->{quit}) {
 563                 $mic //= PublicInbox::IMAPClient->new(%$mic_arg);
 564                 my $err;
 565                 if ($mic && $mic->IsConnected) {
 566                         $err = imap_fetch_all($self, $mic, $url);
 567                         $err //= imap_idle_once($self, $mic, $intvl, $url);
 568                 } else {
 569                         $err = "E: not connected: $!";
 570                 }
 571                 if ($err && !$self->{quit}) {
 572                         warn $err, "\n";
 573                         $mic = undef;
 574                         sleep 60 unless $self->{quit};
 575                 }
 576         }
 577 }
 578
 579 sub watch_atfork_child ($) {
 580         my ($self) = @_;
 581         delete $self->{idle_pids};
 582         delete $self->{poll_pids};
 583         delete $self->{opendirs};
 584         PublicInbox::DS->Reset;
 585         %SIG = (%SIG, %{$self->{sig}}, CHLD => 'DEFAULT');
 586         PublicInbox::DS::sig_setmask($self->{oldset});
 587 }
 588
 589 sub watch_atfork_parent ($) {
 590         my ($self) = @_;
 591         _done_for_now($self);
 592         PublicInbox::DS::block_signals();
 593 }
 594
 595 sub imap_idle_requeue ($) { # DS::add_timer callback
 596         my ($self, $url_intvl) = @{$_[0]};
 597         return if $self->{quit};
 598         push @{$self->{idle_todo}}, $url_intvl;
 599         event_step($self);
 600 }
 601
 602 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 603         my ($self, $pid) = @_;
 604         my $url_intvl = delete $self->{idle_pids}->{$pid} or
 605                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 606
 607         my ($url, $intvl) = @$url_intvl;
 608         return if $self->{quit};
 609         warn "W: PID=$pid on $url died: \$?=$?\n" if $?;
 610         PublicInbox::DS::add_timer(60,
 611                                 \&imap_idle_requeue, [ $self, $url_intvl ]);
 612 }
 613
 614 sub reap { # callback for EOFpipe
 615         my ($pid, $cb, $self) = @{$_[0]};
 616         my $ret = waitpid($pid, 0);
 617         if ($ret == $pid) {
 618                 $cb->($self, $pid); # poll_fetch_reap || imap_idle_reap
 619         } else {
 620                 warn "W: waitpid($pid) => ", $ret // "($!)", "\n";
 621         }
 622 }
 623
 624 sub imap_idle_fork ($$) {
 625         my ($self, $url_intvl) = @_;
 626         my ($url, $intvl) = @$url_intvl;
 627         pipe(my ($r, $w)) or die "pipe: $!";
 628         my $seed = rand(0xffffffff);
 629         my $pid = fork // die "fork: $!";
 630         if ($pid == 0) {
 631                 srand($seed);
 632                 eval { Net::SSLeay::randomize() };
 633                 close $r;
 634                 watch_atfork_child($self);
 635                 watch_imap_idle_1($self, $url, $intvl);
 636                 close $w;
 637                 _exit(0);
 638         }
 639         $self->{idle_pids}->{$pid} = $url_intvl;
 640         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&imap_idle_reap, $self]);
 641 }
 642
 643 sub event_step {
 644         my ($self) = @_;
 645         return if $self->{quit};
 646         my $idle_todo = $self->{idle_todo};
 647         if ($idle_todo && @$idle_todo) {
 648                 my $oldset = watch_atfork_parent($self);
 649                 eval {
 650                         while (my $url_intvl = shift(@$idle_todo)) {
 651                                 imap_idle_fork($self, $url_intvl);
 652                         }
 653                 };
 654                 PublicInbox::DS::sig_setmask($oldset);
 655                 die $@ if $@;
 656         }
 657         fs_scan_step($self) if $self->{mdre};
 658 }
 659
 660 sub watch_imap_fetch_all ($$) {
 661         my ($self, $urls) = @_;
 662         for my $url (@$urls) {
 663                 my $uri = PublicInbox::URIimap->new($url);
 664                 my $sec = uri_section($uri);
 665                 my $mic_arg = $self->{mic_arg}->{$sec} or
 666                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 667                 my $mic = PublicInbox::IMAPClient->new(%$mic_arg) or next;
 668                 my $err = imap_fetch_all($self, $mic, $url);
 669                 last if $self->{quit};
 670                 warn $err, "\n" if $err;
 671         }
 672 }
 673
 674 sub watch_nntp_fetch_all ($$) {
 675         my ($self, $urls) = @_;
 676         for my $url (@$urls) {
 677                 my $uri = uri_new($url);
 678                 my $sec = uri_section($uri);
 679                 my $nn_arg = $self->{nn_arg}->{$sec} or
 680                         die "BUG: no Net::NNTP->new arg for $sec";
 681                 my $nntp_opt = $self->{nntp_opt}->{$sec};
 682                 my $nn = nn_new($nn_arg, $nntp_opt, $url);
 683                 unless ($nn) {
 684                         warn "E: $url: \$!=$!\n";
 685                         next;
 686                 }
 687                 last if $self->{quit};
 688                 if (my $postconn = $nntp_opt->{-postconn}) {
 689                         for my $m_arg (@$postconn) {
 690                                 my ($method, @args) = @$m_arg;
 691                                 $nn->$method(@args) and next;
 692                                 warn "E: <$url> $method failed\n";
 693                                 $nn = undef;
 694                                 last;
 695                         }
 696                 }
 697                 last if $self->{quit};
 698                 if ($nn) {
 699                         my $err = nntp_fetch_all($self, $nn, $url);
 700                         warn $err, "\n" if $err;
 701                 }
 702         }
 703 }
 704
 705 sub poll_fetch_fork ($) { # DS::add_timer callback
 706         my ($self, $intvl, $urls) = @{$_[0]};
 707         return if $self->{quit};
 708         pipe(my ($r, $w)) or die "pipe: $!";
 709         my $oldset = watch_atfork_parent($self);
 710         my $seed = rand(0xffffffff);
 711         my $pid = fork;
 712         if (defined($pid) && $pid == 0) {
 713                 srand($seed);
 714                 eval { Net::SSLeay::randomize() };
 715                 close $r;
 716                 watch_atfork_child($self);
 717                 if ($urls->[0] =~ m!\Aimaps?://!i) {
 718                         watch_imap_fetch_all($self, $urls);
 719                 } else {
 720                         watch_nntp_fetch_all($self, $urls);
 721                 }
 722                 close $w;
 723                 _exit(0);
 724         }
 725         PublicInbox::DS::sig_setmask($oldset);
 726         die "fork: $!"  unless defined $pid;
 727         $self->{poll_pids}->{$pid} = [ $intvl, $urls ];
 728         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&poll_fetch_reap, $self]);
 729 }
 730
 731 sub poll_fetch_reap {
 732         my ($self, $pid) = @_;
 733         my $intvl_urls = delete $self->{poll_pids}->{$pid} or
 734                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 735         return if $self->{quit};
 736         my ($intvl, $urls) = @$intvl_urls;
 737         if ($?) {
 738                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$urls;
 739         }
 740         warn("I: will check $_ in ${intvl}s\n") for @$urls;
 741         PublicInbox::DS::add_timer($intvl, \&poll_fetch_fork,
 742                                         [$self, $intvl, $urls]);
 743 }
 744
 745 sub watch_imap_init ($$) {
 746         my ($self, $poll) = @_;
 747         eval { require PublicInbox::IMAPClient } or
 748                 die "Mail::IMAPClient is required for IMAP:\n$@\n";
 749         eval { require PublicInbox::IMAPTracker } or
 750                 die "DBD::SQLite is required for IMAP\n:$@\n";
 751
 752         my $mic_args = imap_common_init($self); # read args from config
 753
 754         # make sure we can connect and cache the credentials in memory
 755         $self->{mic_arg} = {}; # schema://authority => IMAPClient->new args
 756         my $mics = {}; # schema://authority => IMAPClient obj
 757         for my $url (sort keys %{$self->{imap}}) {
 758                 my $uri = PublicInbox::URIimap->new($url);
 759                 $mics->{uri_section($uri)} //= mic_for($self, $url, $mic_args);
 760         }
 761
 762         my $idle = []; # [ [ url1, intvl1 ], [url2, intvl2] ]
 763         for my $url (keys %{$self->{imap}}) {
 764                 my $uri = PublicInbox::URIimap->new($url);
 765                 my $sec = uri_section($uri);
 766                 my $mic = $mics->{$sec};
 767                 my $intvl = $self->{imap_opt}->{$sec}->{pollInterval};
 768                 if ($mic->has_capability('IDLE') && !$intvl) {
 769                         $intvl = $self->{imap_opt}->{$sec}->{idleInterval};
 770                         push @$idle, [ $url, $intvl // () ];
 771                 } else {
 772                         push @{$poll->{$intvl || 120}}, $url;
 773                 }
 774         }
 775         if (scalar @$idle) {
 776                 $self->{idle_todo} = $idle;
 777                 PublicInbox::DS::requeue($self); # ->event_step to fork
 778         }
 779 }
 780
 781 # flesh out common NNTP-specific data structures
 782 sub nntp_common_init ($) {
 783         my ($self) = @_;
 784         my $cfg = $self->{pi_cfg};
 785         my $nn_args = {}; # scheme://authority => Net::NNTP->new arg
 786         for my $url (sort keys %{$self->{nntp}}) {
 787                 my $sec = uri_section(uri_new($url));
 788
 789                 # Debug and Timeout are passed to Net::NNTP->new
 790                 my $v = cfg_bool($cfg, 'nntp.Debug', $url);
 791                 $nn_args->{$sec}->{Debug} = $v if defined $v;
 792                 my $to = cfg_intvl($cfg, 'nntp.Timeout', $url);
 793                 $nn_args->{$sec}->{Timeout} = $to if $to;
 794
 795                 # Net::NNTP post-connect commands
 796                 for my $k (qw(starttls compress)) {
 797                         $v = cfg_bool($cfg, "nntp.$k", $url) // next;
 798                         $self->{nntp_opt}->{$sec}->{$k} = $v;
 799                 }
 800
 801                 # internal option
 802                 for my $k (qw(pollInterval)) {
 803                         $to = cfg_intvl($cfg, "nntp.$k", $url) // next;
 804                         $self->{nntp_opt}->{$sec}->{$k} = $to;
 805                 }
 806         }
 807         $nn_args;
 808 }
 809
 810 # Net::NNTP doesn't support CAPABILITIES, yet
 811 sub try_starttls ($) {
 812         my ($host) = @_;
 813         return if $host =~ /\.onion\z/s;
 814         return if $host =~ /\A127\.[0-9]+\.[0-9]+\.[0-9]+\z/s;
 815         return if $host eq '::1';
 816         1;
 817 }
 818
 819 sub nn_new ($$$) {
 820         my ($nn_arg, $nntp_opt, $url) = @_;
 821         my $nn = Net::NNTP->new(%$nn_arg) or die "E: <$url> new: $!\n";
 822
 823         # default to using STARTTLS if it's available, but allow
 824         # it to be disabled for localhost/VPN users
 825         if (!$nn_arg->{SSL} && $nn->can('starttls')) {
 826                 if (!defined($nntp_opt->{starttls}) &&
 827                                 try_starttls($nn_arg->{Host})) {
 828                         # soft fail by default
 829                         $nn->starttls or warn <<"";
 830 W: <$url> STARTTLS tried and failed (not requested)
 831
 832                 } elsif ($nntp_opt->{starttls}) {
 833                         # hard fail if explicitly configured
 834                         $nn->starttls or die <<"";
 835 E: <$url> STARTTLS requested and failed
 836
 837                 }
 838         } elsif ($nntp_opt->{starttls}) {
 839                 $nn->can('starttls') or
 840                         die "E: <$url> Net::NNTP too old for STARTTLS\n";
 841                 $nn->starttls or die <<"";
 842 E: <$url> STARTTLS requested and failed
 843
 844         }
 845         $nn;
 846 }
 847
 848 sub nn_for ($$$) { # nn = Net::NNTP
 849         my ($self, $url, $nn_args) = @_;
 850         my $uri = uri_new($url);
 851         my $sec = uri_section($uri);
 852         my $nntp_opt = $self->{nntp_opt}->{$sec} //= {};
 853         my $host = $uri->host;
 854         # Net::NNTP and Net::Netrc both mishandle `0', so we pass `127.0.0.1'
 855         $host = '127.0.0.1' if $host eq '0';
 856         my $cred;
 857         my ($u, $p);
 858         if (defined(my $ui = $uri->userinfo)) {
 859                 require PublicInbox::GitCredential;
 860                 $cred = bless {
 861                         url => $sec,
 862                         protocol => uri_scheme($uri),
 863                         host => $host,
 864                 }, 'PublicInbox::GitCredential';
 865                 ($u, $p) = split(/:/, $ui, 2);
 866                 ($cred->{username}, $cred->{password}) = ($u, $p);
 867                 $cred->check_netrc unless defined $p;
 868         }
 869         my $common = $nn_args->{$sec} // {};
 870         my $nn_arg = {
 871                 Port => $uri->port,
 872                 Host => $host,
 873                 SSL => $uri->secure, # snews == nntps
 874                 %$common, # may Debug ....
 875         };
 876         my $nn = nn_new($nn_arg, $nntp_opt, $url);
 877
 878         if ($cred) {
 879                 $cred->fill; # may prompt user here
 880                 if ($nn->authinfo($u, $p)) {
 881                         push @{$nntp_opt->{-postconn}}, [ 'authinfo', $u, $p ];
 882                 } else {
 883                         warn "E: <$url> AUTHINFO $u XXXX failed\n";
 884                         $nn = undef;
 885                 }
 886         }
 887
 888         if ($nntp_opt->{compress}) {
 889                 # https://rt.cpan.org/Ticket/Display.html?id=129967
 890                 if ($nn->can('compress')) {
 891                         if ($nn->compress) {
 892                                 push @{$nntp_opt->{-postconn}}, [ 'compress' ];
 893                         } else {
 894                                 warn "W: <$url> COMPRESS failed\n";
 895                         }
 896                 } else {
 897                         delete $nntp_opt->{compress};
 898                         warn <<"";
 899 W: <$url> COMPRESS not supported by Net::NNTP
 900 W: see https://rt.cpan.org/Ticket/Display.html?id=129967 for updates
 901
 902                 }
 903         }
 904
 905         $self->{nn_arg}->{$sec} = $nn_arg;
 906         $cred->run($nn ? 'approve' : 'reject') if $cred;
 907         $nn;
 908 }
 909
 910 sub nntp_fetch_all ($$$) {
 911         my ($self, $nn, $url) = @_;
 912         my $uri = uri_new($url);
 913         my ($group, $num_a, $num_b) = $uri->group;
 914         my $sec = uri_section($uri);
 915         my ($nr, $beg, $end) = $nn->group($group);
 916         unless (defined($nr)) {
 917                 chomp(my $msg = $nn->message);
 918                 return "E: GROUP $group <$sec> $msg";
 919         }
 920
 921         # IMAPTracker is also used for tracking NNTP, UID == article number
 922         # LIST.ACTIVE can get the equivalent of UIDVALIDITY, but that's
 923         # expensive.  So we assume newsgroups don't change:
 924         my $itrk = PublicInbox::IMAPTracker->new($url);
 925         my (undef, $l_art) = $itrk->get_last;
 926         $l_art //= $beg; # initial import
 927
 928         # allow users to specify articles to refetch
 929         # cf. https://tools.ietf.org/id/draft-gilman-news-url-01.txt
 930         # nntp://example.com/inbox.foo/$num_a-$num_b
 931         $l_art = $num_a if defined($num_a) && $num_a < $l_art;
 932         $end = $num_b if defined($num_b) && $num_b < $end;
 933
 934         return if $l_art >= $end; # nothing to do
 935         $beg = $l_art + 1;
 936
 937         warn "I: $url fetching ARTICLE $beg..$end\n";
 938         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 939         my ($err, $art);
 940         local $SIG{__WARN__} = sub {
 941                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 942                 $warn_cb->("$pfx$url ", $art ? ("ARTICLE $art") : (), "\n", @_);
 943         };
 944         my $inboxes = $self->{nntp}->{$url};
 945         my $last_art;
 946         my $n = $self->{max_batch};
 947         for ($beg..$end) {
 948                 last if $self->{quit};
 949                 $art = $_;
 950                 if (--$n < 0) {
 951                         _done_for_now($self);
 952                         $itrk->update_last(0, $last_art);
 953                         $n = $self->{max_batch};
 954                 }
 955                 my $raw = $nn->article($art);
 956                 unless (defined($raw)) {
 957                         my $msg = $nn->message;
 958                         if ($nn->code == 421) { # pseudo response from Net::Cmd
 959                                 $err = "E: $msg";
 960                                 last;
 961                         } else { # probably just a deleted message (spam)
 962                                 warn "W: $msg";
 963                                 next;
 964                         }
 965                 }
 966                 s/\r\n/\n/ for @$raw;
 967                 $raw = join('', @$raw);
 968                 if (ref($inboxes)) {
 969                         for my $ibx (@$inboxes) {
 970                                 my $eml = PublicInbox::Eml->new($raw);
 971                                 import_eml($self, $ibx, $eml);
 972                         }
 973                 } elsif ($inboxes eq 'watchspam') {
 974                         my $eml = PublicInbox::Eml->new(\$raw);
 975                         $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 976                                         $self, $eml, "$url ARTICLE $art");
 977                 } else {
 978                         die "BUG: destination unknown $inboxes";
 979                 }
 980                 $last_art = $art;
 981         }
 982         _done_for_now($self);
 983         $itrk->update_last(0, $last_art);
 984         $err;
 985 }
 986
 987 sub watch_nntp_init ($$) {
 988         my ($self, $poll) = @_;
 989         eval { require Net::NNTP } or
 990                 die "Net::NNTP is required for NNTP:\n$@\n";
 991         eval { require PublicInbox::IMAPTracker } or
 992                 die "DBD::SQLite is required for NNTP\n:$@\n";
 993
 994         my $nn_args = nntp_common_init($self); # read args from config
 995
 996         # make sure we can connect and cache the credentials in memory
 997         $self->{nn_arg} = {}; # schema://authority => Net::NNTP->new args
 998         for my $url (sort keys %{$self->{nntp}}) {
 999                 nn_for($self, $url, $nn_args);
1000         }
1001         for my $url (keys %{$self->{nntp}}) {
1002                 my $uri = uri_new($url);
1003                 my $sec = uri_section($uri);
1004                 my $intvl = $self->{nntp_opt}->{$sec}->{pollInterval};
1005                 push @{$poll->{$intvl || 120}}, $url;
1006         }
1007 }
1008
1009 sub watch { # main entry point
1010         my ($self, $sig, $oldset) = @_;
1011         $self->{oldset} = $oldset;
1012         $self->{sig} = $sig;
1013         my $poll = {}; # intvl_seconds => [ url1, url2 ]
1014         watch_imap_init($self, $poll) if $self->{imap};
1015         watch_nntp_init($self, $poll) if $self->{nntp};
1016         while (my ($intvl, $urls) = each %$poll) {
1017                 # poll all URLs for a given interval sequentially
1018                 PublicInbox::DS::add_timer(0, \&poll_fetch_fork,
1019                                                 [$self, $intvl, $urls]);
1020         }
1021         watch_fs_init($self) if $self->{mdre};
1022         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
1023         PublicInbox::DS->EventLoop; # calls ->event_step
1024         _done_for_now($self);
1025 }
1026
1027 sub trigger_scan {
1028         my ($self, $op) = @_;
1029         push @{$self->{ops}}, $op;
1030         PublicInbox::DS::requeue($self);
1031 }
1032
1033 sub fs_scan_step {
1034         my ($self) = @_;
1035         return if $self->{quit};
1036         my $op = shift @{$self->{ops}};
1037         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
1038
1039         # continue existing scan
1040         my $opendirs = $self->{opendirs};
1041         my @dirnames = keys %$opendirs;
1042         foreach my $dir (@dirnames) {
1043                 my $dh = delete $opendirs->{$dir};
1044                 my $n = $self->{max_batch};
1045                 while (my $fn = readdir($dh)) {
1046                         _try_path($self, "$dir/$fn");
1047                         last if --$n < 0;
1048                 }
1049                 $opendirs->{$dir} = $dh if $n < 0;
1050         }
1051         if ($op && $op eq 'full') {
1052                 foreach my $dir (keys %{$self->{mdmap}}) {
1053                         next if $opendirs->{$dir}; # already in progress
1054                         my $ok = opendir(my $dh, $dir);
1055                         unless ($ok) {
1056                                 warn "failed to open $dir: $!\n";
1057                                 next;
1058                         }
1059                         my $n = $self->{max_batch};
1060                         while (my $fn = readdir($dh)) {
1061                                 _try_path($self, "$dir/$fn");
1062                                 last if --$n < 0;
1063                         }
1064                         $opendirs->{$dir} = $dh if $n < 0;
1065                 }
1066         }
1067         _done_for_now($self);
1068         # do we have more work to do?
1069         PublicInbox::DS::requeue($self) if keys %$opendirs;
1070 }
1071
1072 sub scan {
1073         my ($self, $op) = @_;
1074         push @{$self->{ops}}, $op;
1075         fs_scan_step($self);
1076 }
1077
1078 sub _importer_for {
1079         my ($self, $ibx) = @_;
1080         my $importers = $self->{importers};
1081         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
1082         if (scalar(keys(%$importers)) > 2) {
1083                 delete $importers->{"$ibx"};
1084                 _done_for_now($self);
1085         }
1086
1087         $importers->{"$ibx"} = $im;
1088 }
1089
1090 # XXX consider sharing with V2Writable, this only requires read-only access
1091 sub content_exists ($$) {
1092         my ($ibx, $eml) = @_;
1093         my $over = $ibx->over or return;
1094         my $mids = mids($eml);
1095         my $chash = content_hash($eml);
1096         my ($id, $prev);
1097         for my $mid (@$mids) {
1098                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1099                         my $cmp = $ibx->smsg_eml($smsg) or return;
1100                         return 1 if $chash eq content_hash($cmp);
1101                 }
1102         }
1103         undef;
1104 }
1105
1106 sub _spamcheck_cb {
1107         my ($sc) = @_;
1108         sub { # this gets called by (V2Writable||Import)->add
1109                 my ($mime, $ibx) = @_;
1110                 return if content_exists($ibx, $mime);
1111                 my $tmp = '';
1112                 if ($sc->spamcheck($mime, \$tmp)) {
1113                         return PublicInbox::Eml->new(\$tmp);
1114                 }
1115                 warn $mime->header('Message-ID')." failed spam check\n";
1116                 undef;
1117         }
1118 }
1119
1120 sub is_maildir {
1121         $_[0] =~ s!\Amaildir:!! or return;
1122         $_[0] =~ tr!/!/!s;
1123         $_[0] =~ s!/\z!!;
1124         $_[0];
1125 }
1126
1127 sub is_watchspam {
1128         my ($cur, $ws, $ibx) = @_;
1129         if ($ws && !ref($ws) && $ws eq 'watchspam') {
1130                 warn <<EOF;
1131 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
1132 EOF
1133                 return 1;
1134         }
1135         undef;
1136 }
1137
1138 sub uri_new {
1139         my ($url) = @_;
1140
1141         # URI::snews exists, URI::nntps does not, so use URI::snews
1142         $url =~ s!\Anntps://!snews://!i;
1143         URI->new($url);
1144 }
1145
1146 sub imap_url {
1147         my ($url) = @_;
1148         require PublicInbox::URIimap;
1149         my $uri = PublicInbox::URIimap->new($url);
1150         $uri ? $uri->canonical->as_string : undef;
1151 }
1152
1153 my %IS_NNTP = (news => 1, snews => 1, nntp => 1);
1154 sub nntp_url {
1155         my ($url) = @_;
1156         require URI;
1157         my $uri = uri_new($url);
1158         return unless $uri && $IS_NNTP{$uri->scheme} && $uri->group;
1159         $url = $uri->canonical->as_string;
1160         # nntps is IANA registered, snews is deprecated
1161         $url =~ s!\Asnews://!nntps://!;
1162         $url;
1163 }
1164
1165 1;