lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       https://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path);
  11 use PublicInbox::MdirReader;
  12 use PublicInbox::NetReader;
  13 use PublicInbox::Filter::Base qw(REJECT);
  14 use PublicInbox::Spamcheck;
  15 use PublicInbox::Sigfd;
  16 use PublicInbox::DS qw(now add_timer);
  17 use PublicInbox::MID qw(mids);
  18 use PublicInbox::ContentHash qw(content_hash);
  19 use PublicInbox::EOFpipe;
  20 use POSIX qw(_exit WNOHANG);
  21
  22 sub compile_watchheaders ($) {
  23         my ($ibx) = @_;
  24         my $watch_hdrs = [];
  25         if (my $whs = $ibx->{watchheader}) {
  26                 for (@$whs) {
  27                         my ($k, $v) = split(/:/, $_, 2);
  28                         # XXX should this be case-insensitive?
  29                         # Or, mutt-style, case-sensitive iff
  30                         # a capital letter exists?
  31                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  32                 }
  33         }
  34         if (my $list_ids = $ibx->{listid}) {
  35                 for (@$list_ids) {
  36                         # RFC2919 section 6 stipulates
  37                         # "case insensitive equality"
  38                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  39                         push @$watch_hdrs, ['List-Id', $re ];
  40                 }
  41         }
  42         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  43 }
  44
  45 sub new {
  46         my ($class, $cfg) = @_;
  47         my (%mdmap, $spamc);
  48         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  49         my (@imap, @nntp);
  50
  51         # "publicinboxwatch" is the documented namespace
  52         # "publicinboxlearn" is legacy but may be supported
  53         # indefinitely...
  54         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  55                 my $k = "$pfx.watchspam";
  56                 my $dirs = $cfg->get_all($k) // next;
  57                 for my $dir (@$dirs) {
  58                         my $uri;
  59                         if (is_maildir($dir)) {
  60                                 # skip "new", no MUA has seen it, yet.
  61                                 $mdmap{"$dir/cur"} = 'watchspam';
  62                         } elsif ($uri = imap_uri($dir)) {
  63                                 $imap{$$uri} = 'watchspam';
  64                                 push @imap, $uri;
  65                         } elsif ($uri = nntp_uri($dir)) {
  66                                 $nntp{$$uri} = 'watchspam';
  67                                 push @nntp, $uri;
  68                         } else {
  69                                 warn "unsupported $k=$dir\n";
  70                         }
  71                 }
  72         }
  73
  74         my $k = 'publicinboxwatch.spamcheck';
  75         my $default = undef;
  76         my $spamcheck = PublicInbox::Spamcheck::get($cfg, $k, $default);
  77         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  78
  79         $cfg->each_inbox(sub {
  80                 # need to make all inboxes writable for spam removal:
  81                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  82
  83                 my $watches = $ibx->{watch} or return;
  84                 $watches = PublicInbox::Config::_array($watches);
  85                 for my $watch (@$watches) {
  86                         my $uri;
  87                         if (is_maildir($watch)) {
  88                                 compile_watchheaders($ibx);
  89                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  90                                 my $cur_dst = $mdmap{$cur} //= [];
  91                                 return if is_watchspam($cur, $cur_dst, $ibx);
  92                                 push @{$mdmap{$new} //= []}, $ibx;
  93                                 push @$cur_dst, $ibx;
  94                         } elsif ($uri = imap_uri($watch)) {
  95                                 my $cur_dst = $imap{$$uri} //= [];
  96                                 return if is_watchspam($uri, $cur_dst, $ibx);
  97                                 compile_watchheaders($ibx);
  98                                 push(@imap, $uri) if 1 == push(@$cur_dst, $ibx);
  99                         } elsif ($uri = nntp_uri($watch)) {
 100                                 my $cur_dst = $nntp{$$uri} //= [];
 101                                 return if is_watchspam($uri, $cur_dst, $ibx);
 102                                 compile_watchheaders($ibx);
 103                                 push(@nntp, $uri) if 1 == push(@$cur_dst, $ibx);
 104                         } else {
 105                                 warn "watch unsupported: $k=$watch\n";
 106                         }
 107                 }
 108         });
 109
 110         my $mdre;
 111         if (scalar keys %mdmap) {
 112                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 113                 $mdre = qr!\A($mdre)/!;
 114         }
 115         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 116
 117         bless {
 118                 max_batch => 10, # avoid hogging locks for too long
 119                 spamcheck => $spamcheck,
 120                 mdmap => \%mdmap,
 121                 mdre => $mdre,
 122                 pi_cfg => $cfg,
 123                 imap => scalar keys %imap ? \%imap : undef,
 124                 nntp => scalar keys %nntp? \%nntp : undef,
 125                 imap_order => scalar(@imap) ? \@imap : undef,
 126                 nntp_order => scalar(@nntp) ? \@nntp: undef,
 127                 importers => {},
 128                 opendirs => {}, # dirname => dirhandle (in progress scans)
 129                 ops => [], # 'quit', 'full'
 130         }, $class;
 131 }
 132
 133 sub _done_for_now {
 134         my ($self) = @_;
 135         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 136         for my $im (values %{$self->{importers}}) {
 137                 next if !$im; # $im may be undef during cleanup
 138                 eval { $im->done };
 139                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 140         }
 141 }
 142
 143 sub remove_eml_i { # each_inbox callback
 144         my ($ibx, $self, $eml, $loc) = @_;
 145
 146         eval {
 147                 # try to avoid taking a lock or unnecessary spawning
 148                 my $im = $self->{importers}->{"$ibx"};
 149                 my $scrubbed;
 150                 if ((!$im || !$im->active) && $ibx->over) {
 151                         if (content_exists($ibx, $eml)) {
 152                                 # continue
 153                         } elsif (my $scrub = $ibx->filter($im)) {
 154                                 $scrubbed = $scrub->scrub($eml, 1);
 155                                 if ($scrubbed && $scrubbed != REJECT &&
 156                                           !content_exists($ibx, $scrubbed)) {
 157                                         return;
 158                                 }
 159                         } else {
 160                                 return;
 161                         }
 162                 }
 163
 164                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 165                 $im->remove($eml, 'spam');
 166                 $scrubbed //= do {
 167                         my $scrub = $ibx->filter($im);
 168                         $scrub ? $scrub->scrub($eml, 1) : undef;
 169                 };
 170                 if ($scrubbed && $scrubbed != REJECT) {
 171                         $im->remove($scrubbed, 'spam');
 172                 }
 173         };
 174         if ($@) {
 175                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 176                 _done_for_now($self);
 177         }
 178 }
 179
 180 sub _remove_spam {
 181         my ($self, $path) = @_;
 182         # path must be marked as (S)een
 183         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 184         my $eml = eml_from_path($path) or return;
 185         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 186         $self->{pi_cfg}->each_inbox(\&remove_eml_i, $self, $eml, $path);
 187 }
 188
 189 sub import_eml ($$$) {
 190         my ($self, $ibx, $eml) = @_;
 191
 192         # any header match means it's eligible for the inbox:
 193         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 194                 my $ok;
 195                 for my $wh (@$watch_hdrs) {
 196                         my @v = $eml->header_raw($wh->[0]);
 197                         $ok = grep(/$wh->[1]/, @v) and last;
 198                 }
 199                 return unless $ok;
 200         }
 201         eval {
 202                 my $im = _importer_for($self, $ibx);
 203                 if (my $scrub = $ibx->filter($im)) {
 204                         my $scrubbed = $scrub->scrub($eml) or return;
 205                         $scrubbed == REJECT and return;
 206                         $eml = $scrubbed;
 207                 }
 208                 $im->add($eml, $self->{spamcheck});
 209         };
 210         if ($@) {
 211                 warn "$ibx->{name} add failed: $@\n";
 212                 _done_for_now($self);
 213         }
 214 }
 215
 216 sub _try_path {
 217         my ($self, $path) = @_;
 218         my $fl = PublicInbox::MdirReader::maildir_path_flags($path) // return;
 219         return if $fl =~ /[DT]/; # no Drafts or Trash
 220         if ($path !~ $self->{mdre}) {
 221                 warn "unrecognized path: $path\n";
 222                 return;
 223         }
 224         my $inboxes = $self->{mdmap}->{$1};
 225         unless ($inboxes) {
 226                 warn "unmappable dir: $1\n";
 227                 return;
 228         }
 229         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 230         local $SIG{__WARN__} = sub {
 231                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 232                 $warn_cb->($pfx, "path: $path\n", @_);
 233         };
 234         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 235                 return _remove_spam($self, $path);
 236         }
 237         foreach my $ibx (@$inboxes) {
 238                 my $eml = eml_from_path($path) or next;
 239                 import_eml($self, $ibx, $eml);
 240         }
 241 }
 242
 243 sub quit_done ($) {
 244         my ($self) = @_;
 245         return unless $self->{quit};
 246
 247         # don't have reliable wakeups, keep signalling
 248         my $done = 1;
 249         for (qw(idle_pids poll_pids)) {
 250                 my $pids = $self->{$_} or next;
 251                 for (keys %$pids) {
 252                         $done = undef if kill('QUIT', $_);
 253                 }
 254         }
 255         $done;
 256 }
 257
 258 sub quit {
 259         my ($self) = @_;
 260         $self->{quit} = 1;
 261         %{$self->{opendirs}} = ();
 262         _done_for_now($self);
 263         quit_done($self);
 264         if (my $idle_mic = $self->{idle_mic}) {
 265                 eval { $idle_mic->done };
 266                 if ($@) {
 267                         warn "IDLE DONE error: $@\n";
 268                         eval { $idle_mic->disconnect };
 269                         warn "IDLE LOGOUT error: $@\n" if $@;
 270                 }
 271         }
 272 }
 273
 274 sub watch_fs_init ($) {
 275         my ($self) = @_;
 276         my $done = sub {
 277                 delete $self->{done_timer};
 278                 _done_for_now($self);
 279         };
 280         my $cb = sub { # called by PublicInbox::DirIdle::event_step
 281                 _try_path($self, $_[0]->fullname);
 282                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 283         };
 284         require PublicInbox::DirIdle;
 285         # inotify_create + EPOLL_CTL_ADD
 286         PublicInbox::DirIdle->new([keys %{$self->{mdmap}}], $cb);
 287 }
 288
 289 sub net_cb { # NetReader::(nntp|imap)_each callback
 290         my ($uri, $art, $kw, $eml, $self, $inboxes) = @_;
 291         return if grep(/\Adraft\z/, @$kw);
 292         local $self->{cur_uid} = $art; # IMAP UID or NNTP article
 293         if (ref($inboxes)) {
 294                 my @ibx = @$inboxes;
 295                 my $last = pop @ibx;
 296                 for my $ibx (@ibx) {
 297                         my $tmp = PublicInbox::Eml->new(\($eml->as_string));
 298                         import_eml($self, $ibx, $tmp);
 299                 }
 300                 import_eml($self, $last, $eml);
 301         } elsif ($inboxes eq 'watchspam') {
 302                 if ($uri->scheme =~ /\Aimaps?\z/ && !grep(/\Aseen\z/, @$kw)) {
 303                         return;
 304                 }
 305                 $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 306                                 $self, $eml, "$uri #$art");
 307         } else {
 308                 die "BUG: destination unknown $inboxes";
 309         }
 310 }
 311
 312 sub imap_fetch_all ($$) {
 313         my ($self, $uri) = @_;
 314         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 315         $self->{incremental} = 1;
 316         $self->{on_commit} = [ \&_done_for_now, $self ];
 317         local $self->{cur_uid};
 318         local $SIG{__WARN__} = sub {
 319                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 320                 my $uid = $self->{cur_uid};
 321                 $warn_cb->("$pfx$uri", $uid ? ("UID:$uid") : (), "\n", @_);
 322         };
 323         PublicInbox::NetReader::imap_each($self, $uri, \&net_cb, $self,
 324                                         $self->{imap}->{$$uri});
 325 }
 326
 327 sub imap_idle_once ($$$$) {
 328         my ($self, $mic, $intvl, $uri) = @_;
 329         my $i = $intvl //= (29 * 60);
 330         my $end = now() + $intvl;
 331         warn "I: $uri idling for ${intvl}s\n";
 332         local $0 = "IDLE $0";
 333         unless ($mic->idle) {
 334                 return if $self->{quit};
 335                 return "E: IDLE failed on $uri: $!";
 336         }
 337         $self->{idle_mic} = $mic; # for ->quit
 338         my @res;
 339         until ($self->{quit} || !$mic->IsConnected ||
 340                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 341                 @res = $mic->idle_data($i);
 342                 $i = $end - now();
 343         }
 344         delete $self->{idle_mic};
 345         unless ($self->{quit}) {
 346                 $mic->IsConnected or return "E: IDLE disconnected on $uri";
 347                 $mic->done or return "E: IDLE DONE failed on $uri: $!";
 348         }
 349         undef;
 350 }
 351
 352 # idles on a single URI
 353 sub watch_imap_idle_1 ($$$) {
 354         my ($self, $uri, $intvl) = @_;
 355         my $sec = uri_section($uri);
 356         my $mic_arg = $self->{net_arg}->{$sec} or
 357                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 358         my $mic;
 359         local $0 = $uri->mailbox." $sec";
 360         until ($self->{quit}) {
 361                 $mic //= PublicInbox::NetReader::mic_new(
 362                                         $self, $mic_arg, $sec, $uri);
 363                 my $err;
 364                 if ($mic && $mic->IsConnected) {
 365                         local $self->{mics_cached}->{$sec} = $mic;
 366                         my $m = imap_fetch_all($self, $uri);
 367                         $m == $mic or die "BUG: wrong mic";
 368                         $mic->IsConnected and
 369                                 $err = imap_idle_once($self, $mic, $intvl, $uri)
 370                 } else {
 371                         $err = "E: not connected: $!";
 372                 }
 373                 if ($err && !$self->{quit}) {
 374                         warn $err, "\n";
 375                         $mic = undef;
 376                         sleep 60 unless $self->{quit};
 377                 }
 378         }
 379 }
 380
 381 sub watch_atfork_child ($) {
 382         my ($self) = @_;
 383         delete $self->{idle_pids};
 384         delete $self->{poll_pids};
 385         delete $self->{opendirs};
 386         PublicInbox::DS->Reset;
 387         %SIG = (%SIG, %{$self->{sig}}, CHLD => 'DEFAULT');
 388         PublicInbox::DS::sig_setmask($self->{oldset});
 389 }
 390
 391 sub watch_atfork_parent ($) {
 392         my ($self) = @_;
 393         _done_for_now($self);
 394         PublicInbox::DS::block_signals();
 395 }
 396
 397 sub imap_idle_requeue { # DS::add_timer callback
 398         my ($self, $uri_intvl) = @_;
 399         return if $self->{quit};
 400         push @{$self->{idle_todo}}, $uri_intvl;
 401         event_step($self);
 402 }
 403
 404 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 405         my ($self, $pid) = @_;
 406         my $uri_intvl = delete $self->{idle_pids}->{$pid} or
 407                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 408
 409         my ($uri, $intvl) = @$uri_intvl;
 410         return if $self->{quit};
 411         warn "W: PID=$pid on $uri died: \$?=$?\n" if $?;
 412         add_timer(60, \&imap_idle_requeue, $self, $uri_intvl);
 413 }
 414
 415 sub reap { # callback for EOFpipe
 416         my ($pid, $cb, $self) = @{$_[0]};
 417         my $ret = waitpid($pid, 0);
 418         if ($ret == $pid) {
 419                 $cb->($self, $pid); # poll_fetch_reap || imap_idle_reap
 420         } else {
 421                 warn "W: waitpid($pid) => ", $ret // "($!)", "\n";
 422         }
 423 }
 424
 425 sub imap_idle_fork ($$) {
 426         my ($self, $uri_intvl) = @_;
 427         my ($uri, $intvl) = @$uri_intvl;
 428         pipe(my ($r, $w)) or die "pipe: $!";
 429         my $seed = rand(0xffffffff);
 430         my $pid = fork // die "fork: $!";
 431         if ($pid == 0) {
 432                 srand($seed);
 433                 eval { Net::SSLeay::randomize() };
 434                 close $r;
 435                 watch_atfork_child($self);
 436                 watch_imap_idle_1($self, $uri, $intvl);
 437                 close $w;
 438                 _exit(0);
 439         }
 440         $self->{idle_pids}->{$pid} = $uri_intvl;
 441         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&imap_idle_reap, $self]);
 442 }
 443
 444 sub event_step {
 445         my ($self) = @_;
 446         return if $self->{quit};
 447         my $idle_todo = $self->{idle_todo};
 448         if ($idle_todo && @$idle_todo) {
 449                 my $oldset = watch_atfork_parent($self);
 450                 eval {
 451                         while (my $uri_intvl = shift(@$idle_todo)) {
 452                                 imap_idle_fork($self, $uri_intvl);
 453                         }
 454                 };
 455                 PublicInbox::DS::sig_setmask($oldset);
 456                 die $@ if $@;
 457         }
 458         fs_scan_step($self) if $self->{mdre};
 459 }
 460
 461 sub watch_imap_fetch_all ($$) {
 462         my ($self, $uris) = @_;
 463         for my $uri (@$uris) {
 464                 imap_fetch_all($self, $uri);
 465                 last if $self->{quit};
 466         }
 467 }
 468
 469 sub watch_nntp_fetch_all ($$) {
 470         my ($self, $uris) = @_;
 471         $self->{incremental} = 1;
 472         $self->{on_commit} = [ \&_done_for_now, $self ];
 473         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 474         local $self->{cur_uid};
 475         my $uri = '';
 476         local $SIG{__WARN__} = sub {
 477                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 478                 my $art = $self->{cur_uid};
 479                 $warn_cb->("$pfx$uri", $art ? ("ARTICLE $art") : (), "\n", @_);
 480         };
 481         for $uri (@$uris) {
 482                 PublicInbox::NetReader::nntp_each($self, $uri, \&net_cb, $self,
 483                                         $self->{nntp}->{$$uri});
 484                 last if $self->{quit};
 485         }
 486 }
 487
 488 sub poll_fetch_fork { # DS::add_timer callback
 489         my ($self, $intvl, $uris) = @_;
 490         return if $self->{quit};
 491         pipe(my ($r, $w)) or die "pipe: $!";
 492         my $oldset = watch_atfork_parent($self);
 493         my $seed = rand(0xffffffff);
 494         my $pid = fork;
 495         if (defined($pid) && $pid == 0) {
 496                 srand($seed);
 497                 eval { Net::SSLeay::randomize() };
 498                 close $r;
 499                 watch_atfork_child($self);
 500                 if ($uris->[0]->scheme =~ m!\Aimaps?!i) {
 501                         watch_imap_fetch_all($self, $uris);
 502                 } else {
 503                         watch_nntp_fetch_all($self, $uris);
 504                 }
 505                 close $w;
 506                 _exit(0);
 507         }
 508         PublicInbox::DS::sig_setmask($oldset);
 509         die "fork: $!"  unless defined $pid;
 510         $self->{poll_pids}->{$pid} = [ $intvl, $uris ];
 511         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&poll_fetch_reap, $self]);
 512 }
 513
 514 sub poll_fetch_reap {
 515         my ($self, $pid) = @_;
 516         my $intvl_uris = delete $self->{poll_pids}->{$pid} or
 517                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 518         return if $self->{quit};
 519         my ($intvl, $uris) = @$intvl_uris;
 520         if ($?) {
 521                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$uris;
 522         }
 523         warn("I: will check $_ in ${intvl}s\n") for @$uris;
 524         add_timer($intvl, \&poll_fetch_fork, $self, $intvl, $uris);
 525 }
 526
 527 sub watch_imap_init ($$) {
 528         my ($self, $poll) = @_;
 529         my $mics = PublicInbox::NetReader::imap_common_init($self);
 530         my $idle = []; # [ [ uri1, intvl1 ], [uri2, intvl2] ]
 531         for my $uri (@{$self->{imap_order}}) {
 532                 my $sec = uri_section($uri);
 533                 my $mic = $mics->{$sec};
 534                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 535                 if ($mic->has_capability('IDLE') && !$intvl) {
 536                         $intvl = $self->{cfg_opt}->{$sec}->{idleInterval};
 537                         push @$idle, [ $uri, $intvl // () ];
 538                 } else {
 539                         push @{$poll->{$intvl || 120}}, $uri;
 540                 }
 541         }
 542         if (scalar @$idle) {
 543                 $self->{idle_todo} = $idle;
 544                 PublicInbox::DS::requeue($self); # ->event_step to fork
 545         }
 546 }
 547
 548 sub watch_nntp_init ($$) {
 549         my ($self, $poll) = @_;
 550         PublicInbox::NetReader::nntp_common_init($self);
 551         for my $uri (@{$self->{nntp_order}}) {
 552                 my $sec = uri_section($uri);
 553                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 554                 push @{$poll->{$intvl || 120}}, $uri;
 555         }
 556 }
 557
 558 sub watch { # main entry point
 559         my ($self, $sig, $oldset) = @_;
 560         $self->{oldset} = $oldset;
 561         $self->{sig} = $sig;
 562         my $poll = {}; # intvl_seconds => [ uri1, uri2 ]
 563         watch_imap_init($self, $poll) if $self->{imap};
 564         watch_nntp_init($self, $poll) if $self->{nntp};
 565         while (my ($intvl, $uris) = each %$poll) {
 566                 # poll all URIs for a given interval sequentially
 567                 add_timer(0, \&poll_fetch_fork, $self, $intvl, $uris);
 568         }
 569         watch_fs_init($self) if $self->{mdre};
 570         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
 571         PublicInbox::DS->EventLoop; # calls ->event_step
 572         _done_for_now($self);
 573 }
 574
 575 sub trigger_scan {
 576         my ($self, $op) = @_;
 577         push @{$self->{ops}}, $op;
 578         PublicInbox::DS::requeue($self);
 579 }
 580
 581 sub fs_scan_step {
 582         my ($self) = @_;
 583         return if $self->{quit};
 584         my $op = shift @{$self->{ops}};
 585         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 586
 587         # continue existing scan
 588         my $opendirs = $self->{opendirs};
 589         my @dirnames = keys %$opendirs;
 590         foreach my $dir (@dirnames) {
 591                 my $dh = delete $opendirs->{$dir};
 592                 my $n = $self->{max_batch};
 593                 while (my $fn = readdir($dh)) {
 594                         _try_path($self, "$dir/$fn");
 595                         last if --$n < 0;
 596                 }
 597                 $opendirs->{$dir} = $dh if $n < 0;
 598         }
 599         if ($op && $op eq 'full') {
 600                 foreach my $dir (keys %{$self->{mdmap}}) {
 601                         next if $opendirs->{$dir}; # already in progress
 602                         my $ok = opendir(my $dh, $dir);
 603                         unless ($ok) {
 604                                 warn "failed to open $dir: $!\n";
 605                                 next;
 606                         }
 607                         my $n = $self->{max_batch};
 608                         while (my $fn = readdir($dh)) {
 609                                 _try_path($self, "$dir/$fn");
 610                                 last if --$n < 0;
 611                         }
 612                         $opendirs->{$dir} = $dh if $n < 0;
 613                 }
 614         }
 615         _done_for_now($self);
 616         # do we have more work to do?
 617         PublicInbox::DS::requeue($self) if keys %$opendirs;
 618 }
 619
 620 sub scan {
 621         my ($self, $op) = @_;
 622         push @{$self->{ops}}, $op;
 623         fs_scan_step($self);
 624 }
 625
 626 sub _importer_for {
 627         my ($self, $ibx) = @_;
 628         my $importers = $self->{importers};
 629         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 630         if (scalar(keys(%$importers)) > 2) {
 631                 delete $importers->{"$ibx"};
 632                 _done_for_now($self);
 633         }
 634
 635         $importers->{"$ibx"} = $im;
 636 }
 637
 638 # XXX consider sharing with V2Writable, this only requires read-only access
 639 sub content_exists ($$) {
 640         my ($ibx, $eml) = @_;
 641         my $over = $ibx->over or return;
 642         my $mids = mids($eml);
 643         my $chash = content_hash($eml);
 644         my ($id, $prev);
 645         for my $mid (@$mids) {
 646                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 647                         my $cmp = $ibx->smsg_eml($smsg) or return;
 648                         return 1 if $chash eq content_hash($cmp);
 649                 }
 650         }
 651         undef;
 652 }
 653
 654 sub _spamcheck_cb {
 655         my ($sc) = @_;
 656         sub { # this gets called by (V2Writable||Import)->add
 657                 my ($mime, $ibx) = @_;
 658                 return if content_exists($ibx, $mime);
 659                 my $tmp = '';
 660                 if ($sc->spamcheck($mime, \$tmp)) {
 661                         return PublicInbox::Eml->new(\$tmp);
 662                 }
 663                 warn $mime->header('Message-ID')." failed spam check\n";
 664                 undef;
 665         }
 666 }
 667
 668 sub is_maildir {
 669         $_[0] =~ s!\Amaildir:!! or return;
 670         $_[0] =~ tr!/!/!s;
 671         $_[0] =~ s!/\z!!;
 672         $_[0];
 673 }
 674
 675 sub is_watchspam {
 676         my ($cur, $ws, $ibx) = @_;
 677         if ($ws && !ref($ws) && $ws eq 'watchspam') {
 678                 warn <<EOF;
 679 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
 680 EOF
 681                 return 1;
 682         }
 683         undef;
 684 }
 685
 686 sub folder_select { 'select' } # for PublicInbox::NetReader
 687
 688 1;