lib/PublicInbox/Watch.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # ref: https://cr.yp.to/proto/maildir.html
   5 #       https://wiki2.dovecot.org/MailboxFormat/Maildir
   6 package PublicInbox::Watch;
   7 use strict;
   8 use v5.10.1;
   9 use PublicInbox::Eml;
  10 use PublicInbox::InboxWritable qw(eml_from_path);
  11 use PublicInbox::MdirReader;
  12 use PublicInbox::NetReader;
  13 use PublicInbox::Filter::Base qw(REJECT);
  14 use PublicInbox::Spamcheck;
  15 use PublicInbox::DS qw(now add_timer);
  16 use PublicInbox::MID qw(mids);
  17 use PublicInbox::ContentHash qw(content_hash);
  18 use PublicInbox::EOFpipe;
  19 use POSIX qw(_exit WNOHANG);
  20
  21 sub compile_watchheaders ($) {
  22         my ($ibx) = @_;
  23         my $watch_hdrs = [];
  24         if (my $whs = $ibx->{watchheader}) {
  25                 for (@$whs) {
  26                         my ($k, $v) = split(/:/, $_, 2);
  27                         # XXX should this be case-insensitive?
  28                         # Or, mutt-style, case-sensitive iff
  29                         # a capital letter exists?
  30                         push @$watch_hdrs, [ $k, qr/\Q$v\E/ ];
  31                 }
  32         }
  33         if (my $list_ids = $ibx->{listid}) {
  34                 for (@$list_ids) {
  35                         # RFC2919 section 6 stipulates
  36                         # "case insensitive equality"
  37                         my $re = qr/<[ \t]*\Q$_\E[ \t]*>/i;
  38                         push @$watch_hdrs, ['List-Id', $re ];
  39                 }
  40         }
  41         $ibx->{-watchheaders} = $watch_hdrs if scalar @$watch_hdrs;
  42 }
  43
  44 sub new {
  45         my ($class, $cfg) = @_;
  46         my (%mdmap, $spamc);
  47         my (%imap, %nntp); # url => [inbox objects] or 'watchspam'
  48         my (@imap, @nntp);
  49
  50         # "publicinboxwatch" is the documented namespace
  51         # "publicinboxlearn" is legacy but may be supported
  52         # indefinitely...
  53         foreach my $pfx (qw(publicinboxwatch publicinboxlearn)) {
  54                 my $k = "$pfx.watchspam";
  55                 my $dirs = $cfg->get_all($k) // next;
  56                 for my $dir (@$dirs) {
  57                         my $uri;
  58                         if (is_maildir($dir)) {
  59                                 # skip "new", no MUA has seen it, yet.
  60                                 $mdmap{"$dir/cur"} = 'watchspam';
  61                         } elsif ($uri = imap_uri($dir)) {
  62                                 $imap{$$uri} = 'watchspam';
  63                                 push @imap, $uri;
  64                         } elsif ($uri = nntp_uri($dir)) {
  65                                 $nntp{$$uri} = 'watchspam';
  66                                 push @nntp, $uri;
  67                         } else {
  68                                 warn "unsupported $k=$dir\n";
  69                         }
  70                 }
  71         }
  72
  73         my $k = 'publicinboxwatch.spamcheck';
  74         my $default = undef;
  75         my $spamcheck = PublicInbox::Spamcheck::get($cfg, $k, $default);
  76         $spamcheck = _spamcheck_cb($spamcheck) if $spamcheck;
  77
  78         $cfg->each_inbox(sub {
  79                 # need to make all inboxes writable for spam removal:
  80                 my $ibx = $_[0] = PublicInbox::InboxWritable->new($_[0]);
  81
  82                 my $watches = $ibx->{watch} or return;
  83                 $watches = PublicInbox::Config::_array($watches);
  84                 for my $watch (@$watches) {
  85                         my $uri;
  86                         if (is_maildir($watch)) {
  87                                 compile_watchheaders($ibx);
  88                                 my ($new, $cur) = ("$watch/new", "$watch/cur");
  89                                 my $cur_dst = $mdmap{$cur} //= [];
  90                                 return if is_watchspam($cur, $cur_dst, $ibx);
  91                                 push @{$mdmap{$new} //= []}, $ibx;
  92                                 push @$cur_dst, $ibx;
  93                         } elsif ($uri = imap_uri($watch)) {
  94                                 my $cur_dst = $imap{$$uri} //= [];
  95                                 return if is_watchspam($uri, $cur_dst, $ibx);
  96                                 compile_watchheaders($ibx);
  97                                 push(@imap, $uri) if 1 == push(@$cur_dst, $ibx);
  98                         } elsif ($uri = nntp_uri($watch)) {
  99                                 my $cur_dst = $nntp{$$uri} //= [];
 100                                 return if is_watchspam($uri, $cur_dst, $ibx);
 101                                 compile_watchheaders($ibx);
 102                                 push(@nntp, $uri) if 1 == push(@$cur_dst, $ibx);
 103                         } else {
 104                                 warn "watch unsupported: $k=$watch\n";
 105                         }
 106                 }
 107         });
 108
 109         my $mdre;
 110         if (scalar keys %mdmap) {
 111                 $mdre = join('|', map { quotemeta($_) } keys %mdmap);
 112                 $mdre = qr!\A($mdre)/!;
 113         }
 114         return unless $mdre || scalar(keys %imap) || scalar(keys %nntp);
 115
 116         bless {
 117                 max_batch => 10, # avoid hogging locks for too long
 118                 spamcheck => $spamcheck,
 119                 mdmap => \%mdmap,
 120                 mdre => $mdre,
 121                 pi_cfg => $cfg,
 122                 imap => scalar keys %imap ? \%imap : undef,
 123                 nntp => scalar keys %nntp? \%nntp : undef,
 124                 imap_order => scalar(@imap) ? \@imap : undef,
 125                 nntp_order => scalar(@nntp) ? \@nntp: undef,
 126                 importers => {},
 127                 opendirs => {}, # dirname => dirhandle (in progress scans)
 128                 ops => [], # 'quit', 'full'
 129         }, $class;
 130 }
 131
 132 sub _done_for_now {
 133         my ($self) = @_;
 134         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 135         for my $im (values %{$self->{importers}}) {
 136                 next if !$im; # $im may be undef during cleanup
 137                 eval { $im->done };
 138                 warn "$im->{ibx}->{name} ->done: $@\n" if $@;
 139         }
 140 }
 141
 142 sub remove_eml_i { # each_inbox callback
 143         my ($ibx, $self, $eml, $loc) = @_;
 144
 145         eval {
 146                 # try to avoid taking a lock or unnecessary spawning
 147                 my $im = $self->{importers}->{"$ibx"};
 148                 my $scrubbed;
 149                 if ((!$im || !$im->active) && $ibx->over) {
 150                         if (content_exists($ibx, $eml)) {
 151                                 # continue
 152                         } elsif (my $scrub = $ibx->filter($im)) {
 153                                 $scrubbed = $scrub->scrub($eml, 1);
 154                                 if ($scrubbed && $scrubbed != REJECT &&
 155                                           !content_exists($ibx, $scrubbed)) {
 156                                         return;
 157                                 }
 158                         } else {
 159                                 return;
 160                         }
 161                 }
 162
 163                 $im //= _importer_for($self, $ibx); # may spawn fast-import
 164                 $im->remove($eml, 'spam');
 165                 $scrubbed //= do {
 166                         my $scrub = $ibx->filter($im);
 167                         $scrub ? $scrub->scrub($eml, 1) : undef;
 168                 };
 169                 if ($scrubbed && $scrubbed != REJECT) {
 170                         $im->remove($scrubbed, 'spam');
 171                 }
 172         };
 173         if ($@) {
 174                 warn "error removing spam at: $loc from $ibx->{name}: $@\n";
 175                 _done_for_now($self);
 176         }
 177 }
 178
 179 sub _remove_spam {
 180         my ($self, $path) = @_;
 181         # path must be marked as (S)een
 182         $path =~ /:2,[A-R]*S[T-Za-z]*\z/ or return;
 183         my $eml = eml_from_path($path) or return;
 184         local $SIG{__WARN__} = PublicInbox::Eml::warn_ignore_cb();
 185         $self->{pi_cfg}->each_inbox(\&remove_eml_i, $self, $eml, $path);
 186 }
 187
 188 sub import_eml ($$$) {
 189         my ($self, $ibx, $eml) = @_;
 190
 191         # any header match means it's eligible for the inbox:
 192         if (my $watch_hdrs = $ibx->{-watchheaders}) {
 193                 my $ok;
 194                 for my $wh (@$watch_hdrs) {
 195                         my @v = $eml->header_raw($wh->[0]);
 196                         $ok = grep(/$wh->[1]/, @v) and last;
 197                 }
 198                 return unless $ok;
 199         }
 200         eval {
 201                 my $im = _importer_for($self, $ibx);
 202                 if (my $scrub = $ibx->filter($im)) {
 203                         my $scrubbed = $scrub->scrub($eml) or return;
 204                         $scrubbed == REJECT and return;
 205                         $eml = $scrubbed;
 206                 }
 207                 $im->add($eml, $self->{spamcheck});
 208         };
 209         if ($@) {
 210                 warn "$ibx->{name} add failed: $@\n";
 211                 _done_for_now($self);
 212         }
 213 }
 214
 215 sub _try_path {
 216         my ($self, $path) = @_;
 217         my $fl = PublicInbox::MdirReader::maildir_path_flags($path) // return;
 218         return if $fl =~ /[DT]/; # no Drafts or Trash
 219         if ($path !~ $self->{mdre}) {
 220                 warn "unrecognized path: $path\n";
 221                 return;
 222         }
 223         my $inboxes = $self->{mdmap}->{$1};
 224         unless ($inboxes) {
 225                 warn "unmappable dir: $1\n";
 226                 return;
 227         }
 228         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 229         local $SIG{__WARN__} = sub {
 230                 my $pfx = ($_[0] // '') =~ /^([A-Z]: )/g ? $1 : '';
 231                 $warn_cb->($pfx, "path: $path\n", @_);
 232         };
 233         if (!ref($inboxes) && $inboxes eq 'watchspam') {
 234                 return _remove_spam($self, $path);
 235         }
 236         foreach my $ibx (@$inboxes) {
 237                 my $eml = eml_from_path($path) or next;
 238                 import_eml($self, $ibx, $eml);
 239         }
 240 }
 241
 242 sub quit_done ($) {
 243         my ($self) = @_;
 244         return unless $self->{quit};
 245
 246         # don't have reliable wakeups, keep signalling
 247         my $done = 1;
 248         for (qw(idle_pids poll_pids)) {
 249                 my $pids = $self->{$_} or next;
 250                 for (keys %$pids) {
 251                         $done = undef if kill('QUIT', $_);
 252                 }
 253         }
 254         $done;
 255 }
 256
 257 sub quit {
 258         my ($self) = @_;
 259         $self->{quit} = 1;
 260         %{$self->{opendirs}} = ();
 261         _done_for_now($self);
 262         quit_done($self);
 263         if (my $idle_mic = $self->{idle_mic}) {
 264                 eval { $idle_mic->done };
 265                 if ($@) {
 266                         warn "IDLE DONE error: $@\n";
 267                         eval { $idle_mic->disconnect };
 268                         warn "IDLE LOGOUT error: $@\n" if $@;
 269                 }
 270         }
 271 }
 272
 273 sub watch_fs_init ($) {
 274         my ($self) = @_;
 275         my $done = sub {
 276                 delete $self->{done_timer};
 277                 _done_for_now($self);
 278         };
 279         my $cb = sub { # called by PublicInbox::DirIdle::event_step
 280                 _try_path($self, $_[0]->fullname);
 281                 $self->{done_timer} //= PublicInbox::DS::requeue($done);
 282         };
 283         require PublicInbox::DirIdle;
 284         # inotify_create + EPOLL_CTL_ADD
 285         my $dir_idle = PublicInbox::DirIdle->new($cb);
 286         $dir_idle->add_watches([keys %{$self->{mdmap}}]);
 287 }
 288
 289 sub net_cb { # NetReader::(nntp|imap)_each callback
 290         my ($uri, $art, $kw, $eml, $self, $inboxes) = @_;
 291         return if grep(/\Adraft\z/, @$kw);
 292         local $self->{cur_uid} = $art; # IMAP UID or NNTP article
 293         if (ref($inboxes)) {
 294                 my @ibx = @$inboxes;
 295                 my $last = pop @ibx;
 296                 for my $ibx (@ibx) {
 297                         my $tmp = PublicInbox::Eml->new(\($eml->as_string));
 298                         import_eml($self, $ibx, $tmp);
 299                 }
 300                 import_eml($self, $last, $eml);
 301         } elsif ($inboxes eq 'watchspam') {
 302                 if ($uri->scheme =~ /\Aimaps?\z/ && !grep(/\Aseen\z/, @$kw)) {
 303                         return;
 304                 }
 305                 $self->{pi_cfg}->each_inbox(\&remove_eml_i,
 306                                 $self, $eml, "$uri #$art");
 307         } else {
 308                 die "BUG: destination unknown $inboxes";
 309         }
 310 }
 311
 312 sub imap_fetch_all ($$) {
 313         my ($self, $uri) = @_;
 314         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 315         $self->{incremental} = 1;
 316         $self->{on_commit} = [ \&_done_for_now, $self ];
 317         local $self->{cur_uid};
 318         local $SIG{__WARN__} = sub {
 319                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 320                 my $uid = $self->{cur_uid};
 321                 $warn_cb->("$pfx$uri", $uid ? ("UID:$uid") : (), "\n", @_);
 322         };
 323         PublicInbox::NetReader::imap_each($self, $uri, \&net_cb, $self,
 324                                         $self->{imap}->{$$uri});
 325 }
 326
 327 sub imap_idle_once ($$$$) {
 328         my ($self, $mic, $intvl, $uri) = @_;
 329         my $i = $intvl //= (29 * 60);
 330         my $end = now() + $intvl;
 331         warn "I: $uri idling for ${intvl}s\n";
 332         local $0 = "IDLE $0";
 333         unless ($mic->idle) {
 334                 return if $self->{quit};
 335                 return "E: IDLE failed on $uri: $!";
 336         }
 337         $self->{idle_mic} = $mic; # for ->quit
 338         my @res;
 339         until ($self->{quit} || !$mic->IsConnected ||
 340                         grep(/^\* [0-9]+ EXISTS/, @res) || $i <= 0) {
 341                 @res = $mic->idle_data($i);
 342                 $i = $end - now();
 343         }
 344         delete $self->{idle_mic};
 345         unless ($self->{quit}) {
 346                 $mic->IsConnected or return "E: IDLE disconnected on $uri";
 347                 $mic->done or return "E: IDLE DONE failed on $uri: $!";
 348         }
 349         undef;
 350 }
 351
 352 # idles on a single URI
 353 sub watch_imap_idle_1 ($$$) {
 354         my ($self, $uri, $intvl) = @_;
 355         my $sec = uri_section($uri);
 356         my $mic_arg = $self->{net_arg}->{$sec} or
 357                         die "BUG: no Mail::IMAPClient->new arg for $sec";
 358         my $mic;
 359         local $0 = $uri->mailbox." $sec";
 360         until ($self->{quit}) {
 361                 $mic //= PublicInbox::NetReader::mic_new(
 362                                         $self, $mic_arg, $sec, $uri);
 363                 my $err;
 364                 if ($mic && $mic->IsConnected) {
 365                         local $self->{mics_cached}->{$sec} = $mic;
 366                         my $m = imap_fetch_all($self, $uri);
 367                         $m == $mic or die "BUG: wrong mic";
 368                         $mic->IsConnected and
 369                                 $err = imap_idle_once($self, $mic, $intvl, $uri)
 370                 } else {
 371                         $err = "E: not connected: $!";
 372                 }
 373                 if ($err && !$self->{quit}) {
 374                         warn $err, "\n";
 375                         $mic = undef;
 376                         sleep 60 unless $self->{quit};
 377                 }
 378         }
 379 }
 380
 381 sub watch_atfork_child ($) {
 382         my ($self) = @_;
 383         delete $self->{idle_pids};
 384         delete $self->{poll_pids};
 385         delete $self->{opendirs};
 386         PublicInbox::DS->Reset;
 387         my $sig = delete $self->{sig};
 388         $sig->{CHLD} = 'DEFAULT';
 389         @SIG{keys %$sig} = values %$sig;
 390         PublicInbox::DS::sig_setmask($self->{oldset});
 391 }
 392
 393 sub watch_atfork_parent ($) {
 394         my ($self) = @_;
 395         _done_for_now($self);
 396         PublicInbox::DS::block_signals();
 397 }
 398
 399 sub imap_idle_requeue { # DS::add_timer callback
 400         my ($self, $uri_intvl) = @_;
 401         return if $self->{quit};
 402         push @{$self->{idle_todo}}, $uri_intvl;
 403         event_step($self);
 404 }
 405
 406 sub imap_idle_reap { # PublicInbox::DS::dwaitpid callback
 407         my ($self, $pid) = @_;
 408         my $uri_intvl = delete $self->{idle_pids}->{$pid} or
 409                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 410
 411         my ($uri, $intvl) = @$uri_intvl;
 412         return if $self->{quit};
 413         warn "W: PID=$pid on $uri died: \$?=$?\n" if $?;
 414         add_timer(60, \&imap_idle_requeue, $self, $uri_intvl);
 415 }
 416
 417 sub reap { # callback for EOFpipe
 418         my ($pid, $cb, $self) = @{$_[0]};
 419         my $ret = waitpid($pid, 0);
 420         if ($ret == $pid) {
 421                 $cb->($self, $pid); # poll_fetch_reap || imap_idle_reap
 422         } else {
 423                 warn "W: waitpid($pid) => ", $ret // "($!)", "\n";
 424         }
 425 }
 426
 427 sub imap_idle_fork ($$) {
 428         my ($self, $uri_intvl) = @_;
 429         my ($uri, $intvl) = @$uri_intvl;
 430         pipe(my ($r, $w)) or die "pipe: $!";
 431         my $seed = rand(0xffffffff);
 432         my $pid = fork // die "fork: $!";
 433         if ($pid == 0) {
 434                 srand($seed);
 435                 eval { Net::SSLeay::randomize() };
 436                 close $r;
 437                 watch_atfork_child($self);
 438                 watch_imap_idle_1($self, $uri, $intvl);
 439                 close $w;
 440                 _exit(0);
 441         }
 442         $self->{idle_pids}->{$pid} = $uri_intvl;
 443         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&imap_idle_reap, $self]);
 444 }
 445
 446 sub event_step {
 447         my ($self) = @_;
 448         return if $self->{quit};
 449         my $idle_todo = $self->{idle_todo};
 450         if ($idle_todo && @$idle_todo) {
 451                 my $oldset = watch_atfork_parent($self);
 452                 eval {
 453                         while (my $uri_intvl = shift(@$idle_todo)) {
 454                                 imap_idle_fork($self, $uri_intvl);
 455                         }
 456                 };
 457                 PublicInbox::DS::sig_setmask($oldset);
 458                 die $@ if $@;
 459         }
 460         fs_scan_step($self) if $self->{mdre};
 461 }
 462
 463 sub watch_imap_fetch_all ($$) {
 464         my ($self, $uris) = @_;
 465         for my $uri (@$uris) {
 466                 imap_fetch_all($self, $uri);
 467                 last if $self->{quit};
 468         }
 469 }
 470
 471 sub watch_nntp_fetch_all ($$) {
 472         my ($self, $uris) = @_;
 473         $self->{incremental} = 1;
 474         $self->{on_commit} = [ \&_done_for_now, $self ];
 475         my $warn_cb = $SIG{__WARN__} || \&CORE::warn;
 476         local $self->{cur_uid};
 477         my $uri = '';
 478         local $SIG{__WARN__} = sub {
 479                 my $pfx = ($_[0] // '') =~ /^([A-Z]: |# )/g ? $1 : '';
 480                 my $art = $self->{cur_uid};
 481                 $warn_cb->("$pfx$uri", $art ? ("ARTICLE $art") : (), "\n", @_);
 482         };
 483         for $uri (@$uris) {
 484                 PublicInbox::NetReader::nntp_each($self, $uri, \&net_cb, $self,
 485                                         $self->{nntp}->{$$uri});
 486                 last if $self->{quit};
 487         }
 488 }
 489
 490 sub poll_fetch_fork { # DS::add_timer callback
 491         my ($self, $intvl, $uris) = @_;
 492         return if $self->{quit};
 493         pipe(my ($r, $w)) or die "pipe: $!";
 494         my $oldset = watch_atfork_parent($self);
 495         my $seed = rand(0xffffffff);
 496         my $pid = fork;
 497         if (defined($pid) && $pid == 0) {
 498                 srand($seed);
 499                 eval { Net::SSLeay::randomize() };
 500                 close $r;
 501                 watch_atfork_child($self);
 502                 if ($uris->[0]->scheme =~ m!\Aimaps?!i) {
 503                         watch_imap_fetch_all($self, $uris);
 504                 } else {
 505                         watch_nntp_fetch_all($self, $uris);
 506                 }
 507                 close $w;
 508                 _exit(0);
 509         }
 510         PublicInbox::DS::sig_setmask($oldset);
 511         die "fork: $!"  unless defined $pid;
 512         $self->{poll_pids}->{$pid} = [ $intvl, $uris ];
 513         PublicInbox::EOFpipe->new($r, \&reap, [$pid, \&poll_fetch_reap, $self]);
 514 }
 515
 516 sub poll_fetch_reap {
 517         my ($self, $pid) = @_;
 518         my $intvl_uris = delete $self->{poll_pids}->{$pid} or
 519                 die "BUG: PID=$pid (unknown) reaped: \$?=$?\n";
 520         return if $self->{quit};
 521         my ($intvl, $uris) = @$intvl_uris;
 522         if ($?) {
 523                 warn "W: PID=$pid died: \$?=$?\n", map { "$_\n" } @$uris;
 524         }
 525         warn("I: will check $_ in ${intvl}s\n") for @$uris;
 526         add_timer($intvl, \&poll_fetch_fork, $self, $intvl, $uris);
 527 }
 528
 529 sub watch_imap_init ($$) {
 530         my ($self, $poll) = @_;
 531         my $mics = PublicInbox::NetReader::imap_common_init($self);
 532         my $idle = []; # [ [ uri1, intvl1 ], [uri2, intvl2] ]
 533         for my $uri (@{$self->{imap_order}}) {
 534                 my $sec = uri_section($uri);
 535                 my $mic = $mics->{$sec};
 536                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 537                 if ($mic->has_capability('IDLE') && !$intvl) {
 538                         $intvl = $self->{cfg_opt}->{$sec}->{idleInterval};
 539                         push @$idle, [ $uri, $intvl // () ];
 540                 } else {
 541                         push @{$poll->{$intvl || 120}}, $uri;
 542                 }
 543         }
 544         if (scalar @$idle) {
 545                 $self->{idle_todo} = $idle;
 546                 PublicInbox::DS::requeue($self); # ->event_step to fork
 547         }
 548 }
 549
 550 sub watch_nntp_init ($$) {
 551         my ($self, $poll) = @_;
 552         PublicInbox::NetReader::nntp_common_init($self);
 553         for my $uri (@{$self->{nntp_order}}) {
 554                 my $sec = uri_section($uri);
 555                 my $intvl = $self->{cfg_opt}->{$sec}->{pollInterval};
 556                 push @{$poll->{$intvl || 120}}, $uri;
 557         }
 558 }
 559
 560 sub watch { # main entry point
 561         my ($self, $sig, $oldset) = @_;
 562         $self->{oldset} = $oldset;
 563         $self->{sig} = $sig;
 564         my $poll = {}; # intvl_seconds => [ uri1, uri2 ]
 565         watch_imap_init($self, $poll) if $self->{imap};
 566         watch_nntp_init($self, $poll) if $self->{nntp};
 567         while (my ($intvl, $uris) = each %$poll) {
 568                 # poll all URIs for a given interval sequentially
 569                 add_timer(0, \&poll_fetch_fork, $self, $intvl, $uris);
 570         }
 571         watch_fs_init($self) if $self->{mdre};
 572         PublicInbox::DS->SetPostLoopCallback(sub { !$self->quit_done });
 573         PublicInbox::DS::event_loop($sig, $oldset); # calls ->event_step
 574         _done_for_now($self);
 575 }
 576
 577 sub trigger_scan {
 578         my ($self, $op) = @_;
 579         push @{$self->{ops}}, $op;
 580         PublicInbox::DS::requeue($self);
 581 }
 582
 583 sub fs_scan_step {
 584         my ($self) = @_;
 585         return if $self->{quit};
 586         my $op = shift @{$self->{ops}};
 587         local $PublicInbox::DS::in_loop = 0; # waitpid() synchronously
 588
 589         # continue existing scan
 590         my $opendirs = $self->{opendirs};
 591         my @dirnames = keys %$opendirs;
 592         foreach my $dir (@dirnames) {
 593                 my $dh = delete $opendirs->{$dir};
 594                 my $n = $self->{max_batch};
 595                 while (my $fn = readdir($dh)) {
 596                         _try_path($self, "$dir/$fn");
 597                         last if --$n < 0;
 598                 }
 599                 $opendirs->{$dir} = $dh if $n < 0;
 600         }
 601         if ($op && $op eq 'full') {
 602                 foreach my $dir (keys %{$self->{mdmap}}) {
 603                         next if $opendirs->{$dir}; # already in progress
 604                         my $ok = opendir(my $dh, $dir);
 605                         unless ($ok) {
 606                                 warn "failed to open $dir: $!\n";
 607                                 next;
 608                         }
 609                         my $n = $self->{max_batch};
 610                         while (my $fn = readdir($dh)) {
 611                                 _try_path($self, "$dir/$fn");
 612                                 last if --$n < 0;
 613                         }
 614                         $opendirs->{$dir} = $dh if $n < 0;
 615                 }
 616         }
 617         _done_for_now($self);
 618         # do we have more work to do?
 619         PublicInbox::DS::requeue($self) if keys %$opendirs;
 620 }
 621
 622 sub scan {
 623         my ($self, $op) = @_;
 624         push @{$self->{ops}}, $op;
 625         fs_scan_step($self);
 626 }
 627
 628 sub _importer_for {
 629         my ($self, $ibx) = @_;
 630         my $importers = $self->{importers};
 631         my $im = $importers->{"$ibx"} ||= $ibx->importer(0);
 632         if (scalar(keys(%$importers)) > 2) {
 633                 delete $importers->{"$ibx"};
 634                 _done_for_now($self);
 635         }
 636
 637         $importers->{"$ibx"} = $im;
 638 }
 639
 640 # XXX consider sharing with V2Writable, this only requires read-only access
 641 sub content_exists ($$) {
 642         my ($ibx, $eml) = @_;
 643         my $over = $ibx->over or return;
 644         my $mids = mids($eml);
 645         my $chash = content_hash($eml);
 646         my ($id, $prev);
 647         for my $mid (@$mids) {
 648                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 649                         my $cmp = $ibx->smsg_eml($smsg) or return;
 650                         return 1 if $chash eq content_hash($cmp);
 651                 }
 652         }
 653         undef;
 654 }
 655
 656 sub _spamcheck_cb {
 657         my ($sc) = @_;
 658         sub { # this gets called by (V2Writable||Import)->add
 659                 my ($mime, $ibx) = @_;
 660                 return if content_exists($ibx, $mime);
 661                 my $tmp = '';
 662                 if ($sc->spamcheck($mime, \$tmp)) {
 663                         return PublicInbox::Eml->new(\$tmp);
 664                 }
 665                 warn $mime->header('Message-ID')." failed spam check\n";
 666                 undef;
 667         }
 668 }
 669
 670 sub is_maildir {
 671         $_[0] =~ s!\Amaildir:!! or return;
 672         $_[0] =~ tr!/!/!s;
 673         $_[0] =~ s!/\z!!;
 674         $_[0];
 675 }
 676
 677 sub is_watchspam {
 678         my ($cur, $ws, $ibx) = @_;
 679         if ($ws && !ref($ws) && $ws eq 'watchspam') {
 680                 warn <<EOF;
 681 E: $cur is a spam folder and cannot be used for `$ibx->{name}' input
 682 EOF
 683                 return 1;
 684         }
 685         undef;
 686 }
 687
 688 sub folder_select { 'select' } # for PublicInbox::NetReader
 689
 690 1;